Copy and Paste Gui

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Moinsen,

wahrscheinlich bin ich blind, aber ich sehe keinen Lösungansatz.

Problemstellung:

Habe ein GUI mit mehreren Eingabefelder für Text. Nun kann man natürlich mit copy un Paste Text einfügen. Sofern dieser Text länger ist, als das GUI Feld, wird an den Gui Rändern automatisch umgebrochen (für die ANzeige) Greift man später auf die Eingabe als String zu, ist die ursprüngliche Formatierung mit crlf erhalten geblieben. Man bekommt also nicht was man sieht.

Mein Lösungsansatz ist nun die crlf aus dem Text der Zwischenablage zu entfernen. Aber wie?

Danke für Eure Hilfe.

Peter

Ps.: Kein Doppelpost

**BugFix**

Ich würde auf die Schnelle die Zwwischenablage so aktualisieren: ClipPut( StringReplace(ClipGet(), @CRLF, '') )

**Bitnugger**

Ich denke du suchst folgende Information:

AutoIt

; ...
GUICtrlSendMsg($idEdit, $EM_FMTLINES, True, 0) ; Das Edit soll die "weichen" Zeilenumbrüche mit CRCRLF markieren
Local $sSoftBreakText = GUICtrlRead($idEdit) ; Nun holen wir uns den so präparierten Inhalt
GUICtrlSendMsg($idEdit, $EM_FMTLINES, False, 0) ; Das Edit wieder auf die Default-Formatierung umgestellen
Local $sFormatedText = StringReplace($sSoftBreakText, @CR & @CRLF, @CRLF) ; Die "weichen" Zeilenumbrüche nun durch echte ersetzen

FileWrite(@ScriptDir & '\Formated_Text.txt', $sFormatedText) ; Formatierten Text in Datei speichern
; ...

Hier noch ein Example...

Format Text

AutoIt

;-- TIME_STAMP   2017-11-01 18:47:51   v 0.1

#Region    ;************ Includes ************
#Include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#EndRegion ;************ Includes ************

FileDelete(@ScriptDir & '\Formated_Text.txt')

#Region - GUI Create
GUICreate('Format Text', 200, 200, -1, -1)
$idEdit = GUICtrlCreateEdit(FileRead(@ScriptFullPath), 0, 0, 200, 200, $ES_MULTILINE)
GUISetState()
#EndRegion

#Region - GUI SwitchLoop
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
;~         Case
;~         Case
;~         Case
;~         Case Else
    EndSwitch
WEnd
#EndRegion

GUICtrlSendMsg($idEdit, $EM_FMTLINES, True, 0) ; Das Edit soll die "weichen" Zeilenumbrüche mit CRCRLF markieren
Local $sSoftBreakText = GUICtrlRead($idEdit) ; Nun holen wir uns den so präparierten Inhalt
GUICtrlSendMsg($idEdit, $EM_FMTLINES, False, 0) ; Das Edit wieder auf die Default-Formatierung umgestellen
Local $sFormatedText = StringReplace($sSoftBreakText, @CR & @CRLF, @CRLF) ; Die "weichen" Zeilenumbrüche nun durch echte ersetzen

FileWrite(@ScriptDir & '\Formated_Text.txt', $sFormatedText) ; Formatierten Text in Datei speichern
ShellExecute(@ScriptDir & '\Formated_Text.txt')

Alles anzeigen

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Bitnugger

Ja das funktioniert so.

Ich komme mir allerdings wie ein Zauberlehrling vor. Ich verstehe das nur teilweise. Ja mir ist klar (ev. nur teilweise) was ein weicher Zeilenumbruch ist. Aber wo nimmst Du den her? Ich hatte das auf hex Ebene probiert und im String nichts gefunden.

Hast Du, freundlicherweise, noch eine weitergehende Erklärung für die Lösung?

Gruß

Peter

**BugFix**

Zitat von Peter S. Taler

Aber wo nimmst Du den her?

Ich bin mal so frei:

