GUICtrlCreateGraphic soll auf Rechtsklick die Farbe ändern (gelöst)

GUIGetCursorInfo ist das was du brauchst:

#include <Misc.au3>
#include <GUIConstantsEx.au3>


Opt("GUIOnEventMode", 1)


;Variablen
$fenster = 0


$rhorizontal1 = 0
$rhorizontal2 = 0
$rhorizontal3 = 0


$rvertikal1 = 0
$rvertikal2 = 0
$rvertikal3 = 0


;Anklickbare Felder von links nach rechts, von oben nach unten
$f1 = 0
$f2 = 0
$f3 = 0
$f4 = 0






$fenster  = GUICreate ("GUI 4x4", 140, 140)
GUISetOnEvent($GUI_EVENT_SECONDARYDOWN, "_RightClick")
GUISetBkColor (0xFFFFFF)
GUISetOnEvent(-3, "_Exit")


   $rvertikal1 = GUICtrlCreateGraphic (0, 0, 1, 140)
	GUICtrlSetBkColor ($rvertikal1, 0xA0A0A0)
   $rvertikal2 = GUICtrlCreateGraphic (70, 0, 1, 140)
	GUICtrlSetBkColor ($rvertikal2, 0xA0A0A0)
   $rvertikal3 = GUICtrlCreateGraphic (140, 0, 1, 140)
	GUICtrlSetBkColor ($rvertikal3, 0xA0A0A0)


   $rhorizontal1 = GUICtrlCreateGraphic (0, 0, 140, 1)
	GUICtrlSetBkColor ($rhorizontal1, 0xA0A0A0)
   $rhorizontal2 = GUICtrlCreateGraphic (0, 70, 140, 1)
	GUICtrlSetBkColor ($rhorizontal2, 0xA0A0A0)
   $rhorizontal3 = GUICtrlCreateGraphic (0, 140, 140, 1)
	GUICtrlSetBkColor ($rhorizontal3, 0xA0A0A0)


   $f1 = GUICtrlCreateGraphic (1, 1, 69, 69)
	GUICtrlSetOnEvent(-1, "ueberpruefung")
   $f2 = GUICtrlCreateGraphic (71, 1, 69, 69)
	GUICtrlSetOnEvent(-1, "ueberpruefung")
   $f3 = GUICtrlCreateGraphic (1, 71, 69, 69)
	GUICtrlSetOnEvent(-1, "ueberpruefung")
   $f4 = GUICtrlCreateGraphic (71, 71, 69, 69)
	GUICtrlSetOnEvent(-1, "ueberpruefung")


GUISetState (@SW_SHOW)


While 1
    Sleep (10)
 Wend


Func _RightClick()
	$curInfo = GUIGetCursorInfo($fenster)
	Switch $curInfo[4]
		Case $f1
			GUICtrlSetBkColor ($f1, 0x000000)
		Case $f2
			GUICtrlSetBkColor ($f2, 0x000000)
		Case $f3
			GUICtrlSetBkColor ($f3, 0x000000)
		Case $f4
			GUICtrlSetBkColor ($f4, 0x000000)
	EndSwitch
EndFunc


Func ueberpruefung ()
    Select
    Case @GUI_CtrlId = $f1
	   GUICtrlSetBkColor ($f1, 0xFF0000)
    Case @GUI_CtrlId = $f2
	   GUICtrlSetBkColor ($f2, 0xFF0000)
    Case @GUI_CtrlId = $f3
	   GUICtrlSetBkColor ($f3, 0xFF0000)
	Case @GUI_CtrlId = $f4
	   GUICtrlSetBkColor ($f4, 0xFF0000)
	EndSelect
 EndFunc


 Func _Exit ()
	Exit
 EndFunc

Eieiei...

Zunächst mal was zu dem Skript an sich und zu deinem Stil. Es ist eigentlich Schwachsinn, vorher alle Variablen mit 0 zu initialisieren. Das erledigt man - wenn überhaupt - mit einer Deklaration a la Global $fenster. Du kannst es aber auch einfach weglassen, AutoIt stört das nicht. Und es empfiehlt sich, englische Bezeichner zu verwenden. Das liest sich wesentlich schöner, weil der Code rundrum ja auch englisch ist. Weiterhin... Bei vier Elementen der gleichen Art spielt das noch keine so große Rolle, aber zum Speichern der Control-IDs kannst du auch gut ein Array verwenden.

Inhaltlich kannst du dir die ersten sechs Graphic-Controls auch sparen. Leg einfach ein großes dahinter und stell es auf $GUI_DISABLE. Das klappt genau so.

