Script loggt plötzlich nicht mehr

Code4Fun

Guten Morgen,

ich habe mal eine Frage. Bei mir läuft ein Autoit Script, welches jetzt schon seit Monaten ohne Probleme lief. Es macht nichts anderes, als eine Webseite zu überprüfen und Informationen in ein Logfile schreibt. Ich lasse den Windows PC jede Nacht automatisch um 23:59 Uhr booten. Danach fängt das Script mit einem neuen Logfile an.

Aktuell läuft der Zeitstempel im Logfile bis ca. 04:04 Uhr, dann wird nichts mehr ins Logfile geschrieben. Der Prozess vom Script läuft aber noch, d.h. eigentlich sollte er weiter protokollieren.

Wie kann ich denn sowas monitoren / abfangen, bzw. den Fehler rausfinden.

Danke

**alpines**

Zitat von Code4Fun

Wie kann ich denn sowas monitoren / abfangen, bzw. den Fehler rausfinden.

Noch mehr loggen. Wenn du eine Webseite überprüfst nehme ich mal an du verwendest noch die IE.au3 und diese wird vermutlich beim Laden einer Webseite festhängen oder die Browserinstanz überhaupt nicht starten.

Kannst du das abgespeckte Skript mal hochladen?

Code4Fun

Mein Script

C

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
    #AutoIt3Wrapper_Icon=pushme.ico
    #AutoIt3Wrapper_Outfile_x64=ServerMonitorin01ushService.exe
    #AutoIt3Wrapper_Compression=4
    #AutoIt3Wrapper_Res_Comment= Servermonitoring Push Service
    #AutoIt3Wrapper_Res_Description= Servermonitoring Push Service
    #AutoIt3Wrapper_Res_Fileversion=0.1.0.58
    #AutoIt3Wrapper_Res_Fileversion_AutoIncrement=y
    #AutoIt3Wrapper_Res_LegalCopyright=Code4Fun
    #AutoIt3Wrapper_Res_Language=1031
    #AutoIt3Wrapper_AU3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
    #AutoIt3Wrapper_Run_Stop_OnError=y
    #AutoIt3Wrapper_Run_Tidy=y
    #Tidy_Parameters=/gd /reel /ri /sci 9  /kv 0
    #AutoIt3Wrapper_Run_Au3Stripper=y
    #Au3Stripper_Parameters=/so /mo
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <String.au3>
#include <WinHttp.au3>
#include <TrayConstants.au3>
#include <Array.au3>
#include <Date.au3>
#include <FileConstants.au3>

;HotKeySet("{ESC}", "_Exit")

#Region ; Script Kopf
    #cs ----------------------------------------------------------------------------
        AutoIt Version:     3.3.14.5
        Author:             Code4Fun

        Script Function:

        Diese Script soll sich automatisch auf der Monitoring Website einloggen und im Quelltext nach einem bestimmten Wort suchen.
        Wenn dieses Wort vorhanden ist, löse eine Push Me Aktion aus.
        Es soll so konfigurierbar sein, das über eine ini Datei Holger, Matthias oder Peter angetriggert werden.

        Erstellungendatum: vom 10.05.2019

        Änderungsdatum:

        Version: 0.0.1.0

        History:

        0.0.1.0 Initialerstellung
    #ce ----------------------------------------------------------------------------
#EndRegion ; Script Kopf

#Region ; Globale Variablen Deklaration
    ;Opt("MustDeclareVars", 1) ; Variablen müssen deklariert sein

    Global $iMsg, $exititem, $sInputFreitext, $idMyedit, $sLesePushMeURL, $sLeseIdentifier, $sLeseTitle, $sLeseImageURL, $hGUI, $sLeseBody, $sLeseURL, $aAlarmString, $aAlarmServer, $aAlarmKlasse
    Global $aCSRF, $sPOST, $sServerName, $sPaket, $hConnect, $hSession, $aIEproxy, $sProxy, $sPaket2, $hConnect2, $sServerName2, $hSession2, $sBenutzerName, $sPasswort, $sLocation, $sLeseTitle4Log
    Global $iCount = 1, $iOrangeCounter = 0, $iRedCounter = 0
    Global $iAlarmCount = 0
    Global $iDurchlaufCounter = 1
    Global $sFileVersion = FileGetVersion(@AutoItExe)
    Global $sStartDatum = @MDAY & "." & @MON & "." & @YEAR
    Global $sStartZeit = @HOUR & ":" & @MIN & ":" & @SEC

