[Nim] Gibt es sowas wie @GUI_CtrlId in Nim

**Oscar**

Ich programmiere gerade eine Bildschirm-Tastatur. Für jede "Taste" möchte ich die selbe Prozedur aufrufen und innerhalb der Prozedur dann entsprechend der angeklickten "Taste" unterschiedlich verfahren.

Dazu brauche ich aber sowas wie @GUI_CtrlId in AutoIt. Gibt es sowas oder wie kann man das Problem sonst lösen?

Edit: Hier noch ein Testprogramm, wie ich es versucht habe zu lösen (geht nicht):

Code

import wNim

const aKeys = [
              ["Q", "W", "E", "R", "T", "Z", "U", "I", "O", "P", "<-"],
              ["A", "S", "D", "F", "G", "H", "J", "K", "L", "_", "<-'"],
              ["Y", "X", "C", "V", "B", "N", "M", ",", ".", "-", "+"]
              ]

var
  aKeyBtn: array[0..32, wButton]
  iX, iY, iW: int

let app = App()
let frame = Frame(title="Test", size=(1200, 340))
let panel = Panel(frame)

proc keyEvent(keyID: int) =
  echo keyID

for i in 0..2:
  iY = 10 + i * 80
  for j in 0..10:
    iX = 10 + i * 30 + j * 100
    case i * 11 + j
    of 10: iW = 150
    of 21: iW = 120
    else: iW = 90
    aKeyBtn[i * 11 + j] = Button(panel, label=aKeys[i][j], pos=(iX, iY), size=(iW, 70), style=wBorderDouble)
    aKeyBtn[i * 11 + j].font = Font(32, faceName="Source Code Pro", weight=wFontWeightBold)
    aKeyBtn[i * 11 + j].wEvent_Button do ():
      keyEvent(i * 11 + j)

frame.center()
frame.show()
app.mainLoop()

Alles anzeigen

**BugFix**

Du kannst jedem Ctrl bei Erstellung eine ID zuweisen. (mit enum, erster Wert wIdUser)

Für den Frame kannst du einen Event Handler erstellen mit Parameter wEvent.

Im Handler kannst du dann wEvent.Id abfragen.

Da du auf Tastatur reagieren möchtest kann man das vielleicht über Accelerator in Verbindung mit den ID lösen.

Bin gerade am Arbeiten und kann nicht weiter nachschauen.

**Oscar**

Zitat von BugFix

Du kannst jedem Ctrl bei Erstellung eine ID zuweisen. (mit enum, erster Wert wIdUser)
Für den Frame kannst du einen Event Handler erstellen mit Parameter wEvent.
Im Handler kannst du dann wEvent.Id abfragen.

Äh...ja...

Ich fürchte, ohne Beispiel bin ich da aufgeschmissen.

Zitat von BugFix

Da du auf Tastatur reagieren möchtest

Nee, nix Tastatur. Soll ja eben eine Bildschirm-Tastatur sein (reine Mausbedienung).

**BugFix**

Wenn ich heute Abend im Hotel bin, schreibe ich dir ein Bsp.

**BugFix**

So, hier ein Bsp.:

Code

import wnim/[wApp, wFrame, wPanel, wButton]

type
  ButtonID = enum
    idBt1 = wIdUser, idBt2, idBt3, idBt4

let app = App()
let frame = Frame(title="Test Button ID", size=(600,400))
let panel = Panel(frame)

let buttton1 = Button(panel, label="1", id=idBt1, pos=(10,10), size=(30,30))
let buttton2 = Button(panel, label="2", id=idBt2, pos=(60,10), size=(30,30))
let buttton3 = Button(panel, label="3", id=idBt3, pos=(110,10), size=(30,30))
let buttton4 = Button(panel, label="4", id=idBt4, pos=(160,10), size=(30,30))

frame.wEvent_Button do (event: wEvent):
  let sender = event.getEventObject()
  case sender.id:
    of idBt1: echo "Button 1"
    of idBt2: echo "Button 2"
    of idBt3: echo "Button 3"
    of idBt4: echo "Button 4"
    else: discard

frame.center()
frame.show()
app.mainLoop()

