Makro starten

Zitat von Vitaq

Hast du vielleicht einen Tipp an was ich mich orientieren kann

Inwiefern? In der Autoithilfe findest du unter Sprachreferenz ein simples Beispiel zum Erstellen einer Funktion mit Parameter und Rückgabewert. Was die eigentliche Aufgabe angeht kannst du dich ja am bisherigen Code orientieren.

Deine Funktion muss grob folgendes tun:

0. Rückgabe Variable $iActionNumber lokal in der Funktion deklarieren und den Wert 0 (kein Treffer, Maus außerhalb der Bereiche) zuweisen

1. Mausposition ermitteln

2. Für alle im Array definierten Bereiche prüfen ob die ermittelte Mausposition innerhalb des jeweiligen Bereichs ist, Sobald du einen Treffer hast setzt du deine Rückgabevariable auf die zugehörige "ActionNumber" der Array Zeile und verlässt die Schleife mit dem Statement exitloop, damit unnötige weitere Prüfungen vermieden werden. Für diesen Teil solltest du dir im Array Tutorial den Umgang mit Schleifen und Arrays nochmal anschauen.

3. Nun gibst du dein Ergbnis mittels Return $iActionNumber zurück und verlässt die Funktion

Zum Überprüfen deiner Funktion empfiehlt es sich die Ergebnisse des Funktionsaufruf mit consolewrite in der Sciteconsole auszugeben. So kannst du dann live sehen sobald deine Maus sich in Bereich 1 oder 2 bewegt. Funktioniert das zuverlässig kannst du weitermachen und die anderen Funktionen implementieren und testen.

Es ist nicht ganz klar was du meinst, aber ich denke du willst die Auswertung der Positionen machen.

Dazu brauchst du mal eine Schleife und dazu verwendest du am Besten gleich die Schleife die du sowieso brauchst,

damit das Script sich nicht gleich wioeder schliesst.

Darin solltest du die Mausposition abfragen aber diesmal bitte nur eine Abfrage, dann vergleichst du nach jeder Abfrage

ob eine Position aus dem Array darauf zutrtifft und entscheidest dabei welche Aktion ausgeführt wird.

Du könntest auch gleich den Inhalt des Send-Befehls als String im Array unterbringen.

Beispiel

Global $aActionAreas[3][5] = 
[["Actionsnummer/Makronummer","xStart","xEnd","yStart","yEnd"],["^a",957,
 1132, 305, 349],["^b",757, 832, 305, 349]]

Send($aActionAreas[1][0]) oder Send($aActionAreas[2][0])

Und nicht vergessen die While oder Do Schleife durch einen kleinen Sleep(80) etwas drosseln ich hatte bei deinem Ersten Script eine

CPU(Kern)-Last von fast 100%

Und nimm das Angebot von misterspeed lieber an, von ihm könntest du in 2 Monaten mehr Lernen als ich mir in

2 Jahren selbst beigebracht habe.

Tuxedo hat natürlich recht, dass man das alles auch etwas kompakter und direkter programmieren kann. Ich hab das hier aber bewusst nicht vorgeschlagen, damit es verständlicher und Übersichtlicher bleibt und verschiedene Teilaufgaben klar voneinander getrennt bleiben. Das erleichtert es hier auf Detail- / Anfängerfragen besser einzugehen und man sieht immer wieder kleine Erfolgserlebnisse (z.B. dass der Bereich nun korrekt und live in der console angegeben wird), Davon ab ist das Vorgehen für komplexere und größere zukünftige Scripte hilfreich. Optimieren kann man ein funktionstüchtiges Script immer auch im Nachhinein.

Zuviel auf einmal führt zu Fehlern und Frustation wenns eben nicht sofort alles funktioniert. Ich glaub wir wollen alle nicht, dass seine Hauptschleife endlos Excelinstanzen startet und seinen Rechner nach wenigen Sekunden zum Absturz bringt.

