Code effizienter machen

Damion

Hallo Leute,

ich möchte von einem aktiven Netzwerkadapter diverse Werte in einer Msgbox anzeigen lassen.
Dazu speichere ich die ipconfig /all in eine txt Datei. In dieser Datei suche ich nach einer IPv4
Adresse (die in diesem Fall nur in dem Block des aktiven Netzwerkadapters steht).
Von dieser Zeile suche ich nach oben und unten die nächsten Leerzeilen, was Anfang und Ende
des jeweiligen Adapters ist.
Wenn ich auf diesen Weg den Bereich eingrenzt habe, schreibe ich die gewünschten Werte in ein Array
und gebe diese in der Msgbox aus.

So weit der Stand und macht auch das was es soll...

..aber irgendwie kommt mir das alles zu kompliziert vor wie ich das angehe.
Vielleicht kann mir mal jemand seine Ideen dazu äußern wie er oder sie
da dran gehen würden.
Damit meine ich nicht, wie ich mir alternativ die gewünschten Werte herzaubere(kann aber auch gerne erwähnt werden)
sondern eher wie ich die Informationen "eleganter" aus der Textdatei bekomme.

Die ipconfig /all sieht ja von Rechner zu Rechner verschieden aus (Anzahl der Adapter, Variable Reihenfolgen etc).

Gruß Damion

Spoiler anzeigen

#include <Constants.au3>
#include <Inet.au3>
#include <File.au3>
#include <Array.au3>

;Deklaration der benötigten Arrays
Local $WerteArray[7]
Local $SucheArray[7]

;Suchbegriffe dem SucheArray zugewiesen

$SucheArray[0] = "IPv4"
$SucheArray[1] = "Subnetzmaske"
$SucheArray[2] = "Standardgateway"
$SucheArray[3] = "Physi"
$SucheArray[4] = "DHCP aktiviert"
$SucheArray[5] = "DHCP-Server"
$SucheArray[6] = "DNS-Server"

;Aufruf der IPCONFIG /all Routine mit erstellen und speichern in die Textdatei IP.txt
Run('cmd /c ipconfig /all > "IP.txt"', "", @SW_HIDE)

Sleep(500)

;Zählen der Zeilen in der Textdatei IP.txt
$Zeilen_Count = _FileCountLines("IP.txt")

;Suche nach verbundener Schnittstelle, anhand der IPv4 Adresse
For $i = 1 To $Zeilen_Count Step 1
$Zeile = FileReadLine("IP.txt", $i)
$Suche = StringInStr($Zeile, $SucheArray[0])
If $Suche > 0 Then
ExitLoop
ElseIf $i=$Zeilen_Count Then
msgbox(64,"Netzwerkeinstellungen","Es sind keine Netzwerkadapter verbunden.")
Exit
EndIf

;Suche nach nächster Leerzeile, ausgehend von IPv4 Adresse
For $Stop = $i To $Zeilen_Count
$Zeile = FileReadLine("IP.txt", $Stop)
If $Zeile = "" Then
ExitLoop
EndIf
Next

; Beschreiben des Arrays mit den gesuchten Werten
For $Filter = $Start To $Stop

For $Array = 0 To UBound($SucheArray) - 1
$Zeile = FileReadLine("IP.txt", $Filter)
$Suche = StringInStr($Zeile, $SucheArray[$Array])
If $Suche > 0 Then
$SSplit = StringSplit($Zeile, ":", 2)
$WerteArray[$Array] = $SSplit[1]

ExitLoop
EndIf
Next