So, nun zum eigentlichen Thema. Du kannst mittels GUISetOnEvent die Events $GUI_EVENT_PRIMARYDOWN und $GUI_EVENT_SECONDARYDOWN abfangen. Das erste ist ein Linksklick, das zweite ein Rechtsklick. Mittels GUIGetCursorInfo() holst du dir dann das Control-Handle. Ich habe alle hier angesprochenen Änderungen mal auf dein Skript übertragen.

Hier gilt es aber zu beachten, dass alles dem Beispiel angepasst worden ist. Falls die GUI noch mehr Elemente enthält, muss in den Klick-Funktionen noch eine Abfrage nach der Control-ID erfolgen. Habe ich mir hier jetzt - weil es möglich ist und das Skript signifikant verkürzt - gespart.

#include <GUIConstants.au3>

Opt("GUIOnEventMode", True)

Global $hWnd
Global $cTiles[4] ;Anklickbare Felder (L->R, O->U)

$hWnd = GUICreate("GUI 4x4", 140, 140)
GUISetOnEvent($GUI_EVENT_CLOSE, Close)
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, LeftClick)
GUISetOnEvent($GUI_EVENT_SECONDARYDOWN, RightClick)
$cBackground = GUICtrlCreateGraphic(0, 0, 140, 140)
GUICtrlSetBkColor($cBackground, 0xA0A0A0)
GUICtrlSetState($cBackground, $GUI_DISABLE)
$cTiles[0] = GUICtrlCreateGraphic(1, 1, 69, 69)
$cTiles[1] = GUICtrlCreateGraphic(71, 1, 69, 69)
$cTiles[2] = GUICtrlCreateGraphic(1, 71, 69, 69)
$cTiles[3] = GUICtrlCreateGraphic(71, 71, 69, 69)
For $cTile In $cTiles
GUICtrlSetBkColor($cTile, 0xFFFFFF)
Next
GUISetState()

While True
Sleep(42)
WEnd

Func Close()
Exit
EndFunc

Func LeftClick()
$cClicked = GUIGetCursorInfo()[4]
GUICtrlSetBkColor($cClicked, 0xFF0000)
EndFunc

Func RightClick()
$cClicked = GUIGetCursorInfo()[4]
GUICtrlSetBkColor($cClicked, 0x00FF00)
EndFunc

@chesstiger Bei deinem Script vernachlässigst du aber die Tatsache, dass nur die 4 Tiles angemalt werden sollen.
Wenn man auf den Hintergrund klickt wird er auch eingefärbt also musst du noch GUICetCursorInfo()[4] switchen oder mit einer For-Schleife noch die Tiles abfragen.

Das stimmt. Ist mir auch eben aufgefallen. $GUI_DISABLE wird ja durch GUIGetCursorInfo erfolgreich umgangen.

Aber wer braucht schon ein Switch oder For? Wir sind doch kreativ und wissen, wie AutoIt Control-IDs vergibt.

#include <GUIConstants.au3>

Opt("GUIOnEventMode", True)

Global $hWnd
Global $cTiles[4] ;Anklickbare Felder (L->R, O->U)

$hWnd = GUICreate("GUI 4x4", 140, 140)
GUISetOnEvent($GUI_EVENT_CLOSE, Close)
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, LeftClick)
GUISetOnEvent($GUI_EVENT_SECONDARYDOWN, RightClick)
$cBackground = GUICtrlCreateGraphic(0, 0, 140, 140)
GUICtrlSetBkColor($cBackground, 0xA0A0A0)
GUICtrlSetState($cBackground, $GUI_DISABLE)
$cTiles[0] = GUICtrlCreateGraphic(1, 1, 69, 69)
$cTiles[1] = GUICtrlCreateGraphic(71, 1, 69, 69)
$cTiles[2] = GUICtrlCreateGraphic(1, 71, 69, 69)
$cTiles[3] = GUICtrlCreateGraphic(71, 71, 69, 69)
For $cTile In $cTiles
GUICtrlSetBkColor($cTile, 0xFFFFFF)
Next
GUISetState()

While True
Sleep(42)
WEnd

Func Close()
Exit
EndFunc

Func LeftClick()
$cClicked = GUIGetCursorInfo()[4]
If ($cTiles[0] > $cClicked) Or ($cClicked > $cTiles[3]) Then Return
GUICtrlSetBkColor($cClicked, 0xFF0000)
EndFunc

Func RightClick()
$cClicked = GUIGetCursorInfo()[4]
If ($cTiles[0] > $cClicked) Or ($cClicked > $cTiles[3]) Then Return
GUICtrlSetBkColor($cClicked, 0x00FF00)
EndFunc