Ich denke ich werde mich in Zukunft auch an deine Fersen heften um von dir soviel wie möglich lernen zu können,

das von dir beschriebene zwingt mich nämlich dazu nur kleine Scripte zu schreiben weil ich sonst den Überblick verliere,

Ich hoffe ich kann auch auf dich zählen misterspeed.

Zitat von Vitaq

If $aPos = $aActionAreas[0][1] then

$aPos ist ein Array, keine Variable.

Zitat von Vitaq

Und das heisst was?

Dass du keine Arrays mit Variablen vergleichen kannst wie du Variablen mit Variablen vergleichst. Du musst einen Index des Arrays angeben, ansonsten wird das nichts.

Das sind die Grundlagen von AutoIt, vielleicht solltest du sie dir nochmal anschauen.

Zitat von Vitaq

Code

$aPos ist ein Array, keine Variable.

Und das heisst was?

In der Hilfe die Funktion mousegetpos() anschauen.

Dort steht unter anderem:

Zitat

Returns a two-element array that containing the mouse coordinates: $array[0] = X coord (horizontal), $array[1] = Y coord (vertical)

So die Funktion sagt dir also die Xmaus Koordinate und Ymaus Koordinate, welche jeweils in einem Element des mousegetpos Arrays gespeichert ist.

Deine eigene Funktion soll nun prüfen ob die Maus innerhalb der Bereiche liegt.

In deinem eigenen Array hast du die minimalen und maximalen X bzw. Y Koordinaten jedes Bereichs gespeichert.

Deine Funktion muss nun also prüfen ob:

- (Xmaus größer Xmin UND Xmaus kleiner Xmax) UND (Ymaus größer Ymin UND Ymaus kleiner Ymax) ist -> korrekt wäre im Übrigen statt "<" bzw ">" ein "<=" bzw. ">=" ein Pixel hin oder her spielt aber nicht wirklich eine Rolle

- wenn ja liegt die Maus im Bereich, wenn nein liegt sie irgendwo anderst

Diese Prüfung musst du für alle gespeicherten Bereiche in deinem eigenen Array machen. Sowas hab ich im Übrigen in deinem allerersten Script schon gesehen.

Zitat von Vitaq

Local $iActionNumber = "0" hab das eingetragen sollte passen

Passt im Übrigen nicht ganz, auch wenn es zufällig keinen Unterschied macht.

Alles was du in Anführungszeichen setzt interpretiert Autoit als String und nicht als Zahl, bzw intern wird ein String als die Zahl 0 interpretiert. Deswegen passt das hier zufälligerweise.

Zahlen solltest du aber um Probleme bei logischen Vergleichen zu vermeiden immer ohne Anführungszeichen in Variablen/Arrays speichern. Ansonsten wunderst du dich irgendwann warum deine IF Bedingung immer ein falsches Ergebnis liefert statt dem von dir erwarteten.

Zitat von Vitaq

If $aPos = $aActionAreas[0][1] then

Bedenke bitte, dass dein Array in Zeile 0 keine Bereichs Koordinaten enthält, sondern nur die Überschriften des Arrays (zumindestens wenn du dich Aufgrund meines Tipps dazu entschieden hast Überschriften zu speichern).

Ich kürz das nun mal ein wenig ab... denke so ist es verständlicher wie der Aufbau gemeint war:

#include <array.au3>
#include <WindowsConstants.au3>

; Globale Variablen deklarieren und initialisieren:
Global $aMyActionAreas[4][5] = [    ["Actionsnummer/Makronummer","xStart","xEnd","yStart","yEnd"], _
                                [1, 957, 1132, 305, 349], _
                                [2, 757, 832,  305, 349], _
                                [3, 400, 555,  305, 349] _
                            ]
;_ArrayDisplay($aMyActionAreas)
Global $sMyFilepath = "C:\test\test.txt"

