Such Hilfe zu Win 10 Problem - Potplayer "Benachrichtigung" nervt

;-- TIME_STAMP   2020-09-15 06:10:53   v 0.1

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

Opt('MustDeclareVars', 1)

#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <Debug.au3>
#include <WinAPIProc.au3>
#include <WinAPISysWin.au3>

Global $bDEBUG = True ; $iPID: True = @AutoItPID, False = ProcessWait('PotPlayerMini64.exe')

; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
;~ "PotPlayerMini64.exe" starten und warten, bis das Popup erscheint, dann dieses Script starten
;~ und die gewünschten Einträge aus _DebugArrayDisplay (ohne Header) in die Zwischenablage kopieren,
;~ um sie in einer Ini zu speichern!
; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

_OpenPotPlayer() ; Nur für Demo - anderfalls nur _CheckPotPlayer() aufrufen!!!
;~ _CheckPotPlayer()

Func _CheckPotPlayer()
    ConsoleWrite('@@ (26) :(' & @MIN & ':' & @SEC & ') _CheckPotPlayer()' & @LF) ;### Function Trace
    Local $iPID, $bVisible = True, $aProcessWindows, $aPotPlayer[0][6], $aChildWindows, $NN = 1, $sTitle, $vClip, $iIndex

    $iPID = $bDEBUG ? @AutoItPID : ProcessWait('PotPlayerMini64.exe')

    $aProcessWindows = _WinAPI_EnumProcessWindows($iPID, $bVisible)
    If UBound($aProcessWindows) > 0 Then
        ConsoleWrite('> $aProcessWindows:' & @CRLF & _ArrayToString($aProcessWindows, @TAB & ', ') & @CRLF & @CRLF)
;~         _DebugArrayDisplay($aProcessWindows, '$aProcessWindows')
        _ArrayAdd($aPotPlayer, $aProcessWindows[1][0] & '|' & $aProcessWindows[1][1] & '|' & $NN & '|Parent|' & _
            _ArrayToString(WinGetPos($aProcessWindows[1][0]), ', ') & '|' & WinGetTitle($aProcessWindows[1][0])) ; Handle, ClassName, NN, Type, Position, Title

        $aChildWindows = _WinAPI_EnumChildWindows($aPotPlayer[0][0], $bVisible)
        If UBound($aChildWindows) > 0 Then
;~             _DebugArrayDisplay($aChildWindows, '$aChildWindows', '', 0, Default, 'Handle|ClassName')
            For $i = 1 To $aChildWindows[0][0] Step 1
                $NN = UBound(_ArrayFindAll($aPotPlayer, $aChildWindows[$i][1], 1, 0, 0, 0, 1))
                $NN = $NN < 1 ? 1 : $NN + 1
                $sTitle = StringRegExpReplace(WinGetTitle($aChildWindows[$i][0]), '(.*)\R.*', '\1')
                _ArrayAdd($aPotPlayer, $aChildWindows[$i][0] & '|' & $aChildWindows[$i][1] & '|' & $NN & '|Child|' & _
                    _ArrayToString(ControlGetPos($aChildWindows[$i][0], '', ''), ', ') & '|' & $sTitle) ; Handle, ClassName, NN, Type, Position, Title
            Next
            ConsoleWrite('! $aPotPlayer:' & @CRLF & __ArrayToString($aPotPlayer) & @CRLF)
            _DebugArrayDisplay($aPotPlayer, '$aPotPlayer', '', 0, Default, 'Handle|ClassName|NN|Type|Position|Title')
            ; 0x010E156C|Button|1|Child|2, 35, 100, 25|Refresh
            $vClip = ClipGet()
            $iIndex = _ArraySearch($aPotPlayer, StringLeft($vClip, 10))
            If $iIndex > -1 Then
                $vClip = StringRegExp(StringStripWS($vClip, 2), '(?m)(.+)\R?', 3)
;~                 _DebugArrayDisplay($vClip, '$vClip')
                ConsoleWrite('[PARENT]' & @CRLF & 'CLASSNAME=' & $aPotPlayer[0][1] & @CRLF & 'TITLE=' & $aPotPlayer[0][5] & @CRLF & '[CHILDS]' & @CRLF)
                For $i = 0 To UBound($vClip) -1 Step 1
                    $iIndex = _ArraySearch($aPotPlayer, StringLeft($vClip[$i], 10))
                    If $iIndex = 0 Then
                        ConsoleWrite('ACTION=Kill' & @CRLF)
                        ExitLoop
                    EndIf
                    ConsoleWrite('CLASSNAME=' & $aPotPlayer[$iIndex][1] & @CRLF & 'INSTANCE=' & $aPotPlayer[$iIndex][2] & @CRLF & 'TITLE=' & $aPotPlayer[$iIndex][5] & @CRLF & 'ACTION=Hide' & @CRLF)
                Next
            EndIf
        EndIf
    EndIf
