Funktionen zur Anzeige von Markierungen

**autoiter**

Hallo Leute,

ich wollte mir einige Funktionen zusammenbasteln, um Markierungen auf allen möglichen Fenstern anzuzeigen. Als Alternative zu Videotutorials, soll das Anlernen neuer Arbeitsvorgänge an einem konkret vorliegendem Fall möglich sein. Markierungen und Text-/Audioanleitungen sollen dabei unterstützen.

Erst wollte ich es ganz ohne GDI+ machen, weil ich davon keine Ahnung habe. Mit GDI+ könnte ich aber auch Pfeile nutzen oder die Boxen variieren. Allerdings krampfe mir da einen ab. Kennt jemand hier vielleicht ein schon bestehendes Projekt, das ich nutzen kann?

Bei meinem ersten Versuch blenden die Boxen schön aus (_WinAPI_AnimateWindow($aDeleteHandles[$i], BitOR($AW_BLEND, $AW_HIDE), 500) Zeile 221).

Wie kann man das mit GDI+ machen?

Zur Veranschaulichung mal meine beiden Versuche. Es gibt mehrere Beispiele (auskommentiert).
Ohne GDI+

Spoiler anzeigen

AutoIt

; Zu den Funktionen __HintBoxes_GuiHole und __HintBoxes_AddCtrlRegion siehe Hilfe etwa zu _WinAPI_CreateRoundRectRgn


#include-once
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <WinAPISys.au3>
#include <Array.au3>


;~ Example1()
;~ Example2()
;~ Example3()
Example4()


Func Example1()
	MsgBox(0, "Beispiel 1", "Zwei Markierungen werden um angegebene Positionen mit einem Timeout von 2 Sekunden angezeigt.")


	Local $aCoords[2][5] = [[50, 50, 100, 200, 0xFFE9A2], [500, 500, 300, 500, 0x616161]]
	Local $hBox = _HintBoxes_By_Pos($aCoords, 15, 1000)


EndFunc   ;==>Example1


Func Example2()
	MsgBox(0, "Beispiel 2", "Der Editor wird geöffnet und ein Markierung darum mit einem Timeout von 1 Sekunde angezeigt.")


	Run("notepad.exe")
	WinWait("[CLASS:Notepad]", "", 10)
	Local $hWnd = WinGetHandle("[CLASS:Notepad]")


	_HintBoxes_By_Handle($hWnd, "", 10, 1000)


	WinClose("[CLASS:Notepad]")
EndFunc   ;==>Example2


Func Example3()
	MsgBox(0, "Beispiel 3", "Eine GUI wird eingeblendet und zwei Markierungen in unterschiedlichen Farben mit einem Timeout von 2 Sekunden angezeigt.")
	Local $hGui = GUICreate("Test", 350, 210)
	Local $id_Input = GUICtrlCreateInput("", 20, 30, 200, 25)
	Local $id_Input2 = GUICtrlCreateInput("", 20, 60, 200, 25)
	GUISetState(@SW_SHOW)


	Local $aControlIDs[2] = [$id_Input, $id_Input2]
	Local $aColors[2] = [0xFFE9A2, 0x616161]


	_HintBoxes_By_Handle($hGui, $aControlIDs, 5, 2000, $aColors)


	GUIDelete($hGui)
EndFunc   ;==>Example3


Func Example4()
	Local $hGui = GUICreate("Test", 350, 210)
	Local $id_Input = GUICtrlCreateInput("", 20, 30, 200, 25)
	Local $id_Button_Show = GUICtrlCreateButton("1. Marker einblenden", 25, 170, 120, 25)
	Local $id_Button_Hide = GUICtrlCreateButton("Alle Marker ausblenden", 180, 170, 140, 25)


	GUISetState(@SW_SHOW)
	Local $hBox1, $hBox2, $iCounter = 1
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $id_Button_Show


				If $iCounter = 1 Then
					$hBox1 = _HintBoxes_By_Handle($hGui, $id_Input, 5, 0, 0xFFE9A2)
					GUICtrlSetData($id_Button_Show, "2. Marker einblenden")
					$iCounter += 1
				ElseIf $iCounter = 2 Then
					$hBox2 = _HintBoxes_By_Handle($hGui, "", 5, 0, 0x616161)
					GUICtrlSetData($id_Button_Show, "2. Marker löschen")
					$iCounter += 1
				Else
					_Delete_HintBoxes($hBox2)
					GUICtrlSetData($id_Button_Show, "2. Marker einblenden")
					$iCounter -= 1
				EndIf
			Case $id_Button_Hide
				_Delete_HintBoxes()
				GUICtrlSetData($id_Button_Show, "1. Marker einblenden")
				$iCounter = 1
		EndSwitch
	WEnd


	GUIDelete($hGui)
EndFunc   ;==>Example4


















