StringSplit innhalber einer Funktion, funktioniert nicht

**AspirinJunkie**

Ach wenn hier schon alle Skripte dazu posten dann will ich mal nicht so sein und auch eine Version anbieten:

AutoIt

#include <Array.au3>

$a_BIOSInfo = _GetBIOSInfo()
_ArrayDisplay($a_BIOSInfo)

Func _GetBIOSInfo()
    Local $o_Class = ObjGet("winmgmts:").Get("Win32_Bios")
    Local $o_Props = $o_Class.Properties_(), $i_C = 0, $a_Ret[$o_Props.Count()][2]
    Local $o_Item = $o_Class.Instances_(16).ItemIndex(0)

    For $o_Prop In $o_Props
        $a_Ret[$i_C][0] = $o_Prop.Name
        $a_Ret[$i_C][1] = Execute("$o_Item." & $o_Prop.Name)
        $i_C += 1
    Next
    Return $a_Ret
EndFunc   ;==>_GetBIOSInfo

Alles anzeigen

**autoiter**

Hammer-cool AspirinJunkie (wie immer)

**Bitnugger**

Zitat von Musashi

The requested action with this object has failed.

Hm, da bin ich aber sehr erstaunt, dass auf einigen System nicht alle Properties unterstützt werden. Bei mir (Win 10 X64) sind sie alle verfügbar, aber wie bei BugFix sind einige davon nicht befüllt.

Funktioniert denn die Version von AspirinJunkie bei euch?

Hier der Ordnung halber noch mal meine Version mit Error-Handler...

_GetBIOSInfo()

C

;-- TIME_STAMP   2017-10-20 19:44:56   v 1.1

#Region ;************ Includes ************
#include <Array.au3>
#EndRegion ;************ Includes ************

Opt('MustDeclareVars', 1) ; Variablen müssen vor der Verwendung deklariert werden

Global $oMyError = ObjEvent("AutoIt.Error","MyErrFunc")

Global Enum $eBiosCharacteristics, $eBIOSVersion, $eBuildNumber, $eCaption, $eCodeSet, $eCurrentLanguage, $eDescription, $eEmbeddedControllerMajorVersion, $eEmbeddedControllerMinorVersion, $eIdentificationCode, $eInstallableLanguages, $eInstallDate, $eLanguageEdition, $eListOfLanguages, $eManufacturer, $eName, $eOtherTargetOS, $ePrimaryBIOS, $eReleaseDate, $eSerialNumber, $eSMBIOSBIOSVersion, $eSMBIOSMajorVersion, $eSMBIOSMinorVersion, $eSMBIOSPresent, $eSoftwareElementID, $eSoftwareElementState, $eStatus, $eSystemBiosMajorVersion, $eSystemBiosMinorVersion, $eTargetOperatingSystem, $eVersion, $eSizeOff

Global $g_aBIOSInfo = _GetBIOSInfo()

If @error Then
    ConsoleWrite("! Fehler in der Funktion _GetBIOSInfo! Error = " & @error & @CRLF)
Else
    For $i = 0 To $eSizeOff - 1 Step 1
        ConsoleWrite(StringFormat('> %32s = %s\r', $g_aBIOSInfo[$i][0], $g_aBIOSInfo[$i][1]))
    Next
    ConsoleWrite(@CRLF)

    Local $aSplit

    $aSplit = _SplitStr($g_aBIOSInfo[$eSMBIOSBIOSVersion][1])
    ConsoleWrite(StringFormat('! %32s = %s\r', 'SMBBIOSVersion Split 1', $aSplit[0]))
    ConsoleWrite(StringFormat('! %32s = %s\r', 'SMBBIOSVersion Split 2', $aSplit[1]))

    ConsoleWrite(@CRLF)

    $aSplit = _SplitStr($g_aBIOSInfo[$eVersion][1])
    ConsoleWrite(StringFormat('- %32s = %s\r', '       Version Split 1', $aSplit[0]))
    ConsoleWrite(StringFormat('- %32s = %s\r', '       Version Split 2', $aSplit[1]))

    ConsoleWrite(@CRLF)

    ConsoleWrite(StringFormat('+ %32s = %s\r', '       Version Split 1', _SplitStr($g_aBIOSInfo[$eVersion][1])[0]))
    ConsoleWrite(StringFormat('+ %32s = %s\r', '       Version Split 2', _SplitStr($g_aBIOSInfo[$eVersion][1])[1]))

    ConsoleWrite(@CRLF)

    ConsoleWrite(StringFormat('@ %32s = %s\r', $g_aBIOSInfo[$eManufacturer][0], $g_aBIOSInfo[$eManufacturer][1]))

    _ArrayDisplay($g_aBIOSInfo)
