Zeitstempel setzten beim Öffen & schliessen eines Programmes

ru642

Hallo Liebe Autoit Community

Ich stehe leider mal wieder vor einem Problem.
Ich möchte je einen Zeitstempel schreiben wenn ein Programm (bei meinem Test notepad.exe) geöffnet / geschlossen wurde.
Ich denke man sieht was ich machen möchte die Variablen $aTime (Startzeit), $eTime (Endzeit) sollten per korrektem Script gefüllt werden.
Folgendes sind meine kläglichen Versuche:

AutoIt

HotKeySet("{ESC}", "Terminate")
Func Terminate()
    Exit
EndFunc   ;==>Terminate


Local $aTime
Local $eTime
Local $activeProcess = 0
ConsoleWrite ($activeProcess)


While 1
If ProcessExists ("notepad.exe") Then
$activeProcess =1
Else
   Sleep (20)
EndIf
WEnd


If $activeProcess = 1 Then
$aTime = @HOUR & ":" & @MIN & ":" & @SEC

Alles anzeigen

Ich bedanke mich bereits im Voraus für eure wertvolle Hilfe!
Mfg Ru642

**alpines**

Deine $activeProcess = 1 Abfrage ist außerhalb der While-Schleife und wird niemals aufgerufen werden.
Du musst viel mehr prüfen ob dein Prozess läuft und ob du ihn bereits als laufend in $activeProcess gespeichert hast.
Wenn nicht, dann setzt du $activeProcess = 1 und speicherst die Zeit und sollte der Prozess nicht existieren aber $activeProcess = 1 sein, so wurde er terminiert und du kannst die Zeit wieder speichern, solltest aber noch $activeProcess auf 0 setzen und dann beginnt das ganze Spiel von vorne.

ru642

Hallo Alpines danke für deine Antwort.

Ich habe nun die Abfrage in die Schleife mit aufgenommen aber nun wird natürlich die Zeit immer wieder ausgegeben.
Wie kann ich das einmalig ausgeben ?

Hier mein angepasster Script:

AutoIt

HotKeySet("{ESC}", "Terminate")
Func Terminate()
    Exit
EndFunc   ;==>Terminate


Local $aTime
Local $eTime
Local $activeProcess = 0




While 1
If ProcessExists ("notepad.exe") Then
$activeProcess =1


If $activeProcess = 1 Then
$aTime = @HOUR & ":" & @MIN & ":" & @SEC
ConsoleWrite ($aTime)
$activeProcess = 0
Else
   Sleep (20)


EndIf
EndIf
WEnd

Alles anzeigen

**alpines**

Zitat von ru642

Wie kann ich das einmalig ausgeben ?

Ich hab dir die Logik doch im vorgegangenen Post beschrieben. Du musst irgendwie abspeichern ob dein Prozess schon läuft und die Zeit nur ersetzen wenn der Prozess läuft und er laut deiner Variable noch nicht gestartet ist. Sollte der Prozess bereits laufen und du hast das in der Variable abgespeichert, dann schreibst du natürlich nicht nochmal die Zeit rein.
Wenn der Prozess nicht läuft und deine Variable beinhaltet, dass der Prozess läuft, dann speicherst du wieder die Uhrzeit und setzt die Variable 0.

**Kanashius**

Ich vermute mal, du willst nicht unbedingt Programme, sondern eher Fenster protokollieren. Dabei würd sich das hier anbieten:

AutoIt

#include <APISysConstants.au3>
#include <WinAPISys.au3>
#include <Array.au3>
OnAutoItExitRegister('OnAutoItExit')


Global $g_hForm = GUICreate('')
GUIRegisterMsg(_WinAPI_RegisterWindowMessage('SHELLHOOK'), 'WM_SHELLHOOK')
_WinAPI_RegisterShellHookWindow($g_hForm)
Global $arWatchedWindows[0][4]
Global $arFilter=["notepad.exe"]


While 1
    Sleep(1000)
WEnd