Func _HintBoxes_By_Handle($hWnd, $vControls = "", $iStrength = 5, $iDuration = 2000, $vColor = 0xB10000)


	Local $aPos = WinGetPos($hWnd)


	; get height of window title and width of window frame - may be different when XP theme is ON/OFF
	Local $g_iHtit = _WinAPI_GetSystemMetrics($SM_CYCAPTION)
	Local $g_iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)


	Local $hGui = GUICreate("", $aPos[2] + $iStrength * 4, $aPos[3] + $iStrength * 4, $aPos[0] - $iStrength * 2, $aPos[1] - $iStrength * 2, -1, $WS_EX_TOPMOST + $WS_EX_TOOLWINDOW)


	__HintBoxes_HandlesArray($hGui)


	If IsArray($vControls) Then
		If Not IsArray($vColor) Then Return 0
		If UBound($vControls) <> UBound($vColor) Then Return 0
		Local $aControls[UBound($vControls)], $aColor[UBound($vColor)]
		For $i = 0 To UBound($vControls) - 1
			$aControls[$i] = $vControls[$i]
			$aColor[$i] = $vColor[$i]
		Next
		Local $ah_LabelIDs[UBound($vControls) * 4]
	Else
		Local $ah_LabelIDs[4]
		Local $aControls[1], $aColor[1]
		$aControls[0] = $vControls
		$aColor[0] = $vColor
		If $vControls = "" Then
			WinMove($hGui, "", $aPos[0] - $iStrength * 2, $aPos[1] - $iStrength * 2 - $g_iHtit - $g_iFrame)
			$aPos[0] = 0
			$aPos[1] = 0
			$aPos[3] = $aPos[3]
		EndIf
	EndIf


	For $i = 0 To UBound($aControls) - 1
		If $vControls <> "" Then
			$aPos = ControlGetPos($hWnd, "", $aControls[$i])
		EndIf
		$ah_LabelIDs[$i * 4] = GUICtrlCreateLabel("", $aPos[0] + $iStrength, $aPos[1] + $iStrength, $iStrength, $aPos[3] + $iStrength) ; Left
		GUICtrlSetBkColor(-1, $aColor[$i])
		$ah_LabelIDs[$i * 4 + 1] = GUICtrlCreateLabel("", $aPos[0] + $iStrength, $aPos[1] + $iStrength, $aPos[2] + $iStrength, $iStrength) ; Top
		GUICtrlSetBkColor(-1, $aColor[$i])
		$ah_LabelIDs[$i * 4 + 2] = GUICtrlCreateLabel("", $aPos[0] + $aPos[2] + $iStrength, $aPos[1] + $iStrength, $iStrength, $aPos[3] + $iStrength) ; Right
		GUICtrlSetBkColor(-1, $aColor[$i])
		$ah_LabelIDs[$i * 4 + 3] = GUICtrlCreateLabel("", $aPos[0] + $iStrength, $aPos[1] + $aPos[3] + $iStrength, $aPos[2] + $iStrength, $iStrength) ; Bottom
		GUICtrlSetBkColor(-1, $aColor[$i])
	Next
	__HintBoxes_GuiHole($hGui, 0, 0, $aPos[2], $aPos[3], $ah_LabelIDs, $g_iHtit, $g_iFrame)
	WinActivate($hWnd)
	GUISetState(@SW_SHOWNA)


	If $iDuration = 0 Then Return $hGui


	Sleep($iDuration)
	_Delete_HintBoxes($hGui)
EndFunc   ;==>_HintBoxes_By_Handle


Func _HintBoxes_By_Pos($aAreas, $iStrength = 5, $iDuration = 2000)
	If Not IsArray($aAreas) Then Return 0


	Local $iCols = UBound($aAreas, $UBOUND_COLUMNS)
	If $iCols < 4 Then Return 0
	Local $hexColorDefault = 0xB10000, $hexColor, $bColors = False
	If $iCols = 5 Then $bColors = True


	Local $iWidth = @DesktopWidth
	Local $iHeight = @DesktopHeight


	Local $hGui = GUICreate("", $iWidth, $iHeight, 0, 0, -1, $WS_EX_TOPMOST + $WS_EX_TOOLWINDOW)


	__HintBoxes_HandlesArray($hGui)


	Local $g_iHtit = _WinAPI_GetSystemMetrics($SM_CYCAPTION)
	Local $g_iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)


	Local $ah_LabelIDs[UBound($aAreas) * 4]


	For $i = 0 To UBound($aAreas) - 1


		If $bColors Then
			If $aAreas[$i][4] <> "" Then
				$hexColor = $aAreas[$i][4]
			Else
				$hexColor = $hexColorDefault
			EndIf
		Else
			$hexColor = $hexColorDefault
		EndIf
		$ah_LabelIDs[$i * 4] = GUICtrlCreateLabel("", $aAreas[$i][0] - $iStrength * 2 + $iStrength * 2, $aAreas[$i][1] - $iStrength * 2 + $iStrength * 2, $iStrength, $aAreas[$i][3] + $iStrength * 4) ; Left
		GUICtrlSetBkColor(-1, $hexColor)
		$ah_LabelIDs[$i * 4 + 1] = GUICtrlCreateLabel("", $aAreas[$i][0] - $iStrength + $iStrength * 2, $aAreas[$i][1] - $iStrength * 2 + $iStrength * 2, $aAreas[$i][2] + $iStrength * 2, $iStrength) ; Top
		GUICtrlSetBkColor(-1, $hexColor)
		$ah_LabelIDs[$i * 4 + 2] = GUICtrlCreateLabel("", $aAreas[$i][0] + $aAreas[$i][2] + $iStrength + $iStrength * 2, $aAreas[$i][1] - $iStrength * 2 + $iStrength * 2, $iStrength, $aAreas[$i][3] + $iStrength * 4) ; Right
		GUICtrlSetBkColor(-1, $hexColor)
		$ah_LabelIDs[$i * 4 + 3] = GUICtrlCreateLabel("", $aAreas[$i][0] - $iStrength + $iStrength * 2, $aAreas[$i][1] + $aAreas[$i][3] + $iStrength + $iStrength * 2, $aAreas[$i][2] + $iStrength * 2, $iStrength) ; Bottom
		GUICtrlSetBkColor(-1, $hexColor)
	Next


	__HintBoxes_GuiHole($hGui, 0, 0, $iWidth, $iHeight, $ah_LabelIDs, $g_iHtit, $g_iFrame)
	GUISetState(@SW_SHOWNA)


	If $iDuration = 0 Then Return $hGui


	Sleep($iDuration)
	_Delete_HintBoxes($hGui)