Der weiche Zeilenumbruch wird mit GUICtrlSendMsg($idEdit, $EM_FMTLINES, True, 0 ) für das Control aktiviert. D.h. Umbrüche durch Word wrapping werden damit markiert anstatt mit CRLF

(https://msdn.microsoft.com/en-us/library/…0(v=vs.85).aspx).

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Bleibt ein Danke.

Es erschütert mich immer wieder,was man fallweise nicht kennt.

Peter

Closed.....

**Bitnugger**

Als ich mit diesem Problem zu kämpfen hatte und mein Script dann nach mehreren Stunden endlich lief, stolperte ich per Zufall über $EM_FMTLINES... mit der Erkenntnis, dass ich wieder mal viel Zeit verschwendet hatte, weil ich von den meisten Controls nur die am häufigsten verwendeten Möglichkeiten kenne.

Hier noch ein Beispiel...

Save formated text

AutoIt

;-- TIME_STAMP   2017-11-01 19:54:47   v 0.1

#Region    ;************ Includes ************
#Include <WindowsConstants.au3>
#Include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#EndRegion ;************ Includes ************

FileDelete(@ScriptDir & '\Formated_Text.txt')

#Region - GUI Create
GUICreate('Format Text', 200, 200, -1, -1)
Local $idEdit = GUICtrlCreateEdit('', 0, 0, 200, 170, BitOR($GUI_SS_DEFAULT_EDIT, $ES_MULTILINE))
Local $idButton_Save = GUICtrlCreateButton('Save Text', 5, 173, 90, 20)
Local $idButton_Exit = GUICtrlCreateButton('Exit', 105, 173, 90, 20)
GUICtrlSetLimit($idEdit, 100000)
GUICtrlSetData($idEdit, FileRead(@ScriptFullPath))
GUISetState()
#EndRegion

#Region - GUI SwitchLoop
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $idButton_Save
            ; Some styles cannot be changed dynamically, check MSDN documentation. $CBS_UPPERCASE combo style is one example.
            Local $idEdit_FormatedText = GUICtrlCreateEdit('', 0, 0, 200, 200, $ES_MULTILINE)
            GUICtrlSetData($idEdit_FormatedText, GUICtrlRead($idEdit))

            GUICtrlSendMsg($idEdit_FormatedText, $EM_FMTLINES, True, 0) ; Das Edit soll die "weichen" Zeilenumbrüche mit CRCRLF markieren
            Local $sSoftBreakText = GUICtrlRead($idEdit_FormatedText) ; Nun holen wir uns den so präparierten Inhalt
            GUICtrlSendMsg($idEdit_FormatedText, $EM_FMTLINES, False, 0) ; Das Edit wieder auf die Default-Formatierung umgestellen
            Local $sFormatedText = StringReplace($sSoftBreakText, @CR & @CRLF, @CRLF) ; Die "weichen" Zeilenumbrüche nun durch echte ersetzen

            FileWrite(@ScriptDir & '\Formated_Text.txt', $sFormatedText) ; Formatierten Text in Datei speichern
            ShellExecute(@ScriptDir & '\Formated_Text.txt')
            ExitLoop
    EndSwitch
WEnd
#EndRegion

Alles anzeigen

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Irgendwie ist das so. man beschäftigt sich mit der Programiersprache - aber nicht mit Windows. Aber irgendwie greift das eine in das andere...

<ich habe in dieser Angelegenheit auch zuviel Zeit verbraucht. Vorallem weil man gefühlt 1000 Ansätze sieht. Nur welcher ist der richtige??

Da allerdings hilft das Forum - meist - schnell....

Gruß

Peter

Danke für den Code

**BugFix**

Geht mir oft ähnlich, aber ich setze zum Suchen inzwischen meist zuerst bei MSDN an. Aber selbst, wenn ich anderswo eine Lösung entdeckt habe, ist das Nachlesen auf MSDN doch recht hilfreich. Oft sind es Dinge, die dann einfach auch mal "hängen" bleiben.

**Bitnugger**

MSDN hat mir auch schon sehr oft geholfen... vor allem bei WM_COMMAND und WM_NOTIFY.