Zitat von chesstiger

Aber wer braucht schon ein Switch oder For? Wir sind doch kreativ und wissen, wie AutoIt Control-IDs vergibt.

Das ist ja mal richtig fahrlässig programmiert

Ich glaube man blickt da in ein paar Monaten besser durch wenn man das lieber loopt aber jeder solls machen wie er es am besten versteht,
und bei dem Coding-Stil vom TE ist das glaube ich eher verwirrend.

Und um das ganze Felxibel zu halten machen wir es doch einfach so:

#include <GUIConstants.au3>


Opt("GUIOnEventMode", True)
Global $hWnd
Global $iWidth=800,$iHeight=600,$iFieldsWidthCount=4,$iFieldsHeightCount=4 ;Hier eifnach die Größe und die Anzahl Felder ändern -> sehen was passiert :)
Global $cTiles[$iFieldsWidthCount*$iFieldsHeightCount] ;Anklickbare Felder (L->R, O->U)


$hWnd = GUICreate("GUI "&$iFieldsWidthCount&"x"&$iFieldsHeightCount, $iWidth, $iHeight)
GUISetOnEvent($GUI_EVENT_CLOSE, Close)
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, LeftClick)
GUISetOnEvent($GUI_EVENT_SECONDARYDOWN, RightClick)
$cBackground = GUICtrlCreateGraphic(0, 0, $iWidth,$iHeight)
GUICtrlSetBkColor($cBackground, 0xA0A0A0)
GUICtrlSetState($cBackground, $GUI_DISABLE)
local $iFieldsWidth=($iWidth-$iFieldsWidthCount-1)/$iFieldsWidthCount,$iFieldsHeight=($iHeight-$iFieldsHeightCount-1)/$iFieldsHeightCount
for $i=0 to $iFieldsWidthCount-1 step 1
	for $j=0 to $iFieldsHeightCount-1 step 1
		$cTiles[$i*$iFieldsHeightCount+$j] = GUICtrlCreateGraphic(1+$i*$iFieldsWidth+$i,1+$j*$iFieldsHeight+$j, $iFieldsWidth, $iFieldsHeight)
		GUICtrlSetBkColor(-1, 0xFFFFFF)
	next
next
GUISetState()


While sleep(10)
WEnd


Func Close()
	Exit
EndFunc


Func LeftClick()
	$cClicked = GUIGetCursorInfo()[4]
	If ($cTiles[0] > $cClicked) Or ($cClicked > $cTiles[UBound($cTiles)-1]) Then Return
	GUICtrlSetBkColor($cClicked, 0xFF0000)
EndFunc


Func RightClick()
	$cClicked = GUIGetCursorInfo()[4]
	If ($cTiles[0] > $cClicked) Or ($cClicked > $cTiles[UBound($cTiles)-1]) Then Return
	GUICtrlSetBkColor($cClicked, 0x00FF00)
EndFunc

So kann man noch nen bisschen mit den Parametern spielen

MfG Kanashius

@alpines
Kann man jetzt sehen, wie man will. Auf die aufsteigende Vergabe der Control-IDs kann man sich eigentlich verlassen, das ist immer so. Zumindest bei einfachen Controls wie Graphic oder Button. Und dann liest man einfach: "Wenn die Control-ID nicht zwischen $cTiles[0] und $cTiles[1] liegt, dann return"
Persönlich finde ich das sogar besser lesbar als eine For-Schleife.

Aber, wie du schon sagtest, jedem das seine. Ob das für Anfänger angemessen ist, kann man wohl auch mit recht bezweifeln.

Aber immerhin hast du nicht damit gerechnet...

Super, ich hab mal den grünen Haken für [gelöst] gesetzt (1. Beitrag bearbeiten), wenn du weitere Fragen hast kannst du sie gerne hier stellen oder einen neuen Thread aufmachen

Du fängst mit Index 0 an und gehst bis zum letzten Eintrag - 1.

Zitat von Jefta

Also quasi einfach nur $iFieldsWidthCount -1?
(Beispiel: $iFieldsWidthCount = 400 wird zu $iFieldsWidthCount = 399)

Und wieso muss das so sein?
(Schuldigung wenn es nervt... )

Sozusagen. Computer zählen generell mit Index 0 statt wir mit Index 1, wenn du Controls platzieren willst dann ist der oberste linke Pixel nicht 1/1 sondern 0/0.
Ist das Fenster 300/300 breit so ist der unterste rechte Pixel 299/299.