PDF ´s automatisch umbennen

**alpines**

Zitat von Sascha123456

seit

/ot Da kräuseln sich mir direkt die Fingernägel. http://www.seid-seit.de/

Sascha123456

haha ja ...ich schreibe in der Arbeit einfach schnell ohne zu denken. Da wirst noch mehr Fehler finden

**alpines**

Klappt eigentlich jetzt alles? Wenn ja kannst du ja den grünen Haken für erledigt / gelöst setzen indem du den 1. Beitrag bearbeitest.

Sascha123456

Es tut mir leid das ich nochmals nerven muss ^^, aber es kam noch ein kelines Problem zum vorschein...und zwar funktioniert alles tadelos solange die PDF nur eine Seite lang ist.
Jedoch wenn diese 2 Seiten lang wird, dann speichert er mir die PDF´s als jede einzeln ab..? Das ist natürlich ein Problem, er soll diese als eine PDF mit 2 oder 3 Seiten lassen.

Vielen Dank und frohe Ostern

**autoiter**

Hallo @Sascha123456,

Ich kann das nicht nachvollziehen:

Zitat von Sascha123456

und zwar funktioniert alles tadelos solange die PDF nur eine Seite lang ist.
Jedoch wenn diese 2 Seiten lang wird, dann speichert er mir die PDF´s als jede einzeln ab..? Das ist natürlich ein Problem, er soll diese als eine PDF mit 2 oder 3 Seiten lassen.

Eine zweiseitige PDF bleibt zweiseitig und eine zehnseitige PDF bleibt zehnseitig. Schau dir mal den Code an:

AutoIt

FileMove($sSourcePath, $sNewFullPath, 8) ; Datei wird verschoben/umbenannt.

Die Datei wird einfach verschoben. Das andere ist nur zum Extrahieren des Namens und verändert die vorhandene PDFCreator.pdf überhaupt nicht. Daher würde ich nicht davon sprechen, es bei zwei oder drei Seiten zu lassen, sondern wie fügt man die zusammen?

Ich kann mir nur vorstellen, dass dein Druckprozess jede Seite als einzelne Datei erstellt oder PDFCreate selbst immer eine Seite schreibt oder bei Bedarf an ein Dokument anhängt, aber nach jedem Durchlauf das Skript ausgeführt wird.
.. Das ist alles nur Mutmaßung. Kannst du es vielleicht noch einmal genauer erklären?

Schöne Feiertage

Sascha123456

Hallo,

ja du könntest recht haben damit das dieses Problem seitens dem Creator verursacht wird, leider finde ich keine Eisntellung dies bezüglich...jetzt weiß ich fürs erste nicht weiter...vielleicht leigt es auchz an der Druckausgabe der Maschine.

Es passiert folgender Maßen:
Er druckt sobald eine PDF Seite voll ist, dann bei der nächsten Messung schreibt er die PDF einfach weiter....also erst die Messdaten der vorherigen Messung die scheinbar nicht mehr auf die Seite gepasst haben und dann die neuen Messdaten bis die Seite wieder voll ist usw

Sascha123456

Kurzes Update:
Ich habe jetzt ein paar Sachen probiert und fesgestellt das selbst wenn ich die 2seitige PDF dem Script zur Verfügung stelle, kann er dieses nicht mehr umwandeln. Fehlermeldung erscheint "Fehler beim auslesen der Artikelnummer"

So sieht die PDF aus die er nicht umwandeln kann...

Diese habe ich zu 2 seiten zusammengefügt, dann ging es noch diese umzuwandeln...
Jedoch wenn ich diese zusammengefügte Datei nochmal über den Creator drucke und automatisch abspeichern lasse dann geht das Script leider nicht mehr.

**autoiter**

Hallo @Sascha123456,
das eigentliche Problem scheint mir eigentlich die Automatisierung der Erstellung der richtigen PDF Dateien. Also jeden Bericht komplett in einer Datei zu haben. Das Umbenennen sollte dann auch noch klappen. (Wenn du selbst schon die Dateien zusammen friemeln musst, kannst du sie auch selbst benennen.)
Macht es vllt. Sinn, alle Dateien erst einmal fortlaufend zu benennen und sie später in einem weiteren Durchlauf nach den richtigen Inhalten aufzuteilen und in mit Artikelnummer zu benennen?