MsgBox(64, "Netzwerkeinstellungen", @CRLF _
& FileReadLine("IP.txt", $Start - 1) & @CRLF _
& "---------------------------------------" & @CRLF _
& "IPv4 Adresse = " & StringTrimRight($WerteArray[0], 12) & @CRLF _
& "Subnetzmaske = " & $WerteArray[1] & @CRLF _
& "Standart Gateway = " & $WerteArray[2] & @CRLF _
& "MAC Adresse = " & $WerteArray[3] & @CRLF _
& "DHCP aktiviert = " & $WerteArray[4] & @CRLF _
& "DHCP Server = " & $WerteArray[5] & @CRLF _
& "DNS Server =" & $WerteArray[6])

FileDelete("IP.txt")

**alpines**

Alles kann man optimieren. Es gibt bereits schon UDFs die mit der WMI arbeiten die die Infos direkt ausspuckt.
Ich habe das hier im englischen Forum gefunden: https://www.autoitscript.com/forum/topic/17…c-in-workgroup/

Mit StringSplit habe ich das ganze meiner Meinung nach etwas schicker lösen können (im Vergleich zu deinem).
Aber das ganze kann man sicherlich mit regulären Ausdrücken noch hübscher lösen:

Bei dieser Variante werden allerdings die Einträge die zuerst gefunden werden zuerst abgespeichert, also ist die Reihenfolge im Array egal.
Du kannst das sicherlich umbauen, ist ja nur ein Vorschlag wie man es lösen kann.

AutoIt

#include <Array.au3>


RunWait("cmd /c ipconfig /all > ip.txt")


Local $aSplit = StringSplit(FileRead("IP.txt"), @CRLF, 3)
Local $aCategories[7] = ["IPv4-Adresse", "Subnetzmaske", "Standardgateway", "Physikalische Adresse", "DHCP aktiviert", "DHCP-Server", "DNS-Server"]
Local $aResults[7]


For $i = 0 To UBound($aSplit) - 1
	;Nach der 1. IP-Adresse suchen


	If StringInStr($aSplit[$i], "IPv4-Adresse") Then
		For $i = $i To 0 Step -1
			If $aSplit[$i] = "" Then
				$i += 1
				ExitLoop ;Ganz oben im aktuellen Adapter angekommen
			EndIf
		Next


		ExitLoop
	EndIf
Next


For $i = $i To UBound($aSplit) - 1 ;Den ausgewählten Adapter durchgehen und Werte suchen
	For $j = 0 To UBound($aCategories) - 1
		If StringInStr($aSplit[$i], $aCategories[$j]) Then ;Kategorie gefunden
			$aResults[$j] = StringSplit($aSplit[$i], ": ", 3)[1]
			ExitLoop
		EndIf
	Next


	If $aSplit[$i] = "" Then ExitLoop ;Wenn Adapter durch ist
Next


_ArrayDisplay($aResults)

Alles anzeigen

Damion

Danke für den Link, ist sehr interessant.

Deine Lösung gefällt mir auch sehr gut, ist schon um einiges schlanker wie die meine.

Was macht eigentlich genau $i += 1 , zählt das noch zu $i 1 dazu also $i=$i+1 ?

Ja, wie so eine Lösung mit regulären Ausdrücken aussehen könnte würde mich
auch sehr interessieren.

**Oscar**

Für mein Computer-Info hatte ich mal diverse Funktionen geschrieben, die das per WMI auslesen:

AutoIt

#include <Array.au3>


$aNetwork = _CI_GetNetworkAdapter()
_ArrayDisplay($aNetwork)