EndFunc   ;==>_HintBoxes_By_Pos


Func _Delete_HintBoxes($hGui = "")
	If $hGui = "" Then
		Local $aDeleteHandles = __HintBoxes_HandlesArray("", False)
	Else
		Local $aDeleteHandles = __HintBoxes_HandlesArray($hGui, False)
	EndIf
	If Not @error Then
		For $i = 0 To UBound($aDeleteHandles) - 1
			_WinAPI_AnimateWindow($aDeleteHandles[$i], BitOR($AW_BLEND, $AW_HIDE), 500)
		Next
	EndIf
EndFunc   ;==>_Delete_HintBoxes










Func __HintBoxes_GuiHole($hWin, $iX, $iY, $iSizeW, $iSizeH, $ah_LabelIDs, $g_iHtit = 0, $g_iFrame = 0)
	Local $hOuter_rgn, $hInner_rgn, $hCombined_rgn


	$hOuter_rgn = _WinAPI_CreateRectRgn(0, 0, $iSizeW, $iSizeH)
	$hInner_rgn = _WinAPI_CreateRectRgn($iX, $iY, $iX + $iSizeW, $iY + $iSizeH)
	$hCombined_rgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
	_WinAPI_CombineRgn($hCombined_rgn, $hOuter_rgn, $hInner_rgn, $RGN_DIFF)
	_WinAPI_DeleteObject($hOuter_rgn)
	_WinAPI_DeleteObject($hInner_rgn)
	For $i = 0 To UBound($ah_LabelIDs) - 1
		__HintBoxes_AddCtrlRegion($hCombined_rgn, $ah_LabelIDs[$i], $hWin, $g_iHtit, $g_iFrame)
	Next
	_WinAPI_SetWindowRgn($hWin, $hCombined_rgn)
EndFunc   ;==>__HintBoxes_GuiHole


Func __HintBoxes_AddCtrlRegion($hFull_rgn, $idCtrl, $hWin, $g_iHtit, $g_iFrame)
	Local $aCtrl_pos, $hCtrl_rgn


	$aCtrl_pos = ControlGetPos($hWin, "", $idCtrl)
	$hCtrl_rgn = _WinAPI_CreateRectRgn($aCtrl_pos[0] + $g_iFrame, $aCtrl_pos[1] + $g_iHtit + $g_iFrame, _
			$aCtrl_pos[0] + $aCtrl_pos[2] + $g_iFrame, $aCtrl_pos[1] + $aCtrl_pos[3] + $g_iHtit + $g_iFrame)
	_WinAPI_CombineRgn($hFull_rgn, $hFull_rgn, $hCtrl_rgn, $RGN_OR)
	_WinAPI_DeleteObject($hCtrl_rgn)
EndFunc   ;==>__HintBoxes_AddCtrlRegion


Func __HintBoxes_HandlesArray($hGui = "", $bAdd = True)
	Local Static $aHandles[0]
	If $bAdd Then
		_ArrayAdd($aHandles, $hGui)
	Else
		If $hGui = "" Then
			Local $aDeleteHandles = $aHandles
			ReDim $aHandles[0]
			Return $aDeleteHandles
		Else
			$iIndex = _ArraySearch($aHandles, $hGui)
			If Not @error Then
				Local $aDeleteHandles[1] = [$aHandles[$iIndex]]
				_ArrayDelete($aHandles, $iIndex)
				Return $aDeleteHandles
			Else
				Return SetError(1)
			EndIf
		EndIf
	EndIf
EndFunc   ;==>__HintBoxes_HandlesArray

Alles anzeigen

Mit GDI+

Spoiler anzeigen

AutoIt

_GDIPlus_Startup()




;~ Example1()
;~ Example2()
;~ Example3()
Example4()








Func Example1()
	MsgBox(0, "Beispiel 1", "Zwei Markierungen werden um angegebene Positionen mit einem Timeout von 2 Sekunden angezeigt.")


	Local $aCoords[2][5] = [[50, 50, 100, 200, 0xFFFF0000], [500, 500, 300, 500, 0xFF000000]]
	Local $hBox = _HintBoxes_By_Pos($aCoords, 15, 1000)


EndFunc   ;==>Example1


Func Example2()
	MsgBox(0, "Beispiel 2", "Der Editor wird geöffnet und ein Markierung darum mit einem Timeout von 1 Sekunde angezeigt.")


	Run("notepad.exe")
	WinWait("[CLASS:Notepad]", "", 10)
	Local $hWnd = WinGetHandle("[CLASS:Notepad]")


	_HintBoxes_By_Handle($hWnd, "", 10, 1000)


	WinClose("[CLASS:Notepad]")
EndFunc   ;==>Example2


Func Example3()
	MsgBox(0, "Beispiel 3", "Eine GUI wird eingeblendet und zwei Markierungen in unterschiedlichen Farben mit einem Timeout von 2 Sekunden angezeigt.")
	Local $hGui = GUICreate("Test", 350, 210)
	Local $id_Input = GUICtrlCreateInput("", 20, 30, 200, 25)
	Local $id_Input2 = GUICtrlCreateInput("", 20, 60, 200, 25)
	GUISetState(@SW_SHOW)


	Local $aControlIDs[2] = [$id_Input, $id_Input2]
	Local $aColors[2] = [0xFF8080FF, 0xFFFF0000]


	_HintBoxes_By_Handle($hGui, $aControlIDs, 5, 2000, $aColors)


	GUIDelete($hGui)
EndFunc   ;==>Example3