Sascha123456

Hallo @autoiter

das zusammen fügen der einzelnen pdf zu zwei war nur mal eben testweise

Prinzipiell sollte das ja alles automatisch geschehen.

Dein Vorschlag würd zwar Sinn machen jedoch ist das Problem nicht so groß wie es scheint, denn wenn die PDF eine Seite maximal hat funzt auch alles so wie es soll.
Das Problem tritt erst auf wenn die PDF länger wird als eine Seite, weil zb die Menge an Messdaten nicht mehr ausreicht.

Vielleicht kurzes Hintergundwissen:
Ich starte den virtuellen Drucker in meinem Messprogramm am anfang mit PRINTER, FILE 0
Und beende es am Ende wieder mit PRINTER, FILE 1

Bisher alles so weit so gut.
Jedoch wenn die PDF nun zb 2 Seiten hat dann erstellt er mir daraus auch 2 PDF´s...obwohl der PRINTER-Befehl erst am ende kommt....warum weiß erstmal niemand^^...

**autoiter**

Das Problem mit dem von dir geposteten Problem-PDF war wohl die Art, wie du es erstellt hast (als Bilddatei?). Ich musste erst einmal OCR in einem PDF Editor drüber laufen lassen, bevor es geklappt hat..

Wenn das alles eigentlich kein Problem für dich ist, dann mach es eben manuell und benenne die Datei dabei eben auch gleich selbst.

Zitat von Sascha123456

Bisher alles so weit so gut.
Jedoch wenn die PDF nun zb 2 Seiten hat dann erstellt er mir daraus auch 2 PDF´s...obwohl der PRINTER-Befehl erst am ende kommt....warum weiß erstmal niemand^^...

Es wird also einmal PDFCreator.pdf mit dem Anfang und dann noch einmal PDFCreator.pdf mit dem Ende erstellt?

Wenn das so ist, könnte man die Dateien doch Artikelnummer.pdf und Artikelnummer_2.pdf nennen, oder?

Das könnte man einmal automatisieren, wenn das Skript die Dateien verschiebt und dabei nur durchnummeriert und man am Ende mit einem zweiten Skript über das Verzeichnis geht und jede Datei ohne erwarteten Kopf, wie etwa Artikel der vorherigen zuordnet.

Oder das Skript schreibt bei jedem Aufruf, die aktuelle Datei in eine Textdatei. Wenn der erwartete Textteil für einen Anfang nicht in der aktuellen PDF ist, wird eben die vorherige Artikelnummer aus der Textdatei ausgelesen und mit Nummerierung gespeichert..

Mit noch etwas Arbeit könnte man sicher auch eine zusammenhängende PDF erstellen.

Sascha123456

Morgen @autoiter

also ich hab nun ausreichend rum probiert und stelle fest es liegt weder am Script noch am Creator, das ganze liegt an der Maschinensteuerung.....ärgerlich

Nun wie das ganze aussieht habe ich dir nochmal mit angehängt.

Man kann sehen das die erste Datei normal und wie gewollt umbenannt wird und die 2te lässt er als PDCreator.pdf weil dort kein Kopf mehr enthalten ist mit der Artikelnummer um zu wissen wie er es umbennen soll....

Ich denke ich habe 2 Möglichkeiten:
Entweder ich schaffe es das er bei der 2ten PDF auch den Kopf oben mit anfügt, damit er dies auch umbenennen kann...jedoch glaube ich das dies rein von der Steuerung nicht möglich ist..

Oder man modifiziert deine Idee in etwa so das man sagt, ok benenne die erste PDF normal um und die 2te benennst du mir unabhänig vom Inhalt der PDF nochmal um in den selben Namen wie zuvor die erste.
Das darf er allerdings nur dann tun wenn eine 2te PDF innerhalb der nächsten 2 oder 3 minuten hereinkommt. Und wenn nicht, anschließend wieder normal umbenennen wie immer.

