Ca. 3 % CPU-Auslastung durch Endlos-Skript normal?

fraschi

Hallo miteinander,

ich habe das unten stehende kleine Anfänger-Quick-and-Dirty-Skript erstellt und gestartet. Grundsätzlich macht es auch das, was es soll, nämlich auf dieses unnötige Win10-Appstor-Fenster warten und es sodann automatisiert schließen.

Mir ist jetzt lediglich im Prozessmonitor aufgefallen, dass dieses ständig in einer Endlos-Schleife laufende Skript ca. 2 bis 3 Prozent CPU-Leistung benötigt, und wollte mal fragen, ob das bei so einem Endlos-Schleifen-Skript ganz normal ist? Oder ob es hier noch Optimierungsmöglichkeiten gibt, dass diese ständige CPU-Belastung nicht oder nur in geringerem Maße auftritt, die Funktion aber dennoch gewährleistet ist?

Besten Dank im Voraus für sachdienliche Hinweis.

AutoIt

AutoItSetOption ( "WinTitleMatchMode" , 2 )
Close_Appstore_Frage()


Func Close_Appstore_Frage()
	While 1 = 1
		WinWait("App im Store suchen?")
		; Wait for 0,2 seconds to display the window.
		Sleep(200)
		; Close the window using the Title.
		WinClose("App im Store suchen?")
	Wend
EndFunc   ;==>Close_Appstore_Frage

Alles anzeigen

**alpines**

Das Sleep kannst du weglassen, da WinWait alle 250ms selber pollt. Wenn du die Auslastung reduzieren willst, dann erstell dir am besten eine eigene Abfrage mit WinExists und sleepe 500ms.
Eigentlich sollte bei 250ms trotzdem die Auslastung unter einen Prozent sinken.

fraschi

Danke, das hat schon mal sehr geholfen ... damit liegt die CPU-Belastung jetzt nur noch bei rd. 0,1 %.

**AspirinJunkie**

Eventuell kannst du die Auslastung noch weiter minimieren indem du das Skript permant in den Schlaf schickst und Windows anweist das Skript aufzuwecken sobald ein neues Fenster erstellt wurde.
Also die Windows-Events abfangen.

So könnte ich mir das Grundkonzept vorstellen:

AutoIt

Global Const $EVENT_OBJECT_CREATE = 0x8000
HotKeySet("{ESC}", "_raus")


; Funktion _reactOnFocusChange mit EVENT_SYSTEM_FOREGROUND "verbinden"
$hWinEventProc = DllCallbackRegister(_reactOnNewWindow, "none", "hwnd;int;hwnd;long;long;int;int")
DllCall("User32.dll", "hwnd", "SetWinEventHook", "uint", $EVENT_OBJECT_CREATE, "uint", $EVENT_OBJECT_CREATE, "hwnd", 0, "ptr", DllCallbackGetPtr($hWinEventProc), "int", 0, "int", 0, "uint", 0x2)


; sparsame Endlosschleife
While Sleep(1000)
WEnd




; Funktion welche ausgeführt wird, sobald ein neues Fenster erstellt wird
Func _reactOnNewWindow($hHook, $iEvent, $hWnd, $idObject, $idChild, $iEventThread, $iEventTime)
    If StringInStr(WinGetTitle($hWnd), "App im Store suchen?") Then
		MsgBox(0, "Fenster da", WinGetTitle($hWnd))
	EndIf
EndFunc   ;==>_reactOnFocusChange


; Wenn ESC gedrückt wird - beenden
Func _raus()
	Exit
EndFunc

Alles anzeigen

Kommt das angesprochene Fenster in den Vordergrund?
Dann wäre $EVENT_SYSTEM_FOREGROUND als Event sicherlich besser.

fraschi

Hmm, ist ja interessant ... auf solchen komplexen Code wäre ich ja niemals gekommen ...

ABER irgendwie scheint es nicht wirklich wie erwartet zu funktionieren: Wenn das Fenster kommt, passiert erst mal gar nichts, erst irgendwann später bei irgendwelchen anderen Fenster-Aktionen kommt die MessageBox.

Möglicherweise liegt es ja daran, dass dieses Fenster mit der Frage, ob eine App im Store gesucht werden soll, kein normales Windows-Programm-Fenster ist, sondern nach so einer Modern-UI-Anwendung aussieht (und vielleicht daher die Events sich auch unterscheiden? ... keine Ahnung).

Wobei mein kleines Skript mit dem Schließen aufgrund des Titels - wenn ich das wieder anschmeiße - ja soweit ganz gut und zufriedenstellend funktioniert.

Dein Skript hat tatsächlich nur noch ca. 0,02 % CPU-Belastung erzeugt, aber ich denke mal, dass ich mit der von '@alpines' genannten Version und der 0,1 % CPU-Belastung schon ganz zufrieden sein kann.