Func _CI_GetNetworkAdapter($strComputer = '.')
	Local $aReturn[1][13] = [[ _
			'Hersteller:', 'Name:', 'Adapter-Typ:', 'Kennung:', 'MTU:', _
			'MAC-Adresse:', 'IP-Adresse:', 'IP-Subnetzmaske:', 'Adresstyp:', _
			'DHCP-Server:', 'IP erhalten:', 'IP läuft ab:', 'Standardgateway:']]
	Local $x = 0, $objWMIService, $colItems, $colItems2
	$objWMIService = ObjGet('winmgmts:\\' & $strComputer & '\root\cimv2')
	If Not IsObj($objWMIService) Then Return SetError(1, 0, 0)
	$colItems = $objWMIService.ExecQuery('SELECT * FROM Win32_NetworkAdapter WHERE Netconnectionstatus > 0', 'WQL', 0x30)
	If Not IsObj($colItems) Then Return SetError(2, 0, 0)
	For $objItem In $colItems
		$x += 1
		ReDim $aReturn[$x + 1][13]
		$aReturn[$x][0] = $objItem.Manufacturer
		$aReturn[$x][1] = $objItem.Name
		$aReturn[$x][2] = $objItem.AdapterType
		$aReturn[$x][3] = $objItem.NetConnectionID
		$aReturn[$x][4] = _CI_GetMTU($objItem.NetConnectionID)
		$aReturn[$x][5] = $objItem.MACAddress
		$colItems2 = $objWMIService.ExecQuery('SELECT * FROM Win32_NetworkAdapterConfiguration', 'WQL', 0x30)
		If IsObj($colItems2) Then
			For $objItem2 In $colItems2
				If $objItem.Caption = $objItem2.Caption Then
					If $objItem2.IPEnabled = -1 Then
						$aReturn[$x][6] = $objItem2.IPAddress(0)
						$aReturn[$x][7] = $objItem2.IPSubnet(0)
						If $objItem2.DHCPEnabled = -1 Then
							$aReturn[$x][8] = 'von DHCP zugewiesen'
							$aReturn[$x][9] = $objItem2.DHCPServer
							$aReturn[$x][10] = _WMIDateStringToDate($objItem2.DHCPLeaseObtained)
							$aReturn[$x][11] = _WMIDateStringToDate($objItem2.DHCPLeaseExpires)
						Else
							$aReturn[$x][8] = 'Manuell konfiguriert'
						EndIf
						$aReturn[$x][12] = $objItem2.DefaultIPGateway(0)
					EndIf
				EndIf
			Next
		EndIf
	Next
	Return $aReturn
EndFunc   ;==>_CI_GetNetworkAdapter


Func _CI_GetMTU($sNetworkAdapter)
	Switch @OSVersion
		Case 'WIN_VISTA', 'WIN_7'
			Local $sPID = Run(@ComSpec & ' /c netsh interface ipv4 show subinterface "' & $sNetworkAdapter & '"', @SystemDir, @SW_HIDE, $STDOUT_CHILD)
			Local $sOut = ''
			While 1
				$sOut &= StdoutRead($sPID)
				If @error Then ExitLoop
			WEnd
			Return StringRegExpReplace($sOut, '(?s).*?(\d+).*', '$1') & ' Bytes'
		Case Else
			Return 'nicht verfügbar'
	EndSwitch
EndFunc   ;==>_CI_GetMTU


Func _WMIDateStringToDate($dtmDate)
	Return StringMid($dtmDate, 7, 2) & '.' & StringMid($dtmDate, 5, 2) & '.' & StringLeft($dtmDate, 4) _
	& '   ' & _
	StringMid($dtmDate, 9, 2) & ':' & StringMid($dtmDate, 11, 2) & ':' & StringMid($dtmDate, 13, 2)
EndFunc   ;==>_WMIDateStringToDate

Alles anzeigen

**alpines**

Zitat von Damion

Was macht eigentlich genau $i += 1 , zählt das noch zu $i 1 dazu also $i=$i+1 ?

Genau, das addiert auf $i einen drauf. Das habe ich absichtlich so gewählt da sonst die Abbruchbedingung in der 2. Schleife (unten If $aSplit[$i] = "" Then) sofort ausgelöst wird.

Damion

Auch eine schöne alternative Lösung von Oscar

Dann danke schon mal für eure Antworten.

Wenn noch jemand eine Lösung mit reguläre Ausdrücke parat hat, würde ich mich
freuen.

Einen schönen sonnigen Samstag noch!

Gruß Damion