Hallo an alle,wer kann mir dabei helfen das wenn ich auf einen Button in meiner GUI drücke dieser Befehl ausgeführt wird.
Ist von einer Batch Datei.
set PGPASSWORD=12345
"C:\Program Files\PostgreSQL\9.5\bin\pg_dump.exe" --host localhost --port 5432 --username "postgres" --no-password --format custom --blobs --verbose --file c:\asv\sicherung\asv_%date:~6,4%_%date:~3,2%_%date:~0,2%.backup "asv"
set PGPASSWORD=null
Was muss ich da machen ????? Wer kann mir dabei helfen ????
DANKKKKKKE 
Pack den Code in eine .bat Datei und führe sie mit AutoIt aus. 
Ggf. kann man die au3 Exe noch mit der .bat Datei packen, damit
am Ende nur noch die Autoit Exe zu sehen ist.
schau dir mal ShellExecute() an. Damit erreichst du genau das.
set PGPASSWORD=12345
Das macht allerdings keinen Sinn, wenn du die pg_dump.exe mit dem Parameter --no-password aufrufst... ich tippe mal darauf, dass hier --password 12345 der richtige Parameter ist.
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#Region ;************ Includes ************
#Include <EditConstants.au3>
#Include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WinAPIMisc.au3>
#EndRegion ;************ Includes ************
;-- TIME_STAMP 2016-08-05 06:25:25
Opt('MustDeclareVars', 1)
#Region - ;************ GUI Create **********
GUICreate('Backup', 1280, 360)
Local $idButton_DirC = GUICtrlCreateButton('Inhalt von Laufwerk C: anzeigen', 10, 320, 420, 32)
Local $idButton_Backup = GUICtrlCreateButton('Backup starten', 430, 320, 420, 32)
Local $idButton_Exit = GUICtrlCreateButton('Programm beenden',850, 320, 420, 32)
Local $idEdit_Log = GUICtrlCreateEdit('', 10, 10, 1260, 300, BitOR($GUI_SS_DEFAULT_EDIT, $ES_READONLY))
GUISetState()
_WriteLog('Backup Programm Start: ', _NowDate() & ' - ' & _NowTime())
#EndRegion ;************ GUI Create **********
#Region - ;************ GUI SelectLoop ******
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $idButton_Exit
Exit
Case $idButton_DirC
_DirC()
Case $idButton_Backup
_Backup()
EndSwitch
WEnd
#EndRegion ;************ GUI SelectLoop ******
Exit
Func _DirC()
_WriteLog('Inhalt von Laufwerk ', 'C: anzeigen...')
Local $iPID = Run(@ComSpec & " /c " & "Dir C:", "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
_WriteOutputToLog($iPID)
EndFunc
Func _Backup()
Local $sPassword = 12345
Local $sPG_DUMP = '"C:\Program Files\PostgreSQL\9.5\bin\pg_dump.exe" '
Local $sFileName = "c:\asv\sicherung\asv_" & StringReplace(_NowCalcDate(), '/', '_') & ".backup.asv"
Local $sCMD = $sPG_DUMP & '--host localhost --port 5432 --username postgres --password ' & $sPassword & ' --format custom --blobs --verbose --file "' & $sFileName & '"'
_WriteLog('Backup Befehl: ', $sCMD)
If FileExists($sPG_DUMP) = 0 Then
_WriteLog('Fatal Error: ', 'Das Program ' & $sPG_DUMP & 'konnte nicht gefunden werden!')
Return SetError(1, 0, $sPG_DUMP)
EndIf
Local $iPID = Run($sCMD, '', @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
_WriteLog('PG_DUMP.EXE wurde gestartet - ', '$iPID = ' & $iPID)
_WriteOutputToLog($iPID)
EndFunc
Func _WriteOutputToLog($iPID)
Local $sOutput = ""
While 1
$sOutput = StdoutRead($iPID)
If @error Then ; Exit the loop if the process closes or StdoutRead returns an error.
ExitLoop
EndIf
_WriteLog('Stdout Read: ', $sOutput)
WEnd
While 1
$sOutput = StderrRead($iPID)
If @error Then ; Exit the loop if the process closes or StderrRead returns an error.
ExitLoop
EndIf
_WriteLog('Stderr Read: ', $sOutput)
WEnd
EndFunc
Func _WriteLog($sPrefix, $sText)
If $sText = '' Then Return
GUICtrlSetData($idEdit_Log, $sPrefix & _WinAPI_OemToChar($sText) & @CRLF, 1)
EndFunc