Func WM_SHELLHOOK($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg
    Switch $hWnd
        Case $g_hForm
            Local $sTitle = WinGetTitle($lParam)
            Switch $wParam
				Case $HSHELL_WINDOWCREATED
					local $title=WinGetTitle($lParam),$pid=WinGetProcess($lParam),$pname=ProcessGetName($pid)
					If true Then;_ArraySearch($arFilter,$pname)<>-1 Then
						ReDim $arWatchedWindows[UBound($arWatchedWindows)+1][4]
						local $index=UBound($arWatchedWindows)-1
						$arWatchedWindows[$index][0]=$lParam
						$arWatchedWindows[$index][1]=$title
						$arWatchedWindows[$index][2]=$pid
						$arWatchedWindows[$index][3]=$pname
						_windowCreated($arWatchedWindows[$index][0],$arWatchedWindows[$index][1],$arWatchedWindows[$index][2],$arWatchedWindows[$index][3])
					EndIf
                Case $HSHELL_WINDOWDESTROYED
					for $i=0 to UBound($arWatchedWindows)-1 step 1
						If $lParam=$arWatchedWindows[$i][0] Then
							_windowDestroyed($arWatchedWindows[$i][0],$arWatchedWindows[$i][1],$arWatchedWindows[$i][2],$arWatchedWindows[$i][3])
							_ArrayDelete($arWatchedWindows,$i)
						EndIf
					next
            EndSwitch
    EndSwitch
EndFunc   ;==>WM_SHELLHOOK


Func _windowCreated($windowHandle,$windowTitle,$pid,$pname)
	ConsoleWrite('Created: ' & $windowHandle&" - "&$windowTitle&@crlf&@tab&@tab&$pid&" - "&$pname & @CRLF)
EndFunc


Func _windowDestroyed($windowHandle,$windowTitle,$pid,$pname)
	ConsoleWrite('Destroyed: ' & $windowHandle&" - "&$windowTitle&@crlf&@tab&@tab&$pid&" - "&$pname & @CRLF)
EndFunc


Func OnAutoItExit()
    _WinAPI_DeregisterShellHookWindow($g_hForm)
	GUIDelete($g_hForm)
EndFunc   ;==>OnAutoItExit


Func ProcessGetName($PId)
    If IsNumber($PId) = 0 Then
        SetError(2)
    ElseIf $PId > 9999 Then
        SetError(1)
    Else
        Local $PList = ProcessList()
        Local $i = 1
        Local $ProcessName = ""


        While $i <= $PList[0][0] And $ProcessName = ""
            If $PList[$i][1] = $PId Then
                $ProcessName = $PList[$i][0]
            Else
                $i = $i + 1
            EndIf
        WEnd
        Return $ProcessName
    EndIf
EndFunc ;==>ProcessGetName

Alles anzeigen

Es wird auf die Windowsevents zum erstellen und zerstören eines Fensters gelauscht und gegebenenfalls das Event behandelt.
In der auskommentierten If bedingung kannst du auch prozesse zum filtern angeben, damit nur diese protokolliert werden

Du kannst auch ggf. das Event $HSHELL_WINDOWACTIVATED noch zusätzlich abfragen, dann würde jedes aktivieren eines anderen Fensters mitprotokolliert werden. Dann kannst du auch messen, wie lange ein Fenster genutzt wird,... aber das kommt ja auch drauf an, wofür die Zeitstempel sind

Ich hoffe, das hilft dir weiter.

MfG Kanashius

ru642

Hallo Kanashius
Danke für deinen Script, leider komme ich mit diesem leider überhaupt nicht mehr draus.
Ich habe den Script mal ausgeführt und dieser loggt brav alle fenster die ich öffne & schliesse.
In meinem Fall brauche ich nicht viel, nur 1 Programm soll geloggt werden.
Es geht darum dem Kunden die Nutzungsdauer des Programms zu verrechnen.
Desshalb muss diese irgendwie festgehalten werden.

Ich habe deinen auskommentierten Teil erneut in den Script eingepflegt und getestet erhalte aber eine Fehlermeldung.
Ich gehe mal davon aus das ein then zu viel ist ?

AutoIt

If true Then _ArraySearch($arFilter,$pname)<>-1 Then
If true Then _ArraySearch($arFilter,$pname)^ ERROR

Hier noch mein Versuch den ich vor deiner Nachricht erstellt hatte:

AutoIt

HotKeySet("{ESC}", "Terminate")
Func Terminate()
    Exit
EndFunc   ;==>Terminate


Local $aTime
Local $eTime
Local $activeProcess = 0
Local $activeRunning = 0






While 1
$Process = ProcessExists ("notepad.exe")
If $Process >0 Then
$activeProcess =1


If $activeProcess = 1 and $activeRunning = 0 Then
ConsoleWrite ($aTime)
$activeRunning =1
$aTime = @HOUR & ":" & @MIN & ":" & @SEC


If $activeProcess = 1 and $activeRunning = 1 and $Process = 0 Then
$activeProcess =0
$activeRunning =0
$eTime = @HOUR & ":" & @MIN & ":" & @SEC
Else
   Sleep (20)
$activeProcess =0
$activeRunning = 0
EndIf
EndIf
EndIf
WEnd

Alles anzeigen

MFG Ru642

**Oscar**

Zitat von ru642

Es geht darum dem Kunden die Nutzungsdauer des Programms zu verrechnen.

In dem Fall würde ich das anders angehen:

AutoIt

Global $sIniFile = @ScriptDir & '\TimeProtocol.ini'


Global $iProcTime = IniRead($sIniFile, 'Protocol', 'Time', 0)
AdlibRegister('_AddTime', 1000)
HotKeySet('{ESC}', '_Exit')


While Sleep(1000)
WEnd


Func _Exit()
	If ProcessExists('Notepad.exe') Then Return
	IniWrite($sIniFile, 'Protocol', 'Time', $iProcTime)
	Exit
EndFunc


Func _AddTime()
	If ProcessExists('Notepad.exe') Then
		$iProcTime += 1
		ToolTip(_FormatTime($iProcTime))
	EndIf
EndFunc


Func _FormatTime($iSec)
	Local $iHour, $iMin
	$iHour = Int($iSec / 3600)
	$iSec = Mod($iSec, 3600)
	$iMin = Int($iSec / 60)
	$iSec = Mod($iSec, 60)
	Return StringFormat('%02i:%02i:%02i', $iHour, $iMin, $iSec)
EndFunc   ;==>_FormatTime

Alles anzeigen

ru642

Hallo Oscar

deine Version gefällt mir sehr gut, wollte mich erst später dann mit dem Filewrite beschäftigen, wäre aber so oder so auf dieses zurückgekommen.

~~Leider habe ich noch ein schwerwiegendes Problem und zwar wird kein ini File erstellt.~~
~~Der Tooltip zeigt aber an das hochgezählt wird.~~

Edit: habe ich bereits selber hingekriegt

ru642

Hallo Oscar

ich habe nun bei der Func AddTime () den IniWrite($sIniFile, 'Protocol', 'Time', $iProcTime) auch noch hinzugefügt.
Nun wird ein ini-File erstellt und in dieses die Zeit hinzugefügt.
~~Nun habe ich festgestellt das im File keine Formatierung hh/mm/ss besteht.~~
~~Wie setzt man dies am besten um ?~~

Edit: Habe mir hier einfach die bereits bestehende Funktion _FormatTime zu nutze gemacht.

AutoIt

Global $sIniFile = @ScriptDir & '\TimeProtocol.ini'
Global $iProcTime = IniRead($sIniFile, 'Protocol', 'Time', 0)
AdlibRegister('_AddTime', 1000)
HotKeySet('{ESC}', '_Exit')
While Sleep(1000)
WEnd
Func _Exit()
	If ProcessExists('Notepad.exe') Then Return
	IniWrite($sIniFile, 'Protocol', 'Time', $iProcTime)
	Exit
EndFunc
Func _AddTime()
	If ProcessExists('Notepad.exe') Then
		$iProcTime += 1
		ToolTip(_FormatTime($iProcTime))
		IniWrite($sIniFile, 'Protocol', 'Time', $iProcTime)
	EndIf
EndFunc
Func _FormatTime($iSec)
	Local $iHour, $iMin
	$iHour = Int($iSec / 3600)
	$iSec = Mod($iSec, 3600)
	$iMin = Int($iSec / 60)
	$iSec = Mod($iSec, 60)
	Return StringFormat('%02i:%02i:%02i', $iHour, $iMin, $iSec)
EndFunc   ;==>_FormatTime

Alles anzeigen

ru642

Hallo Oscar
ich habe nun deinen Script etwas erweitert.
Da ich noch nie mit Filewrite beschäftigt habe besteht noch eine Frage.
Wie genau kann ich verhindern das Einträge überschrieben werden.
Beispiel aktuell sieht das File folgendermassen aus:
[Protocol]
Time=17.08.2017/scr:00:00:22

Ich möchte nun aber verhidnern das die Zeit von Benutzer scr am nächsten Tag überschrieben wird + es kann auch ein anderer Benutzer den Script ausführen dann würde die ja auch wieder alles überschreiben.

Etwas in die Richtung und ich wäre glücklich bis zum Mond und zurück:

[Protocol]
Time=16.08.2017/mat:00:05:11
Time=17.08.2017/scr:00:00:22
Time=17.08.2017/mab:01:00:05
Time=18.08.2017/scr:00:10:22
usw.

Trotzdem schon vielen, vielen Dank für die unglaublich grosse Hilfe!

Aktueller Script:

AutoIt

Global $sIniFile = @ScriptDir & '\TimeProtocol.ini'
Global $iProcTime = IniRead($sIniFile, 'Protocol', 'Time', 0)
AdlibRegister('_AddTime', 1000)
HotKeySet('{ESC}', '_Exit')
While Sleep(1000)
WEnd
Func _Exit()
	If ProcessExists('firefox.exe') Then Return
	IniWrite($sIniFile, 'Protocol', 'Time', $iProcTime)
	Exit
EndFunc
Func _AddTime()
	If ProcessExists('firefox.exe') Then
		$iProcTime += 1
		ToolTip(_FormatTime($iProcTime))
		IniWrite($sIniFile, 'Protocol', 'Time', @MDAY & "."& @MON & "."& @YEAR & "/"& @UserName & ":" & _FormatTime ($iProcTime))
	EndIf
EndFunc
Func _FormatTime($iSec)
	Local $iHour, $iMin
	$iHour = Int($iSec / 3600)
	$iSec = Mod($iSec, 3600)
	$iMin = Int($iSec / 60)
	$iSec = Mod($iSec, 60)
	Return StringFormat('%02i:%02i:%02i', $iHour, $iMin, $iSec)
EndFunc   ;==>_FormatTime

Alles anzeigen

Mfg Ru642

NO1 :-)