Trotzdem auch Dir danke fürs Nachdenken.

**AspirinJunkie**

Ja war nur noch ein weiterer Gedankenanstoß zu dem Thema und auch nicht 100% ausgearbeitet. Muss mich bei sowas immer durch die ganzen Listen wühlen welches Event nun das korrekte hierfür ist.
Wenn es momentan nicht klappt dann kannst du ja nochmal versuchen oben 2x EVENT_OBJECT_CREATE durch $EVENT_SYSTEM_FOREGROUND auszutauschen.

fraschi

Nee, danke, aber bringt hier auch keine andere Wirkung ...

**alpines**

Die wohl vernünftigste, rationalste und logischte Konsequenz bzw. Möglichkeit wäre wohl einfach Windows 10 zu deinstallieren und weiter 7 zu benutzen

**AspirinJunkie**

Darf ich bloß mal kurz fragen wo du die Definition von $EVENT_SYSTEM_FOREGROUND her hast, da ich ja vergessen habe diese zu erwähnen?
Im Grunde meinte ich es so:

AutoIt

Global Const $EVENT_SYSTEM_FOREGROUND = 0x3
Global Const $EVENT_OBJECT_CREATE = 0x8000
HotKeySet("{ESC}", "_raus")


Global $hWinEventProc = DllCallbackRegister(_reactOnNewWindow, "none", "hwnd;int;hwnd;long;long;int;int")
DllCall("User32.dll", "hwnd", "SetWinEventHook", "uint", $EVENT_SYSTEM_FOREGROUND, "uint", $EVENT_SYSTEM_FOREGROUND, "hwnd", 0, "ptr", DllCallbackGetPtr($hWinEventProc), "int", 0, "int", 0, "uint", 0x2)


; sparsame Endlosschleife
While Sleep(10000)
WEnd


; Funktion welche ausgeführt wird, sobald ein neues Fenster erstellt wird
Func _reactOnNewWindow($hHook, $iEvent, $hWnd, $idObject, $idChild, $iEventThread, $iEventTime)
    If StringInStr(WinGetTitle($hWnd), "App im Store suchen?") Then
		MsgBox(0, "Fenster da", WinGetTitle($hWnd))
	EndIf
EndFunc   ;==>_reactOnFocusChange


; Wenn ESC gedrückt wird - beenden
Func _raus()
	Exit
EndFunc

Alles anzeigen

Und dies führt nicht zum gewünschten Ergebnis bei dir?

fraschi

Danke, mit DEM Code klappt es zwar, hat aber den Nachteil, dass ich die ESC-Taste ansonsten nicht für andere Zwecke benutzen kann, bzw. sich beim Versuch, sie wie gewohnt zu verwenden, dann erst mal das Skript beendet und erst beim zweiten ESC die eigentlich gewünschte Funktion ausgeführt wird. Und danach müsste ich dann das Skript erstmal wieder erneut händisch starten.
Ist alles dann doch nicht so prickelnd ...

**AspirinJunkie**

War doch nur ein Beispiel mit dem ESC.
Sollst dir doch noch anpassen wie du lustig bist.

fraschi

O.k., danke ... ich bin halt blutiger Anfänger ... Ich hab die HotkeySet-Zeile (und die zugehörige Funktion) jetzt einfach erstmal auskommentiert, so dass es nunmehr wie gewünscht und mit nur noch 0,02 % CPU-Belastung funktioniert.

Nochmals danke ...

**autoiter**

Hallo @AspirinJunkie,
ich würde mich extremst freuen, wenn du folgendes noch mal kurz referierst:

Zitat von AspirinJunkie

Eventuell kannst du die Auslastung noch weiter minimieren indem du das Skript permant in den Schlaf schickst und Windows anweist das Skript aufzuwecken sobald ein neues Fenster erstellt wurde.
Also die Windows-Events abfangen.

...

Zitat von AspirinJunkie

Kommt das angesprochene Fenster in den Vordergrund?
Dann wäre $EVENT_SYSTEM_FOREGROUND als Event sicherlich besser.

Kann ich $EVENT_SYSTEM_FOREGROUND (0x3) einfach in deinem Skript durch andere Events tauschen? (https://msdn.microsoft.com/en-us/library/…6(v=vs.85).aspx)

**Kanashius**

Ja, das sollte gehen. Les dir aber unbedingt die Beschreibung des Events durch (Rechts neben dem Namen). Manchmal werden bestimmte Werte in andere Parameter geschrieben,...

Gerade vor ein paar Tagen hatte ich diese Methode zum protokollieren des erstellens/löschens eines Fensters gepostet.