Func Example4()
	Local $hGui = GUICreate("Test", 350, 210)
	Local $id_Input = GUICtrlCreateInput("", 20, 30, 200, 25)
	Local $id_Button_Show = GUICtrlCreateButton("1. Marker einblenden", 25, 170, 120, 25)
	Local $id_Button_Hide = GUICtrlCreateButton("Alle Marker ausblenden", 180, 170, 140, 25)


	GUISetState(@SW_SHOW)
	Local $hBox1, $hBox2, $iCounter = 1
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $id_Button_Show


				If $iCounter = 1 Then
					$hBox1 = _HintBoxes_By_Handle($hGui, $id_Input, 5, 0, 0xFF8080FF)
					GUICtrlSetData($id_Button_Show, "2. Marker einblenden")
					$iCounter += 1
				ElseIf $iCounter = 2 Then
					$hBox2 = _HintBoxes_By_Handle($hGui, "", 5, 0, 0xFF000000)
					GUICtrlSetData($id_Button_Show, "2. Marker löschen")
					$iCounter += 1
				Else
					_Delete_HintBoxes($hBox2)
					GUICtrlSetData($id_Button_Show, "2. Marker einblenden")
					$iCounter -= 1
				EndIf
			Case $id_Button_Hide
				_Delete_HintBoxes()
				GUICtrlSetData($id_Button_Show, "1. Marker einblenden")
				$iCounter = 1
		EndSwitch
	WEnd


	GUIDelete($hGui)
EndFunc   ;==>Example4
















Func _HintBoxes_By_Handle($hWnd, $vControls = "", $iStrength = 5, $iDuration = 2000, $vColor = 0xFFFF0000)


	Local $aPos = WinGetPos($hWnd)


	; get height of window title and width of window frame - may be different when XP theme is ON/OFF -- siehe Hilfe etwa zu _WinAPI_CreateRoundRectRgn
	Local $g_iHtit = _WinAPI_GetSystemMetrics($SM_CYCAPTION)
	Local $g_iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)
	Local $hGui = GUICreate("", $aPos[2] + $iStrength * 4, $aPos[3] + $iStrength * 4, $aPos[0] - $iStrength * 2, $aPos[1] - $iStrength * 2, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TRANSPARENT), $hWnd)


	GUISetBkColor(0xABCDEF, $hGui)
	_WinAPI_SetLayeredWindowAttributes($hGui, 0xABCDEF, 255)
	GUISetState(@SW_SHOWNA)


	__HintBoxes_HandlesArray($hGui)


	If IsArray($vControls) Then
		If Not IsArray($vColor) Then Return 0
		If UBound($vControls) <> UBound($vColor) Then Return 0
		Local $aControls[UBound($vControls)], $aColor[UBound($vColor)]
		For $i = 0 To UBound($vControls) - 1
			$aControls[$i] = $vControls[$i]
			$aColor[$i] = $vColor[$i]
		Next
		Local $ah_LabelIDs[UBound($vControls) * 4]
	Else
		Local $ah_LabelIDs[4]
		Local $aControls[1], $aColor[1]
		$aControls[0] = $vControls
		$aColor[0] = $vColor
		If $vControls = "" Then
			WinMove($hGui, "", $aPos[0] - $iStrength, $aPos[1] - $iStrength - $g_iHtit - $g_iFrame, $aPos[2] + $iStrength * 4, $aPos[3] + $iStrength * 4 + $g_iHtit + $g_iFrame)
			$aPos[0] = 0
			$aPos[1] = 0
			$aPos[2] = $aPos[2] - $iStrength
			$aPos[3] = $aPos[3] - $iStrength
		EndIf
	EndIf


	Local $hPen, $hGraphics, $nX, $nY, $nWidth, $nHeight


	For $i = 0 To UBound($aControls) - 1
		If $vControls <> "" Then
			$aPos = ControlGetPos($hWnd, "", $aControls[$i])
		EndIf
		$hPen = _GDIPlus_PenCreate($aColor[$i], $iStrength)
		$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
		$nX = $aPos[0] + $iStrength + $g_iFrame
		$nY = $aPos[1] + $iStrength + $g_iHtit + $g_iFrame
		$nWidth = $aPos[2] + $iStrength - $g_iFrame
		$nHeight = $aPos[3] + $iStrength - $g_iFrame
		_GDIPlus_GraphicsDrawRect($hGraphics, $nX, $nY, $nWidth, $nHeight, $hPen)
		_GDIPlus_GraphicsDispose($hGraphics)
		_GDIPlus_PenDispose($hPen)
	Next


	WinActivate($hWnd)


	If $iDuration = 0 Then Return $hGui


	Sleep($iDuration)
	_GDIPlus_GraphicsDispose($hGraphics)
	_GDIPlus_PenDispose($hPen)
	_Delete_HintBoxes($hGui)
EndFunc   ;==>_HintBoxes_By_Handle