ru642: Inidateien können nur einmal den selben Schlüssel (Time) in einer Sektion (Protocol) haben. Du könntest statt IniWrite, FileWrite nehmen, was ich aber unsinnig finde, da ini (Initialisierungs) Dateien dafür da sind, nur einmal einen Schlüssel in einer Sektion zu besitzen.

Lg NO1

ru642

Kann ich das Irgendwie austriksen in dem ich z.B. Time durch das Datum ersetzte und pro Benutzer ein File erstellen lasse ?

AutoIt

Global $sIniFile = @ScriptDir & '\Time\' & @UserName & '.ini'
Global $iProcTime = IniRead($sIniFile,'Protocol',@MDAY & "."& @MON & "."& @YEAR ,0)
AdlibRegister('_AddTime', 1000)
;HotKeySet('{ESC}', '_Exit')
While Sleep(1000)
WEnd
;Func _Exit()
;	If ProcessExists('firefox.exe') Then Return
;	IniWrite($sIniFile,'Protocol', 'Time', $iProcTime)
;	Exit
;EndFunc
Func _AddTime()
	If ProcessExists('notepad.exe') Then
		$iProcTime += 1
		ToolTip(_FormatTime($iProcTime))
		IniWrite($sIniFile,'Protocol',@MDAY & "."& @MON & "."& @YEAR, @UserName & ":" & _FormatTime ($iProcTime))
	EndIf