EndFunc

Func _OpenPotPlayer()
    ConsoleWrite('@@ (71) :(' & @MIN & ':' & @SEC & ') _OpenPotPlayer()' & @LF) ;### Function Trace
    GUICreate('PotPlayer', 600, 240, -1, 100)
    GUICtrlCreateLabel('Popup', 2, 2, 100)
    Local $idRefresh = GUICtrlCreateButton('Refresh', 2, 35, 100)
    Local $idExit = GUICtrlCreateButton('Exit', 120, 35, 100)
    Local $idEdit = GUICtrlCreateEdit('Ads are cool! ;-)', 2, 80, 596, 100)
    GUICtrlSetColor($idEdit, 0xFF0000)
    GUISetState()

    _CheckPotPlayer()

    While True
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idExit
                Exit
            Case $idRefresh
                _CheckPotPlayer()
        EndSwitch
    WEnd
EndFunc

Func __ArrayToString($aArray)
    ConsoleWrite('@@ (93) :(' & @MIN & ':' & @SEC & ') __ArrayToString()' & @LF) ;### Function Trace
    If UBound($aArray, 2) <> 6 Then Exit 999
    Local $sArray, $aPos, _
        $FOH = '! %-12s | %-32s | %-3s | %-6s | %-26s | %s\n', _
        $FOD = '! %-12s | %-32s | %3i | %-6s | %5i, %5i, %5i, %5i | "%s"\n'
    $sArray &= StringFormat($FOH, 'Handle', 'ClassName', 'NN', 'Type', 'Position', 'Title')
    For $i = 0 To UBound($aArray) -1 Step 1
        $aPos = StringSplit($aArray[$i][4], ', ', 3)
        If UBound($aPos) < 4 Then
            ReDim $aPos[4]
            $aPos[0] = -1
        EndIf
        ;                             Handle          ClassName       NN              Type            Position                                Title
        ;                   $FOD = '! %-12s           %-32s           %3i             %-6s            %5i,      %5i,      %5i,      %5i       %s\n'
        $sArray &= StringFormat($FOD, $aArray[$i][0], $aArray[$i][1], $aArray[$i][2], $aArray[$i][3], $aPos[0], $aPos[1], $aPos[2], $aPos[3], $aArray[$i][5])
    Next
    Return $sArray
EndFunc

;-- TIME_STAMP   2020-09-17 09:47:22   v 0.1

Opt('MustDeclareVars', 1)

#include <WindowsConstants.au3>
#include <Process.au3>
#include <WinAPIProc.au3>
#include <WinAPISysWin.au3>

Global $sShow = '{F2}', $sHide = '!{F2}', $sESC = '{ESC}'

_SetHotKey($sShow, '_HotKeyPressed')
_SetHotKey($sHide, '_HotKeyPressed')
_SetHotKey($sESC, '_HotKeyPressed')

Global $g_tStruct = DllStructCreate($tagPOINT) ; Create a structure that defines the point to be checked.
Global $hGUI = GUICreate(@ScriptName & ' - Show = ' & $sShow & ', Hide = ' & $sHide & ', Exit = ' & $sESC, @DesktopWidth - 200, 400)
Global $aClientSize = WinGetClientSize($hGUI)
Global $idEdit = GUICtrlCreateEdit('', 0, 0, $aClientSize[0], $aClientSize[1])
GUICtrlSetFont(-1, 10, 800, 0, 'Courier New')
GUISetState(@SW_SHOWMINIMIZED)
SplashTextOn('', 'Press '&$sShow&' um Infos zu dem Fenster unter dem Cursor anzuzeigen, '&@CRLF&$sHide&' um die Info auszublenden, oder '&@CRLF&$sESC&' um das Script zu beenden.', $aClientSize[0] - 150, 90)
;~ ToolTip('Press '&$sShow&' um Infos zu dem Fenster unter dem Cursor anzuzeigen, '&$sHide&' um die Info auszublenden, oder '&$sESC&' um das Script zu beenden.', @DesktopWidth / 3, @DesktopHeight / 2)
Sleep(3000)
SplashOff()
;~ ToolTip('')
Do
Until GUIGetMsg() = -3
Exit