EndIf

Func _GetBIOSInfo()
    Local $objWMI, $colItems, $objItem, $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
    Local $sBIOSVersion, $sManufacturer, $sSerialNumber
    Local $aReturn[0][2]
    Local $strBiosCharacteristics, $strBIOSVersion, $strListOfLanguages

    $objWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")
    $colItems = $objWMI.ExecQuery("SELECT * FROM Win32_BIOS", "WQL", BitOR($wbemFlagReturnImmediately, $wbemFlagForwardOnly))
    If IsObj($colItems) Then
        For $objItem In $colItems
            With $objItem
                $strBiosCharacteristics &= .BiosCharacteristics & ","
                _ArrayAddItem($aReturn, "BiosCharacteristics", $strBiosCharacteristics)
                $strBIOSVersion &= .BIOSVersion & ","
                _ArrayAddItem($aReturn, "BIOSVersion", $strBIOSVersion)
                _ArrayAddItem($aReturn, "BuildNumber", .BuildNumber)
                _ArrayAddItem($aReturn, "Caption", .Caption)
                _ArrayAddItem($aReturn, "CodeSet", .CodeSet)
                _ArrayAddItem($aReturn, "CurrentLanguage", .CurrentLanguage)
                _ArrayAddItem($aReturn, "Description", .Description)
                _ArrayAddItem($aReturn, "EmbeddedControllerMajorVersion", .EmbeddedControllerMajorVersion)
                _ArrayAddItem($aReturn, "EmbeddedControllerMinorVersion", .EmbeddedControllerMinorVersion)
                _ArrayAddItem($aReturn, "IdentificationCode", .IdentificationCode)
                _ArrayAddItem($aReturn, "InstallableLanguages", .InstallableLanguages)
                _ArrayAddItem($aReturn, "InstallDate", .InstallDate)
                _ArrayAddItem($aReturn, "LanguageEdition", .LanguageEdition)
                $strListOfLanguages &= .ListOfLanguages & ","
                _ArrayAddItem($aReturn, "ListOfLanguages", $strListOfLanguages)
                _ArrayAddItem($aReturn, "Manufacturer", .Manufacturer)
                _ArrayAddItem($aReturn, "Name", .Name)
                _ArrayAddItem($aReturn, "OtherTargetOS", .OtherTargetOS)
                _ArrayAddItem($aReturn, "PrimaryBIOS", .PrimaryBIOS)
                _ArrayAddItem($aReturn, "ReleaseDate", .ReleaseDate)
                _ArrayAddItem($aReturn, "SerialNumber", .SerialNumber)
                _ArrayAddItem($aReturn, "SMBIOSBIOSVersion", .SMBIOSBIOSVersion)
                _ArrayAddItem($aReturn, "SMBIOSMajorVersion", .SMBIOSMajorVersion)
                _ArrayAddItem($aReturn, "SMBIOSMinorVersion", .SMBIOSMinorVersion)
                _ArrayAddItem($aReturn, "SMBIOSPresent", .SMBIOSPresent)
                _ArrayAddItem($aReturn, "SoftwareElementID", .SoftwareElementID)
                _ArrayAddItem($aReturn, "SoftwareElementState", .SoftwareElementState)
                _ArrayAddItem($aReturn, "Status", .Status)
                _ArrayAddItem($aReturn, "SystemBiosMajorVersion", .SystemBiosMajorVersion)
                _ArrayAddItem($aReturn, "SystemBiosMinorVersion", .SystemBiosMinorVersion)
                _ArrayAddItem($aReturn, "TargetOperatingSystem", .TargetOperatingSystem)
                _ArrayAddItem($aReturn, "Version", .Version)
            EndWith
        Next
    Else
        Return SetError(1)
    EndIf

    Return $aReturn
