Frage zur Gui bzw GUICtrlSetState

Rigobert

Hi, ich habe folgendes Dilemma.

Bei meiner Funktion werden erstmal alle GUIGroups erstellt und Disabled sowie Versteckt.

Code

Func fuellungenarray($auswahl)
	$wahl = IniReadSection("produktini\"&$auswahl&".ini", $auswahl)
	$group = IniRead("produktini\"&$auswahl&".ini", 'GroupName', $auswahl, '')
	$groupsettings = IniReadSection("produktini\"&$auswahl&".ini", 'GroupSetting')
	$controlstart = IniReadSection("produktini\"&$auswahl&".ini", 'ControlStart')
 	$Anzahl = UBound($wahl)
	$groupauswahl = GUICtrlCreateGroup($group, $groupsettings[1][1], $groupsettings[2][1],     $groupsettings[3][1], $groupsettings[4][1])
	GUICtrlSetState($groupauswahl, 160)
GUICtrlSetFont(-1, 8, 400, 0, "Arial")
Global $arFuellung[$Anzahl]
For $i = 0 To UBound($arFuellung) -1
	If $i = 0 Then
		$wahl[0][1] = 'Nichts gewählt'
	EndIf
	$arFuellung[$i] = GUICtrlCreateRadio($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1])
	GUICtrlSetState($arFuellung[$i], 160)
 Next
For $i = 0 To UBound($arFuellung) -2 Step 2
    GUICtrlSetState($arFuellung[0], $GUI_CHECKED)
	GUICtrlSetState($arFuellung[0], 160)
Next
GUICtrlCreateGroup("", -99, -99, 1, 1)
EndFunc

Alles anzeigen

So mit dieser Funktion und den Aufrufen aus einem Array heraus werden alle erstellt, Disabled und Versteckt.

Nun wollte ich die durch Klick auf die zugehörigen Radiobuttons wieder Enablen und Anzeigen.

AutoIt

Func fuellungenarray_einblenden($auswahl)
	$wahl = IniReadSection("produktini\"&$auswahl&".ini", $auswahl)
	$group = IniRead("produktini\"&$auswahl&".ini", 'GroupName', $auswahl, '')
 	$Anzahl = UBound($wahl)
	$groupauswahl = GUICtrlRead($group,$GUI_READ_EXTENDED)


	GUICtrlSetState($groupauswahl, 80)
GUICtrlSetFont(-1, 8, 400, 0, "Arial")
Global $arFuellung[$Anzahl]
For $i = 0 To UBound($arFuellung) -1
	If $i = 0 Then
		$wahl[0][1] = 'Nichts gewählt'
	EndIf
	GUICtrlSetState($arFuellung[$i], 80)
 Next
For $i = 0 To UBound($arFuellung) -2 Step 2
	GUICtrlSetState($arFuellung[0], 80)
    GUICtrlSetState($arFuellung[0], $GUI_CHECKED)
Next
EndFunc

Alles anzeigen

Allerdings Funktioniert das nicht, irgendwie habe ich heute echte Knoten.
Wäre Super wenn mir da auch noch jemand einen Anstoss in die richtige richtung geben könnte.

Vieln Dank im Voraus

**alpines**

Was soll deiner Meinung nach bei einem State von 80 denn passieren? Sind das die Konstanten zusammenaddiert?

Rigobert

Ja genau, also wie im Handbuch beschrieben:
State values can be summed up as for example $GUI_DISABLE (128) + $GUI_HIDE (32) sets the control in an disabled and hidden state

So müsste ja 80 das folgende tun:
$GUI_ENABLE (64)
Control will be enabled.
$GUI_SHOW (16)
Control will be visible. On Tabitem control will select the first tab to be
displayed.

Oder habe ich das Falsch verstanden?
Ich meine bei 160 tut er ja auch was er tun soll.

Danke im Voraus

**alpines**

Zitat von Rigobert

Global $arFuellung[$Anzahl]
For $i = 0 To UBound($arFuellung) -1
If $i = 0 Then
$wahl[0][1] = 'Nichts gewählt'
EndIf
GUICtrlSetState($arFuellung[$i], 80)
Next
For $i = 0 To UBound($arFuellung) -2 Step 2
GUICtrlSetState($arFuellung[0], 80)
GUICtrlSetState($arFuellung[0], $GUI_CHECKED)
Next

Alles anzeigen

Dieser Teil will sich mir absolut nicht erschließen.

Du erstellst ein globales Array mit einer bestimten Anzahl und versuchst dann die States zu setzen.
Schau mal mit _ArrayDisplay() nach ob das Array auch wirklich voll ist, normalerweise müsste es wegen der Neu-Deklaration leer sein.

Außerdem ist die 2. For-Schleife mir ebenfalls schleierhaft, du gehst durchs Array aber veränderst nur den Index 0.

Rigobert

Ja, du hast recht.
Man sollte eine Funktion nicht einfach Kopieren und die States ändern und nicht alles dabei berücksichtigen.
Erstens muss das Global weg, zweitens füllt er mir bei der ersten Funktion zwar das Array, aber ich fülle es immer nur mit den letzten werten.
Gibt es ausser mit Eval noch eine Möglichkeit Variablen zusammen zu führen?

AutoIt

Func fuellungenarray($auswahl)
	$wahl = IniReadSection("produktini\"&$auswahl&".ini", $auswahl)
	$group = IniRead("produktini\"&$auswahl&".ini", 'GroupName', $auswahl, '')
	$groupsettings = IniReadSection("produktini\"&$auswahl&".ini", 'GroupSetting')
	$controlstart = IniReadSection("produktini\"&$auswahl&".ini", 'ControlStart')
 	$Anzahl = UBound($wahl)
	$groupauswahl = GUICtrlCreateGroup($group, $groupsettings[1][1], $groupsettings[2][1],     $groupsettings[3][1], $groupsettings[4][1])
	GUICtrlSetState($groupauswahl, 160)
GUICtrlSetFont(-1, 8, 400, 0, "Arial")
Global $arFuellung[$Anzahl]
For $i = 0 To UBound($arFuellung) -1
	If $i = 0 Then
		$wahl[0][1] = 'Nichts gewählt'
	EndIf
	$arFuellung[$i] = GUICtrlCreateRadio($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1])
	GUICtrlSetState($arFuellung[$i], 160)
 Next
For $i = 0 To UBound($arFuellung) -2 Step 2
    GUICtrlSetState($arFuellung[0], $GUI_CHECKED)
	GUICtrlSetState($arFuellung[0], 160)
Next
GUICtrlCreateGroup("", -99, -99, 1, 1)
EndFunc

Alles anzeigen

Hier beim setzen des Arrays $arFuellung ist der Hund im Pfeffer begraben
Dieses Array wird bei mir immo durch eine Dynamische Anzahl neu befüllt, und natürlich ist immer nur das Letzte befüllen vorhanden.

Ich sagte ja ich denke ich muss da nochmal komplett drüber
Danke dir

**alpines**

Zitat von Rigobert

Dieses Array wird bei mir immo durch eine Dynamische Anzahl neu befüllt, und natürlich ist immer nur das Letzte befüllen vorhanden.

Was du suchst ist ReDim. Wenn du ReDim $aArray[UBound($aArray) + 1] verwendest, wird das Array um eins vergrößert aber alle Elemente bleiben erhalten.
Wenn du es verkleinerst werden alle Indizes die abgeschnitten worden sind entfernt aber der Rest bleibt erhalten.

Zitat von Rigobert

Gibt es ausser mit Eval noch eine Möglichkeit Variablen zusammen zu führen?

Eval solltest du im Normalfall überhaupt nicht verwenden. Wo nutzt du das im Script überhaupt bzw. was willst du erreichen mit "Variablen zusammenführen"?

Rigobert

Danke dir für deine Geduld mit einem Begriffsstutzigen Menschen
Ich habe mir das ganze jetzt nochmal überlegt, ich denke ich sollte das wie ich es in PHP auch machen würde mit einem Array lösen.
Nur habe ich jetzt ein Problem mit den Array in AutoIT.
Ich setze das hier Falsch: Global $arFuellung[$Anzahl]
Hier sollte ich das einfügen denke ich Global $arFuellung[$auswahl][$Anzahl]
Nur $auswahl ist ein String.
Da bringt mir AutoIT einen Fehler
Jetzt habe ich das versucht als String einzusetzen, ["&"$auswahl&"] aber auch da bringt er mir einen Fehler

Ich denke mal ich habe keine Ahnung mehr

**alpines**

Zitat von Rigobert

Danke dir für deine Geduld mit einem Begriffsstutzigen Menschen

Da gabs schon schlimmere.

Zitat von Rigobert

Nur habe ich jetzt ein Problem mit den Array in AutoIT.

In "AutoIT" kenne ich mich nicht aus aber in AutoIt kann ich dir weiterhelfen.

Zitat von Rigobert

Ich denke mal ich habe keine Ahnung mehr

Die Lösung liegt doch auf der Hand. Wenn $auswahl ein String ist und du das als Zahl haben willst, wie wäre es denn wenn du es mal in die Funktion Number gibst?

Rigobert

Das hast du jetzt Falsch verstanden^^
Aber ich habe auch Geduld mit dir^^

Ne das soll ja als String kommen.
In PHP kann ich ja sowas machen über eine DB-Abfrage: $db[Schuh]
In "AutoIt" bekomme ich das aber irgendwie nicht hin

Danke

**alpines**

Achso. Sowas geht in AutoIt standardmäßig mit den Arrays nicht.

Was du suchst ist das Objekt Scripting.Dictionary. Damit kannst du Werte zu Keys zuweisen und sie wie in php ansprechen.
Du kannst ja eine For-Schleife nehmen und durchs Array gehen bis du den Index gefunden hast den du nutzen möchtest.

Rigobert

Hm, dann sollte ich mir evtl. was einfallen lassen für die Inis.
Also nochmal komplett überarbeiten

Danke dir

**alpines**

Zitat von Rigobert

Hm, dann sollte ich mir evtl. was einfallen lassen für die Inis.
Also nochmal komplett überarbeiten

Statt den ausgewählten Text abzuspeichern kannst du den Index abspeichern und die Sache ist gegessen.

Rigobert

Hm, also ich habe das jetzt nochmal neu Definiert in meinem Code sprich etwas überarbeitet.(Also genau das was ich bin nämlich überarbeitet)

Sieht nun so aus:

AutoIt

Func fuellungenarray($auswahl,$setini)
	$wahl = IniReadSection("produktini\"&$auswahl&".ini", $auswahl)
	$group = IniRead("produktini\"&$auswahl&".ini", 'GroupName', $auswahl, '')
	$groupsettings = IniReadSection("produktini\"&$auswahl&".ini", 'GroupSetting')
	$controlstart = IniReadSection("produktini\"&$auswahl&".ini", 'ControlStart')
 	$Anzahl = UBound($wahl)
	$groupauswahl = GUICtrlCreateGroup($group, $groupsettings[1][1], $groupsettings[2][1], $groupsettings[3][1], $groupsettings[4][1])
GUICtrlSetFont(-1, 8, 400, 0, "Arial")
Local $arFuellung[$Anzahl]
For $i = 0 To UBound($arFuellung) -1
	If $i = 0 Then
		$wahl[0][1] = 'Nichts gewählt'
	EndIf
	$arFuellung[$i] = GUICtrlCreateRadio($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1])
		GUICtrlSetState($arFuellung[$i], 160)
 Next
For $i = 0 To UBound($arFuellung) -2 Step 2
    GUICtrlSetState($arFuellung[0], $GUI_CHECKED)
Next
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlSetState($groupauswahl , 160)
EndFunc

Alles anzeigen

Wie man sieht übergebe ich nun noch eine $setini.
Das ist der Indexwert den ich zusätzlich benötige.
Jetzt stelle ich mir die Frage wie kann ich es machen das alles was Relevant ist und Eindeutig sein muss diesen WErt mit zugewiesen bekommt.
$wahl ist ja nun nach der IniReadSection schon ein Array.
Ich hätte das nun gerne so gemacht z.B.:

AutoIt

$wahl_&$setini = IniReadSection("produktini\"&$auswahl&".ini,$auswahl)

So hätte ich eindeutige namen für die Controls.
Aber irgendwie will AutoIt das so nicht schlucken.
Hat mir da vielleicht nochmal jemand einen rat?
Das mit dem ReDim hab ich mir durchgelesen, muss aber zugeben immo übersteigt das mein Verständnis.
Da brauch ich erst wieder etwas ruhe das ich mir das mal verinnerlichen kann.

Danke schonmal im Voraus

P.s: Wahrscheinlich habe ich wieder das offensichtliche übersehen, habt aber bitte nachsicht mit mir

MfG

**autoiter**

Hallo @Rigobert,

Ich meine mit Assign kann es so in der Art machen. Allerdings wäre es wohl am besten ein Array mit den einzelnen IniReadSection-Arrays zu machen, wo dein setini den Index markiert.

AutoIt

Func fuellungenarray($auswahl,$setini)
$aArrayWahlen[$setini] = IniReadSection("produktini\"&$auswahl&".ini,$auswahl)

**alpines**

Zitat von Rigobert

$wahl_&$setini = IniReadSection("produktini\"&$auswahl&".ini,$auswahl)

Dieser Ausdruck ist sowieso falsch. Was wolltest du mit dem denn überhaupt erreichen?

Rigobert

Hi, es geht mir dabei eigentlich nichtmal so um die ReadIniSections.
Mir geht es Hauptsächlich um die eindeutigkeit bei den Controls.
Z.b.:

AutoIt

$groupauswahl[$setini] = GUICtrlCreateGroup($group, $groupsettings[1][1], $groupsettings[2][1], $groupsettings[3][1], $groupsettings[4][1])

Hier ist das ja noch ok.
Aber hier :

AutoIt

Local $arFuellung[$Anzahl]
For $i = 0 To UBound($arFuellung) -1
	If $i = 0 Then
		$wahl[0][1] = 'Nichts gewählt'
	EndIf
	$arFuellung[$i] = GUICtrlCreateRadio($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1])
		GUICtrlSetState($arFuellung[$i], 160)
 Next
For $i = 0 To UBound($arFuellung) -2 Step 2
    GUICtrlSetState($arFuellung[0], $GUI_CHECKED)
Next

Alles anzeigen

Da komme ich immo nicht klar.
Ok, ich denke statt $arFuellung, kann ich da ja $Anzahl einsetzen.
Was dann so aussehen würde:

AutoIt

For $i = 0 To UBound($Anzahl) -1
	If $i = 0 Then
		$wahl[0][1] = 'Nichts gewählt'
	EndIf
	$auswahl[$i] = GUICtrlCreateRadio($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1])
		GUICtrlSetState($auswahl[$i], 160)
 Next
For $i = 0 To UBound($Anzahl) -2 Step 2
    GUICtrlSetState($auswahl[0], $GUI_CHECKED)
Next

Hier denke ich sollte ich irgendwie das Array erweitern.
Also das aus $auswahl[$i] gleich sowas wird wie $auswahl[$setini][$i]
Aber das ist der Punkt wo bugfix ja auch meint das der Knoten im Kopf entsteht

P.s: Ich glaube das ich hier mein Verständnisproblem habe.
Weil ich irgendwie der Meinung bin das es hier ja schon Eindeutig ist, aber die Arrays sagen mir da was anderes immo.
Oder ich bin zu Doof das wirklich zu verstehen
Und genau das würde ich gerne ändern.

Die IniReads sind da eher uninteressant, da ich die ja immer Aktuell auslese wenn ich die Controls erstelle.
Wirklich erreichen will ich dadurch eigentlich nur das wie schon gesagt meine Controls alle Eindeutig sind, was sie immo nicht sind.
Beim Befüllen werden diese immo dauernd überschrieben bis zum letzten und das ist dann auch das einzige das ich wirklich ansprechen kann
Denn diese Funktion wird ja in der GUI erstellung aufgerufen:

AutoIt

For $i = 1 To $AnzahlProduktKategorien
 	fuellungenarray($auswahlKategorien[$i][1],$i)
Next

Hier sollen die GuiControls erstellt werden und dann entsprechend Hide und Disable.
Da die Erste Auswahl Gruppe in der Gui immer an 2ter Stelle steht also feste gleiche Coords haben.
Je nach Auswahl aus der ersten Gruppe die ja "Dynamisch" Statisch ist, soll dann die 2te Gruppe Angezeigt werden.
Dann nach Auswahl aus der 2ten Gruppe wird die 3te angezeigt usw. usw.
Das ganze soll eine Art Beschreibungstext Maschine werden.
Da wir sehr viele gleiche Produkte haben die sich im Text und in der Beschreibung nur in ein paar dingen unterscheiden, diese will ich hier zusammenfassen um dann den Text aus einem Block mit den Entsprechenden werten anzupassen.
Also z.B. Textblock: Dies ist ein [Produkt] aus der [Kategorie], es hat die Maße: [Groesse] und das Gewicht beträgt: [Gewicht] die Farbe ist: [Farbe]

usw. usw.
Dabei geht es mir darum das solche Fehler beim Copy und Paste nicht mehr vorkommen die man macht wenn man diese Texte Tausendfach von Hand bearbeitet.
Ich will das nur noch oben Auswählen und dann wird der Textblock geladen und die Vars im Text mit den Daten aus der Auswahl der Gui gefüllt.

Ich hoffe das war soweit verständlich erklärt.
Was ich sonst noch habe sind verschiedene Textblöcke, diese habe ich aber in der Gui schon drin.
Also die Inis werden aus der gleichen Gui befüllt.
In dieser sind einfach verschiedene Tabs und verschiedene kleine Guis die für die Einstellungen zuständig sind.
Dies ist alles schon fertig.
Nur hier mit der sache tu ich mich echt schwer.
Der Rest der Guis ist mit seinen Controls eh Statisch also kein Problem gewesen.
Schön Aufgebaut und selbst erklärend^^

Danke im Voraus für eure Geduld

MfG

**autoiter**

Hey @Rigobert,
ich verstehe den Code nicht komplett. Aber ändere doch mal bei deinem ersten Code..

AutoIt

Local $arFuellung[$Anzahl]
For $i = 0 To UBound($arFuellung) -1
	If $i = 0 Then
		$wahl[0][1] = 'Nichts gewählt' ; Was soll das?
	EndIf
	$arFuellung[$i] = GUICtrlCreateRadio($wahl[$i][1], $controlstart[1][1], $controlstart[2][1] + 20*$i, $controlstart[3][1], $controlstart[4][1])
		GUICtrlSetState($arFuellung[$i], 160)
 Next
For $i = 0 To UBound($arFuellung) -2 Step 2
    GUICtrlSetState($arFuellung[0], $GUI_CHECKED) ; Hier Setzt du immer den Wert vom Control $arFuellung[0]. Deshalb wird es überschrieben, statt dass das nächste den Wert bekommt. Also $arFuellung[$i]
Next

Alles anzeigen

Rigobert

Oh sorry, das war ein versehen wegen dem Copy und Paste
Darum dieses Script.

Hier soll ja das State der [0] auf Checked gesetzt werden.
Da muss ich die For entfernen, danke für den Hinweis.
Das muss eigentlich nur heisen:

GUICtrlSetState($arFuellung[0], $GUI_CHECKED)

An der stelle geht es ja um den Initialen Aufruf der Gui.
Glatt übersehen

**Kanashius**

Hmmm... So wie ich das Verstanden hab wäre die Verwendung von Comboboxen recht sinnvoll. Dort trifft man ja aus mehreren Werten eine Auswahl...
Ich hab da mal zum erstellen von SQL-Befehlen was gebaut, vielleicht ist das in etwa deine Struktur/was du brauchen könntest:

AutoIt

#include <GuiScrollBars.au3>
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiComboBoxEx.au3>


Global Const $SIF_DISABLENOSCROLL = 0x8
Global $iWidth = 800, $iHeight = 600, $iScrollControlHeight = 25, $iEntryColWidth = 150, $iEntryOperWidth = 40,$iScrollControllHeightSpace=5,$iScrollControllWidthSpace=5
Global $iLastItemWidth,$iLastItemHeigt,$iLastHorizontalScrolled,$iLastVerticalScrolled
Global $arCols = [["Name", "col"], ["Name2", "col2"]],$arOper=["+","-","*","/"],$arScrollControls[0],$sNoSelection="- -"


$hMainGui = GUICreate("Export", $iWidth, $iHeight,-1,-1,BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU,$WS_MAXIMIZEBOX,$WS_SIZEBOX))
$hAddRow = GUICtrlCreateButton("Add Col", 5, $iHeight - 30, 60, 25)
$hReady = GUICtrlCreateButton("Ready", $iWidth-65, $iHeight - 30, 60, 25)




$hScrollGui=GUICreate("",$iWidth-15,$iHeight-40,5,5,$WS_CHILD,$WS_EX_CLIENTEDGE,$hMainGui)
GUISetState(@SW_SHOW,$hScrollGui)


GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_VSCROLL, "WM_VSCROLL")
GUIRegisterMsg($WM_HSCROLL, "WM_HSCROLL")


GUISetState(@SW_SHOW,$hMainGui)
_GUIScrollBars_Init($hScrollGui)
_GUIScrollBars_ShowScrollBar($hScrollGui,$SB_BOTH,true)


While 1
	$msg = GUIGetMsg(1)
	if $msg[1]=$hMainGui then
		Switch $msg[0]
			case -3
				exit
			case $hAddRow
				_addScrollControl()
			case $hReady
				_getResult()
		EndSwitch
	else
		for $i=0 to UBound($arScrollControls)-1 step 1
			local $tmp=$arScrollControls[$i]
			for $j=0 to UBound($tmp)-1 step 1
				if $msg[0]=$tmp[$j] then
					if $j=0 then
						;exit
						_removeControl($i)
					elseif $j=1 then
						;top
						_switchControl($i,$i-1)
					elseif $j=2 then
						;down
						_switchControl($i,$i+1)
					;3 nicht notwendig (spaltenname)
					elseif $j>3 then
						if Mod($j,2)=0 then ;combo
							if GUICtrlRead($tmp[$j])=$sNoSelection then
								_removeAllControlsBehind($i,$j)
							else
								if NOT $j<UBound($tmp) then ;ist letztes Item
									_addOper($i)
								endif
							endif
						else ;oper
							if GUICtrlRead($tmp[$j])=$sNoSelection then
								_removeAllControlsBehind($i,$j)
							else
								if NOT $j<UBound($tmp) then ;ist letztes Item
									_addCombo($i)
								endif
							endif
						endif
					endif
					ExitLoop 2
				endif
			next
		next
	endif
WEnd


Func _getResult()
	local $sResult=""
	for $i=0 to UBound($arScrollControls)-1 step 1
		local $tmp=$arScrollControls[$i]
		local $string="Spaltenname: "&GUICtrlRead($tmp[3])&" Aufbau: "
		for $j=4 to UBound($tmp)-1 step 1
			if Mod($j,2)=0 then ;combo
				$index=_GUICtrlComboBoxEx_GetCurSel(GUICtrlGetHandle($tmp[$j]))
				if $index>0 then
					$string&=$arCols[$index-1][1]&" "
				endif
			else ;operant
				if GUICtrlRead($tmp[$j])<>$sNoSelection then
					$string&=GUICtrlRead($tmp[$j])&" "
				endif
			endif
		next
		$sResult&=$string&@crlf
	next
	MsgBox(48,"",$sResult)
EndFunc


Func _addCombo($index)
	local $iTopSpace=5+$iScrollControllHeightSpace+($index*($iScrollControlHeight+$iScrollControllHeightSpace))
	local $tmp=$arScrollControls[$index]
	ReDim $tmp[UBound($tmp)+1]
	local $elements=UBound($tmp)-1
	local $spaces=$iScrollControllWidthSpace*($elements-3)
	local $combos=$iEntryColWidth*Int(($elements-4)/2+0.5)
	local $opers=$iEntryOperWidth*(Int(($elements-4)/2))
	$tmp[UBound($tmp)-1]=GUICtrlCreateCombo($sNoSelection,80+$iEntryColWidth+$spaces+$combos+$opers+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,$iEntryColWidth,$iScrollControlHeight)
	GUICtrlSetFont(-1,$iScrollControlHeight-15)
	GUICtrlSetData(-1,_getColString())
	$arScrollControls[$index]=$tmp
	_setHoriScroll()
EndFunc


Func _addOper($index)
	local $iTopSpace=5+$iScrollControllHeightSpace+($index*($iScrollControlHeight+$iScrollControllHeightSpace))
	local $tmp=$arScrollControls[$index]
	ReDim $tmp[UBound($tmp)+1]
	local $elements=UBound($tmp)-1
	local $spaces=$iScrollControllWidthSpace*($elements-3)
	local $combos=$iEntryColWidth*Int(($elements-4)/2+0.5)
	local $opers=$iEntryOperWidth*(Int(($elements-4)/2))
	$tmp[UBound($tmp)-1]=GUICtrlCreateCombo($sNoSelection,80+$iEntryColWidth+$spaces+$combos+$opers+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,$iEntryOperWidth,$iScrollControlHeight)
	GUICtrlSetFont(-1,$iScrollControlHeight-15)
	GUICtrlSetData(-1,_getOperString())
	$arScrollControls[$index]=$tmp
	_setHoriScroll()
EndFunc


Func _removeAllControlsBehind($index,$j)
	local $tmp=$arScrollControls[$index]
	for $i=$j+1 to UBound($tmp)-1 step 1
		GUICtrlDelete($tmp[$i])
	next
	ReDim $tmp[$j+1]
	$arScrollControls[$index]=$tmp
EndFunc


Func _addScrollControl()
	GUISwitch($hScrollGui)
	if UBound($arScrollControls)>0 then
		local $arControlsLast=$arScrollControls[UBound($arScrollControls)-1]
		GUICtrlSetState($arControlsLast[2],$GUI_ENABLE)
	endif
	ReDim $arScrollControls[UBound($arScrollControls)+1]
	local $arControls[5],$iActEntry=UBound($arScrollControls)-1,$iTopSpace=5+$iScrollControllHeightSpace+($iActEntry*($iScrollControlHeight+$iScrollControllHeightSpace))
	$arControls[0]=GUICtrlCreateButton("X",5+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,20,$iScrollControlHeight)
	$arControls[1]=GUICtrlCreateButton(ChrW(8679),30+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,20,$iScrollControlHeight)
	if UBound($arScrollControls)=1 then GUICtrlSetState(-1,$GUI_DISABLE)
	GUICtrlSetFont(-1,20)
	$arControls[2]=GUICtrlCreateButton(ChrW(8681),55+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,20,$iScrollControlHeight)
	GUICtrlSetFont(-1,20)
	GUICtrlSetState(-1,$GUI_DISABLE)
	$arControls[3]=GUICtrlCreateInput("",80+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,$iEntryColWidth,$iScrollControlHeight)
	GUICtrlSendMsg(-1, 0x1501, 0, "Spaltenname")
	GUICtrlSetFont(-1,$iScrollControlHeight-15)
	$arControls[4]=GUICtrlCreateCombo($sNoSelection,80+$iEntryColWidth+$iScrollControllWidthSpace+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,$iEntryColWidth,$iScrollControlHeight)
	GUICtrlSetData(-1,_getColString())
	GUICtrlSetFont(-1,$iScrollControlHeight-15)
	$arScrollControls[$iActEntry]=$arControls
	_setVertScroll()
	_setHoriScroll()
EndFunc


Func _switchControl($i,$j)
	local $tmpI=$arScrollControls[$i]
	local $tmpJ=$arScrollControls[$j]
	$arScrollControls[$i]=$tmpJ
	$arScrollControls[$j]=$tmpI
	$iTopSpaceJ=5+$iScrollControllHeightSpace+($i*($iScrollControlHeight+$iScrollControllHeightSpace))
	for $k=0 to UBound($tmpJ)-1 step 1
		ControlMove($hScrollGui,"",$tmpJ[$k],ControlGetPos($hScrollGui,"",$tmpJ[$k])[0]-7+$iLastHorizontalScrolled,$iTopSpaceJ+$iLastVerticalScrolled)
	next
	$iTopSpaceI=5+$iScrollControllHeightSpace+($j*($iScrollControlHeight+$iScrollControllHeightSpace))
	for $k=0 to UBound($tmpI)-1 step 1
		ControlMove($hScrollGui,"",$tmpI[$k],ControlGetPos($hScrollGui,"",$tmpI[$k])[0]-7+$iLastHorizontalScrolled,$iTopSpaceI+$iLastVerticalScrolled)
	next
	if $i=0 then
		GUICtrlSetState($tmpI[1],$GUI_ENABLE)
		GUICtrlSetState($tmpJ[1],$GUI_DISABLE)
	endif
	if $j=0 then
		GUICtrlSetState($tmpJ[1],$GUI_ENABLE)
		GUICtrlSetState($tmpI[1],$GUI_DISABLE)
	endif
	if $i=UBound($arScrollControls)-1 then
		GUICtrlSetState($tmpI[2],$GUI_ENABLE)
		GUICtrlSetState($tmpJ[2],$GUI_DISABLE)
	endif
	if $j=UBound($arScrollControls)-1 then
		GUICtrlSetState($tmpJ[2],$GUI_ENABLE)
		GUICtrlSetState($tmpI[2],$GUI_DISABLE)
	endif
	_WinAPI_RedrawWindow($hScrollGui)
EndFunc


Func _removeControl($i)
	local $tmp=$arScrollControls[$i]
	for $j=0 to UBound($tmp)-1 step 1
		GUICtrlDelete($tmp[$j])
	next
	for $j=$i+1 to UBound($arScrollControls)-1 step 1
		$arScrollControls[$j-1]=$arScrollControls[$j]
		local $tmp=$arScrollControls[$j-1]
		$iTopSpace=5+$iScrollControllHeightSpace+(($j-1)*($iScrollControlHeight+$iScrollControllHeightSpace))
		for $k=0 to UBound($tmp)-1 step 1
			ControlMove($hScrollGui,"",$tmp[$k],ControlGetPos($hScrollGui,"",$tmp[$k])[0]-7+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled)
		next
	next
	ReDim $arScrollControls[UBound($arScrollControls)-1]
	_setVertScroll()
	_WinAPI_RedrawWindow($hScrollGui)
EndFunc


Func _setVertScroll()
	local $elements=UBound($arScrollControls)
	local $clientHeight=WinGetPos($hScrollGui)[3]
	local $itemHeight=($iScrollControlHeight+$iScrollControllHeightSpace)
	$iLastItemHeigt=$itemHeight
	Local $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)
    DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE,$SIF_DISABLENOSCROLL))
    DllStructSetData($tSCROLLINFO, "nMin", 0)
    DllStructSetData($tSCROLLINFO, "nMax", $elements)
    DllStructSetData($tSCROLLINFO, "nPage", int($clientHeight/$itemHeight))
    _GUIScrollBars_SetScrollInfo(HWnd($hScrollGui), $SB_VERT, $tSCROLLINFO)
EndFunc


Func _setHoriScroll()
	local $elements=0
	for $i=0 to UBound($arScrollControls)-1 step 1
		if $elements<UBound($arScrollControls[$i]) then
			$elements=UBound($arScrollControls[$i])
		endif
	next
	local $clientWidth=WinGetPos($hScrollGui)[2]
	local $spaces=$iScrollControllWidthSpace*($elements-3)
	local $combos=$iEntryColWidth*Int(($elements-4)/2+0.5)
	local $opers=$iEntryOperWidth*(Int(($elements-4)/2))
	local $itemWidth=(80+$iEntryColWidth+$spaces+$combos+$opers)/$elements
	$iLastItemWidth=$itemWidth
	Local $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)
    DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE,$SIF_DISABLENOSCROLL))
    DllStructSetData($tSCROLLINFO, "nMin", 0)
    DllStructSetData($tSCROLLINFO, "nMax", $elements)
    DllStructSetData($tSCROLLINFO, "nPage", int($clientWidth/$itemWidth))
    _GUIScrollBars_SetScrollInfo(HWnd($hScrollGui), $SB_HORZ, $tSCROLLINFO)
EndFunc


Func _getColString()
	local $string=""
	for $i=0 to UBound($arCols)-1 step 1
		$string&=$arCols[$i][0]
		if $i<>UBound($arCols)-1 then
			$string&="|"
		endif
	next
	return $string
EndFunc


Func _getOperString()
	local $string=""
	for $i=0 to UBound($arOper)-1 step 1
		$string&=$arOper[$i]
		if $i<>UBound($arOper)-1 then
			$string&="|"
		endif
	next
	return $string
EndFunc


Func WM_SIZE($hWnd, $Msg, $wParam, $lParam)
	_setVertScroll()
	_setHoriScroll()
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE


Func WM_HSCROLL($hWnd, $Msg, $wParam, $lParam)
	Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
	local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_HORZ)
    $iMin = DllStructGetData($tSCROLLINFO, "nMin")
    $iMax = DllStructGetData($tSCROLLINFO, "nMax")
    $iPage = DllStructGetData($tSCROLLINFO, "nPage")
    $iPosX = DllStructGetData($tSCROLLINFO, "nPos")
    $iPos = $iPosX
    $iTrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
    #forceref $iMin, $iMax
    Switch $iScrollCode
        Case $SB_LINELEFT ; user clicked left arrow
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - 1)
        Case $SB_LINERIGHT ; user clicked right arrow
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + 1)
        Case $SB_PAGELEFT ; user clicked the scroll bar shaft left of the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - $iPage)
        Case $SB_PAGERIGHT ; user clicked the scroll bar shaft right of the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + $iPage)
        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iTrackPos)
    EndSwitch
    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    $iPos = DllStructGetData($tSCROLLINFO, "nPos")
	If ($iPos <> $iPosX) Then
		_GUIScrollBars_ScrollWindow($hWnd, $iLastItemWidth * ($iPosX - $iPos), 0)
		$iLastHorizontalScrolled+=$iLastItemWidth * ($iPosX - $iPos)
	endif
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_HSCROLL