Func _HintBoxes_By_Pos($aAreas, $iStrength = 5, $iDuration = 2000)
	If Not IsArray($aAreas) Then Return 0


	Local $iCols = UBound($aAreas, $UBOUND_COLUMNS)
	If $iCols < 4 Then Return 0
	Local $hexColorDefault = 0xB10000, $hexColor, $bColors = False
	If $iCols = 5 Then $bColors = True


	Local $iWidth = @DesktopWidth
	Local $iHeight = @DesktopHeight


	; get height of window title and width of window frame - may be different when XP theme is ON/OFF -- siehe Hilfe etwa zu _WinAPI_CreateRoundRectRgn
	Local $g_iHtit = _WinAPI_GetSystemMetrics($SM_CYCAPTION)
	Local $g_iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)
	Local $hGui = GUICreate("", $iWidth, $iHeight, 0, 0, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TRANSPARENT, $WS_EX_TOOLWINDOW))


	GUISetBkColor(0xABCDEF, $hGui)
	_WinAPI_SetLayeredWindowAttributes($hGui, 0xABCDEF, 255)
	GUISetState(@SW_SHOWNA)


	__HintBoxes_HandlesArray($hGui)


	Local $ah_LabelIDs[UBound($aAreas) * 4]


	For $i = 0 To UBound($aAreas) - 1


		If $bColors Then
			If $aAreas[$i][4] <> "" Then
				$hexColor = $aAreas[$i][4]
			Else
				$hexColor = $hexColorDefault
			EndIf
		Else
			$hexColor = $hexColorDefault
		EndIf
		Local $hPen = _GDIPlus_PenCreate($hexColor, $iStrength)
		Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
		Local $nX = $aAreas[$i][0] + $iStrength + $g_iFrame
		Local $nY = $aAreas[$i][1] + $iStrength + $g_iHtit + $g_iFrame
		Local $nWidth = $aAreas[$i][2] + $iStrength + $g_iFrame
		Local $nHeight = $aAreas[$i][3] + $iStrength + $g_iFrame
		_GDIPlus_GraphicsDrawRect($hGraphics, $nX, $nY, $nWidth, $nHeight, $hPen)
		_GDIPlus_GraphicsDispose($hGraphics)
		_GDIPlus_PenDispose($hPen)
	Next




	GUISetState(@SW_SHOWNA)


	If $iDuration = 0 Then Return $hGui


	Sleep($iDuration)
	_Delete_HintBoxes($hGui)


EndFunc   ;==>_HintBoxes_By_Pos


Func _Delete_HintBoxes($hGui = "")
	If $hGui = "" Then
		Local $aDeleteHandles = __HintBoxes_HandlesArray("", False)
	Else
		Local $aDeleteHandles = __HintBoxes_HandlesArray($hGui, False)
	EndIf
	If Not @error Then
		For $i = 0 To UBound($aDeleteHandles) - 1
;~ 			_WinAPI_AnimateWindow($aDeleteHandles[$i], BitOR($AW_BLEND, $AW_HIDE), 500) ; funktioniert nicht.
			GUIDelete($aDeleteHandles[$i])
		Next
	EndIf
EndFunc   ;==>_Delete_HintBoxes










Func __HintBoxes_GuiHole($hWin, $iX, $iY, $iSizeW, $iSizeH, $ah_LabelIDs, $g_iHtit = 0, $g_iFrame = 0)
	Local $hOuter_rgn, $hInner_rgn, $hCombined_rgn


	$hOuter_rgn = _WinAPI_CreateRectRgn(0, 0, $iSizeW, $iSizeH)
	$hInner_rgn = _WinAPI_CreateRectRgn($iX, $iY, $iX + $iSizeW, $iY + $iSizeH)
	$hCombined_rgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
	_WinAPI_CombineRgn($hCombined_rgn, $hOuter_rgn, $hInner_rgn, $RGN_DIFF)
	_WinAPI_DeleteObject($hOuter_rgn)
	_WinAPI_DeleteObject($hInner_rgn)
	For $i = 0 To UBound($ah_LabelIDs) - 1
		__HintBoxes_AddCtrlRegion($hCombined_rgn, $ah_LabelIDs[$i], $hWin, $g_iHtit, $g_iFrame)
	Next
	_WinAPI_SetWindowRgn($hWin, $hCombined_rgn)
EndFunc   ;==>__HintBoxes_GuiHole


Func __HintBoxes_AddCtrlRegion($hFull_rgn, $idCtrl, $hWin, $g_iHtit, $g_iFrame)
	Local $aCtrl_pos, $hCtrl_rgn


	$aCtrl_pos = ControlGetPos($hWin, "", $idCtrl)
	$hCtrl_rgn = _WinAPI_CreateRectRgn($aCtrl_pos[0] + $g_iFrame, $aCtrl_pos[1] + $g_iHtit + $g_iFrame, _
			$aCtrl_pos[0] + $aCtrl_pos[2] + $g_iFrame, $aCtrl_pos[1] + $aCtrl_pos[3] + $g_iHtit + $g_iFrame)
	_WinAPI_CombineRgn($hFull_rgn, $hFull_rgn, $hCtrl_rgn, $RGN_OR)
	_WinAPI_DeleteObject($hCtrl_rgn)
EndFunc   ;==>__HintBoxes_AddCtrlRegion


Func __HintBoxes_HandlesArray($hGui = "", $bAdd = True)
	Local Static $aHandles[0]
	If $bAdd Then
		_ArrayAdd($aHandles, $hGui)
	Else
		If $hGui = "" Then
			Local $aDeleteHandles = $aHandles
			ReDim $aHandles[0]
			Return $aDeleteHandles
		Else
			$iIndex = _ArraySearch($aHandles, $hGui)
			If Not @error Then
				Local $aDeleteHandles[1] = [$aHandles[$iIndex]]
				_ArrayDelete($aHandles, $iIndex)
				Return $aDeleteHandles
			Else
				Return SetError(1)
			EndIf
		EndIf
	EndIf
EndFunc   ;==>__HintBoxes_HandlesArray

Alles anzeigen

**alpines**

Zitat von autoiter

Wie kann man das mit GDI+ machen?

Das rausfaden? Schau dir doch mal deine _GDIPlus_PenCreate an. Du übergibst ihr dort eine Farbe die du erstellen willst.
Die Farbe ist 4 Byte (ARGB). Der Alphakanal gibt die Deckung der Farbe an. FF = volle Deckung, 00 = transparent.
Du kannst die Boxen aktualisieren (Graphics clearen) und mit einem neuen Pinsel transparenter zeichnen.

