StringInStr mit mehreren Substrings

timee000

Hallo

Ich bin auf der suche nach einer Möglichkeit womit ich mehrere Substrings in einem String finden kann.

Sozusagen wie:

StringRegExp($string, "apfel&banane&birne")

Allerdings gibt es bei StringRegExp nur ODER | aber nicht UND &.

Bisher hatte ich es so gelöst:

Code

$pattern = "apfel|banane|birne"
$string = "apfel apfel banane"
$ar_regexp = StringRegExp($string, $pattern, 3)
If UBound($ar_regexp) = Stringsplit($pattern, "|")[0] Then MsgBox(0, "Erfolgreich", "Alle Strings enthalten")

Leider ist diese Methode sehr fehleranfällig da 2x Apfel und 1x Banane gefunden wird aber nicht Birne.

If StringInStr And StringInStr fällt auch raus da ich nicht weiß wie viele Substrings gesucht werden.

Und mit einer For-Next Schleife wollte ich auch nicht so gerne Arbeiten da es sehr viele Dateien sind und diese "langsam" ist.

Kennt jemand vielleicht noch eine andere Möglichkeit dieses Problem zu lösen?

Mfg timee000

xSunLighTx3

Mach dir am besten ein Array aus den Strings, die du auslesen willst und das fragst du dann in einer For Schleife ab.

**alpines**

Fang doch einfach die Gruppen im regulären Ausdruck und geh das Ergebnisarray durch, wenn du alle findest, dann hast du auch alle gefunden.

AutoIt

$sFindMe = "apfel|zimt|bananenbrot|pepsi"
$sString = "Ich backe meinen Apfelkuchen gerne mit etwas Zimt und Bananenbrot."

$aRegEx = StringRegExp($sString, "(?i)" & "(" & $sFindMe & ")", 3)

If Not UBound($aRegEx) Then
    MsgBox(16, "Fehler", "Keiner der Strings wurde gefunden.")
    Exit
EndIf

$aFindMe = StringSplit($sFindMe, "|", 3)
ConsoleWrite($sString & @CRLF)

For $i = 0 To UBound($aFindMe) - 1
    $bFound = False

    For $j = 0 To UBound($aRegEx) - 1
        If $aFindMe[$i] = $aRegEx[$j] Then
            $bFound = True
            ExitLoop
        EndIf
    Next

    If Not $bFound Then
        ConsoleWrite($aFindMe[$i] & " wurde nicht gefunden." & @CRLF)
    EndIf
Next

Alles anzeigen

Zitat von xSunLighTx3

Mach dir am besten ein Array aus den Strings, die du auslesen willst und das fragst du dann in einer For Schleife ab.

Dieses Vorgehen ist nicht zu empfehlen, du scannst bei dem Vorgehen den String immer neu und die Laufzeit wächst proportional zu der Anzahl an Strings.

Wenn der Eingabestring mehrere hundert KB ist, dann kann das schon ziemlich lange dauern.

Mein Vorgehen ist da wesentlich effizienter, da du den Text nur einmal scannst und dann die Funde durchgehst.

timee000

Zitat von alpines

Fang doch einfach die Gruppen im regulären Ausdruck und geh das Ergebnisarray durch, wenn du alle findest, dann hast du auch alle gefunden.

Stimmt soweit habe ich garnicht gedacht. Vielen Dank alpines. Funktioniert bestens!

Mfg timee000