Array - _ArrayInsert - Bitnugger

AutoMit

Hallo,

in Anlehung an das sehr interessante Script von Bitnugger

eine Array Frage

Code

Local $aFile = [ _
    '# 2 ', _
    'a', _
    '# 2 ', _
    'b', _
    '# 2 ', _
    'c', _
    '# 2 ', _
    'd']

    
    For $i = 0 To UBound($aFile) -1 Step 1
    If $i < UBound($aFile) -1 And StringLeft($aFile[$i], 3) = '# 2' Then
        _ArrayInsert($aFile, $i + 1, '# 2a' )
    EndIf
Next
_ArrayDisplay($aFile, '$aFile')
_ArrayToClip ( $aFile , @CRLF )

Alles anzeigen

Mein Ziel ist

Code

# 2 
# 2a
a
# 2 
# 2a
b
# 2 
# 2a
c
# 2 
# 2a
d

Alles anzeigen

statt dessen erhalte ich

Code

# 2 
# 2a
# 2a
# 2a
# 2a
# 2a
# 2a
# 2a
# 2a
a
# 2 
b
# 2 
c
# 2 
d

Alles anzeigen

Wie muss obiger Code abgeändert werden?

Wenn folgendes nutze

For $i = 0 To UBound($aFile) -1 Step 1

und über _ArrayInsert eine Zeile zum $aFile Array hinzufüge, wird die maximale Anzahl der Zeilen automatisch erhöht oder was muss ich schreiben, damit hinzugefügte Zeilen bei der For-Schleife berücksichtigt werden?

Danke

**alpines**

Du hast vergessen den Forschleifenzähler $i um eins zu erhöhen wenn du _ArrayInsert nutzt. Wenn du nämlich hinter dem aktuellen Element einfügst musst du das ja praktisch überspringen.

So klappts:

AutoIt

#include <Array.au3>

Local $aFile = [ _
    '# 2 ', _
    'a', _
    '# 2 ', _
    'b', _
    '# 2 ', _
    'c', _
    '# 2 ', _
    'd']


For $i = 0 To UBound($aFile) - 1 Step 1
    If $i < UBound($aFile) -1 And StringLeft($aFile[$i], 3) = '# 2' Then
        _ArrayInsert($aFile, $i + 1, '# 2a' )
        $i += 1
    EndIf
Next
_ArrayDisplay($aFile, '$aFile')
_ArrayToClip ( $aFile , @CRLF )

Alles anzeigen

AutoMit

Danke Alpines, in meinem Script funktioniert das nicht. Ab Zeile #Region 221 wird nichts mehr ins Array eingefügt. Habe ich noch was übersehen?

Hier der Code

Forum - Array.au3

Testdatei Regionen.au3

**alpines**

Das liegt daran, dass du anfänglich nur einmal die Größe des Arrays holst.

Anschließend fügst du immer mehr Elemente ein aber die ursprüngliche Grenze bleibt ja, deshalb läuft es auch nur bis 220 da du 440 Zeilen hast (und du immer einen Index überspringst, deshalb nur die Hälfte).

Also entweder eine While-Schleife nehmen oder du gehst das ganze von hinten durch, dann bleiben die Arrayindizes nämlich nach vornehin konsistent.

Und noch als kleiner Tipp nebenbei:

AutoIt

_ArrayInsert ( $aFile, $i + 1, "Test " & StringRight ( $aFile[$i] ,  StringLen ( $aFile[$i]  ) -8  )  )
;oder
($aFile[$i])

Bitte nicht so einen Code schreiben, wenn es vom Interpreter nicht ausdrücklich verlangt wird (ab und zu muss man ($aFile[$i]) nutzen), dann die überflüssigen Klammern weglassen und statt

StringRight und StringLen lieber StringTrimLeft nehmen, StringTrimLeft($aFile[$i], 8) erledigt dasselbe und ist wesentlich kürzer.

AutoMit

Wie kann ich das innerhalb der Schleife aktuell halten? Das ist der Kern meiner Frage aus dem ersten Beitrag – steht allerdings ganz am Ende

Code

For $i = 0 To UBound($aFile) - 1 Step 1
        If StringLeft ( ($aFile[$i]) , 8 ) = '#Region ' Then
            _ArrayInsert ( $aFile, $i + 1, "Test " & StringRight ( $aFile[$i] ,  StringLen ( $aFile[$i]  ) -8  )  )
            $i  += 1
        EndIf
