$oRDP - Keine Verbindung zu Server

Kev

Hallo,

ich hab das Problem, das bei einigen Servern ich keine Verbindung via. RDP Objekt in Autoit herstellen kann.

Genau definierbar ist es nicht. Es ist egal ob windows server 2019 oder 2016. Die Verbindung bleibt einfach mit nem weissen Screen hängen incl. Disconnected Text.

Per mstsc funktioniert es wunderbar, auch andere Hosts funktionieren per autoit und rdp objekt. Hab das Thema auch schon woanders gesehen, jedoch auch unbeantwortet.

Scheint irgendein Problem mit dem $ordp objekt zu sein.

Bspcode, welcher bei einigen hosts nicht funktioniert.

C

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

$host = "server"
$hGUI = GUICreate("RDP Embedded Sessions", 952, 675, -1, -1, $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
$oRDP = ObjCreate("MsTscAx.MsTscAx.2")
$oRDP_Ctrl = GUICtrlCreateObj($oRDP, 64, 44, 800, 600)
GUICtrlSetResizing(-1, $GUI_DOCKALL)
GUICtrlSetStyle($oRDP_Ctrl , $WS_VISIBLE)
$oRDP.DesktopWidth = 800
$oRDP.DesktopHeight = 600
$oRDP.Fullscreen = False
$oRDP.ColorDepth = 16
$oRDP.AdvancedSettings3.SmartSizing = True
$oRDP.Server = $host
$oRDP.UserName = "username"
$oRDP.Domain = ""
$oRDP.AdvancedSettings2.ClearTextPassword = "pw"
$oRDP.ConnectingText = "Connecting to " & $host
$oRDP.DisconnectedText = "Disconnected from " & $host
$oRDP.StartConnected = True
$oRDP.RemoteProgramMode = True

$oRDP.Connect()


GUISetState(@SW_SHOW, $hGUI)


;~ $oRDP.ServerStartProgram ('')

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
      Case $GUI_EVENT_CLOSE
  
      Exit
   EndSwitch

WEnd

Alles anzeigen

**water**

Du solltest bei COM Objekten immer abfragen, ob ein Fehler aufgetreten ist. Implementiere einen COM error handler wie in der Hilfe unter ObjEvent beschrieben.

Kev

Hi water,

hab ich gemacht, wie im bsp2 von objevent.

leider ohne jeden fehler. es gibt keine messagebox die aufpoppt weil @error anscheinend nicht ausgelößt wird.

**water**

Kannst Du bitte das gesamte Skript mit dem COM error handler posten?

Kev

C

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $__g_oTemplateCOMErrorHandler = 0


$host = ""
$hGUI = GUICreate("RDP Embedded Sessions", 952, 675, -1, -1, $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
$oRDP = ObjCreate("MsTscAx.MsTscAx.10")
$oRDP_Ctrl = GUICtrlCreateObj($oRDP, 64, 44, 800, 600)
GUICtrlSetResizing(-1, $GUI_DOCKALL)
GUICtrlSetStyle($oRDP_Ctrl, $WS_VISIBLE)
$oRDP.DesktopWidth = 800
$oRDP.DesktopHeight = 600
$oRDP.Fullscreen = False
$oRDP.ColorDepth = 16
$oRDP.AdvancedSettings3.SmartSizing = True
Template_COMErrorRegister()
$oRDP.Server = $host
If @error Then MsgBox(4096, "COM Error Detected", @error)
Template_COMErrorUnregister()
Template_COMErrorRegister()
$oRDP.UserName = ""
If @error Then MsgBox(4096, "COM Error Detected", @error)
Template_COMErrorUnregister()
Template_COMErrorRegister()
$oRDP.Domain = ""
If @error Then MsgBox(4096, "COM Error Detected", @error)
Template_COMErrorUnregister()
Template_COMErrorRegister()
$oRDP.AdvancedSettings2.ClearTextPassword = ""
If @error Then MsgBox(4096, "COM Error Detected", @error)
Template_COMErrorUnregister()
$oRDP.ConnectingText = "Connecting to " & $host
$oRDP.DisconnectedText = "Disconnected from " & $host
$oRDP.StartConnected = True
$oRDP.RemoteProgramMode = True

Template_COMErrorRegister()
$oRDP.Connect()
If @error Then MsgBox(4096, "COM Error Detected", @error)
Template_COMErrorUnregister()


GUISetState(@SW_SHOW, $hGUI)


;~ $oRDP.ServerStartProgram ('')

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE

            Exit
    EndSwitch

WEnd


Func Template_COMErrorRegister()
    $__g_oTemplateCOMErrorHandler = ObjEvent("AutoIt.Error", "Template_COMErrFunc")
EndFunc   ;==>Template_COMErrorRegister

Func Template_COMErrorUnregister()
    $__g_oTemplateCOMErrorHandler = 0
EndFunc   ;==>Template_COMErrorUnregister

Func Template_COMErrFunc()
    ; Do nothing special, just check @error after suspect functions.
EndFunc   ;==>Template_COMErrFunc

Alles anzeigen

**water**

Probier mal das (Du wirst einige Unterschiede zu Deinem Skript erkennen). Die Fehlermeldungen werden auf die SciTE Konsole geschrieben:

C

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $oErrorHandler = ObjEvent("AutoIt.Error", "_COM_Error_Handler")

$host = ""
$hGUI = GUICreate("RDP Embedded Sessions", 952, 675, -1, -1, $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
$oRDP = ObjCreate("MsTscAx.MsTscAx.10")
$oRDP_Ctrl = GUICtrlCreateObj($oRDP, 64, 44, 800, 600)
GUICtrlSetResizing(-1, $GUI_DOCKALL)
GUICtrlSetStyle($oRDP_Ctrl, $WS_VISIBLE)
$oRDP.DesktopWidth = 800
$oRDP.DesktopHeight = 600
$oRDP.Fullscreen = False
$oRDP.ColorDepth = 16
$oRDP.AdvancedSettings3.SmartSizing = True
$oRDP.Server = $host
If @error Then MsgBox(4096, "COM Error Detected", @error)
$oRDP.UserName = ""
If @error Then MsgBox(4096, "COM Error Detected", @error)
$oRDP.Domain = ""
If @error Then MsgBox(4096, "COM Error Detected", @error)
$oRDP.AdvancedSettings2.ClearTextPassword = ""
If @error Then MsgBox(4096, "COM Error Detected", @error)
$oRDP.ConnectingText = "Connecting to " & $host
$oRDP.DisconnectedText = "Disconnected from " & $host
$oRDP.StartConnected = True
$oRDP.RemoteProgramMode = True

$oRDP.Connect()
If @error Then MsgBox(4096, "COM Error Detected", @error)

GUISetState(@SW_SHOW, $hGUI)
;~ $oRDP.ServerStartProgram ('')

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE

            Exit
    EndSwitch

WEnd

; User's COM error function. Will be called if COM error occurs
Func _COM_Error_Handler($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

Alles anzeigen

Kev

merci ! leider wie auch davor, kein @error event.

gui geht auf, disconnected from xxxxx

ohne fehler, ohne event, ohne irgendwas...

bin echt am verzweifeln

Kev

Zitat

+>Setting Hotkeys...--> Press Ctrl+Alt+Break to Restart or Ctrl+Break to Stop
Connecting
Return Value:
** Connecting Event raised by MsRdpClient8NotSafeForScripting **
** Disconnected Event raised by MsRdpClient8NotSafeForScripting **
+>13:54:35 AutoIt3.exe ended.rc:0
+>13:54:35 AutoIt3Wrapper Finished.
Process exited with code 0

Alles anzeigen

script läuft 4 sec, keine msgbox, kein error nix, nur weißes bild mit disconnected status

**water**

Seltsam. Ich bekomme eine MsgBox mit folgendem Text:

Zitat

Die Verbindung kann nicht fortgesetzt werden, da die Authentifizierung nicht aktiviert ist. DIe Authentifizierung muss aktiviert sein, damit der Remotecomputer eine Verbindung herstellen kann.

Übersetzt auf English:

Zitat

The connection cannot proceed because authentication is not enabled and the remote computer requires that authentication be enabled to connect.

Da findet man dann auf Google einige Treffer:

Behebung in der Registry: https://evert.meulie.net/faqwd/connecti…nabled-connect/

Behebung in der group Policy: https://stackoverflow.com/questions/4484…-remote-desktop

Vielleicht hilft das?

Kev

Merkwürdig, aber dann würde die RDP verbindung ja per normalem mstsc auch nicht funktionieren, was ja der Fall ist?

hab das securitylevel runtergestellt und den server rebooted. jedoch ohne erfolg, komme über autoit nicht auf den server.

Kev

Meine F.....

endlich !

in dem Stackoverflow Beitrag weiter unten gibt es eine Advancedsetting.

Die habe ich in au3 gesetzt und evoila es funktioniert.

Setting für Server 2016+ und Win10.

$oRDP.AdvancedSettings9.EnableCredSspSupport = True

danke water für deine Hilfe !

**water**

Diese Frage stellt sich mir irgendwie auch: https://www.autoitscript.com/forum/topic/19…comment-1401021

**water**

Cool, hier funzt es mit diesem Setting auch

Kev

muss man erstmal draufkommen, hab wirklich etliche advancedsettings durchgetestet.

das allerdings seh ich zum ersten mal

$oRDP - Keine Verbindung zu Server

Ähnliche Themen

Checkbox schalten über das Internet - vergleichbar mit Schach online

Ldap

AutoIt-Zugriff auf eine PostgreSQL Datenbank mittels ODBC-ADO

TCP-Client: Abfrage nach Verbindungsabbruch zum TCP-Server