Ich weiß aber gar nicht ob das so möglich ist, viellciht lasse ich das erstellen von PDF´s bei so langen Messprogrammen einfach weg. Ist zwar unschön aber bei den kleineren Programmen funktioniert es ja dafür

**chesstiger**

Das mit der Zeit ist sogar recht gut machbar, Stichwort FileGetTime. Die Frage ist nur, ob die Zeittoleranz so gewählt werden kann, dass keine Fehlzuordnungen passieren.

**autoiter**

Die Frage habe ich mir auch gestellt.
In deinem Beispiel steht in Seite 2 auch "Seite 2". Ist das vllt. immer so (wäre doch sicherer als Fehler bei Artikel)? Das könnte man doch nutzen! Dann könnte man die Datei entweder der jüngsten Datei im Artikelnummer Verzeichnis zuordnen, oder dem Namen der letzten Datei, der immer in eine Textdatei geschrieben wird.

Sascha123456

Morgen

ja diese Idee ist sogar noch besser mit der Seitenzahl.

Das mit der Zeit ist aber auch machbar, denn innerhalb 2 Minuten ist es eigentlich nicht möglich das ein 2tes Protokoll ankommt. Da keines meiner Messprogramme so schnell sein kann.

Ich weiß aber nicht welche Lösung einfacher wäre^^....glaub ich sollte dringend mal Scripting lernen

**autoiter**

Hallo @Sascha123456,

Zitat von Sascha123456

....glaub ich sollte dringend mal Scripting lernen

Das ist immer von Vorteil und jedenfalls zu empfehlen.

Ansonsten stelle deine Anfrage das nächste Mal auch in den Bereich der Programmieranfragen mit oder ohne Gegenleistung. Du möchtest ja etwas programmiert bekommen..

Versuch es mal mit folgendem Skript. Bei einem Fehler beim Ermitteln der Artikelnummer sucht es nach dem String: "Seite: 2". Wird er gefunden, wird im Artikelnummer-Verzeichnis nach der jüngsten Datei geschaut und geprüft, ob sie jünger als x Minuten ist. Wenn das zutrifft, wird die Datei mit dem Dateinamen dieser Datei und dem Zusatz Seite_2 versehen.
Den Minutenabstand kannst du oben im Skript ($iMaxDiff = ) anpassen.

Das ist nicht flexibel und @chesstiger könnte dir da sicher etwas besseres basteln. Ich gehe jetzt einfach mal von Laborbedingungen aus und hoffe das funktioniert so.

Spoiler anzeigen

AutoIt

#include <File.au3>
#include <Date.au3>




Global $sSourcePath = @ScriptDir & "\pdfcreatorDir\PDFCreator.pdf" ; Datei die PDFCreator die Dateien erstellt.


Global $sResultFolder = @ScriptDir & "\ArtikelnummerDir\" ; Ordner, in den deine Ergebnisse abgelegt werden.


Global $sXPDF = @ScriptDir & "\pdftotext\pdftotext.exe" ; Pfad der pdftotext.exe.


Global $iMaxDiff = 10005 ; maximaler Zeitabstand zwischen Seite 1 und Seite 2 in Minuten.






Global $sNewName = ""
Global $sContent = _GetContent_PDF($sSourcePath) ; Funktion gibt den Text als String zurück.
Global $aMatches = StringRegExp($sContent, "(?i)ARTIKEL\h+:\h+([0-9.]+)_", 3) ; Das Pattern von chesstiger, um die Artikelnummer auszulesen.


If Not @error Then
	Global $sNewFullPath = $sResultFolder & $aMatches[0] & ".pdf" ; Zielpfad der neuen Datei.


	If FileExists($sNewFullPath) Then ; Wenn die Datei bereits existiert.
		Local $i = 1
		Do
			$sNewFullPath = $sResultFolder & $aMatches[0] & "_" & StringFormat("%03d", $i) & ".pdf" ; In Schleife wird hochgezählt.
			$i += 1
		Until Not FileExists($sNewFullPath) ; Bis neu konstruierter Dateiname nicht existiert.
	EndIf