Next

Ich hoffte, dass es durch Deine eingefügte Zeile „$i += 1“ korrigiert ist. Aber diese Zeile ist wohl nur dafür da, um die nächste richtige Zeile in der IF-Abfrage zu bearbeiten.

Wie berücksichtige ich in der FOR-Schleife das vergrößerte Array?

PS: Du warst schneller Ich schaue es mir gleich an.

PS 2: Danke für den Tipp mit den Klammern, stimmt - hatte ich beim Reduzieren des Codes fürs Forum übersehen.

**alpines**

Aktualiser die Seite mal, ich hab meinen Post mehrfach editiert.

AutoMit

Zitat von alpines

Also entweder eine While-Schleife nehmen oder du gehst das ganze von hinten durch, dann bleiben die Arrayindizes nämlich nach vornehin konsistent.

Magst Du dafür je ein kurzes Beispiel schreiben? Ich habe für beide Varianten "While" und "rückwärts" keine Idee, wie ich das auf das obige Beispiel anpasse.

**alpines**

AutoIt

#include <Array.au3>

$Quell_Datei = @ScriptDir & "\Testdatei Regionen.au3"

Local $aFile = FileReadToArray ( $Quell_Datei )

Local $i = 0

While $i < UBound($aFile)
        If StringLeft ( ($aFile[$i]) , 8 ) = '#Region ' Then
            _ArrayInsert ( $aFile, $i + 1, "Test " & StringRight ( $aFile[$i] ,  StringLen ( $aFile[$i]  ) -8  )  )
            $i  += 1
        EndIf

    $i += 1
WEnd

_ArrayDisplay ( $aFile , "Ergebnis" )

Alles anzeigen

AutoIt

#include <Array.au3>

$Quell_Datei = @ScriptDir & "\Testdatei Regionen.au3"

Local $aFile = FileReadToArray ( $Quell_Datei )

For $i = UBound($aFile) - 1 To 0 Step -1
    If StringLeft ( ($aFile[$i]) , 8 ) = '#Region ' Then
        _ArrayInsert ( $aFile, $i + 1, "Test " & StringRight ( $aFile[$i] ,  StringLen ( $aFile[$i]  ) -8  )  )
    EndIf
Next

_ArrayDisplay ( $aFile , "Ergebnis" )

Alles anzeigen

**alpines**

Rückwärts durchlaufen funktioniert übrigens auch bei anderen Problemen.

Beispiel: Ich will ein Array durchgehen und jedes Element löschen welches eine bestimmte Voraussetzung erfüllt,

dann durchlaufe ich das Array von hinten nach vorne, da die Elementindizes nach vorne hin konsistent bleiben.

Lösche ich von vorne nach hinten, so verkleinert sich die Größe meines Arrays und ich gehe Out Of Bounds mit meinem For-Header.

Das ist ein sehr toller Trick den man sich auf jeden Fall merken sollte.

**Bitnugger**

AutoIt

;-- TIME_STAMP   2018-10-14 13:57:09   v 0.1

#include <Array.au3>

Example()

Func Example()
    Local $aResult, $aFile = ['# 2 ', 'a', '# 2 ', 'b', '# 2 ', 'c', '# 2 ', 'd']

    $aResult = Example_While($aFile)
    _ArrayDisplay($aResult, '$aResult - While')

    $aResult = Example_For($aFile)
    _ArrayDisplay($aResult, '$aResult - For')

    ; Aber Achtung...
    ; denn steht der gesuchte String in der letzten Zeile des Arrays, wird kein '# 2a' eingefügt, weil _ArrayInsert hier versagt...
    Local $aFile2 = ['# 2 ', 'a', '# 2 ', 'b', '# 2 ', 'c', '# 2 ', 'd', '# 2 ']

    ; Fehler!
    $aResult = Example_While($aFile2)
    _ArrayDisplay($aResult, '$aResult - While')

    ; Fehler!
    $aResult = Example_For($aFile2)
    _ArrayDisplay($aResult, '$aResult - For')

    ; so geht es...
    $aResult = Example_For2($aFile2)
    _ArrayDisplay($aResult, '$aResult - For2')

;~     _ArrayToClip ($aResult, @CRLF)
EndFunc