EndFunc
Func _FormatTime($iSec)
	Local $iHour, $iMin
	$iHour = Int($iSec / 3600)
	$iSec = Mod($iSec, 3600)
	$iMin = Int($iSec / 60)
	$iSec = Mod($iSec, 60)
	Return StringFormat('%02i:%02i:%02i', $iHour, $iMin, $iSec)
EndFunc   ;==>_FormatTime

Alles anzeigen

**Oscar**

Was willst Du denn nun erreichen?
Im Ausgangs-Post war es Start-/Endzeit, im Post#6 die Nutzungsdauer und nun Datum/Zeit je Benutzer.
Definiere doch mal genau, was das Script aufzeichnen soll, dann kann man Dir auch weiterhelfen.

ru642

Hallo Oscar
ich will die Nutzungsdauer wissen.
Am besten pro Tag darum auch das Datum.
So kann ich am besten rausfiltern wieviel eine Applikation über den Zeitraum von einer Woche oder Monat benutzt wurde.

**BugFix**

Dann erstelle für jeden User eine Log-Datei:

AutoIt

OnAutoItExitRegister("_WriteLog")


Global $sLogFile = @ScriptDir & '\Time\' & @UserName & '.log'
Global $iProcTime = ''
Global $sProcess = 'notepad.exe'


AdlibRegister('_AddTime', 1000)
;HotKeySet('{ESC}', '_Exit')
While Sleep(1000)
WEnd


;Func _Exit()
;	If ProcessExists('firefox.exe') Then Return
;	IniWrite($sIniFile,'Protocol', 'Time', $iProcTime)
;	Exit
;EndFunc


Func _AddTime()
	If ProcessExists($sProcess) Then
		$iProcTime += 1
;~ 		ToolTip(_FormatTime($iProcTime))
	EndIf
EndFunc


Func _WriteLog()
	Local $fH = FileOpen($sLogFile, 1+8)
	FileWrite($fH, StringFormat('%s.$s.%s %s: %s%s', @MDAY, @MON, @YEAR, $sProcess, _FormatTime($iProcTime), @CRLF))
	FileClose($fH)
EndFunc


Func _FormatTime($iSec)
	Local $iHour, $iMin
	$iHour = Int($iSec / 3600)
	$iSec = Mod($iSec, 3600)
	$iMin = Int($iSec / 60)
	$iSec = Mod($iSec, 60)
	Return StringFormat('%02i:%02i:%02i', $iHour, $iMin, $iSec)
EndFunc   ;==>_FormatTime

Alles anzeigen