#EndRegion ; Globale Variablen Deklaration
ConsoleWrite($sStartDatum & @CRLF)
_WriteLog("### START ###")
AdlibRegister("_Monitoring_Login", 10000)

;Tray-Menü anpassen
Opt("TrayAutoPause", 0) ; Script will not be paused when clicking the tray icon.
Opt("TrayOnEventMode", 1)
Opt("TrayMenuMode", 1 + 2)
;Opt("TrayIconDebug", 1) ; Zeigt die aktuelle Skriptzeile im Trayicon Tipp um das Debugging zu unterstützen

$exititem = TrayCreateItem("Beenden")
TrayItemSetState(-1, $TRAY_UNCHECKED)
TrayItemSetOnEvent(-1, "_Exit")
TraySetState()

#Region ; Hauptschleife
    While 1
        ;Monitoring_Login()
        Sleep(1000)
    WEnd
#EndRegion ; Hauptschleife

#Region ; Funktionen

    Func _Monitoring_Login()
        _WriteLog("START: _reboot")
        _reboot()
        _WriteLog("START: _IPChecker")
        _IPChecker()
        ;ConsoleWrite("Lokation ist: " & $sLocation & @CRLF)
        If $sLocation = "01" Then ; Login für Privat verwendet
            _WriteLog("START: Lokation 01 erkannt")
            $sBenutzerName = "Mein Benutzername"
            $sPasswort = "Mein Passwort"
        Else ; Login für  verwenden
            _WriteLog("START: Lokation 02 erkannt")
            $sBenutzerName = "Benutzername"
            $sPasswort = "Passwort"
        EndIf
        _WriteLog($iDurchlaufCounter)
        ;ConsoleWrite("Durchlauf Nr: " & $iDurchlaufCounter & @CRLF)
;~         TraySetToolTip("Version von Servermonitor Push Me: " & $sFileVersion & @CRLF & "Start der Anwendung am: " & $sStartDatum & @CRLF & "um: " & $sStartZeit & " Uhr" & @CRLF & "Durchlauf Nr: " & $iDurchlaufCounter & @CRLF & "Anzahl orangene Alarme seit Start: " & $iOrangeCounter & @CRLF & "Anzahl rote Alarme seit Start: " & $iRedCounter)
        TraySetToolTip("Version: " & $sFileVersion & @CRLF & "Start am: " & $sStartDatum & @CRLF & "um: " & $sStartZeit & " Uhr" & @CRLF & "Round: " & $iDurchlaufCounter & @CRLF & "O-Alarme: " & $iOrangeCounter & @CRLF & "R-Alarme: " & $iRedCounter)
        _WriteLog("START: $hSession")
        $hSession = _WinHttpOpen('Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:66.0) Gecko/20100101 Firefox/66.0')
        ;host
        $sServerName = 'hier steht die URL drin'
        _WriteLog("START: $hConnect")
        $hConnect = _WinHttpConnect($hSession, $sServerName)
        $sPaket = _WinHttpSimpleSSLRequest($hConnect, 'GET', '/')
        $aCSRF = _StringBetween($sPaket, 'name="csrf" value="', '" />')
        ;ConsoleWrite("$aCSRF ist: " & $aCSRF[0] & @CRLF)
        $iCount = 1
        _FileWrite($sPaket) ; schreibe eine Kontroll HTML Datei
        $sPOST = "csrf=" & $aCSRF[0] & "&user_name=" & $sBenutzerName & "&user_password=" & $sPasswort & "&action=login"
        ;ConsoleWrite("$sPOST = " & $sPOST & @CRLF)
        $sPaket = ""
        _WriteLog("START: While $sPaket")
        While $sPaket = "" ;Entweder auf "0" = Zeichen oder 0 = Zahl prüfen
            $sPaket = _WinHttpSimpleSSLRequest($hConnect, 'POST', '/', 'https://**** die URL ****/', $sPOST)
        WEnd
        _WriteLog("ENDE: While $sPaket")
        _FileWrite($sPaket) ; schreibe eine Kontroll HTML Datei
        ; suche nach dem Alarmstring
        Local $aAlarmString = _StringBetween($sPaket, '<div class="card text-white ', ' mb-3"') ; hier wird der Status der Server ausgelesen. Möglich ist bg-success / bg-warning und bg-danger
