Mausbewegung erkennen

HotKeySet("{ESC}", "_Exit")

Global $g_bMouseMoved, $g_aMousePosOld, $g_aMousePosNew

While True
    $g_bMouseMoved = False
    $g_aMousePosOld = MouseGetPos()
    Sleep(100)
    $g_aMousePosNew = MouseGetPos()

    If ($g_aMousePosOld[0] <> $g_aMousePosNew[0]) Or ($g_aMousePosOld[1] <> $g_aMousePosNew[1]) Then
        $g_bMouseMoved = True
        _Action()
    EndIf
WEnd

Func _Action()
    ConsoleWrite("+ Maus wurde bewegt : X=" & $g_aMousePosNew[0] & "  Y=" & $g_aMousePosNew[1] & @CRLF)
EndFunc

Func _Exit()
    ConsoleWrite("! Skript abgebrochen" & @CRLF)
    Exit
EndFunc

;-- TIME_STAMP   2020-01-28 11:33:46

Opt('MustDeclareVars', 1)

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region - GUI Create
Global $g_hGUI1 = GUICreate('GUI 1 WM_MOUSEMOVE ', 406, 429, 561, 309)
GUISetState()
Global $g_hGUI2 = GUICreate('GUI 2 WM_MOUSEMOVE ', 406, 429, 963, 309)
GUISetState()

GUIRegisterMsg($WM_MOUSEMOVE, "WM_MOUSEMOVE")
#EndRegion

#Region - GUI SwitchLoop
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
#EndRegion

; WM_MOUSEMOVE event handler
;~ wParam    -    Indicates whether various virtual keys are down. This parameter can be one or more of the following values.
;~         Value                   Meaning
;~         MK_CONTROL    0x0008    The CTRL key is down.
;~         MK_LBUTTON    0x0001    The left mouse button is down.
;~         MK_MBUTTON    0x0010    The middle mouse button is down.
;~         MK_RBUTTON    0x0002    The right mouse button is down.
;~         MK_SHIFT      0x0004    The SHIFT key is down.
;~         MK_XBUTTON1   0x0020    The first X button is down.
;~         MK_XBUTTON2   0x0040    The second X button is down.


;~ lParam    -    The low-order word specifies the x-coordinate of the cursor. The coordinate is relative to the upper-left corner of the client area.
;~                The high-order word specifies the y-coordinate of the cursor. The coordinate is relative to the upper-left corner of the client area.

;~ Return value
;~ If an application processes this message, it should return zero.
; ------------------------------------------------------
Func WM_MOUSEMOVE($hWnd, $iMsgID, $wParam, $lParam)
    #forceref $iMsgID, $wParam
    Local $aPos = _Method_2($lParam)
    Switch $hWnd
        Case $g_hGUI1
            WinSetTitle($g_hGUI1, '', 'GUI 1 WM_MOUSEMOVE X = ' & $aPos[0] & ', Y = ' & $aPos[1])
        Case $g_hGUI2
            WinSetTitle($g_hGUI2, '', 'GUI 2 WM_MOUSEMOVE X = ' & $aPos[0] & ', Y = ' & $aPos[1])
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOUSEMOVE

;~ Method_2 (GET_X_LPARAM/GET_Y_LPARAM)
Func _Method_2($lParam)
    Local $tStructDWord = DllStructCreate('dword XY')
    Local $tStructShort = DllStructCreate('short Y;short X', DllStructGetPtr($tStructDWord))
    DllStructSetData($tStructDWord, 'XY', $lParam)
    Local $aPos = [DllStructGetData($tStructShort, 'X'), DllStructGetData($tStructShort, 'Y')]

    Return $aPos
EndFunc   ;==>_Method_2