GUI: Verhindern, dass Neustart durchgeführt wird und die Meldung "Das Programm verhindert, dass Windows abgemeldet wird." aufkommt

Tralveller

Hallo zusammen,

ich habe mir eine GUI geschrieben, um dem Anwender einen aktuellen Status anzuzeigen.

Aber als "Perfektionist" will man ja immer noch etwas verbessern.

Kann man evtl. es auch so erweitern, dass wenn der Anwender "Herunterfahren" "Neu starten" oder "Abmelden" auswählt, dass verhindert wird, damit man die Meldung erhält:

"Dieses Programm verhindert, dass Windows neu gestartet wird."

Der Inhalt kann nicht angezeigt werden, da er nicht mehr verfügbar ist.

Bisher habe ich dazu keinen Ansatz finden können.

Hat da jemand eine Idee?

Danke und Viele Grüße

Tralveller

**alpines**

Das Bild ist nicht sichtbar, lad es mal auf imgur.com hoch und verlink es hier bitte.

Oder lad es hier im Forum hoch aber verlink es nicht im Text, dann ist es als Anhang downloadbar.

**Kanashius**

Normal müsste es unter Windows reichen, ein Fenster zu erstellen, welches sich beim "Schließen" Befehl nicht schließt, sondern blockiert. Ob sichtbar oder nicht ist glaub ich egal.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Man kann unter Windows den Reg eintrag zum Anzeigen des Herunterfahren Buttons löschen. Kein Button - kein Herunterfahren. Nun kannst Du eigene Software aufsetzen, die das via shutdown erledigt. Wir nutzen das um Datensicherungen von bestimmten Rechnern auf den Server zu erzwingen.

Es sit natürlich auch die Möglich den Reg Eitrag beim Starten Deiner Software zu löschen - und beim Beenden wieder zu starten. Müsste man ausprobieren ob Löschen des Reg Eintrages sofort Wirkung zeigt - oder es eines Neustarts bedarf.

Gruß

Peter

**bernd670**

Hallo,

hast du dir in der Hilfe schon mal das Beispiel von _WinAPI_ShutdownBlockReasonQuery angesehen. Wenn es auch mit Windows 10 funktionieren soll, muss man nur die erste If-Abfrage etwas anpassen.

Spoiler anzeigen

Code

#include <WinAPISys.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

If  Number(_WinAPI_GetVersion()) < 6.0 Then ; Anpassung für Windows 10
    MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Error', 'Require Windows Vista or later.')
    Exit
EndIf

Local $hForm = GUICreate('Test ' & StringReplace(@ScriptName, '.au3', '()'), 200, 200)
Local $Button = GUICtrlCreateButton('', 73, 62, 54, 54, $BS_ICON)
GUICtrlSetImage(-1, @SystemDir & '\shell32.dll', 45)
GUICtrlSetTip(-1, 'Log off ' & @UserName)
Local $Check = GUICtrlCreateCheckbox('Block Windows shutdown', 10, 173, 144, 21)
GUIRegisterMsg($WM_QUERYENDSESSION, 'WM_QUERYENDSESSION')
GUISetState(@SW_SHOW)

; Set the highest shutdown priority for the current process to prevent closure the other processes.
_WinAPI_SetProcessShutdownParameters(0x03FF)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $Button
            Shutdown(0)
        Case $Check
            If GUICtrlRead($Check) = $GUI_CHECKED Then
                _WinAPI_ShutdownBlockReasonCreate($hForm, 'This application is blocking system shutdown because the saving critical data is in progress.')
            Else
                _WinAPI_ShutdownBlockReasonDestroy($hForm)
            EndIf
    EndSwitch
WEnd

Func WM_QUERYENDSESSION($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $wParam, $lParam

    Switch $hWnd
        Case $hForm
            If _WinAPI_ShutdownBlockReasonQuery($hForm) Then
                Return 0
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_QUERYENDSESSION

Alles anzeigen