Func _SetHotKey($_sKey, $_sFuncName)
    If Not HotKeySet($_sKey, $_sFuncName) Then Exit MsgBox(16, @ScriptName, 'HotKey ' &$_sKey& ' konnte nicht gesetzt werden!')
    Return True
EndFunc

Func _HotKeyPressed()
    Switch @HotKeyPressed ; The last hotkey pressed.
        Case $sShow
            If _WinAPI_IsIconic($hGUI) Then GUISetState(@SW_RESTORE)
            DllStructSetData($g_tStruct, "x", MouseGetPos(0))
            DllStructSetData($g_tStruct, "y", MouseGetPos(1))
            Local $hChild = _WinAPI_WindowFromPoint($g_tStruct)
            Local $hParent = _WinAPI_GetAncestor($hChild, $GA_ROOT)
            Local $iPID = WinGetProcess($hParent)
            Local $sProcessFileName = _WinAPI_GetProcessFileName($iPID)
            Local $sProcessName     = _ProcessGetName($iPID)
            Local $sRuleName        = StringRegExpReplace($sProcessName, '(?i)(.*?)\.exe', '\1')

            GUICtrlSetData($idEdit, '')
            Local $sText
;~             $sText = GUICtrlRead($idEdit) & @CRLF & '@HotKeyPressed = ' & @HotKeyPressed & @CRLF
;~             $sText = '> @HotKeyPressed            ==>> ' & @HotKeyPressed & @CRLF

            If $hChild Then $sText &= '> $hChild (WindowFromPoint) ==>> ' & $hChild & ' (CLASS = ' & _WinAPI_GetClassName($hChild) & ')' & @CRLF
            $sText &= '> $hParent                  ==>> ' & $hParent & ' (CLASS = ' & _WinAPI_GetClassName($hParent) & ') ( Title = ' & WinGetTitle($hParent) & ')' & @CRLF
            $sText &= '> $iPID                     ==>> ' & $iPID & @CRLF
            $sText &= '> $sProcessFileName         ==>> ' & $sProcessFileName & @CRLF
            $sText &= '> $sProcessName             ==>> ' & $sProcessName & @CRLF
            $sText &= '> $sRuleName                ==>> ' & $sRuleName & @CRLF
            SplashTextOn('', 'Suche nach Firewallregeln, die im Regelname "'&$sRuleName&'" enthalten...', $aClientSize[0] - 50, 50)
;~             ToolTip('Suche nach Firewallregeln, die im Regelname "'&$sRuleName&'" beinhalten...', @DesktopWidth / 3, @DesktopHeight / 2)
            ; Ausgehende Firewallregeln suchen, die $sRuleName beinhalten
;~             Local $iPID = Run(@ComSpec & " /c " & 'netsh.exe advfirewall firewall show rule name=all dir=out|find /I "'&$sRuleName&'"', '', @SW_HIDE, $STDOUT_CHILD)
            Local $iPID = Run(@ComSpec & " /c " & 'netsh.exe advfirewall firewall show rule name=all dir=out|find /I "Regelname:"|find /I "'&$sRuleName&'"', '', @SW_HIDE, $STDOUT_CHILD)
            ProcessWaitClose($iPID)
            Local $sRead = StdoutRead($iPID)
            SplashOff()
;~             ToolTip('')

            ; Die Regel muss nicht zwingend den Namen der Exe beinhalten!
            If $sRead Then $sText &= @CRLF & 'Firewallregeln gefunden, die im Regelname "'&$sRuleName&'" enthalten...' & @CRLF & $sRead & @CRLF

            GUICtrlSetData($idEdit, $sText)
        Case $sHide
            If Not _WinAPI_IsIconic($hGUI) Then GUISetState(@SW_MINIMIZE)
        Case $sESC
            Exit
    EndSwitch
EndFunc

; > $hChild (WindowFromPoint) ==>> 0x0002102C (CLASS = Internet Explorer_Server)
; > $hParent                  ==>> 0x00150FB0 (CLASS = HH Parent) ( Title = AutoIt Help (v3.3.14.5))
; > $iPID                     ==>> 16852
; > $sProcessFileName         ==>> C:\Program Files (x86)\AutoIt3\AutoIt3Help.exe
; > $sProcessName             ==>> AutoIt3Help.exe
; > $sRuleName                ==>> AutoIt3Help
;
; Firewallregeln gefunden, die im Regelname "AutoIt3Help" enthalten...
; Regelname:                               AutoIt3Help viewer (autoit3help.exe)