Wenn du deine Fenster verschiebst werden die Boxen übrigens nicht aktualisiert, du musst also noch die WM_MOVE hooken mit GUIRegisterMsg.

**autoiter**

Hey danke dir @alpines,
genau das rausfaden meinte ich.

Zitat von alpines

Wenn du deine Fenster verschiebst werden die Boxen übrigens nicht aktualisiert, du musst also noch die WM_MOVE hooken mit GUIRegisterMsg.

Ja, das fehlt definitiv noch. Bisher habe ich mir aber noch mit dem Erstellen der einfachen Boxen einen abgekrampft - da stand der Rest noch hinten an. Ich habe da noch viel Arbeit vor mir.

Friesel

Moin!

Ich habe mich schon vor einiger Zeit an etwas Ähnlichem versucht. Hab das Programm aber nie zuende geführt.
Der Ansatz ist vieleicht etwas unorthodox, kommt aber ganz ohne GDI aus und benötigt nur ein "bisschen" WinApi

Es funktioniert für beliebige Fenster, was das Ganze komplizierter macht, als bei der Verwendung von selbst erstellen Guis. Daher musste ich auch die Bewegung des Child Fensters registrieren und nicht wie es sein sollte, des Parent Fensters.
Wenn dir das so rum nicht gefällt, solltest du dir den Befehl _WinAPI_SetParent in Verbindung mit _WinAPI_SetWindowLong ansehen. Damit kann man ein beliebiges Fenster mit dem Popup Style versehen und als Child einbinden.

Die Klassen bzw. Namen der Controls kannst du ja mit einem Tool wie Au3Info anzeigen lassen und entsprechend im Skript verwenden. Ansonsten gibts hier eine UDF von Großvater, die alle Controls eines Fensters ausliest (noch nicht von mir getestet).
Du kannst selbstverständlich auch beliebig mit GDI+ in der transparenten Gui malen, aber der Einfachheit halber habe ich Labels verwedet.

Funktioniert ziemlich gut mit Scite oder Au3Info als zu "verunstaltendem" Fenster. Andere Fenster, wie z.B. die AutoIt Hilfe oder der Explorer machen Probleme, was ich aber nicht weiter ergründet habe. Musst du einfach mal selbst rumprobieren

Die Funktionen "_TagControl" und "_CreateThickFrame" habe ich bewusst getrennt, so dass man mit "_CreateThickFrame" eigene Rahmen "von Hand" erstellen kann.
Achtung: Später gezeichnete Rahmen überlagern komplett vorher erstellte.

Hier das Skript (nicht das Sauberste

Spoiler anzeigen

AutoIt

#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WinAPIShPath.au3>
#include <Array.au3>
#include <GDIPlus.au3>


Opt("MustDeclareVars", 1)


Global $iPid, $iXParent, $iYParent, $iWidthParent, $iHeightParent, $idFirstControl, $idLastControl
Global $hWin, $aPos, $iClientHeight, $hChild, $idButtonClose, $idButtonDelete, $hTimerP, $iMsg


_Au3InfoDemo() ;Au3Info starten und einige Controls umranden


;Demo mit Scite starten (Scite muss geöffnet sein)
$hWin = WinGetHandle("[CLASS:SciTEWindow]")
$aPos = WinGetPos($hWin, "")
If IsArray($aPos) Then
	;Koordinaten auf popup Fenster umrechnen
	$iXParent = $aPos[0]
	$iYParent = $aPos[1]
	$iWidthParent = $aPos[2] - 16
	$iHeightParent = $aPos[3] - 8
Else
	Exit ;kein Array, keine Demo ;)
EndIf
$iClientHeight = $iHeightParent - _WinAPI_GetClientHeight($hWin) ;Höhe des Parent Fensters ohne Titelleiste und Menü
$hChild = GUICreate("childish", $iWidthParent, $iHeightParent, -5, -56, BitOR($WS_BORDER, $WS_POPUP, $WS_MINIMIZEBOX, $WS_SYSMENU), BitOR($WS_EX_MDICHILD, $WS_EX_LAYERED, $WS_EX_TOOLWINDOW), $hWin)
GUISetBkColor(0xF0F0F0)


$idButtonClose = GUICtrlCreateButton("Overlay schließen", $iWidthParent - 139, 29, 139, 22)
$idButtonDelete = GUICtrlCreateButton("Controls durchlaufen", $iWidthParent - 278, 29, 139, 22)


;nur zu Demozwecken um durch die Controls zu iterieren
Global $aSciteControls[] = ["[CLASS:ToolbarWindow32]", "[CLASS:SciTeTabCtrl]", "[CLASS:Scintilla; INSTANCE:1]", "[CLASS:Scintilla; INSTANCE:2]", "[CLASS:msctls_statusbar32]"]


_WinAPI_SetLayeredWindowAttributes($hChild, 0xF0F0F0, 0)
;~ _WinAPI_SetLayeredWindowAttributes($hChild, 0xF0F0F0, 255) ;==> ohne Fade Effekt hier Transparenz setzen und obige Zeile loeschen/auskomentieren
GUIRegisterMsg($WM_MOVE, "_WM_MOVE") ;wenn Child bewegt wird, wird ich Parent bewegt


;"Titelleiste" als letztes zeichnen, damit sie über allen anderen Rahmen liegt
GUICtrlCreateLabel("", 26, 0, $iWidthParent - 162, 29, -1, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetBkColor(-1, 0xFFFFFF)


GUISetState(@SW_SHOW, $hChild)


_CtrlIterate() ;Controls nacheinander einrahmen und Disko machen ;)
_ShowAll() ;alle auf einmal zeigen


