For...Next... für Funktionen?

Hallo,

Ich habe folgendes Problem.

Ich habe mir eine Gui gebastelt, in der beliebig viele Buttons drin sind. Die Anzahl lege ich vorher mit einer Variable fest.
Hiermit werden schonmal die Buttons je nach Anzahl erstellt:

$high = 10
Global $button[99]
$x = 1

For $i = 1 To $anzahl Step 1
$buttonname = "Button " & $i
$button[$x] = GUICtrlCreateButton ($buttonname,10,$high-7)
$high = $high +30
$x = $x +1
Next

Mit dem nächsten Teil, weise ich jedem Button eine Funktion zu:

For $y = 1 To $anzahl Step 1
GUICtrlSetOnEvent ($button[$y],"button"&$y)
Next

Jetzt kommt meine Frage:

Wenn ich 5 Buttons habe, wie mache ich es, dass ich nicht für jeden Button eine Funktion schreiben muss?
Die Funktionen sollen gleich sein, bis auf eine Zahl die sich ändern soll.

Mein Code funktioniert wenn ich dementsprechend viele Funktionen schreibe:

Func button1() 
MsgBox ("","Button","Button1")
Exit
EndFunc

Func button2() 
MsgBox ("","Button","Button2")
Exit
EndFunc

Func button3() 
MsgBox ("","Button","Button3")
Exit
EndFunc

Func button4() 
MsgBox ("","Button","Button4")
Exit
EndFunc

Func button5() 
MsgBox ("","Button","Button5")
Exit
EndFunc

Habe es auch mit einer For...Next Schleife probiert, das haut aber nicht hin.
Habt ihr eine Idee?

Gruß

Zitat von Micha_he

Schau mal unter @GUI_CtrlId bzw. unter @GUI_CtrlHandle in der Hilfe. Damit sollte es möglich sein, aus immer der gleichen Fuktion die Du mit GUICtrlSetOnEvent zuweist, auf unterschiedliche Controls zu reagieren.

So z.B.:

Code

#include <GUIConstantsEx.au3>
Opt("GUIOnEventMode", 1)

Global $iHigh = 30
Global $iFirstButtonId

GUICreate("CtrlId-Test")
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
For $i = 0 To 9
    If Not $iFirstButtonId Then
        $iFirstButtonId = GUICtrlCreateButton("Button" & $i+1, 10, $i*$iHigh)
    Else
        GUICtrlCreateButton("Button" & $i+1, 10, $i*$iHigh)
    EndIf
    GUICtrlSetOnEvent(-1, "_ButtonAktion")
Next
GUISetState(@SW_SHOW)

While 1
    Sleep(100)
Wend

Func _ButtonAktion()
    Msgbox(0,"Info", "Button Nr. " & @GUI_CtrlId - $iFirstButtonId + 1 & " wurde gewählt.")
EndFunc

Func _Exit()
    Exit
EndFunc

Alles anzeigen

Ja, sowas meine ich.
Ich verstehe die If ... Else ... schleife noch nicht ganz.
ich bekomme es hin, das ganze umzuschreiben, nur möchte ich es gern verstehen.

Oben steht ja: "Global $iFirstButtonId" ohne der Variable einen Wert zuzuweisen.
Dann "If Not $iFirstButtonId Then"... Wenn nicht "was?" dann... verstehe ich nicht.

"Else GuiCtrlCreateButton" ... Ohne einer Variable...

Dann: GUICtrlSetOnEvent (-1,"_ButtonAktion")... die -1 heißt das letzte erstellte Element.
Erstelle ich die Buttons einzeln, funktioniert tatsächlich auch nur der Letzte Button.

Kann mich einer aufklären?

/Edit: Wenn ich vor der MsgBox mir $iFirstButtonId und @GUI_CtrlId anzeigen lasse, spuckt er mir für $iFirstButton ID eine 3 und für @GUI_CtrlId eine Zahl ab 3 aus, je nach dem wieiviele Buttons es gibt. Wo kommen diese Zahlen her?

Vielen Dank.
So langsam leuchtet mir das ein