Listview mit Gruppen

nuts

Hi,

ich arbeite gerade an einem Listview mit Gruppen.

Also Beispiel kann die Hilfe zu _GUICtrlListView_GetItemGroupID herhalten.

Spoiler anzeigen

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>


Example()


Func Example()
	Local $hImage, $idListview


	GUICreate("ListView Get Item Group ID", 400, 300)
	$idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
	GUISetState(@SW_SHOW)


	; Load images
	$hImage = _GUIImageList_Create()
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
	_GUICtrlListView_SetImageList($idListview, $hImage, 1)


	; Add columns
	_GUICtrlListView_AddColumn($idListview, "Column 1", 100)
	_GUICtrlListView_AddColumn($idListview, "Column 2", 100)
	_GUICtrlListView_AddColumn($idListview, "Column 3", 100)


	; Add items
	_GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
	_GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
	_GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
	_GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
	_GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
	_GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)


	; Build groups
	_GUICtrlListView_EnableGroupView($idListview)
	_GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1")
	_GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
	_GUICtrlListView_SetItemGroupID($idListview, 0, 1)
	_GUICtrlListView_SetItemGroupID($idListview, 1, 2)
	_GUICtrlListView_SetItemGroupID($idListview, 2, 2)


	; Display Item 3 group ID
	MsgBox($MB_SYSTEMMODAL, "Information", "Item 3 Group ID: " & _GUICtrlListView_GetItemGroupID($idListview, 2))


	; Loop until the user exits.
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
	GUIDelete()
EndFunc   ;==>Example

Alles anzeigen

Und zwar geht es mir jetzt darum herauszufinden welche Items z.B. in Gruppe 2 sind. Hie wären das Item 2 und Item 3.

Mir fällt dazu nur eine Lösung ein: man durchsucht das gesamte Listview und fragt zu jedem Item per _GUICtrlListView_GetItemGroupID die zugehörige ID ab und sortiert diese ID's dann selbst nochmal.
Was meint ihr dazu? Geht das auch einfacher?
Gesucht: _GUICtrlListView_GetGroupitems($hwnd, $groupID)

Gruß

nuts

**alpines**

In C# gibts dafür listView.Groups[0].Items aber in AutoIt gibts das glaube ich nicht.

Schreib dir die _GUICtrlListView_GetGroupItems einfach selber, sollte ja nicht allzuschwierig sein. Die Vorgehensweise die du erläutert hast hört sich eigentlich dafür geeignet an.

nuts

AutoIt

Func _GetListview_GroupItems($hWnd, $iGroupID)


    Local $i_max = _GUICtrlListView_GetItemCount($hWnd) - 1    
    Local $i_match, $s_items


    for $i=0 to $i_max        
       $i_match=_GUICtrlListView_GetItemGroupID($hWnd, $i)        
       if $i_match=$iGroupID then $s_items&= $i & "|"    
   next


    Return StringSplit(StringTrimRight($s_items, 1), "|")


Endfunc

Alles anzeigen

So ungefähr könnte es klappen.
Nunja vielleicht hat ja noch einer eine bessere Lösung.

Man könnte die Sache noch "beschleunigen" wenn sichergesellt wäre, dass alle Items einer Gruppe einen fortlaufenden Index haben, aber davon kann man glaube ich auch nicht immer ausgehen?

**alpines**

Klappt es denn auch?

nuts

Im Prinzip ja.
Ich überlege gerade noch wie man in einem Rutsch alle Gruppen eines Listviews und die jeweils zugehörigen Items erfasst.

P.S. Das Arbeiten mit den Gruppen ist wirklich eine Strafarbeit. Ich sitz da schon den ganzen Nachmittag und dreh mich im Kreis.

**alpines**

Na wie wäre es denn mit einem zweidimensionalen Array wo [x][n] die Gruppe bezeichnet und [n][x] die Items in der Gruppe, nennen kannst du sie dann _GUICtrlListView_GetItemsGrouped().
Ich hab den grünen Haken für erledigt / gelöst gesetzt (du kannst das in Zukunft auch machen, einfach den 1. Beitrag im Thread editieren und Threadstatus anpassen).

nuts

Also wirklich zufrieden bin ich mit meiner Lösung noch nicht ... was soll die Eile?

Und die zweite Geschichte mit 2D Array erfordert ein Redim bei jedem verarbeiteten Item?
Da bin ich auch noch etwas am probieren.

**alpines**

Zitat von nuts

Also wirklich zufrieden bin ich mit meiner Lösung noch nicht ... was soll die Eile?