$hTimerP = TimerInit()
Do
	$iMsg = GUIGetMsg()
	Switch $iMsg
		Case $idButtonDelete
			For $iID = $idFirstControl - 1 To $idLastControl Step 2
				GUICtrlDelete($iID)
				GUICtrlDelete($iID + 1)
			Next
			_CtrlIterate()
			_ShowAll()
	EndSwitch
	;wenn Programm aus dem Skript gestartet wurde und geschlossen wird, endet auch das Skript
	If TimerDiff($hTimerP) > 100 And $iPid Then ;nicht übertrieben häufig überprüfen, weil das zu Lasten von GUIGetMsg ist
		Switch ProcessExists($iPid)
			Case False
				Exit
		EndSwitch
		$hTimerP = TimerInit()
	EndIf
Until $iMsg = $idButtonClose


_FadeOut() ;Programmende




Func _ShowAll() ; IMMER alle Labels unmittelbar nacheinander erstellen, damit man durch iterieren kann
	Local $idLabelTest, $aCtrlPos
	;Rueckgabewert ist die ID des jeweiligen inneren (Text-)Labels -> bei Bedarf auf ausseren Label in den Fktn "_TagControl" und "_CreateThickFrame" umstellen
	;nur benötigte Variablen zuweisen
	$idFirstControl = 	_TagControl("[CLASS:ToolbarWindow32]", 0xFF0000, 1) ;IDs vom ersten und letzten Label werden zum iterieren in _CtrlIterate() benötigt
				_TagControl("[CLASS:SciTeTabCtrl]", 0x0000FF, 2)
	$idLabelTest = 		_TagControl("[CLASS:Scintilla; INSTANCE:1]", 0x00FF00, 10)
				_TagControl("[CLASS:Scintilla; INSTANCE:2]", 0xFFFF00, 6)
	$idLastControl = 	_TagControl("[CLASS:msctls_statusbar32]", 0x0F0F0F)
	;zwei Rahmen "von Hand" erstellen
	$aCtrlPos = ControlGetPos($hChild, "", $idLabelTest)
	If IsArray($aCtrlPos) Then
		$idLastControl = _CreateThickFrame($aCtrlPos[0] + $aCtrlPos[2] * 2 / 3, $aCtrlPos[1], $aCtrlPos[2] / 3, $aCtrlPos[3], 0xFF7700, 16, "Benutzerdefinierter Rahmen")
		$aCtrlPos = ControlGetPos($hChild, "", $idLastControl)
		If IsArray($aCtrlPos) Then
			$idLastControl = _CreateThickFrame($aCtrlPos[0], $aCtrlPos[1], $aCtrlPos[2], $aCtrlPos[3] / 2 - 20, 0x41D5C4, 8, "Benutzerdefinierter Rahmen")
		EndIf
	EndIf
	_FadeIn()
EndFunc   ;==>_ShowAll


Func _CtrlIterate()
	Local $idTemp
	GUICtrlSetState($idButtonClose, $GUI_HIDE)
	GUICtrlSetState($idButtonDelete, $GUI_HIDE)
	For $iControl = 0 To UBound($aSciteControls) - 1
		$idTemp = _TagControl($aSciteControls[$iControl], 0xFF0000, 4)
		_FadeIn()
		Sleep(500)
		Local $iColor = 0x00FF00
		For $iFlicker = 1 To 10
			$iColor = BitXOR($iColor, 0x00FF00, 0xFFFF00) ;gehört in jede Sammlung: Wechsel zwischen zwei Werten
			GUICtrlSetBkColor($idTemp - 1, $iColor)
			GUICtrlSetColor($idTemp, $iColor)
			Sleep(100)
		Next
		GUICtrlSetBkColor($idTemp - 1, 0xFF0000) ;äusserer Label
		GUICtrlSetColor($idTemp, 0xFF0000) ;innerer Label
		_FadeOut()
		GUICtrlDelete($idTemp - 1)
		GUICtrlDelete($idTemp)
	Next
	GUICtrlSetState($idButtonClose, $GUI_SHOW)
	GUICtrlSetState($idButtonDelete, $GUI_SHOW)
EndFunc   ;==>_CtrlIterate


Func _TagControl($sName, $iColor = 0xFF0000, $iThickness = 4)
	Local $aControlPos, $idLabel = ""
	Select
		Case $iColor = Default Or $iColor = -1
			$iColor = 0xFF0000
		Case $iThickness = Default Or $iThickness = 4
			$iThickness = 4
	EndSelect


	$aControlPos = ControlGetPos($hWin, "", ControlGetHandle($hWin, "", $sName))
	If IsArray($aControlPos) Then
		$idLabel = _CreateThickFrame($aControlPos[0], $aControlPos[1] + $iClientHeight, $aControlPos[2], $aControlPos[3], $iColor, $iThickness, $sName)
	EndIf
	Return $idLabel
EndFunc   ;==>_TagControl


Func _CreateThickFrame($iXpos, $iYpos, $iWidth, $iClientHeightght, $iColor = 0xFF0000, $iThickness = 4, $sText = "")
	Local $idLabel
	Select
		Case $iColor = Default Or $iColor = -1
			$iColor = 0xFF0000
		Case $iThickness = Default Or $iThickness = 4
			$iThickness = 4
	EndSelect


	GUICtrlCreateLabel("", $iXpos, $iYpos, $iWidth, $iClientHeightght)
	GUICtrlSetState(-1, $GUI_DISABLE)
	GUICtrlSetBkColor(-1, $iColor)
	$idLabel = GUICtrlCreateLabel($sText, $iXpos + $iThickness, $iYpos + $iThickness, $iWidth - $iThickness * 2, $iClientHeightght - $iThickness * 2, BitOR($SS_CENTER, $SS_CENTERIMAGE))
	GUICtrlSetFont(-1, -1, 900)
	GUICtrlSetColor(-1, $iColor)
	Return $idLabel
