Custom GUI, Image Buttons, Overlapping

Stoani

### UPDATE SEKTION ###

Link: http://terminal.rkgm.at/index.html

#CLOSED

Ältere Versionen
Datenfunk.zip Version 0.1 [Dropbox]
Datenfunk.zip Version 0.2 [Dropbox]
Datenfunk.zip Version 0.3 [Dropbox]
Datenfunk.zip Version 0.4 [Dropbox]

Neueste Version
Datenfunk.zip Version 0.5 [Dropbox]

Zur Veranschaulichung hier ein Bild des Originals:
[Blockierte Grafik: https://i.imgsafe.org/8e8214e837.jpg]

GUI von Version 0.4
[Blockierte Grafik: https://i.imgsafe.org/8eb4dc42ca.png]

Source passend zu Version 0.4

AutoIt: Version 0.5

; VIELEN DANK AN (www.autoit.de):
; Oscar | alpines | Kanashius | UEZ und ein bisschen Großvater!






#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>


Global Const $SC_DRAGMOVE = 0xF012
Global $sGfxFolder = (@ScriptDir & "\gfx\")
Global $hMainGui = _GUICreate_Transparent($sGfxFolder & "terminal.png")
Global $aWinPos = WinGetPos($hMainGui)


Global $aNaviFiles[22]
$aNaviFiles[0] = "top_0"
$aNaviFiles[1] = "top_1"


$aNaviFiles[2] = "bottom_0"
$aNaviFiles[3] = "bottom_1"


$aNaviFiles[4] = "left_0"
$aNaviFiles[5] = "left_1"


$aNaviFiles[6] = "right_0"
$aNaviFiles[7] = "right_1"


$aNaviFiles[8] = "button_0"
$aNaviFiles[9] = "button_1"


$aNaviFiles[10] = "exit_0"
$aNaviFiles[11] = "exit_1"


$aNaviFiles[12] = "new_0"
$aNaviFiles[13] = "new_1"


$aNaviFiles[14] = "status_6_0"
$aNaviFiles[15] = "status_6_1"


$aNaviFiles[16] = "status_14_0"
$aNaviFiles[17] = "status_14_1"


$aNaviFiles[18] = "status_0_0"
$aNaviFiles[19] = "status_0_1"


$aNaviFiles[20] = "status_9_0"
$aNaviFiles[21] = "status_9_1"




;################## Koordinaten #####################
Global $aNaviCoord[22][2]


;Top
$aNaviCoord[0][0] = 811
$aNaviCoord[0][1] = 324
$aNaviCoord[1][0] = 811
$aNaviCoord[1][1] = 324


;Bottom
$aNaviCoord[2][0] = 811
$aNaviCoord[2][1] = 417
$aNaviCoord[3][0] = 811
$aNaviCoord[3][1] = 417


;Left
$aNaviCoord[4][0] = 790
$aNaviCoord[4][1] = 345
$aNaviCoord[5][0] = 790
$aNaviCoord[5][1] = 345


;Right
$aNaviCoord[6][0] = 883
$aNaviCoord[6][1] = 345
$aNaviCoord[7][0] = 883
$aNaviCoord[7][1] = 345


;Button
$aNaviCoord[8][0] = 828
$aNaviCoord[8][1] = 362
$aNaviCoord[9][0] = 828
$aNaviCoord[9][1] = 362


;Exit
$aNaviCoord[10][0] = 828
$aNaviCoord[10][1] = -50
$aNaviCoord[11][0] = 828
$aNaviCoord[11][1] = -50


;Neuer Auftrag
$aNaviCoord[12][0] = 655
$aNaviCoord[12][1] = -50
$aNaviCoord[13][0] = 655
$aNaviCoord[13][1] = -50


;Status 6
$aNaviCoord[14][0] = 572
$aNaviCoord[14][1] = 46
$aNaviCoord[15][0] = 572
$aNaviCoord[15][1] = 46


;Status 14
$aNaviCoord[16][0] = 572
$aNaviCoord[16][1] = 154
$aNaviCoord[17][0] = 572
$aNaviCoord[17][1] = 154


;Status 0
$aNaviCoord[18][0] = 572
$aNaviCoord[18][1] = 262
$aNaviCoord[19][0] = 572
$aNaviCoord[19][1] = 262


;Status 9
$aNaviCoord[20][0] = 572
$aNaviCoord[20][1] = 370
$aNaviCoord[21][0] = 572
$aNaviCoord[21][1] = 370


Global $iNaviCount = UBound($aNaviFiles)
Global $ahNavi[$iNaviCount]


For $i = 0 To $iNaviCount - 1
	$ahNavi[$i] = _GUICreate_Transparent($sGfxFolder & $aNaviFiles[$i] & ".png", -1, -1, 255, $WS_EX_LAYERED + $WS_EX_TOPMOST + $WS_EX_MDICHILD, $hMainGui)
	WinMove($ahNavi[$i], "", $aWinPos[0] + $aNaviCoord[$i][0], $aWinPos[1] + $aNaviCoord[$i][1])
	GUISetCursor(0, -1, $ahNavi[$i])
Next
For $i = 0 To $iNaviCount - 1 Step 2
	GUISetState(@SW_SHOW, $ahNavi[$i])
Next
GUISetState(@SW_SHOW, $hMainGui)
GUIRegisterMsg($WM_LBUTTONDOWN, "_WM_LBUTTONDOWN")
Global $g_tStruct = DllStructCreate($tagPOINT)
Global $aMsg, $iOld = -1, $hHover
While True
	$aMsg = GUIGetMsg(1)
	Switch $aMsg[0]
		Case $GUI_EVENT_CLOSE
			Exit
		Case $GUI_EVENT_MOUSEMOVE
			DllStructSetData($g_tStruct, "x", MouseGetPos(0))
			DllStructSetData($g_tStruct, "y", MouseGetPos(1))
			$hHover = _WinAPI_WindowFromPoint($g_tStruct)
			If $hHover = $hMainGui Then
				If $iOld > -1 Then GUISetState(@SW_SHOW, $ahNavi[$iOld])
				$iOld = -1
			EndIf
			For $i = 0 To 20 Step 2
				If $hHover = $ahNavi[$i] Then
					GUISetState(@SW_HIDE, $ahNavi[$i])
					GUISetState(@SW_SHOW, $ahNavi[$i + 1])
					If $iOld > -1 Then GUISetState(@SW_SHOW, $ahNavi[$iOld])
					$iOld = $i
					ExitLoop
				EndIf
			Next
	EndSwitch
WEnd


Func _WM_LBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
	If $iOld > -1 Then
		Local $sNavi = StringTrimRight($aNaviFiles[$iOld], 2)
		ConsoleWrite($sNavi & @CR)






		If $sNavi = "exit" Then
			_Exit()
		ElseIf $sNavi = "new" Then
			_New()
		ElseIf $sNavi = "top" Then
			_Top()
		ElseIf $sNavi = "bottom" Then
			_Bottom()
		ElseIf $sNavi = "right" Then
			_Right()
		ElseIf $sNavi = "left" Then
			_Left()
		ElseIf $sNavi = "button" Then
			_Button()
		ElseIf $sNavi = "status_6" Then
			_Status_6()
		ElseIf $sNavi = "status_14" Then
			_Status_14()
		ElseIf $sNavi = "status_0" Then
			_Status_0()
		ElseIf $sNavi = "status_9" Then
			_Status_9()
		EndIf


		Return


	EndIf
	_SendMessage($hMainGui, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
EndFunc   ;==>_WM_LBUTTONDOWN


Func _Exit()
	Exit
EndFunc   ;==>_Exit


Func _New()


EndFunc   ;==>_New


Func _Top()


EndFunc   ;==>_Top


Func _Bottom()


EndFunc   ;==>_Bottom


Func _Right()


EndFunc   ;==>_Right


Func _Left()


EndFunc   ;==>_Left


Func _Button()


EndFunc   ;==>_Button


Func _Status_6()


EndFunc


Func _Status_14()


EndFunc


Func _Status_0()


EndFunc


Func _Status_9()


EndFunc




; #INDEX# =======================================================================================================================
; Title .........: GUICreateTransparent
; AutoIt Version : 3.3.6.1
; Description ...: Transparente BildGUIs erstellen.
; Author(s) .....: UEZ und ein bisschen Großvater (www.autoit.de)
; Dll ...........:
; ===============================================================================================================================


; #CURRENT# =====================================================================================================================
; _GUICreate_Transparent
; ===============================================================================================================================




; #FUNCTION# ====================================================================================================================
; Name...........: _GUICreate_Transparent
; Description ...: Transparente Popup-GUIs aus Bildern (z.B. PNG) erstellen
; Syntax.........: _GUICreate_Transparent($sImage, $iLeft = -1, $iTop = -1, $iOpacity = 255)
; Parameters ....: $sImage   - Pfad zur Bilddatei
;                  $iLeft    - Bidschirmposition der linken Seite des GUI in Pixeln
;                  |Default  - -1 (zentriert)
;                  $iTop     - Bidschirmposition der oberen Seite des GUI in Pixeln
;                  |Default  - -1 (zentriert)
;                  $iOpacity - Transparenz für das gesamte GUI (siehe WinSetTrans())
;                  |Default  - 255 (nicht transparent)
; Return values .: Im Erfolgsfall: HWND des GUI aus GUICreate()
;                  Im Fehlerfall: False, @error wird gesetzt:
;                  |1 = GDIPlus konnte nicht gestartet werden
;                  |2 = Die Bilddatei konnte nicht geladen werden
; Author ........: UEZ (www.autoit.de/index.php?page=Thread&postID=199839#post199839)
; Modified.......: Großvater (www.autoit.de)
; Remarks .......: Das GUI wird immer in der Originalgröße des Bildes mit dem Style $WS_POPUP und dem
;                  Exstyle $WS_EX_LAYERED erstellt. Der Exstyle $WS_EX_LAYERED verträgt sich offenbar
;                  nicht mit normalen Child-GUIs. Controls müssen deshalb in (einer) eigenen GUI(s)
;                  mit den Exstyles $WS_EX_MDICHILD und $WS_EX_LAYERED und der HWND des Bild-GUI
;                  als Parent erstellt werden. Dafür liefert UEZ im o.a. Thread ein Beispiel.
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GUICreate_Transparent($sImage, $iLeft = -1, $iTop = -1, $iOpacity = 255, $iExStyle = $WS_EX_LAYERED + $WS_EX_TOPMOST, $hParent = 0)
	; GDIPlus starten
	If Not _GDIPlus_Startup() Then Return SetError(1, 0, 0)
	; Bild laden
	Local $hImage = _GDIPlus_ImageLoadFromFile($sImage)
	If @error Then
		_GDIPlus_Shutdown()
		Return SetError(2, 0, 0)
	EndIf
	Local $iWidth = _GDIPlus_ImageGetWidth($hImage)
	Local $iHeight = _GDIPlus_ImageGetHeight($hImage)
	; GUI erstellen
	Local $hGUI = GUICreate("", $iWidth, $iHeight, $iLeft, $iTop, $WS_POPUP, $iExStyle, $hParent)
	Local $hDCDst = _WinAPI_GetDC($hGUI)
	Local $hDCSrc = _WinAPI_CreateCompatibleDC($hDCDst)
	Local $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
	_WinAPI_SelectObject($hDCSrc, $hBitmap)
	Local $tSize = DllStructCreate($tagSIZE)
	Local $pSize = DllStructGetPtr($tSize)
	DllStructSetData($tSize, "X", $iWidth)
	DllStructSetData($tSize, "Y", $iHeight)
	Local $tSource = DllStructCreate($tagPOINT)
	Local $pSource = DllStructGetPtr($tSource)
	Local $tBlend = DllStructCreate($tagBLENDFUNCTION)
	Local $pBlend = DllStructGetPtr($tBlend)
	DllStructSetData($tBlend, "Alpha", $iOpacity)
	DllStructSetData($tBlend, "Format", 1)
	_WinAPI_UpdateLayeredWindow($hGUI, $hDCDst, 0, $pSize, $hDCSrc, $pSource, 0, $pBlend, $ULW_ALPHA)
	; Ressourcen freigeben
	_GDIPlus_ImageDispose($hImage)
	_WinAPI_DeleteObject($hBitmap)
	_WinAPI_DeleteDC($hDCSrc)
	_WinAPI_ReleaseDC($hGUI, $hDCDst)
	_GDIPlus_Shutdown()
	; HWND des GUI zurückgeben
	Return $hGUI
EndFunc   ;==>_GUICreate_Transparent

Alles anzeigen

######################################
############ Original Post ##############
######################################
Hallo liebe Leute,

ich bins mal wieder

Derzeit bin ich an einem neuen Projekt, da das letzte leider im Sand verlaufen ist.

Also, es geht um ein Programm, welches die Einschulung auf ein Datenfunk-Terminal erleichtern soll.
Dabei wird ein Terminal simuliert und es können verschiedene Aufträge / Szenarien simuliert werden.

Nun ist es allerdings schon so, dass ich in der Anfangsphase schon vor einem Problem stehe und einfach nicht genug Hintergrundwissen habe, wenn es um GDI+, Interlaced Images und Image Buttons geht.

Hier sieht man nun das fertige Terminal-Image.
[Blockierte Grafik: https://i.imgsafe.org/7ba6ae0fe2.png]
Bedienelemte:

Button_Center (Aktiv und Inaktiv)
[Blockierte Grafik: https://i.imgsafe.org/7bada4e417.png][Blockierte Grafik: https://i.imgsafe.org/7badae750f.png]

Nun hab ich allerdings das Problem, dass sich durch die Viertelkreis-Form der Buttons die Bilder überschneiden/überlappen.

Hier nochmal das Background - Image, welches später quasi als GUI dienen soll:
[Blockierte Grafik: https://i.imgsafe.org/7be5b40c79.png]

Ich habs mal mit der Skin UDF von Yashied probiert und leider auch nicht wirklich auf einen grünen Zweig gekommen...
(Ja ich hab auch die Alpha_Images erstellt)

Eigentlich würde ich ja auch lieber die GUI ohne Fensterrahmen machen. Aber dem Problem stelle ich mich erst, wenn ich die Buttons im Griff habe.

Ja ich weiß, es gibt zu dem Thema viel Stoff der schon bearbeitet wurde, allerdings hab ich nicht gefunden, was auch wirklich meinen Vorstellungen entspricht.
Ich hab die Dateien alle als [.ai | .psb | .bmp | .png].

Würd mich freuen, wenn jemand einen guten Vorschlag zur Umsetzung hätte!

Lg Stoani

**alpines**

Kannst du die Buttons nicht rechteckig lassen?
An den Ecken wo sich die Buttons treffen kannst du ja einen kleinen Button draus machen und beim Klick darauf prüfen wo auf dem Button geklickt wurde. (Statt 4 machst du 4+4)
Du rechnest aus ob er oberhalb oder unterhalb des Striches geklickt hat und demnach führst du die Funktion des Buttons aus.

Stoani

Meinst du so:

[Blockierte Grafik: https://i.imgsafe.org/7c49f8d464.png]

Die grünen wären dann die zu überprüfenden mini Buttons?

**alpines**

Wenn du die Buttons über die anderen legen willst ja, ich dachte eher an sowas (ist im Prinzip eigentlich das gleiche).
Deine Variante geht halt nicht allzukrass über die Ecken hinaus, aber wie gesagt: ist im Prinzip das gleiche.
[Blockierte Grafik: http://i.imgur.com/MrUCzt0.png]

//EDIT: Du solltest aber beachten das bei deiner Variante die Buttons eventuell in den Hintergrund rutschen, weil der davorgelegte Button fokussiert wird!

Stoani

Ahhh jetzt check ichs erst.... Nöööö nicht rechteckig lassen... Ich will doch das Terminal simulieren, dann soll es auch gleich aussehen

So als aller aller aller letzte Option vielleicht...

**alpines**

Ich weiß jetzt nicht ob dir das was sagt (und ich finds auf die schnelle nicht) aber man kann GUIs erstellen wo ein Bild das Fenster bildet.
Das Fenster kann man verschieben wenn man auf das Bild klickt und es wird auch nur verschoben wenn man auf eine farbige Stelle klickt, bei transparenten Stellen klickt man stattdessen durch die GUI durch.

Warum nicht 4 Fenster davon erstellen und mit WinApi SetParent versuchen die in die GUI einzubinden?

Stoani

Wäre einen Versuch wert! Danke für den Tipp, dann werd ich mal google gquälen.

**alpines**

Gefunden! Zwar nicht ganz das was ich meinte (hier mit Polygonen statt Bildern aber ist sicherlich analog).
Du kannst die Blätter hin- und herschieben und durch sie durchklicken wenn sie an der Stelle nicht rot sind.

Ich hab gerade eine dreiviertel Stunde versucht das ganze schon für PNGs zu finden (ich weiß das es das gibt, gabs hier auch schon mal im Forum!!) aber ich finde leider nichts.

AutoIt

#Include <GUIConstantsEx.au3>
#Include <WinAPI.au3>
#Include <WindowsConstants.au3>


Global $aPoint[25][2] = [[196, 31], [220, 92], [258, 77], [248, 158], [295, 125], [307, 157], [357, 149], [326, 206], [357, 214], [271, 273], [282, 296], [202, 282], [200, 361], [188, 360], [188, 280], [109, 295], [122, 276], [34, 214], [62, 204], [37, 152], [84, 156], [97, 122], [143, 156], [132, 75], [170, 89]]
$hForm = GUICreate('MyGUI', 500, 475, -1, -1)
GUIRegisterMsg($WM_NCHITTEST, 'WM_NCHITTEST')
GUISetBkColor(0xAA0000)


$hRgn = _WinAPI_CreatePolygonRgn($aPoint)
_WinAPI_SetWindowRgn($hForm, $hRgn)


GUISetState(@SW_SHOW, $hForm)


$hForm2 = GUICreate('MyGUI', 500, 475, -1, -1)
GUIRegisterMsg($WM_NCHITTEST, 'WM_NCHITTEST')
GUISetBkColor(0xAA0000)


$hRgn = _WinAPI_CreatePolygonRgn($aPoint)
_WinAPI_SetWindowRgn($hForm2, $hRgn)


GUISetState(@SW_SHOW, $hForm2)


$hGUI = GUICreate("", 1000, 800)


GUISetState(@SW_SHOW, $hGUI)


_WinAPI_SetParent($hForm, $hGUI)
_WinAPI_SetParent($hForm2, $hGUI)


While Sleep(100)
WEnd


Func _WinAPI_CreatePolygonRgn($aPoint, $iStart = 0, $iEnd = -1, $iMode = 1)


    If UBound($aPoint, 2) < 2  Then
        Return SetError(1, 0, 0)
    EndIf


    Local $Count, $tData, $Struct = ''


    If ($iEnd < 0) Or ($iEnd > UBound($aPoint) - 1) Then
        $iEnd = UBound($aPoint) - 1
    EndIf
    For $i = $iStart To $iEnd
        $Struct &= 'int[2];'
    Next
    $tData = DllStructCreate(StringTrimRight($Struct, 1))
    If @error Then
        Return SetError(1, 0, 0)
    EndIf
    $Count = 1
    For $i = $iStart To $iEnd
        For $j = 0 To 1
            DllStructSetData($tData, $Count, $aPoint[$i][$j], $j + 1)
        Next
        $Count += 1
    Next


    Local $Ret = DllCall('gdi32.dll', 'ptr', 'CreatePolygonRgn', 'ptr', DllStructGetPtr($tData), 'int', $Count - 1, 'int', $iMode)


    If (@error) Or ($Ret[0] = 0) Then
        Return SetError(1, 0, 0)
    EndIf
    Return $Ret[0]
EndFunc   ;==>_WinAPI_CreatePolygonRgn


Func WM_NCHITTEST($hWnd, $Msg, $wParam, $lParam)
    If _WinAPI_DefWindowProc($hWnd, $Msg, $wParam, $lParam) = $HTCLIENT Then
        Return $HTCAPTION
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NCHITTEST

Alles anzeigen

**alpines**

Ich glaubs nicht, endlich hab ich es gefunden obwohl ich die Hoffnung schon fast aufgegeben hatte. Nimm mal die transparente PNG und trag sie bei $sBilddatei ein und probiers mal aus, das setzt die Region direkt um das Bild herum und mit dem SetParent-Beispiel von vorhin kannst du so deine Buttons erstellen!

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>


Global Const $SC_DRAGMOVE = 0xF012
Global $sBilddatei = @ScriptDir & "\1.png"


; Transparentes GUI erzeugen
$hGUI = _GUICreate_Transparent($sBilddatei)


GUISetState(@SW_SHOW, $hGUI)


; Wenn man das GUI bewegen will
GUIRegisterMsg($WM_LBUTTONDOWN, "_WM_LBUTTONDOWN")


Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
Exit


Func _WM_LBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
	_SendMessage($hGUI, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
EndFunc   ;==>_WM_LBUTTONDOWN


; #INDEX# =======================================================================================================================
; Title .........: GUICreateTransparent
; AutoIt Version : 3.3.6.1
; Description ...: Transparente BildGUIs erstellen.
; Author(s) .....: UEZ und ein bisschen Großvater (www.autoit.de)
; Dll ...........:
; ===============================================================================================================================


; #CURRENT# =====================================================================================================================
; _GUICreate_Transparent
; ===============================================================================================================================




; #FUNCTION# ====================================================================================================================
; Name...........: _GUICreate_Transparent
; Description ...: Transparente Popup-GUIs aus Bildern (z.B. PNG) erstellen
; Syntax.........: _GUICreate_Transparent($sImage, $iLeft = -1, $iTop = -1, $iOpacity = 255)
; Parameters ....: $sImage   - Pfad zur Bilddatei
;                  $iLeft    - Bidschirmposition der linken Seite des GUI in Pixeln
;                  |Default  - -1 (zentriert)
;                  $iTop     - Bidschirmposition der oberen Seite des GUI in Pixeln
;                  |Default  - -1 (zentriert)
;                  $iOpacity - Transparenz für das gesamte GUI (siehe WinSetTrans())
;                  |Default  - 255 (nicht transparent)
; Return values .: Im Erfolgsfall: HWND des GUI aus GUICreate()
;                  Im Fehlerfall: False, @error wird gesetzt:
;                  |1 = GDIPlus konnte nicht gestartet werden
;                  |2 = Die Bilddatei konnte nicht geladen werden
; Author ........: UEZ (www.autoit.de/index.php?page=Thread&postID=199839#post199839)
; Modified.......: Großvater (www.autoit.de)
; Remarks .......: Das GUI wird immer in der Originalgröße des Bildes mit dem Style $WS_POPUP und dem
;                  Exstyle $WS_EX_LAYERED erstellt. Der Exstyle $WS_EX_LAYERED verträgt sich offenbar
;                  nicht mit normalen Child-GUIs. Controls müssen deshalb in (einer) eigenen GUI(s)
;                  mit den Exstyles $WS_EX_MDICHILD und $WS_EX_LAYERED und der HWND des Bild-GUI
;                  als Parent erstellt werden. Dafür liefert UEZ im o.a. Thread ein Beispiel.
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GUICreate_Transparent($sImage, $iLeft = -1, $iTop = -1, $iOpacity = 255)
	; GDIPlus starten
	If Not _GDIPlus_Startup() Then Return SetError(1, 0, 0)
	; Bild laden
	Local $hImage = _GDIPlus_ImageLoadFromFile($sImage)
	If @error Then
		_GDIPlus_Shutdown()
		Return SetError(2, 0, 0)
	EndIf
	Local $iWidth = _GDIPlus_ImageGetWidth($hImage)
	Local $iHeight = _GDIPlus_ImageGetHeight($hImage)
	; GUI erstellen
	Local $hGUI = GUICreate("", $iWidth, $iHeight, $iLeft, $iTop, $WS_POPUP, $WS_EX_LAYERED)
	Local $hDCDst = _WinAPI_GetDC($hGUI)
	Local $hDCSrc = _WinAPI_CreateCompatibleDC($hDCDst)
	Local $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
	_WinAPI_SelectObject($hDCSrc, $hBitmap)
	Local $tSize = DllStructCreate($tagSIZE)
	Local $pSize = DllStructGetPtr($tSize)
	DllStructSetData($tSize, "X", $iWidth)
	DllStructSetData($tSize, "Y", $iHeight)
	Local $tSource = DllStructCreate($tagPOINT)
	Local $pSource = DllStructGetPtr($tSource)
	Local $tBlend = DllStructCreate($tagBLENDFUNCTION)
	Local $pBlend = DllStructGetPtr($tBlend)
	DllStructSetData($tBlend, "Alpha", $iOpacity)
	DllStructSetData($tBlend, "Format", 1)
	_WinAPI_UpdateLayeredWindow($hGUI, $hDCDst, 0, $pSize, $hDCSrc, $pSource, 0, $pBlend, $ULW_ALPHA)
	; Ressourcen freigeben
	_GDIPlus_ImageDispose($hImage)
	_WinAPI_DeleteObject($hBitmap)
	_WinAPI_DeleteDC($hDCSrc)
	_WinAPI_ReleaseDC($hGUI, $hDCDst)
	_GDIPlus_Shutdown()
	; HWND des GUI zurückgeben
	Return $hGUI
EndFunc   ;==>_GUICreate_Transparent

Alles anzeigen

**Kanashius**

Ich hab da 2014 auch mal was geschrieben. Damals war ich noch nicht so wissend wie heute (Deshalb wurden keine/kaum Arrays genutzt,...) aber es ist hauptsächlich aus Bildern, es gibt eine Hover-Funktion, Bilder ändern sich beim draufklicken,...
Kannst du dir gerne mal anschauen, vielleicht hilfte es dir weiter oder gibt dir noch ein paar Ideen

MfG Kanashius

**Oscar**

Das Thema fand ich recht praktisch, weil ich das evtl. auch mal gebrauchen kann.
Vielen Dank an Alpines, dass er diese Funktion wiedergefunden hat!
Ich habe dann mal den Rest (Hover-Funktion und erstellen der Childs plus Klick-Funktion) zusammengebaut. Script und Grafiken im ZIP-Archiv (Anhang).

Stoani

Hey Kanashius,
schaut richtig geil aus und geht genau in diese Stilrichtung!

Eine Frage bleibt aber noch:
Brauch ich die "GUICtrlOnHover.au3" als Include?
Die ist nämlich nicht im Skript glaub ich... kann auch sein dass ich mich täusche, erster Kaffee und soooo...

Hui so schnell.. genau in dem moment gepostet @Oscar
Danke für das Example.au3, ich werds mir auf der Zunge zergehen lasssen!

**alpines**

Zitat von Stoani

Brauch ich die "GUICtrlOnHover.au3" als Include?

Alles was keine Miete zahlt oder einen Zweck erfüllt: raus!

Freut mich das wir dir helfen konnten, wenn du - zumindest zu dem Thema - keine Fragen mehr hast kannst du ja den grünen Haken für [gelöst] setzen (1. Beitrag bearbeiten).
Nichtsdestotrotz würde es uns freuen wenn du uns über dein Projekt am Laufen hältst und hier weiter postest.

Stoani

Pfeift, mach ich. (beides)

Stoani

Hallo liebe Leute,

das Programm wird nun doch eher online laufen und in html, css und javascript umgesetzt.

Es ist zwar noch lange nicht fertig, aber ihr könnt es euch gerne und http://terminal.rkgm.at/index.html ansehen.

Trotzdem danke für die Hilfe!

lg Stoani
#Closed