Die Fragestellung wurde beantwortet. Nur weil der Haken gesetzt ist bedeutet das nicht, dass jede Diskussion hier im Keim erstickt wird sondern gerne weiterdiskutiert werden darf.
Du musst nur ReDimmen wenn du out-of-bounds wärst.

Ich hab das ganze mal so implementiert wie ich mir das vorgestellt habe, vielleicht gefällts dir ja. Wenn du die Items haben willst, musst du GetItemText durch GetItem ersetzen, das GetItemText steht nur drinne um _ArrayDisplay richtig nutzen zu können

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3>


Example()


Func Example()
	Local $hImage, $idListview


	GUICreate("ListView Get Item Group ID", 400, 300)
	$idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
	GUISetState(@SW_SHOW)


	; Load images
	$hImage = _GUIImageList_Create()
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
	_GUICtrlListView_SetImageList($idListview, $hImage, 1)


	; Add columns
	_GUICtrlListView_AddColumn($idListview, "Column 1", 100)
	_GUICtrlListView_AddColumn($idListview, "Column 2", 100)
	_GUICtrlListView_AddColumn($idListview, "Column 3", 100)


	; Add items
	_GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
	_GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
	_GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
	_GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
	_GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
	_GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)


	; Build groups
	_GUICtrlListView_EnableGroupView($idListview)
	_GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1")
	_GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
	_GUICtrlListView_SetItemGroupID($idListview, 0, 1)
	_GUICtrlListView_SetItemGroupID($idListview, 1, 2)
	_GUICtrlListView_SetItemGroupID($idListview, 2, 2)


	$aReturn = _GUICtrlListView_GetItemsGrouped($idListview)
	$aReturn2 = _GUICtrlListView_GetItemsGrouped($idListview, 2)


	_ArrayDisplay($aReturn)
	_ArrayDisplay($aReturn2)


	; Loop until the user exits.
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
	GUIDelete()
EndFunc   ;==>Example


Func _GUICtrlListView_GetItemsGrouped($hWnd, $iGroup = Default)
	If $iGroup = Default Then
		Local $aEntries[0][1]


		For $i = 0 To _GUICtrlListView_GetItemCount($hWnd)
			$iCurrentId = _GUICtrlListView_GetItemGroupID($hWnd, $i) - 1


			If $iCurrentId < 0 Then ContinueLoop


			If UBound($aEntries) < $iCurrentId + 1 Then
				ReDim $aEntries[$iCurrentId + 1][UBound($aEntries, 2)]
			EndIf


			If $aEntries[$iCurrentId][UBound($aEntries, 2) - 1] <> "" Then
				ReDim $aEntries[UBound($aEntries)][UBound($aEntries, 2) + 1]
			EndIf


			$aEntries[$iCurrentId][UBound($aEntries, 2) - 1] = _GUICtrlListView_GetItemText($hWnd, $i)
		Next
	Else
		Local $aEntries[0]


		For $i = 0 To _GUICtrlListView_GetItemCount($hWnd)
			If _GUICtrlListView_GetItemGroupID($hWnd, $i) = $iGroup Then
				ReDim $aEntries[UBound($aEntries) + 1]


				$aEntries[UBound($aEntries) - 1] = _GUICtrlListView_GetItemText($hWnd, $i)
			EndIf
		Next
	EndIf


	Return $aEntries
EndFunc

Alles anzeigen

nuts

Danke für deine Mühen.

Irgendwie scheint mir ein 2D Array für ein ganzes Listview mit Gruppen ungeeignet zu sein.
Ein Listview mit mehreren Spalten passt super zum 2D Array, kommen Gruppen hinzu fehlt eine Dimension.

P.S. Wenn der Thread auf erledigt steht motiviert es nicht gerade sich den Thread anzuschauen ...

**alpines**

Zitat von nuts

Irgendwie scheint mir ein 2D Array für ein ganzes Listview mit Gruppen ungeeignet zu sein.

Warum das denn? Ich finde es eignet sich hervorragend.
Man könnte sogar so weit gehen ein 3D-Array daraus zu machen und die SubItems der Items in den Groups in die unterste Dimension einzufügen.

Das war zumindest eine Implementation wie ich sie vorgenommen hätte und wie sie mir gefällt.
Du kannst ja daran rumbasteln und dir dein eigenes Format ausdenken, hat ja niemand was dagegen.

**BugFix**

Warum soo kompliziert? Das Abfragen der Gruppenitem sind doch nur ein paar Zeilen Code:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>


_Example()