EndFunc  ;==>_GetBIOSInfo

Func MyErrFunc()
    ConsoleWrite("! COM Error!" & @CRLF & _
        "!    err.description is  : " & @TAB & $oMyError.description & @CRLF & _
        "!    err.windescription  : " & @TAB & $oMyError.windescription & @CRLF & _
        "!    err.number is       : " & @TAB & Hex($oMyError.number,8) & @CRLF & _
        "!    err.lastdllerror is : " & @TAB & $oMyError.lastdllerror & @CRLF & _
        "!    err.scriptline is   : " & @TAB & $oMyError.scriptline & @CRLF & _
        "!    err.source is       : " & @TAB & $oMyError.source & @CRLF & _
        "!    err.helpfile is     : " & @TAB & $oMyError.helpfile & @CRLF & _
        "!    err.helpcontext is  : " & @TAB & $oMyError.helpcontext & @CRLF)
Endfunc

Func _ArrayAddItem(ByRef $aArray, $sName, $sItem)
    Local $iDim = UBound($aArray) + 1
    ReDim $aArray[$iDim][2]
    $aArray[$iDim - 1][0] = $sName
    $aArray[$iDim - 1][1] = $sItem
EndFunc  ;==>_ArrayAddItem

Func _SplitStr($sStr)
    Local $aSplit[2], $iSeperator = -1, $aSeperator = ['.', ' - ', '-', '']
    Do
        $iSeperator += 1
        If $aSeperator[$iSeperator] = '' Or $sStr = '' Then
            ReDim $aSplit[2]
            $aSplit[0] = $sStr
            $aSplit[1] = ''
            ExitLoop
        EndIf
        $aSplit = StringRegExp($sStr, '(.+)\' & $aSeperator[$iSeperator] & '(.+)', 1)
    Until UBound($aSplit) = 2

    Return $aSplit
EndFunc  ;==>_SplitStr

Alles anzeigen

Musashi

In den meisten Funktionen kann man nicht nach Belieben irgendwelche Zeilen auskommentieren und dabei erwarten, dass sie ohne weitere Anpassungen funktionieren. Hier in diesem Fall müssten lediglich die entsprechenden Enum-Werte entfernt werden. Alternativ könnte man die Funktion auch umschreiben, dass sie nur die gewünschten Werte liefert... z.B.: _GetBIOSInfo('SMBIOSBIOSVersion', 'SMBIOSMajorVersion', 'SMBIOSMinorVersion', 'Version')

Global Enum $eBiosCharacteristics, $eBIOSVersion, $eBuildNumber, $eCaption, $eCodeSet, $eCurrentLanguage, $eDescription, ~~$eEmbeddedControllerMajorVersion~~, $~~eEmbeddedControllerMinorVersion~~, $eIdentificationCode, $eInstallableLanguages, $eInstallDate, $eLanguageEdition, $eListOfLanguages, $eManufacturer, $eName, $eOtherTargetOS, $ePrimaryBIOS, $eReleaseDate, $eSerialNumber, $eSMBIOSBIOSVersion, $eSMBIOSMajorVersion, $eSMBIOSMinorVersion, $eSMBIOSPresent, $eSoftwareElementID, $eSoftwareElementState, $eStatus, $eSystemBiosMajorVersion, $eSystemBiosMinorVersion, $eTargetOperatingSystem, $eVersion, $eSizeOff

Global Enum $eBiosCharacteristics, $eBIOSVersion, $eBuildNumber, $eCaption, $eCodeSet, $eCurrentLanguage, $eDescription, $eIdentificationCode, $eInstallableLanguages, $eInstallDate, $eLanguageEdition, $eListOfLanguages, $eManufacturer, $eName, $eOtherTargetOS, $ePrimaryBIOS, $eReleaseDate, $eSerialNumber, $eSMBIOSBIOSVersion, $eSMBIOSMajorVersion, $eSMBIOSMinorVersion, $eSMBIOSPresent, $eSoftwareElementID, $eSoftwareElementState, $eStatus, $eSystemBiosMajorVersion, $eSystemBiosMinorVersion, $eTargetOperatingSystem, $eVersion, $eSizeOff

;_ArrayAddItem($aReturn, "EmbeddedControllerMajorVersion", .EmbeddedControllerMajorVersion)

;_ArrayAddItem($aReturn, "EmbeddedControllerMinorVersion", .EmbeddedControllerMinorVersion)

**Musashi**

Zitat von autoiter

Hammer-cool AspirinJunkie (wie immer)

Ja, direkt über die Eigenschaften und Methoden des Objektes zu gehen hat schon was !

Das Beispiel von Oscar ist aber auch nicht schlecht. Es ist zwar länger, für 'Normaluser' aber wahrscheinlich leichter zu verstehen und zu modifizieren.

Fazit : Beides sehr gelungene Lösungswege

Gruß Musashi

**Musashi**

Hallo Bitnugger !

Zitat von Bitnugger

Funktioniert denn die Version von AspirinJunkie bei euch?

Ja, sowohl die Version von AspirinJunkie , als auch die von Oscar ! (mein System : Win7 Pro SP1)

Zitat von Bitnugger

In den meisten Funktionen kann man nicht nach Belieben irgendwelche Zeilen auskommentieren und dabei erwarten, dass sie ohne weitere Anpassungen funktionieren. Hier in diesem Fall müssten lediglich die entsprechenden Enum-Werte entfernt werden.

Mir ist schon klar, dass man nicht nach Belieben irgendwelche Zeilen auskommentieren sollte !

Trotzdem halte ich es hier, in gewisser Weise, schon für einen kleinen Designfehler. Die (Re)dimensionierung des Arrays erfolgt anhand der Aufrufe von _ArrayAddItem($aReturn,...). Dass jemand bestimmte Werte ggf. nicht benötigt, wäre nicht so exotisch. Da sich $eSizeOff aber nur nach der Anzahl der Enum-Werte (Global Enum ...) richtet, besteht die Gefahr, dass die Arraygrenze überschritten wird. Es ist für 'Normaluser' nur schwer zu erkennen, dass er auch die jeweiligen Enum-Werte entfernen muss (nur meine Meinung, keine Kritik ).

Gruß Musashi

**Bitnugger**

Zitat von Musashi

Die (Re)dimensionierung des Arrays

Habe ich nun komplett entfernt und auch noch drei Fehler beseitigt. BiosCharacteristics, BIOSVersion und ListOfLanguages sind Arrays... die ich aber als String behandelt hatte.

Zitat von Musashi

Es ist für 'Normaluser' nur schwer zu erkennen, dass er auch die jeweiligen Enum-Werte entfernen muss

Tja, und was bitte soll ich daran ändern?

_GetBIOSInfo

C

;-- TIME_STAMP   2017-10-20 21:33:12   v 1.2

#Region ;************ Includes ************
#include <Array.au3>
#EndRegion ;************ Includes ************

Opt('MustDeclareVars', 1) ; Variablen müssen vor der Verwendung deklariert werden

Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")

Global Enum $eBiosCharacteristics, $eBIOSVersion, $eBuildNumber, $eCaption, $eCodeSet, $eCurrentLanguage, $eDescription, $eEmbeddedControllerMajorVersion, $eEmbeddedControllerMinorVersion, $eIdentificationCode, $eInstallableLanguages, $eInstallDate, $eLanguageEdition, $eListOfLanguages, $eManufacturer, $eName, $eOtherTargetOS, $ePrimaryBIOS, $eReleaseDate, $eSerialNumber, $eSMBIOSBIOSVersion, $eSMBIOSMajorVersion, $eSMBIOSMinorVersion, $eSMBIOSPresent, $eSoftwareElementID, $eSoftwareElementState, $eStatus, $eSystemBiosMajorVersion, $eSystemBiosMinorVersion, $eTargetOperatingSystem, $eVersion, $eSizeOff

Global $g_aBIOSInfo = _GetBIOSInfo()

If @error Then
    ConsoleWrite("! Fehler in der Funktion _GetBIOSInfo! Error = " & @error & @CRLF)
Else
    For $i = 0 To $eSizeOff - 1 Step 1
        ConsoleWrite(StringFormat('> %32s = %s\r', $g_aBIOSInfo[$i][0], $g_aBIOSInfo[$i][1]))
    Next
    ConsoleWrite(@CRLF)

    Local $aSplit

    $aSplit = _SplitStr($g_aBIOSInfo[$eSMBIOSBIOSVersion][1])
    ConsoleWrite(StringFormat('! %32s = %s\r', 'SMBBIOSVersion Split 1', $aSplit[0]))
    ConsoleWrite(StringFormat('! %32s = %s\r', 'SMBBIOSVersion Split 2', $aSplit[1]))

    ConsoleWrite(@CRLF)

    $aSplit = _SplitStr($g_aBIOSInfo[$eVersion][1])
    ConsoleWrite(StringFormat('- %32s = %s\r', '       Version Split 1', $aSplit[0]))
    ConsoleWrite(StringFormat('- %32s = %s\r', '       Version Split 2', $aSplit[1]))

    ConsoleWrite(@CRLF)

    ConsoleWrite(StringFormat('+ %32s = %s\r', '       Version Split 1', _SplitStr($g_aBIOSInfo[$eVersion][1])[0]))
    ConsoleWrite(StringFormat('+ %32s = %s\r', '       Version Split 2', _SplitStr($g_aBIOSInfo[$eVersion][1])[1]))

    ConsoleWrite(@CRLF)

    ConsoleWrite(StringFormat('@ %32s = %s\r', $g_aBIOSInfo[$eManufacturer][0], $g_aBIOSInfo[$eManufacturer][1]))

    _ArrayDisplay($g_aBIOSInfo)
EndIf

Func _GetBIOSInfo()
    Local $objWMI, $colItems, $objItem, $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
    Local $sBIOSVersion, $sManufacturer, $sSerialNumber
    Local $aReturn[$eSizeOff][2]

    $objWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")
    $colItems = $objWMI.ExecQuery("SELECT * FROM Win32_BIOS", "WQL", BitOR($wbemFlagReturnImmediately, $wbemFlagForwardOnly))
    If IsObj($colItems) Then
        For $objItem In $colItems
            With $objItem
                If IsArray(.BiosCharacteristics) Then _ArraySetItem($aReturn, $eBiosCharacteristics, "BiosCharacteristics", _ArrayToString(.BiosCharacteristics, ","))
                If IsArray(.BIOSVersion) Then _ArraySetItem($aReturn, $eBIOSVersion, "BIOSVersion", _ArrayToString(.BIOSVersion, ","))
                _ArraySetItem($aReturn, $eBuildNumber, "BuildNumber", .BuildNumber)
                _ArraySetItem($aReturn, $eCaption, "Caption", .Caption)
                _ArraySetItem($aReturn, $eCodeSet, "CodeSet", .CodeSet)
                _ArraySetItem($aReturn, $eCurrentLanguage, "CurrentLanguage", .CurrentLanguage)
                _ArraySetItem($aReturn, $eDescription, "Description", .Description)
                _ArraySetItem($aReturn, $eEmbeddedControllerMajorVersion, "EmbeddedControllerMajorVersion", .EmbeddedControllerMajorVersion)
                _ArraySetItem($aReturn, $eEmbeddedControllerMinorVersion, "EmbeddedControllerMinorVersion", .EmbeddedControllerMinorVersion)
                _ArraySetItem($aReturn, $eIdentificationCode, "IdentificationCode", .IdentificationCode)
                _ArraySetItem($aReturn, $eInstallableLanguages, "InstallableLanguages", .InstallableLanguages)
                _ArraySetItem($aReturn, $eInstallDate, "InstallDate", .InstallDate)
                _ArraySetItem($aReturn, $eLanguageEdition, "LanguageEdition", .LanguageEdition)
                If IsArray(.ListOfLanguages) Then _ArraySetItem($aReturn, $eListOfLanguages, "ListOfLanguages", _ArrayToString(.ListOfLanguages, ","))
                _ArraySetItem($aReturn, $eManufacturer, "Manufacturer", .Manufacturer)
                _ArraySetItem($aReturn, $eName, "Name", .Name)
                _ArraySetItem($aReturn, $eOtherTargetOS, "OtherTargetOS", .OtherTargetOS)
                _ArraySetItem($aReturn, $ePrimaryBIOS, "PrimaryBIOS", .PrimaryBIOS)
                _ArraySetItem($aReturn, $eReleaseDate, "ReleaseDate", .ReleaseDate)
                _ArraySetItem($aReturn, $eSerialNumber, "SerialNumber", .SerialNumber)
                _ArraySetItem($aReturn, $eSMBIOSBIOSVersion, "SMBIOSBIOSVersion", .SMBIOSBIOSVersion)
                _ArraySetItem($aReturn, $eSMBIOSMajorVersion, "SMBIOSMajorVersion", .SMBIOSMajorVersion)
                _ArraySetItem($aReturn, $eSMBIOSMinorVersion, "SMBIOSMinorVersion", .SMBIOSMinorVersion)
                _ArraySetItem($aReturn, $eSMBIOSPresent, "SMBIOSPresent", .SMBIOSPresent)
                _ArraySetItem($aReturn, $eSoftwareElementID, "SoftwareElementID", .SoftwareElementID)
                _ArraySetItem($aReturn, $eSoftwareElementState, "SoftwareElementState", .SoftwareElementState)
                _ArraySetItem($aReturn, $eStatus, "Status", .Status)
                _ArraySetItem($aReturn, $eSystemBiosMajorVersion, "SystemBiosMajorVersion", .SystemBiosMajorVersion)
                _ArraySetItem($aReturn, $eSystemBiosMinorVersion, "SystemBiosMinorVersion", .SystemBiosMinorVersion)
                _ArraySetItem($aReturn, $eTargetOperatingSystem, "TargetOperatingSystem", .TargetOperatingSystem)
                _ArraySetItem($aReturn, $eVersion, "Version", .Version)
            EndWith
        Next
    Else
        Return SetError(1)
    EndIf

    Return $aReturn
EndFunc   ;==>_GetBIOSInfo

Func MyErrFunc()
    ConsoleWrite("! COM Error!" & @CRLF & _
            "!    err.description is  : " & @TAB & $oMyError.description & @CRLF & _
            "!    err.windescription  : " & @TAB & $oMyError.windescription & @CRLF & _
            "!    err.number is       : " & @TAB & Hex($oMyError.number, 8) & @CRLF & _
            "!    err.lastdllerror is : " & @TAB & $oMyError.lastdllerror & @CRLF & _
            "!    err.scriptline is   : " & @TAB & $oMyError.scriptline & @CRLF & _
            "!    err.source is       : " & @TAB & $oMyError.source & @CRLF & _
            "!    err.helpfile is     : " & @TAB & $oMyError.helpfile & @CRLF & _
            "!    err.helpcontext is  : " & @TAB & $oMyError.helpcontext & @CRLF)
EndFunc   ;==>MyErrFunc

Func _ArraySetItem(ByRef $aArray, $eNum, $sName, $sItem)
    $aArray[$eNum][0] = $sName
    $aArray[$eNum][1] = $sItem
EndFunc   ;==>_ArraySetItem

Func _SplitStr($sStr)
    Local $aSplit[2], $iSeperator = -1, $aSeperator = ['.', ' - ', '-', '']
    Do
        $iSeperator += 1
        If $aSeperator[$iSeperator] = '' Or $sStr = '' Then
            ReDim $aSplit[2]
            $aSplit[0] = $sStr
            $aSplit[1] = ''
            ExitLoop
        EndIf
        $aSplit = StringRegExp($sStr, '(.+)\' & $aSeperator[$iSeperator] & '(.+)', 1)
    Until UBound($aSplit) = 2

    Return $aSplit
EndFunc   ;==>_SplitStr

Alles anzeigen

**Musashi**

Hallo Bitnugger !

Zitat von Bitnugger

Tja, und was bitte soll ich daran ändern?

Du kannst und musst natürlich gar nichts daran ändern !

Ich wollte lediglich einen Punkt ansprechen, der sich nicht allen Usern auf den ersten Blick erschließt, das habe ich getan. Jeder der den Thread bis hier aufmerksam verfolgt hat weiß jetzt, was gemacht werden muss. Es lag nie in meiner Absicht, die Qualität deines Skriptes grundsätzlich in Zweifel zu ziehen !!

Zudem gibt es mittlerweile mehrere Lösungswege, aus denen ein User nach seinen Bedürfnissen auswählen kann.

Also nichts für ungut !

Gruß Musashi

**Bitnugger**

Musashi

Falls ein "Normaler User" die Funktion ändern möchte und damit nicht klar kommt, kann er ja hier im Forum um Hilfe bitten. Konstruktive Kritik an mir oder meinen Scripten ist immer willkommen! Wenn du dir meine letzte Version anschaust, wirst du auch sehen, dass ich deinen Hinweis bezüglich des "Design-Problems" umgesetzt habe. Generell denke ich, dass Scripte von helfenden Usern (vor allem in der Rubrik "Hilfe & Unterstützung") nicht als Endlösung, sondern als Vorlage und Inspiration angesehen werden sollten.

Die Funktion von Oscar (hier fehlt noch die Auswertung der Arrays und eine Korrektur für den Wert ".CurrentLanguage") und AspirinJunkie (wieder was gelernt!) sind beide sehr schön, letztere ist allerdings ohne Error-Handler...

; Row|Col 0|Col 1

; [0]|BiosCharacteristics|{Array}

; [1]|BIOSVersion|{Array}

; [13]|ListOfLanguages|{Array}

".CurrentLanguage" liefert bei mir mehrere Werte, die mit einem "|" getrennt sind - identisch mit dem Inhalt des Arrays ".ListOfLanguages". Die Funktion _StringSplit2D gibt davon nur den ersten Wert zurück.

**Oscar**

Zitat von Bitnugger

und AspirinJunkie (wieder was gelernt!) sind beide sehr schön, letztere ist allerdings ohne Error-Handler

Die Version von AspirinJunkie benötigt keinen Error-Handler, weil er die verfügbaren Properties ausliest und davon dann die Werte ermittelt. Übrigens: Gute Idee, AspirinJunkie!

**Musashi**

Hallo Bitnugger !

Zitat von Bitnugger

Wenn du dir meine letzte Version anschaust, wirst du auch sehen, dass ich deinen Hinweis bezüglich des "Design-Problems" umgesetzt habe.

Einwandfrei !

Durch die Dimensionierung des Arrays ($aReturn[$eSizeOff][2] ) in _GetBIOSInfo() kann man jetzt problemlos nicht benötigte Werte auskommentieren.

Zitat von Bitnugger

Generell denke ich, dass Scripte von helfenden Usern (vor allem in der Rubrik "Hilfe & Unterstützung") nicht als Endlösung, sondern als Vorlage und Inspiration angesehen werden sollten.

Da bin ich völlig deiner Meinung (obwohl ich den Begriff 'Endlösung' in unseren politisch korrekten Zeiten wohl gemieden hätte ). Falls man es unbedingt darauf anlegt, wird man quasi in jedem Skript ein Haar in der Suppe finden können.

Nebenbei :

Wenn ich manchmal von 'Normalusern' oder 'Gelegenheitsusern' spreche, dann ist das nie abwertet gemeint. Zu einem nicht unerheblichen Teil zähle ich mich selbst auch dazu .

Ich denke, damit können wir, zumindest diesen Teilaspekt des Threads, abschließen.

Gruß Musashi

**AspirinJunkie**

Zum Thema Errorhandler:

So wie ich es verstehe habt ihr diesen eingerichtet für die Fälle das Eigenschaften abgerufen werden, welche gar nicht in der Klasse existieren.
Der Errohandler soll hierbei dafür sorgen dass das Skript sich nicht mit einem Fehler verabschiedet - richtig?

Meine Variante sollte auch bisschen als Hinweis dafür verstanden werden wie man es alternativ auch machen könnte.
Der Fall hier dass einfach alle möglichen Werte einer Klasse in ein Array geklatscht werden sollen ist so praxisnah sicherlich nicht.
Aber die Möglichkeit alle vorhandenen Properties zu ermitteln gibt uns die Mittel dies einmalig durchzuführen und dann einfach vorher abzufragen bevor wir auf eine Eigenschaft zugreifen wollen.
Also grundsätzlich z.B. so:

AutoIt

_GetBIOSInfo()


Func _GetBIOSInfo()
    Local $o_Props = _GetWMIClassProbs("Win32_Bios")

    Local $oWMI = ObjGet("winmgmts:")
    For $oItem In $oWMI.ExecQuery("SELECT * FROM Win32_Bios", "WQL", 48)
        If $o_Props.Exists("irgendwas") Then MsgBox(0,"irgendwas", $oItem.irgendwas)
        If $o_Props.Exists("Manufacturer") Then MsgBox(0,"Manufacturer", $oItem.Manufacturer)
    Next
EndFunc   ;==>_GetBIOSInfo

Func _GetWMIClassProbs($s_ClassName)
    Local $o_Class = ObjGet("winmgmts:").Get($s_ClassName)
    If @error Or Not IsObj($o_Class) Then Return SetError(1, @error, "")
    Local $o_Ret = ObjCreate("Scripting.Dictionary")

    For $o_Prop In $o_Class.Properties_
        $o_Ret($o_Prop.Name) = 0
    Next
    Return $o_Ret
EndFunc   ;==>_GetWMIClassProbs

Alles anzeigen

So kann man auch den Fehler verhindern dass auf Eigenschaften zugegriffen wird ohne dass diese existieren.

**Oscar**

Zitat von AspirinJunkie

Der Errohandler soll hierbei dafür sorgen dass das Skript sich nicht mit einem Fehler verabschiedet - richtig?

Genau!

Ohne den Errorhandler würde das Script mit einer Fehlermeldung abbrechen.

Die Fehler kamen, weil einige Properties erst ab Windows10 existieren.

Zitat von AspirinJunkie

Meine Variante sollte auch bisschen als Hinweis dafür verstanden werden wie man es alternativ auch machen könnte.

Finde ich sehr gut!

So ist das viel besser umzusetzen. Die beste Art eine Fehlermeldung zu bearbeiten, ist es, den Fehler erst gar nicht auftreten zu lassen.

**Musashi**

Zitat von AspirinJunkie

So wie ich es verstehe habt ihr diesen eingerichtet für die Fälle das Eigenschaften abgerufen werden, welche gar nicht in der Klasse existieren.

Lt. Spezifikation der Win32_BIOS-Klasse : https://msdn.microsoft.com/en-us/library/…7(v=vs.85).aspx

sind die Properties, die den Fehler verursachen, aber vorhanden :

Zitat von Musashi

Laut Klassenbeschreibung sind das die uint8 Werte :

uint8 EmbeddedControllerMajorVersion;

uint8 EmbeddedControllerMinorVersion;

uint8 SystemBiosMajorVersion;

uint8 SystemBiosMinorVersion;

Ich habe mir die Beschreibung zu diesen vier Properties jetzt aber mal genauer angesehen. Dort steht bei allen :

(hier exemplarisch EmbeddedControllerMajorVersion genommen)

EmbeddedControllerMajorVersion
Data type: uint8Access type: Read-onlyQualifiers: MappingStrings

The major release of the embedded controller firmware.

This value comes from the Embedded Controller Firmware Major Release member of the BIOS Information structure in the SMBIOS information.

Windows Server 2012 R2, Windows 8.1, Windows Server 2012, Windows 8, Windows Server 2008 R2, Windows 7, Windows Server 2008, and Windows Vista: This property is not supported before Windows 10 and Windows Server 2016 Technical Preview.

Der Satz 'This property is not supported before Windows 10 and Windows Server 2016 Technical Preview.' macht mich nun doch etwas stutzig .

Edit : Oscar hat gerade meinen Verdacht bestätigt.

Gruß Musashi