Else
	If Not StringInStr($sContent, "Seite: 2") Then Exit MsgBox(0, "", "Fehler beim Auslesen der Artikelnummer und nicht als zweite Seite erkannt!" & @CRLF & "Skript wird abgebrochen.")
	$sNewName = _GetFirstPage()
	If @error Then Exit MsgBox(0, "", "Fehler beim Auslesen der Artikelnummer und keine passende erste Seite gefunden!" & @CRLF & "Skript wird abgebrochen.")


	Global $sNewFullPath = $sResultFolder & $sNewName & "_Seite_2.pdf" ; Zielpfad der neuen Datei.
EndIf


FileCopy($sSourcePath, $sNewFullPath, 8) ; Datei wird verschoben/umbenannt.






Func _GetFirstPage()
	Local $aFileList = _FileListToArray($sResultFolder)
	_ArrayColInsert($aFileList, 0)
	_ArrayColInsert($aFileList, 2)
	For $i = 1 To $aFileList[0][1]
		$aFileList[$i][0] = FileGetTime($sResultFolder & $aFileList[$i][1], 0, 1)
		$aFileList[$i][2] = FileGetTime($sResultFolder & $aFileList[$i][1], 0)
	Next
	_ArraySort($aFileList, 0, 1)
	_ArrayDisplay($aFileList)
	Local $aTime = $aFileList[1][2]
	$iDateCalc = _DateDiff('n', StringFormat("%s/%s/%s %s:%s:%s", $aTime[0], $aTime[1], $aTime[2], $aTime[3], $aTime[4], $aTime[5]), _NowCalc())
	If $iDateCalc <= $iMaxDiff Then
		Return $aFileList[1][1]
	Else
		Return SetError(1)
	EndIf


EndFunc   ;==>_GetFirstPage




