GUICTRLSetOnEvent welcher Menübutton wurde gedrückt?

svart

Hallo,

ich hoffe ihr kennt einen einen Workaround für mein Problem

Ich möchte gerne in meine GUI Tools (*.exe) ausführen und diese per INI-Datei anpassen, so dass Sie automatisch in der Menübar unter "Tools" angezeigt werden.
Nur leider habe ich keine Ahnung wie ich jetzt herrausfinde, welcher Menübutton gedrückt worden ist..

Das ganze sollte mit Opt("GUIOnEventMode", 1) laufen.

Hier mal ein Beispiel:

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Opt("GUIOnEventMode", 1)


$GUI = GUICreate("TEST", 300,300)
$Menu_Tools = GUICtrlCreateMenu("Tools")
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, "_EXIT")


Local $aTools[4][3]
for $i = 1 to ubound($aTools)-1
	$aTools[$i][0] = "Tool " & $i
 	$aTools[$i][1] = "Pfad zur Exe"
	$aTools[$i][2] =  GUICtrlCreateMenuItem($aTools[$i][0], $Menu_Tools)
	GUICTRLSetOnEvent(-1,"_Test")
Next


While 1
	sleep(50)
WEnd


Func _exit()
	Exit
EndFunc


func _Test()
	msgbox(0,"","WELCHER BUTTON?")
endfunc

Alles anzeigen

Floops

So hier vielleicht?

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
$GUI = GUICreate("TEST", 300,300)
$Menu_Tools = GUICtrlCreateMenu("Tools")
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, "_EXIT")
Local $aTools[4][3]
for $i = 1 to ubound($aTools)-1
	$aTools[$i][0] = "Tool " & $i
 	$aTools[$i][1] = "Pfad zur Exe"
	$aTools[$i][2] =  GUICtrlCreateMenuItem($aTools[$i][0], $Menu_Tools)
	GUICTRLSetOnEvent(-1,"_Test" & $i)
Next


While 1
	sleep(50)
WEnd


Func _exit()
	Exit
EndFunc


func _Test1()
	msgbox(0,"","1")
endfunc


func _Test2()
	msgbox(0,"","2")
endfunc


func _Test3()
	msgbox(0,"","3")
endfunc

Alles anzeigen

Das ist keine wirklich schöne Lösung, falls jemand eine bessere kennt würde mich das sehr interessieren.

**Oscar**

Floops: Bei Deiner Version muss man vorher wissen, wie viele Tools/Funktionen vorhanden sind.

Um das universeller zu gestalten kann man @GUI_CtrlId verwenden:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Opt("GUIOnEventMode", 1)


$GUI = GUICreate("TEST", 300, 300)
$Menu_Tools = GUICtrlCreateMenu("Tools")
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, "_EXIT")


Global $aTools[4][3]
For $i = 1 To UBound($aTools) - 1
	$aTools[$i][0] = "Tool " & $i
	$aTools[$i][1] = "Pfad zur Exe"
	$aTools[$i][2] = GUICtrlCreateMenuItem($aTools[$i][0], $Menu_Tools)
	GUICtrlSetOnEvent(-1, "_Test")
Next


While 1
	Sleep(50)
WEnd


Func _exit()
	Exit
EndFunc   ;==>_exit


Func _Test()
	Local $iCtrl = @GUI_CtrlId - $aTools[1][2] + 1
	MsgBox(0, "", "Tool: " & $iCtrl)
EndFunc   ;==>_Test

Alles anzeigen

Floops

Wusste ich doch, dass es auch eine elegantere Lösung geben muss.

Vielen Dank @Oscar, mal wieder was gelernt!

svart

Vielen Dank.

Jetzt wo du es sagst (oder schreibst)..@GUI_CtrlId hatte ich schon einmal vor 1-2 Jahren bei einem ähnlichen Problem benutzt, bin aber nicht mehr darauf gekommen

**alpines**

Den grünen Haken beim nächsten Thread nicht vergessen!