Func WM_VSCROLL($hWnd, $Msg, $wParam, $lParam)
	Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
	Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
    $iMin = DllStructGetData($tSCROLLINFO, "nMin")
    $iMax = DllStructGetData($tSCROLLINFO, "nMax")
    $iPage = DllStructGetData($tSCROLLINFO, "nPage")
    $iPosY = DllStructGetData($tSCROLLINFO, "nPos")
    $iPos = $iPosY
    $iTrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
    Switch $iScrollCode
        Case $SB_TOP ; user clicked the HOME keyboard key
            DllStructSetData($tSCROLLINFO, "nPos", $iMin)
        Case $SB_BOTTOM ; user clicked the END keyboard key
			DllStructSetData($tSCROLLINFO, "nPos", $iMax)
        Case $SB_LINEUP ; user clicked the top arrow
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - 1)
        Case $SB_LINEDOWN ; user clicked the bottom arrow
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + 1)
        Case $SB_PAGEUP ; user clicked the scroll bar shaft above the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - $iPage)
        Case $SB_PAGEDOWN ; user clicked the scroll bar shaft below the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + $iPage)
        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iTrackPos)
    EndSwitch
    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    $iPos = DllStructGetData($tSCROLLINFO, "nPos")
    If ($iPos <> $iPosY) Then
        _GUIScrollBars_ScrollWindow($hWnd, 0, $iLastItemHeigt * ($iPosY - $iPos))
		$iLastVerticalScrolled+=$iLastItemHeigt * ($iPosY - $iPos)
        $iPosY = $iPos
    EndIf
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL

Alles anzeigen

Hierbei wird bei der Auswahl eines Operanden die nächste Combobox erstellt und das ganze beliebig oft.
Zusätzlich kann man beliebig viele Spalten erstellen.
Bei dir wäre das: Je Produkt wird die 1te Auswahl getroffen, dann die 2te,...
Sollte recht leicht anpassbar sein

**autoiter**

Ich finde deine paar Zeilen Code schon schwer zu lesen

Die For Schleife sollte da also gar nicht hin? Dann bezieht sich

Zitat von Rigobert

Ok, ich denke statt $arFuellung, kann ich da ja $Anzahl einsetzen.

nur auf die erste Schleife?

Im ersten Code (Beitrag 16) schreibst du

AutoIt

Local $arFuellung[$Anzahl]

dann meinst du, "$arFuellung, kann ich da ja (durch) $Anzahlkönnte" ersetzen und machst im zweiten Code:

AutoIt

For $i = 0 To UBound($Anzahl) -1

Ist Anzahl hier die selbe Variable wie oben? (Hier hast du die Deklaration nicht mit im Code, daher kann ich nicht sicher sein).
Wenn ja, dann ist das ein Fehler. Wenn $Anzahl nur eine Variable mit der Anzahl der Elemente eines Arrays ist, brauchst du kein/kannst du kein Ubound verwenden, womit du die Anzahl der Elemente eines Array ermittelst. Auf eine Variable angewendet führt das zu einem Fehler.
Du könntest das durch

AutoIt

For $i = 0 To $Anzahl ; oder $Anzahl -1, wenn notwendig.

ersetzen. Dann passiert hier auch etwas in der Schleife.

Hierzu frage ich mich,

Zitat von Rigobert

Also das aus $auswahl[$i] gleich sowas wird wie $auswahl[$setini][$i]

was ist denn $setini? Wenn du $setini einen Zahlenwert wie 0, 1, 2 usw. gibst, kann das doch als Indexwert von $auswahl dienen. $auswahl[1] ist dann gleich $auswahl[$setini], wenn $setini den Wert 1 hat. Das wäre eindeutig.

Prinzipiell schau dir mal das hier an: https://www.autoitscript.com/wiki/Best_coding_practices

Der Code wäre viel leichter nachvollziehbarer, wenn du dich an Regeln für die Benennung deiner Variablen halten würdest. (Ausführbare Beispiele sind auch nie schlecht ).