Func _GetContent_PDF($sFullPath)
	Local $sTempFile = _TempFile()


	Local $sFile = StringReplace($sTempFile, @TempDir & "\", "")


	Local $sTestread = _XPDF_ToText($sFullPath, $sFile, @TempDir)
	If @error Then Exit MsgBox(0, "", "Fehler beim Lesen der PDF-Datei! (" & @error & ")" & @CRLF & "Skript wird abgebrochen.")
	Local $sString = FileRead($sTempFile)
	FileDelete($sTempFile)
	Return $sString


EndFunc   ;==>_GetContent_PDF




Func _XPDF_ToText($sPDFFile, $sTXTFile, $sTXTPath = @ScriptDir, $iFirstPage = 1, $iLastPage = 0, $bLayout = True) ; https://www.autoitscript.com/forum/topic/160718-code-to-extract-plain-text-from-a-pdf-file/?do=findComment&comment=1166469
	; #FUNCTION# ====================================================================================================================
	; Name...........: _XPDF_ToText
	; Description....: Converts a PDF file to plain  text.
	; Syntax.........: _XPDF_ToText ( "PDFFile" , "TxtFile" [ TxtPath[, FirstPage [, LastPage [, Layout ]]]] )
	; Parameters.....: PDFFile    - PDF Input File.
	;                  TxtFile    - Plain text fileneme to convert to
	;                  TxtPath    - Path to the txt file (default is @ScriptDir)
	;                  FirstPage  - First page to convert (default is 1)
	;                  LastPage   - Last page to convert (default is last page of the document)
	;                  Layout     - If true, maintains (as  best as possible) the original physical layout of the text
	;                               If false, the behavior is to 'undo'  physical  layout  (columns, hyphenation, etc.)
	;                                 and output the text in reading order.
	;                               Default is True
	; Return values..: Success - 1
	;                  Failure - 0, and sets @error to :
	;                   1 - PDF File not found
	;                   2 - Unable to find the external program
	; ===============================================================================================================================
	Local $sOptions


	If Not FileExists($sPDFFile) Then Return SetError(1, 0, 0)
	If Not FileExists($sXPDF) Then Return SetError(2, 0, 0)


	If $iFirstPage <> 1 Then $sOptions &= " -f " & $iFirstPage
	If $iLastPage <> 0 Then $sOptions &= " -l " & $iLastPage
	If $bLayout = True Then $sOptions &= " -layout"


	Local $iReturn = ShellExecuteWait($sXPDF, $sOptions & ' "' & $sPDFFile & '" "' & $sTXTFile & '"', $sTXTPath, "", @SW_HIDE)
	If $iReturn = 0 Then Return 1


	Return 0


EndFunc   ;==>_XPDF_ToText

Alles anzeigen

EDIT: Da war noch ein Fehler im Skript.

Sascha123456

@autoiter

vielen Dank für die Mühe

Ich habe dein Script probiert ,allerdings erhalte ich diese Fenster (siehe Bild)...das scheinen alle PDF´s im Ordner zu sein die umbenannt wurden. Ich habe die Zeit aber auf 2 Minuten gestellt

Und anschließend kommt die Meldung...Fehler beim auslesen...keine passende erste Seite gefunden.

Natzürlich habe ich zuvor die erste Seite durch das andere Script laufen lassen

Ach und kann ich dieses Script einfach an das andere mit drunter hängen? Sodass alles durch ein Script gemacht wird.

**autoiter**

Da habe ich eine Ausgabe vergessen zu löschen. Im Grunde aber ein Glück, denn so kann man meinen weiteren Fehler ja sehr gut sehen

Spoiler anzeigen

AutoIt

#include <File.au3>
#include <Date.au3>




Global $sSourcePath = @ScriptDir & "\pdfcreatorDir\PDFCreator.pdf" ; Datei die PDFCreator die Dateien erstellt.


Global $sResultFolder = @ScriptDir & "\ArtikelnummerDir\" ; Ordner, in den deine Ergebnisse abgelegt werden.


Global $sXPDF = @ScriptDir & "\pdftotext\pdftotext.exe" ; Pfad der pdftotext.exe.


Global $iMaxDiff = 2 ; maximaler Zeitabstand zwischen Seite 1 und Seite 2 in Minuten.






Global $sNewName = ""
Global $sContent = _GetContent_PDF($sSourcePath) ; Funktion gibt den Text als String zurück.
Global $aMatches = StringRegExp($sContent, "(?i)ARTIKEL\h+:\h+([0-9.]+)_", 3) ; Das Pattern von chesstiger, um die Artikelnummer auszulesen.


If Not @error Then
	Global $sNewFullPath = $sResultFolder & $aMatches[0] & ".pdf" ; Zielpfad der neuen Datei.


	If FileExists($sNewFullPath) Then ; Wenn die Datei bereits existiert.
		Local $i = 1
		Do
			$sNewFullPath = $sResultFolder & $aMatches[0] & "_" & StringFormat("%03d", $i) & ".pdf" ; In Schleife wird hochgezählt.
			$i += 1
		Until Not FileExists($sNewFullPath) ; Bis neu konstruierter Dateiname nicht existiert.
	EndIf
Else
	If Not StringInStr($sContent, "Seite: 2") Then Exit MsgBox(0, "", "Fehler beim Auslesen der Artikelnummer und nicht als zweite Seite erkannt!" & @CRLF & "Skript wird abgebrochen.")
	$sNewName = _GetFirstPage()
	If @error Then Exit MsgBox(0, "", "Fehler beim Auslesen der Artikelnummer und keine passende erste Seite gefunden!" & @CRLF & "Skript wird abgebrochen.")


	Global $sNewFullPath = $sResultFolder & $sNewName & "_Seite_2.pdf" ; Zielpfad der neuen Datei.
EndIf


FileMove($sSourcePath, $sNewFullPath, 8) ; Datei wird verschoben/umbenannt.






Func _GetFirstPage()
	Local $aFileList = _FileListToArray($sResultFolder)
	_ArrayColInsert($aFileList, 0)
	For $i = 1 To $aFileList[0][1]
		$aFileList[$i][0] = FileGetTime($sResultFolder & $aFileList[$i][1], 0, 1)
	Next
	_ArraySort($aFileList, 1, 1)
	Local $aTime = FileGetTime($sResultFolder & $aFileList[1][1], 0)
	$iDateCalc = _DateDiff('n', StringFormat("%s/%s/%s %s:%s:%s", $aTime[0], $aTime[1], $aTime[2], $aTime[3], $aTime[4], $aTime[5]), _NowCalc())
	If $iDateCalc <= $iMaxDiff Then
		Return StringTrimRight($aFileList[1][1], 4)
	Else
		Return SetError(1)
	EndIf


EndFunc   ;==>_GetFirstPage




Func _GetContent_PDF($sFullPath)
	Local $sTempFile = _TempFile()


	Local $sFile = StringReplace($sTempFile, @TempDir & "\", "")


	Local $sTestread = _XPDF_ToText($sFullPath, $sFile, @TempDir)
	If @error Then Exit MsgBox(0, "", "Fehler beim Lesen der PDF-Datei! (" & @error & ")" & @CRLF & "Skript wird abgebrochen.")
	Local $sString = FileRead($sTempFile)
	FileDelete($sTempFile)
	Return $sString


EndFunc   ;==>_GetContent_PDF




Func _XPDF_ToText($sPDFFile, $sTXTFile, $sTXTPath = @ScriptDir, $iFirstPage = 1, $iLastPage = 0, $bLayout = True) ; https://www.autoitscript.com/forum/topic/160718-code-to-extract-plain-text-from-a-pdf-file/?do=findComment&comment=1166469
	; #FUNCTION# ====================================================================================================================
	; Name...........: _XPDF_ToText
	; Description....: Converts a PDF file to plain  text.
	; Syntax.........: _XPDF_ToText ( "PDFFile" , "TxtFile" [ TxtPath[, FirstPage [, LastPage [, Layout ]]]] )
	; Parameters.....: PDFFile    - PDF Input File.
	;                  TxtFile    - Plain text fileneme to convert to
	;                  TxtPath    - Path to the txt file (default is @ScriptDir)
	;                  FirstPage  - First page to convert (default is 1)
	;                  LastPage   - Last page to convert (default is last page of the document)
	;                  Layout     - If true, maintains (as  best as possible) the original physical layout of the text
	;                               If false, the behavior is to 'undo'  physical  layout  (columns, hyphenation, etc.)
	;                                 and output the text in reading order.
	;                               Default is True
	; Return values..: Success - 1
	;                  Failure - 0, and sets @error to :
	;                   1 - PDF File not found
	;                   2 - Unable to find the external program
	; ===============================================================================================================================
	Local $sOptions


	If Not FileExists($sPDFFile) Then Return SetError(1, 0, 0)
	If Not FileExists($sXPDF) Then Return SetError(2, 0, 0)


	If $iFirstPage <> 1 Then $sOptions &= " -f " & $iFirstPage
	If $iLastPage <> 0 Then $sOptions &= " -l " & $iLastPage
	If $bLayout = True Then $sOptions &= " -layout"


	Local $iReturn = ShellExecuteWait($sXPDF, $sOptions & ' "' & $sPDFFile & '" "' & $sTXTFile & '"', $sTXTPath, "", @SW_HIDE)
	If $iReturn = 0 Then Return 1


	Return 0


EndFunc   ;==>_XPDF_ToText

Alles anzeigen

EDIT: Hab es nochmal geändert, weil bei der neuen Datei ja die Dateiendung noch als Name übernommen wurde.

Zitat von Sascha123456

Ach und kann ich dieses Script einfach an das andere mit drunter hängen? Sodass alles durch ein Script gemacht wird.

Das ist das alte Skript mit der Erweiterung um die neue Funktion. Ersetze das alte Skript also komplett durch dieses (so es denn funktioniert - hüstel, hüstel..)

Sascha123456

@autoiter

Ich bin hellauf begeistert it work´s great!!

**autoiter**

Supi