EndFunc   ;==>_CreateThickFrame


Func _FadeIn()
	For $i = 1 To 255 Step 5
		_WinAPI_SetLayeredWindowAttributes($hChild, 0xF0F0F0, $i)
		Sleep(6)
	Next
EndFunc   ;==>_FadeIn


Func _FadeOut()
	For $i = 255 To 0 Step -5
		_WinAPI_SetLayeredWindowAttributes($hChild, 0xF0F0F0, $i)
		Sleep(4)
	Next
EndFunc   ;==>_FadeOut


Func _WM_MOVE($hChild, $iMsg, $wParam, $lParam)
	Local $aPos = WinGetPos($hChild)
	If UBound($aPos) = 4 Then
		WinMove($hWin, "", $aPos[0] - 8, $aPos[1])
	EndIf
	Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_MOVE


Func _Au3InfoDemo()
	$iPid = Run(_WinAPI_PathRemoveFileSpec(@AutoItExe) & (@CPUArch = "X86" ? "\Au3Info.exe" : "\Au3Info_x64.exe"))
	ProcessWait($iPid)
	$hWin = WinGetHandle("[CLASS:Au3Info]")
	$aPos = WinGetPos($hWin, "")
	If IsArray($aPos) Then
		;Koordinaten auf popup Fenster umrechnen
		$iXParent = $aPos[0]
		$iYParent = $aPos[1]
		$iWidthParent = $aPos[2] - 16
		$iHeightParent = $aPos[3] - 8
	Else
		Exit
	EndIf
	$iClientHeight = $iHeightParent - _WinAPI_GetClientHeight($hWin)
	$hChild = GUICreate("childish", $iWidthParent, $iHeightParent, -5, -56, BitOR($WS_BORDER, $WS_POPUP, $WS_MINIMIZEBOX, $WS_SYSMENU), BitOR($WS_EX_MDICHILD, $WS_EX_LAYERED, $WS_EX_TOOLWINDOW), $hWin)
	GUISetBkColor(0xF0F0F0)
	$idButtonClose = GUICtrlCreateButton("Overlay schließen", $iWidthParent - 139, 29, 139, 22)
	_WinAPI_SetLayeredWindowAttributes($hChild, 0xF0F0F0, 0)
;~ 	_WinAPI_SetLayeredWindowAttributes($hChild, 0xF0F0F0, 255) ;==> ohne Fade Effekt hier Transparenz setzen und obige Zeile loeschen/auskomentieren
	GUIRegisterMsg($WM_MOVE, "_WM_MOVE")
	;"Titelleiste" als letztes zeichnen, damit sie über allen anderen Rahmen liegt
	GUICtrlCreateLabel("", 26, 0, $iWidthParent - 162, 29, -1, $GUI_WS_EX_PARENTDRAG)
	GUICtrlSetBkColor(-1, 0xFFFFFF)
	GUISetState(@SW_SHOW, $hChild)
	_TagControl("[CLASS:Edit; INSTANCE:1]", 0x00FF00, 1)
	_TagControl("[CLASS:Edit; INSTANCE:2]", 0x00FF00, 1)
	_TagControl("[CLASS:Edit; INSTANCE:3]", 0x00FF00, 1)
	_TagControl("[CLASS:Edit; INSTANCE:4]", 0x00FF00, 1)
	_TagControl("[CLASS:SysTabControl32]", 0xFF0000, 2)


	_FadeIn()


	$hTimerP = TimerInit()
	Do
		$iMsg = GUIGetMsg()
		;wenn Programm aus dem Skript gestartet wurde (wie hier Au3Info) und geschlossen wird, endet auch das Skript bzw wird das Child Fenster geschlossen
		If TimerDiff($hTimerP) > 100 And $iPid Then ;nicht übertrieben häufig überprüfen, weil das zu Lasten von GUIGetMsg ist
			Switch ProcessExists($iPid)
				Case False
					$iPid = 0
					GUIDelete($hChild)
					Return
			EndSwitch
			$hTimerP = TimerInit()
		EndIf
	Until $iMsg = $idButtonClose


	$iPid = 0
	_FadeOut()
	GUIDelete($hChild)
EndFunc   ;==>_Au3InfoDemo

Alles anzeigen

Das sieht zwar jetzt nach sehr viel Code aus, aber das Meiste ist nur Demo.
Was du letzten Endes brauchst, ist die Erstellung der Child Gui und die Funktionen "_TagControl" und "_CreateThickFrame"

==> siehe Funktion "_Au3InfoDemo"

Anmerkung: Ich war nie wirklich zufrieden damit, was wohl auch der Grund ist, weshalb ich nicht weiter gemacht habe.

die Größe des "Parent" Fensters läßt sich ändern, ohne dass die Child Gui sich ändert (kann man verbessern, denke ich).
an bestimmten Stellen ist es möglich, das "Parent" Fenster ohne das Child zu bewegen. Immerhin funktioniert aber das minimieren...
der Fenstertitel wird überdeckt

Beste Grüße, Friesel

**autoiter**

Hallo @Friesel,
Das ist nochmal ein anderer Ansatz, aber auf den ersten Blick sieht das nachvollziehbar für mich aus.
Vielen Dank dafür!