; Test GUI erstellen:
showMyAreas($aMyActionAreas) ; macht das testen einfacher...

; Hauptschleife deines Programms:
While 1
    $iMyAction = mousePosAction($aMyActionAreas) ; Zurückgegebenes Ergebnis wird in Variable gespeichert
    If $iMyAction = 0 Then
        Sleep(50) ; 50ms schlafen, vielleicht gibts ja dann was zu tun!
    Else
        ; endlich was zu tun...
        ConsoleWrite($iMyAction & @CRLF) ; 1 oder 2 oder 3???
;~         openTXT($sMyFilepath) ; TXT in Excel öffnen
;~         executeExcelMakro($iMyAction) ; das passende Makro ausführen!
;~         closeExcel() ; Excel wieder beenden???
        MouseMove(100,100,0) ; Maus außerhalb deiner Bereiche platzieren, damit Aktion nicht gleich nochmal ausgeführt wird
    EndIf
WEnd

; Funktionen:
Func showMyAreas($aAreas)
    For $i = 1 To UBound($aAreas)-1
        GUICreate("Bereich " & $i,$aAreas[$i][2]-$aAreas[$i][1],$aAreas[$i][4]-$aAreas[$i][3],$aAreas[$i][1],$aAreas[$i][3],BitOR($WS_POPUP,$DS_SETFOREGROUND),$WS_EX_TOPMOST)
        GUICtrlCreateLabel("Bereich " & $i,-1,-1)
        GUISetBkColor(0xAA3456)
        GUISetState(@SW_SHOW)
    Next
EndFunc

Func mousePosAction($aAreas)
    Local $iActionNumber = 0 ; auszuführende Aktion
    Local $aMpos = MouseGetPos() ; aktuelle Mausposition

    For $i = 1 To UBound($aAreas)-1 ; für alle Bereiche im Array
        If $aMpos[0] >= $aAreas[$i][1] And $aMpos[0] <= $aAreas[$i][2] And $aMpos[1] >= $aAreas[$i][3] And $aMpos[1] <= $aAreas[$i][4] Then ; Maus ist innerhalb des Bereichs $i
            $iActionNumber = $aAreas[$i][0] ; gefundene Aktion auslesen und speichern
            ExitLoop ; wir haben den Bereich schon gefunden, die anderen Bereiche brauchen wir nicht mehr prüfen, also brechen wir hier ab!
        EndIf
    Next

    ; die Aktion ist nun entweder immernoch 0, weil die Maus in keinem der definierten Bereiche war
    ; oder sie ist 1 bzw. 2 bzw. 3, jenachdem in welchem Bereich deine IF Bedingung erfüllt war
    
    Return $iActionNumber ; Funktion verlassen und das ermittelte Ergebnis zurückgeben
EndFunc

Func openTXT($sFile)
    ;... kannst selber programmieren
EndFunc

Func executeExcelMakro($iAction)
    ;... kannst selber programmieren
EndFunc

Func closeExcel()
    ;... kannst selber programmieren
EndFunc

Der Code mag im Moment nicht perfekt sein, aber er funktioniert und du verstehst hoffentlich

warum und wie er funktioniert, das wäre die Hauptsache.

Jetzt könntest du dir 2 neue Ziele vorgeben:

1. Daß das Script nicht nach jeder Aktionsauslösung neu gestartet werden muss, denn so wie du es jetzt hast

beendet es sich nach einer Erkennung einer deiner beiden Positionen.

2. Dein Script erkennt im Moment nur deine 2 Positionen, jetzt könntest du dir vornehmen, es so

umzubauen, daß auch noch weitere Positionen erkannt werden könnten, so quasi als Fleißaufgabe.

Aber sorge am Besten immer mit einer Sicherheitskopie deines Scripts vor, damit du dein schon

funktionierendes Script nicht verlierst.

So kannst du eine Menge lernen, probier's aus.

Viel Glück

Tuxedo