Func Example_While($aArray)
    Local $i = 0
    While $i < UBound($aArray)
        If StringLeft($aArray[$i], 3) = '# 2' Then
            $i += 1
            _ArrayInsert($aArray, $i, '# 2a')
        EndIf
        $i += 1
    WEnd
    Return $aArray
EndFunc

Func Example_For($aArray)
    For $i = UBound($aArray) -1 To 0 Step -1
        If StringLeft($aArray[$i], 3) = '# 2' Then
            _ArrayInsert($aArray, $i + 1, '# 2a')
        EndIf
    Next
    Return $aArray
EndFunc

Func Example_For2($aArray)
    For $i = UBound($aArray) -1 To 0 Step -1
        If StringLeft($aArray[$i], 3) = '# 2' Then
            If $i = UBound($aArray) -1 Then
                _ArrayAdd($aArray, '# 2a')
            Else
                _ArrayInsert($aArray, $i + 1, '# 2a')
            EndIf
        EndIf
    Next
    Return $aArray
EndFunc

Alles anzeigen

AutoMit

Danke

Ich versuche die beiden Beispiele zu verstehen.

Variante 1 - While

Weißt Du , warum bei einer For-Schleife der Ausdruck in der For-Schleife nicht aktualisiert wird, während bei einer While-Schleife der Ausdruck bei jedem Durchlauf aktualisiert wird?

Details

Interessant - bei einer While Schleife wird vor Ausführung der Wert "UBound($aFile)" aktualisiert.

Getestet mit

$max = UBound($aFile) = 879 in diesem Beispiel

Bei einer For Schleife wird "UBound($aFile)" nicht aktualisiert.

Daher

$max = UBound($aFile) = 659 in diesem Beispiel

=> und da sind die fehlenden 220 Elemente

Variante 2

Array rückwärts - bei mir tritt ein kleiner Fehler auf. Bei Dir auch?

Edit: Danke Bitnugger für Deine Zeilen drüber ( das scheint die Erklärung zu sein )

"

; Aber Achtung...

; denn steht der gesuchte String in der letzten Zeile des Arrays, wird kein '# 2a' eingefügt, weil _ArrayInsert hier versagt...

"

Beim letzte Arraywert "#Region 440" wird kein "Test 440" drunter geschrieben.

Wie wird dieser Wert ( letzte Zeile im Array ) auch berücksichtigt?

Das Script beginnt mit 439 statt 440

@@ Debug(26) : $i = 439

So gehts nicht

;~ For $i = UBound($aFile) To 0 Step -1 ; Fehler

;~ For $i = UBound($aFile) -1 To -1 Step -1 ; Fehler

**alpines**

Zitat von AutoMit

Weißt Du , warum bei einer For-Schleife der Ausdruck in der For-Schleife nicht aktualisiert wird, während bei einer While-Schleife der Ausdruck bei jedem Durchlauf aktualisiert wird?

So sind For-Schleifen nun mal in AutoIt implementiert worden. In C# wird die Bedingung bei jeder Schleifeniteration anfänglich überprüft in AutoIt nur einmal.

While-Schleifen evaluieren hingegen immer bei jeder Iteration, wäre das nicht möglich (ebenso wie bei Do-Until), dann wäre AutoIt eine totale Sprache die bei jeder Eingabe hält (wenn man mal von Ausführung anderer Skript absieht).

Zitat von AutoMit

Array rückwärts - bei mir tritt ein kleiner Fehler auf. Bei Dir auch?

Das kann sein, ich habe mir ehrlich gesagt auch nicht viel Mühe gegeben da es hier ja nur um Proof-Of-Concept geht.

Wenn man da den Index und die Eingaben für _ArrayInsert anpasst kriegt man sicherlich, auch dadrunter ein "Test 440".

Hätte man _ArrayInsert vernünftig implementiert, hätte man sich auch _ArrayAdd komplett sparen können, als Sonderfall muss man halt _ArrayAdd statt _ArrayInsert verwenden.

**alpines**

Generell empfiehlt es sich hier nicht _ArrayInsert zu verwenden sondern lieber einmal das Array zu resizen (du kannst ja vorher errechnen wie groß es wird) und dann es zu befüllen.

Die Erweiterung eines Arrays kostet immer Zeit die du dir einsparen kannst.

AutoMit

Vielen Dank Euch zwei.

Problem gelöst und grünen Haken gesetzt