Func _Example()
	Local $hImage, $idListview


	GUICreate("ListView Get Item Group ID", 400, 300)
	$idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
	GUISetState(@SW_SHOW)


	; Load images
	$hImage = _GUIImageList_Create()
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
	_GUICtrlListView_SetImageList($idListview, $hImage, 1)


	; Add columns
	_GUICtrlListView_AddColumn($idListview, "Column 1", 100)
	_GUICtrlListView_AddColumn($idListview, "Column 2", 100)
	_GUICtrlListView_AddColumn($idListview, "Column 3", 100)


	; Add items
	_GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
	_GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
	_GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
	_GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
	_GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
	_GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)


	; Build groups
	_GUICtrlListView_EnableGroupView($idListview)
	_GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1")
	_GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
	_GUICtrlListView_SetItemGroupID($idListview, 0, 1)
	_GUICtrlListView_SetItemGroupID($idListview, 1, 2)
	_GUICtrlListView_SetItemGroupID($idListview, 2, 2)


	; Display Item 3 group ID
	MsgBox($MB_SYSTEMMODAL, "Information", "Item 3 Group ID: " & _GUICtrlListView_GetItemGroupID($idListview, 2))


	Local $a = _GUICtrlListView_GetItemByGroupID($idListview, 2)
	ConsoleWrite('Member of group 2' & @CRLF)
	For $i = 0 To UBound($a) -1
		ConsoleWrite('Index: ' & $a[$i] & ', Text: ' & _GUICtrlListView_GetItemTextString($idListview, $a[$i]) & @CRLF)
	Next


	; Loop until the user exits.
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
	GUIDelete()
EndFunc   ;==>Example




Func _GUICtrlListView_GetItemByGroupID($hWnd, $iIDGroup)
	Local $iCount = _GUICtrlListView_GetItemCount($hWnd)
	If $iCount = 0 Then Return SetError(1,0,0)
	Local $aGroup[$iCount], $iIndex=0
	For $i = 0 To $iCount -1
		If _GUICtrlListView_GetItemGroupID($hWnd, $i) = $iIDGroup Then
			$aGroup[$iIndex] = $i
			$iIndex += 1
		EndIf
	Next
	ReDim $aGroup[$iIndex]
	Return $aGroup
EndFunc

Alles anzeigen

nuts

Das entspricht ca. meiner Lösung um die Items für eine bestimmte Gruppe zu bestimmen.
Funktioniert gut.

Wie man am besten alle Gruppen und zugehörige Items eines Listviews auf einen Schlag ermittelt bin ich noch am grübeln. 3D Array ist wohl besser, aber dazu muss ich die Array Tutorials nochmal wiederholen.

**BugFix**

Zitat von nuts

3D Array ist wohl besser

3D -- wozu das denn. Du kannst doch eine Information auf den Array-Index legen, schon sparst du eine Dimension.
Hier mal die Funktion zum Auslesen aller Groups mit den zugehörigen Item

AutoIt

; #FUNCTION# ====================================================================================================================
; Name ..........: _GUICtrlListView_GetItemInGroups
; Description ...: Detects all member for a all group
; Syntax ........: _GUICtrlListView_GetItemInGroups($hWnd)
; Parameters ....: $hWnd                - The listview handle
; Return values .: Success              Array with listview index of all member from all group
; ...............:                     [0][0] = count groups
; ...............:                     [1 .. n][] = Group ID (equal with array index)
; ...............:                     [n][0] = count item in group "n", [n][1....] = the item listview-index 
; ...............: Failure              0  @error=1  listview has no item
; ...............:                         @error=2  no groups
; Author ........: BugFix
; ===============================================================================================================================
Func _GUICtrlListView_GetItemInGroups($hWnd)
	Local $iCount = _GUICtrlListView_GetItemCount($hWnd)
	If $iCount = 0 Then Return SetError(1,0,0)
	Local $aGroupItem[$iCount+1][$iCount+1], $iGroupID, $iGroupMax=0, $iItemMax = 0
	For $i = 0 To $iCount -1
		$iGroupID = _GUICtrlListView_GetItemGroupID($hWnd, $i)
		$iGroupMax = $iGroupID < $iGroupMax ? $iGroupMax : $iGroupID
		$aGroupItem[$iGroupID][0] += 1
		$aGroupItem[$iGroupID][ $aGroupItem[$iGroupID][0] ] = $i
		$iItemMax = $aGroupItem[$iGroupID][0] > $iItemMax ? $aGroupItem[$iGroupID][0] : $iItemMax
	Next
	If $iGroupMax = 0 Then Return SetError(2,0,0)
	$aGroupItem[0][0] = $iGroupMax
	ReDim $aGroupItem[$iGroupMax +1][$iItemMax+1]
	Return $aGroupItem
EndFunc  ;==>_GUICtrlListView_GetItemInGroups

Alles anzeigen

nuts

Danke das gefällt mir gut, sehr elegant.