Alles anzeigen

**Oscar**

Zitat von BugFix

So, hier ein Bsp.:

Oh, klasse! Das hilft mir sehr viel weiter.

Vielen Dank!

**Oscar**

Ich habe das jetzt so umgesetzt:

Code

import wNim

const aKeys = [
              "Q", "W", "E", "R", "T", "Z", "U", "I", "O", "P", "<-",
              "A", "S", "D", "F", "G", "H", "J", "K", "L", "_", "<-'",
              "Y", "X", "C", "V", "B", "N", "M", ",", ".", "-", "+"
              ]

var
  aKeyBtn: array[0..32, wButton]
  iX, iY, iW, myID: int

let app = App()
let frame = Frame(title="Test", size=(1200, 340))
let panel = Panel(frame)

frame.wEvent_Button do (event: wEvent):
  let sender = event.getEventObject()
  let sID = int(sender.id)
  echo $sID & " -> " & aKeys[sID]

for i in 0..2:
  iY = 10 + i * 80
  for j in 0..10:
    iX = 10 + i * 30 + j * 100
    case i * 11 + j
    of 10: iW = 150
    of 21: iW = 120
    else: iW = 90
    aKeyBtn[i * 11 + j] = Button(panel, label=aKeys[i * 11 + j], id=myID, pos=(iX, iY), size=(iW, 70), style=wBorderDouble)
    aKeyBtn[i * 11 + j].font = Font(32, faceName="Source Code Pro", weight=wFontWeightBold)
    myID += 1
    
aKeyBtn[10].setToolTip("Test")
frame.center()
frame.show()
app.mainLoop()

Alles anzeigen

Funktioniert wunderbar! Nochmals Danke für Deine Hilfe, Bugfix!

Solche kleinen Beispiele zu den einzelnen Funktionen fehlen noch bei Nim.

**BugFix**

Die ID müssen mit wIdUser (hat den Wert 6000) starten. Sonst läufst du Gefahr mit anderen Standard-ID zu crashen.

In etwa vergleichbar mit ExtendedValue bei Listview-Item. Der muss auch größer als 2000 sein, weil bis dahin Ctrl-ID reserviert sind.

**Oscar**

Zitat von BugFix

Die ID müssen mit wIdUser (hat den Wert 6000) starten. Sonst läufst du Gefahr mit anderen Standard-ID zu crashen.

Ok!

Dann wäre das so aber ok?

Code

import wNim

const aKeys = [
              "Q", "W", "E", "R", "T", "Z", "U", "I", "O", "P", "<-",
              "A", "S", "D", "F", "G", "H", "J", "K", "L", "_", "<-'",
              "Y", "X", "C", "V", "B", "N", "M", ",", ".", "-", "+"
              ]

var
  aKeyBtn: array[0..32, wButton]
  iX, iY, iW: int
  myId: int = int(wIdUser)

let app = App()
let frame = Frame(title="Test", size=(1200, 340))
let panel = Panel(frame)

frame.wEvent_Button do (event: wEvent):
  let sender = event.getEventObject()
  let iId = int(sender.id) - int(wIdUser)
  echo $iId & " -> " & aKeys[iId]

for i in 0..2:
  iY = 10 + i * 80
  for j in 0..10:
    iX = 10 + i * 30 + j * 100
    case i * 11 + j
    of 10: iW = 150
    of 21: iW = 120
    else: iW = 90
    aKeyBtn[i * 11 + j] = Button(panel, label=aKeys[i * 11 + j], id=myId, pos=(iX, iY), size=(iW, 70), style=wBorderDouble)
    aKeyBtn[i * 11 + j].font = Font(32, faceName="Source Code Pro", weight=wFontWeightBold)
    myId += 1
    
frame.center()
frame.show()
app.mainLoop()

Alles anzeigen

**BugFix**

Genau

[Nim] Gibt es sowas wie @GUI_CtrlId in Nim

Oscar 8. Mai 2020 um 08:52

Gun-Food 9. Mai 2020 um 12:36

Ähnliche Themen

GUI mit FileRead aktualisieren und Opt("GUIOnEventMode", 1)

For...Next... für Funktionen?