;~         _ArrayDisplay($aAlarmString)
        Local $aAlarmServer = _StringBetween($sPaket, 'class="text-white">', '<span class="sr-only">') ; hier wird das Serversystem ausgelesen.
;~        _ArrayDisplay($aAlarmServer)

        _WriteLog("START: IF $iError")
        If $aAlarmString[0] = "bg-success" Then ; wenn der String bg-success ist, ist alles im grünen Bereich
            ConsoleWrite($aAlarmString[0] & @CRLF)
            $iAlarmCount = 0 ; 0 = alles im grünen Bereich
            TraySetIcon(@ScriptDir & "\green.ico")
            ;_WriteLog(@HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC & "  " & "grün")
            ;ConsoleWrite("Alles im grünen Bereich" & @CRLF)

        Else
            ;Alarmbereich betreten
            ;ConsoleWrite("Alarmbereich betreten" & @CRLF)
            ;Local $sAlarmString = $aAlarmString[0]
            ;ConsoleWrite("$sAlarmString ist: " & @CRLF & $sAlarmString & @CRLF)
            ;Local $aAlarmKlasse = _StringBetween($sAlarmString, '<div class="', '"') ; hier wird bestimmt, ob es ein orangener oder roter Alarm im Quelltext ist

            If $iAlarmCount = 0 Then
                If $aAlarmString[0] = "bg-warning" Then ; Orangener Alarm festgestellt
                    ;Aktion für Orangenen Alarm auslösen
                    $iOrangeCounter += 1
                    $iAlarmCount = 1 ; 1 = orangener Alarm
                    TraySetIcon(@ScriptDir & "\orange.ico")
                    _WriteLog("System " & $aAlarmServer[0] & ": INSTABIL")
                    ;ConsoleWrite("Orangener Alarm erkannt auf " & $aAlarmServer[0] & @CRLF)
                    ;Push Me mit Orangener Alarm + Servername + Zeit
                    $sLeseTitle = $aAlarmServer[0] & @CRLF & " INSTABIL" & @CRLF
                    $sLeseTitle4Log = $aAlarmServer[0] & ": INSTABIL"
                    $sLeseBody = "System INSTABIL - Details via Login " & @CRLF & "Benutzer 'Benutzer'" & @CRLF & "Kennwort 'Passwort'" & @CRLF & "hier ==>"
                    $sLeseImageURL = "https://**** die URL ****/pushme/OrangenerAlarm.jpg"
                    $sLeseURL = "https://**** die URL ****"
                    MsgBox(65584, "Info vom Servermonitoring", $sLeseTitle & @CRLF & "am: " & @MDAY & "." & @MON & "." & @YEAR & @CRLF & "um: " & @HOUR & ":" & @MIN & ":" & @SEC, 3)
                    _PushMeTo("Holger", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
                    _PushMeTo("Matthias", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
;~                     _PushMeTo("Peter", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
                EndIf
            EndIf

            If $iAlarmCount = 0 Or $iAlarmCount = 1 Then
                If $aAlarmString[0] = "bg-danger" Then ; Roter Alarm festgestellt
                    ;Aktion für Roten Alarm auslösen
                    $iRedCounter += 1
                    $iAlarmCount = 2 ; 2 = roter Alarm
                    TraySetIcon(@ScriptDir & "\red.ico")
                    _WriteLog("System " & $aAlarmServer[0] & ": OFFLINE")
                    ;ConsoleWrite("Roter Alarm erkannt auf " & $aAlarmServer[0] & @CRLF)
                    $sLeseTitle = $aAlarmServer[0] & @CRLF & " OFFLINE" & @CRLF
                    $sLeseTitle4Log = $aAlarmServer[0] & ": OFFLINE"
                    $sLeseBody = "System OFFLINE - Details via Login " & @CRLF & "Benutzer 'Benutzer'" & @CRLF & "Kennwort 'Passwort'" & @CRLF & "hier ==>"
                    $sLeseImageURL = "https://**** die URL ****/pushme/RoterAlarm.jpg"
                    $sLeseURL = "https://**** die URL ****"
                    If $iAlarmCount = 2 Then
                        MsgBox(65552, "Info vom Servermonitoring", $sLeseTitle & @CRLF & "am: " & @MDAY & "." & @MON & "." & @YEAR & @CRLF & "um: " & @HOUR & ":" & @MIN & ":" & @SEC, 3)
                    EndIf
                    _PushMeTo("Holger", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
                    _PushMeTo("Matthias", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
;~                     _PushMeTo("Peter", $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL)
                EndIf
            EndIf
        EndIf
        _WriteLog("ENDE: $hConnect")
        _WinHttpCloseHandle($hConnect)
        ;_WinHttpCloseHandle($hSession)
        $iDurchlaufCounter += 1
    EndFunc   ;==>_Monitoring_Login

    Func _PushMeTo($sVorname, $sLeseTitle, $sLeseBody, $sLeseImageURL, $sLeseURL) ; Diese Funktion wird aufgerufen, wenn die Nachricht an Holger gehen soll
        _WriteLog("START: _PushMeTo()")
        _LeseINI($sVorname) ; lese die INI Datei aus
;~         $hSession2 = _WinHttpOpen('Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:66.0) Gecko/20100101 Firefox/66.0')
;~         ;host
;~         $sServerName2 = 'pushmeapi.jagcesar.se'
;~         $hConnect2 = _WinHttpConnect($hSession2, $sServerName2)
;~         $sPaket2 = _WinHttpSimpleSSLRequest($hConnect2, 'GET', '?identifier=' & $sLeseIdentifier & '&title=' & _EncodeURL($sLeseTitle) & '&body=' & _EncodeURL($sLeseBody) & '&imageURL=' & _EncodeURL($sLeseImageURL) & '&url=' & _EncodeURL($sLeseURL))
        Local $bData = InetRead($sLesePushMeURL & "identifier=" & $sLeseIdentifier & "&title=" & _EncodeURL($sLeseTitle) & "&body=" & _EncodeURL($sLeseBody) & "&imageURL=" & _EncodeURL($sLeseImageURL) & '&url=' & _EncodeURL($sLeseURL), 1) ; Lese die URL. Durch den Aufruf der URL wird via GET die Nachricht an das iPhone gesendet.
        _WriteLog("Info an " & $sVorname & " : " & $sLeseTitle4Log)
        _WriteAlertLog($sLeseTitle4Log)
        ;_WriteLog(@HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC & "  " & "gesendete URL an " & $sVorname & ": " & $sLesePushMeURL & "identifier=" & $sLeseIdentifier & "&title=" & _EncodeURL($sLeseTitle) & "&body=" & _EncodeURL($sLeseBody) & "&imageURL=" & _EncodeURL($sLeseImageURL) & '&url=' & _EncodeURL($sLeseURL))
        Local $sData = BinaryToString($bData)
        If Not $sData = "OK" Then ; Wenn die Website KEIN OK zurück gibt, dann erzeuge Fehlermeldung
            _WriteLog("PushMe an " & $sVorname & ": fehlgeschlagen")
        Else
            _WriteLog("PushMe an " & $sVorname & ": erfolgreich")
        EndIf
        _WriteLog("ENDE: _PushMeTo()")
    EndFunc   ;==>_PushMeTo

    Func _FileWrite($sHTML, $Zusatz = "") ; erstellt zu Kontrollzwecken lokale HTML Dateien,
        Local Const $sFilePath = @ScriptDir
        ; Falls das Verzeichnis bereits existiert, beenden.
        If FileExists($sFilePath) Then ; wenn das Verzeichnis existiert, dann.
            ;ConsoleWrite("Das Verzeichnis " & $sFilePath & " existiert bereits" & @CRLF)
        Else
            ; Öffnet das Script Verzeichnis.
            ShellExecute(@ScriptDir)
            ; Erstellt das Verzeichnis.
            DirCreate($sFilePath)
            ; Zeigt eine Nachricht der Erstellung des Verzeichnisses.
            ConsoleWrite("Das Verzeichnis " & $sFilePath & " wurde erstellt" & @CRLF)
            ; Löscht das Verzeichnis. und alle Unterverzeichnis.
            ;DirRemove($sFilePath, $DIR_REMOVE)
            ; Zeigt eine Nachricht mit dem Entfernen des Verzeichnisses.
            ;MsgBox($MB_SYSTEMMODAL, "", "Das Unterverzeichnis: Folder2 wurde gelöscht.")
        EndIf
        ;ConsoleWrite($iCount & ". Voting " & $Zusatz & @CRLF)
        FileDelete($sFilePath & "\" & $iCount & "-MonitoringLogin" & $Zusatz & ".html")
        FileWrite($sFilePath & "\" & $iCount & "-MonitoringLogin" & $Zusatz & ".html", $sHTML)
        $iCount += 1
    EndFunc   ;==>_FileWrite

    Func _LeseINI($sSection) ; lese die PushMe.ini aus
        $sLeseIdentifier = IniRead(@ScriptDir & "\pushme.ini", $sSection, "identifier", "")
        $sLesePushMeURL = IniRead(@ScriptDir & "\pushme.ini", $sSection, "PushMeURL", "")
        ;$sLeseTitle = IniRead(@ScriptDir & "\pushme.ini", $sSection, "title", "")
        ;$sLeseBody = IniRead(@ScriptDir & "\pushme.ini", $sSection, "body", "")
        ;$sLeseURL = IniRead(@ScriptDir & "\pushme.ini", $sSection, "url", "")
        ;$sLeseImageURL = IniRead(@ScriptDir & "\pushme.ini", $sSection, "imageURL", "")
    EndFunc   ;==>_LeseINI

    Func _DecodeURL($sData) ; Diese Funktion stammt von Prog@ndy und decodiert meinen URL codierten Text wieder in Klartext
        Local $aData = StringSplit(StringReplace($sData, "+", " ", 0, 1), "%")
        $sData = ""
        For $i = 2 To $aData[0]
            $aData[1] &= Chr(Dec(StringLeft($aData[$i], 2))) & StringTrimLeft($aData[$i], 2)
        Next
        Return BinaryToString(StringToBinary($aData[1], 1), 4)
    EndFunc   ;==>_DecodeURL

    Func _EncodeURL($sData) ; Diese Funktion stammt von Prog@ndy und codiert meinen Klartext in einen URL codierten Text
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
        Local $nChar
        $sData = ""
        For $i = 1 To $aData[0]
            ; ConsoleWrite($aData[$i] & @CRLF)
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar, 2)
            EndSwitch
        Next
        Return $sData
    EndFunc   ;==>_EncodeURL

    Func _IPChecker() ; hier wird geprüft, ob die IP den String 192.168.192 enthält. Wenn ja, dann bin ich in 01, ansonsten in 02
        If StringInStr(@IPAddress1 & " " & @IPAddress2 & " " & @IPAddress3 & " " & @IPAddress4, "192.168.193") Then ; hier bin ich in 01
            $sLocation = "01" ; setze die Variable $sLocation auf 01
        Else ; und hier in 02
            $sLocation = "02" ; setze die Variable $sLocation auf 02
        EndIf
    EndFunc   ;==>_IPChecker

    Func _WriteLog($sLogFileText)
        ;Local $now = _NowCalcDate(); den heutigen Tag ermitteln
        ;If $now = @YEAR & "/" & @MON & "/" & @MDAY Then; Tag vergleichen
        ;EndIf
        ; erstelle Logverzeichnis
        Local Const $sFilePath = @ScriptDir & "\Log"
        If FileExists($sFilePath) Then
            ;mache nichts
        Else
            DirCreate($sFilePath)
        EndIf
        ; erstelle Logdatei
        Local $hFileopen = FileOpen($sFilePath & "\" & @YEAR & "-" & @MON & "-" & @MDAY & ".log", BitOR($FO_APPEND, $FO_UTF8))
        FileWrite($hFileopen, @HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC & "  " & "#: " & $sLogFileText & @CRLF)
        FileClose($hFileopen)
    EndFunc   ;==>_WriteLog

    Func _WriteAlertLog($sLogFileText)
        ;Local $now = _NowCalcDate(); den heutigen Tag ermitteln
        ;If $now = @YEAR & "/" & @MON & "/" & @MDAY Then; Tag vergleichen
        ;EndIf
        ; erstelle Logverzeichnis
        Local Const $sFilePath = @ScriptDir & "\Log"
        If FileExists($sFilePath) Then
            ;mache nichts
        Else
            DirCreate($sFilePath)
        EndIf
        ; erstelle Logdatei
        Local $hFileopen = FileOpen($sFilePath & "\" & @YEAR & "-" & @MON & "-" & @MDAY & "-Alert.log", BitOR($FO_APPEND, $FO_UTF8))
        FileWrite($hFileopen, @HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC & "  " & "#: " & $sLogFileText & @CRLF)
        FileClose($hFileopen)
    EndFunc   ;==>_WriteAlertLog

    Func _reboot()
        If @HOUR = 23 And @MIN = 59 Then
            _WriteLog("### Es ist 23:59 Uhr - System wird automatisch neu gestartet ###")
            _WriteLog("### ENDE ###")
            Shutdown(22)
        EndIf
    EndFunc   ;==>_reboot

    Func _Exit()
        _WriteLog("### ENDE ###")
        Exit
    EndFunc   ;==>_Exit

#EndRegion ; Funktionen

Alles anzeigen

**alpines**

Wie sieht denn deine Logdatei aus wenn dein Skript nicht mehr weiterloggen will? Hört sie abrupt auf und das Skript friert quasi ein (arbeitet nicht weiter) oder arbeitet es weiter aber es wird nicht geloggt?

Code4Fun

Hier mal die letzten paar Zeilen aus dem Log (der Zeitstempel ist aber immer unterschiedlich, mal ein paar Minuten mehr, mal weniger)

Spoiler anzeigen

04:06:55:230 #: 1471

04:06:55:230 #: START: $hSession

04:06:55:230 #: START: $hConnect

04:06:55:308 #: START: While $sPaket

04:06:55:480 #: ENDE: While $sPaket

04:06:55:480 #: START: IF $iError

04:06:55:480 #: ENDE: $hConnect

04:07:05:231 #: START: _reboot

04:07:05:231 #: START: _IPChecker

04:07:05:231 #: START: Lokation UL erkannt

04:07:05:231 #: 1472

04:07:05:231 #: START: $hSession

04:07:05:231 #: START: $hConnect

04:07:05:309 #: START: While $sPaket

04:07:05:512 #: ENDE: While $sPaket

04:07:05:512 #: START: IF $iError

04:07:05:512 #: ENDE: $hConnect

04:07:15:231 #: START: _reboot

04:07:15:231 #: START: _IPChecker

04:07:15:231 #: START: Lokation UL erkannt

04:07:15:231 #: 1473

04:07:15:231 #: START: $hSession

04:07:15:231 #: START: $hConnect

04:07:15:309 #: START: While $sPaket

04:07:15:496 #: ENDE: While $sPaket

04:07:15:496 #: START: IF $iError

04:07:15:496 #: ENDE: $hConnect

04:07:25:231 #: START: _reboot

04:07:25:231 #: START: _IPChecker

04:07:25:231 #: START: Lokation UL erkannt

04:07:25:231 #: 1474

04:07:25:231 #: START: $hSession

04:07:25:231 #: START: $hConnect

Wie gesagt, die EXE läuft im Taskmanager noch, aber ob Sie noch "lebt" weiß ich nicht. Hier brauche ich mal Hilfe, wie ich das feststellen kann.

Code4Fun

Was mir schon durch den Kopf ging. Eventuell erstellt der Provider um diese Zeit Backups und die Site ist nicht so verfügbar, wie mein Script das erwartet (oder ich es erwarte). Vielleicht muss ich hier noch was einbauen, damit es "wartet"

**alpines**

Eigentlich sollte WinHttp einen Timeout bereits implementiert haben. Wenn eine Verbindung nicht hergestellt werden konnte, dann wird für gewöhnlich ein Fehler zurückgeworfen.

Vielleicht hast du aber einfach Pech, und dein Router startet um die Uhrzeit neu und die UDF hängt sich einfach auf, bzw. die Seite die du erreichen willst geht gerade offline.

Ich bin leider nicht mehr ganz Fit in WinHttp, aber versuch mal noch explizit einen Timeout zu definieren (entweder direkt über den Funktionsaufruf) oder über WinHttpSetOption o. ä.

Alternativ kannst du auch ein 2. Skript als Watchdog bauen, der das erste abschießt und neustartet, sofern alle x Minuten nicht geloggt werden konnte.

Code4Fun

Ich denke ich mach es mir einfacher. Für mich ist das Monitoring mit der Pushbenachrichtigung nur im Zeitraum von 8 bis 17 Uhr wichtig. Ich lass einfach mal den PC Morgens um 06:00 Uhr booten und schau mir das mal an. Falls es wirklich mit dem Backup der Site zu tun haben sollte, tangiert mich das dann nicht mehr. Aber mal vielen Dank für Deine Tipps.

Code4Fun

Ist jetzt sicherlich technisch nicht die schönste Lösung, aber ohne viel Aufwand funktional. Mein Log sieht jetzt so aus, nachdem ich den PC einfach mal um 06:00 Uhr booten lasse

Spoiler anzeigen

04:04:26:466 #: 1457

04:04:26:466 #: START: $hSession

04:04:26:466 #: START: $hConnect

04:04:26:528 #: START: While $sPaket

04:04:26:716 #: ENDE: While $sPaket

04:04:26:716 #: START: IF $iError

04:04:26:716 #: ENDE: $hConnect

04:04:36:466 #: START: _reboot

04:04:36:466 #: START: _IPChecker

04:04:36:466 #: START: Lokation UL erkannt

04:04:36:466 #: 1458

04:04:36:466 #: START: $hSession

04:04:36:466 #: START: $hConnect

06:02:25:063 #: ### START ###

06:02:35:094 #: START: _reboot

06:02:35:094 #: START: _IPChecker

06:02:35:219 #: START: Lokation UL erkannt

06:02:35:219 #: 1

06:02:35:219 #: START: $hSession

06:02:35:235 #: START: $hConnect

06:02:35:954 #: START: While $sPaket

06:02:36:251 #: ENDE: While $sPaket

06:02:36:251 #: START: IF $iError

06:02:36:297 #: ENDE: $hConnect

06:02:45:094 #: START: _reboot

06:02:45:094 #: START: _IPChecker

06:02:45:094 #: START: Lokation UL erkannt

06:02:45:094 #: 2

Script loggt plötzlich nicht mehr

Ähnliche Themen

Kann mein eigenes Programm nicht löschen - von Avira keine Unterstützung...