_IsPressed() Abfrage strukturieren/verbessern

Professor Bernd · 13. Februar 2021

Hallo.

Dieses mal geht es um Verbesserungsvorschläge zu einer Funktion "KeysForLeftParenthesisWerePressed()", in der verschiedene Tasten mit _IsPressed() abgefragt werden. Es gibt 1 Zeichentaste (Char key) und 3 Steuertasten (Control keys). Damit es nicht zu kompliziert wird (für mich) habe ich die Steuertasten begrenzt auf: Ctrl, Shift und Alt. Den japanischen Hanuta-Keys (richtig: "Hankaku key") habe ich weggelassen, da ich weder einen virtuellen Key-Code zuordnen konnte, noch glaube, dass man ihn zum Schreiben von "(" braucht.

In der Funktion wird die Zeichentaste immer ausgewertet. Zusätzlich wird ermittelt, ob und wieviele Steuertasten ausgewertet werden sollen. Z.B. beim französischen Keyboard-Layout benötigt man nur die Taste 5, um "(" zu schreiben = 0 Steuertasten. Bei deuschen KB-Layout drückt man für "(" die Kombi Shift+8, also 1 Steuertaste, usw. Ob es Tastenkombis gibt, die Ctrl und/oder Alt benutzen um "(" zu schreiben, konnte ich nicht herausfinden.

Kurzbeschreibung

Der Funktion wird 1 Zeichentaste übergeben + 0 bis 3 Steuertasten. Es soll geprüft werden, ob diese Tasten gedrückt wurden. Rückgabe True/False. Wichtig ist, dass dabei auch geprüft werden soll, dass nur die gewünschten Tasten und keine anderen dazu gedrückt werden. Wenn ich wüsste wie, würde ich folgendes programmieren:

If _IsPressed(Zeichentaste) And _IsPressed(Steuertasten) And Not _IsPressed(AndereTasten) Then

Bitte seht euch die Funktion "KeysForLeftParenthesisWerePressed()" mal an und sagt, ob ihr Ideen zur Verbesserung oder Vereinfachung habt.

AutoIt

#include <Array.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <WinAPISys.au3>

Global Const $User32 = DllOpen("User32.dll")

Example()

DllClose($User32)

Func Example()
  While 1
    Sleep(10)

    If KeysForLeftParenthesisWerePressed() Then
      MsgBox($MB_SYSTEMMODAL, "", "'(' wurde eingegeben")
      ConsoleWrite("'(' wurde eingegeben" & @CRLF)
    EndIf

    ; -------------------------------
    ; Zum Abbrechen Shift+F1 drücken!
    ; -------------------------------
    If _IsPressed("10") And _IsPressed("70") Then ExitLoop
  WEnd
EndFunc


; ==============================================================================
; KeysForLeftParenthesisWerePressed
;
; Diese Routine prüft, ob die Tasten (1 oder mehrere) gedrückt wurden, die zum
; Schreiben einer öffnenden runden Klammer "(" benötigt werden.
;
; Wichtig: Diese Routine wartet mit der weiteren Ausführung des Scripts,
;          bis die o.g. Tasten NICHT mehr gedrückt sind!
;
;          Das heißt, wenn alle benötigte Tasten gedrückt sind, wird eine
;          Schleife gestartet, die solange läuft, bis min. 1 der Tasten NICHT
;          mehr gedrückt ist. Erst danach wird das Script weiter ausgeführt.
; ------------------------------------------------------------------------------
Func KeysForLeftParenthesisWerePressed()

  Local $aKeyCodes, $aTmpCodes[0]
  Local $bLeftParenthesisWasPressed = False

;   $aKeyCodes = GetKeyCodesForLeftParenthesis()
;   ;   [0]:   Enthält den virtuellen KeyCode der Zeichentaste als Hex-Wert, den
;   ;          man z.B. in _IsPressed() benutzen kann.
;   ;
;   ; [1]-[3]: Enthalten die virtuellen KeyCodes der Steuertasten "Shift", "Ctrl"
;   ;          und "Alt" als Hex-Wert, den man z.B. in _IsPressed() benutzen kann.
;   ;
;   ; Die Items 1-3 sind optional, das heißt, das Array kann 1 - 4 Items enthalten.

  ; Zum Testen ist die Funktion "GetKeyCodesForLeftParenthesis()" nicht verfügbar.
  ; Deshalb die Werte manuell erzeugen. Zuerst die Zeichentaste, dann die Steuertaste(n).
  $aKeyCodes = StringSplit("38|10", "|", $STR_NOCOUNT) ; = 8+Shift = DE KB-Layout für "("
;   $aKeyCodes = StringSplit("DB|11|12", "|", $STR_NOCOUNT) ; = ß+AltGr = DE KB-Layout für "\"

  Switch UBound($aKeyCodes)

    Case 1 ; 0 Steuertasten werden benutzt = 3 Steuertasten sind UNBENUTZT = Temp-Array bekäme 3 Items.

      ; Alle 3 UNBENUTZEN Steuertasten fest verdrahten.
      If _IsPressed($aKeyCodes[0]) _
          And Not _IsPressed("10") And Not _IsPressed("11") And Not _IsPressed("12") Then
        $bLeftParenthesisWasPressed = True
        While _IsPressed($aKeyCodes[0])
          Sleep(10)
        WEnd
;         ConsoleWrite("Case 1: " & $aKeyCodes[0] & "  Char: " & Chr(Dec($aKeyCodes[0])) & @CRLF)
      EndIf

    Case 2 ; 1 Steuertaste wird benutzt = 2 Steuertasten sind UNBENUTZT = Temp-Array bekommt 2 Items.

      ; Ermittlung der 2 UNBENUTZEN Steuertasten.
      If $aKeyCodes[1] <> "10" Then _ArrayAdd($aTmpCodes, "10")
      If $aKeyCodes[1] <> "11" Then _ArrayAdd($aTmpCodes, "11")
      If $aKeyCodes[1] <> "12" Then _ArrayAdd($aTmpCodes, "12")

      If _IsPressed($aKeyCodes[0]) And _IsPressed($aKeyCodes[1]) _
          And Not _IsPressed($aTmpCodes[0]) And Not _IsPressed($aTmpCodes[1]) Then
        $bLeftParenthesisWasPressed = True
        While _IsPressed($aKeyCodes[0]) And _IsPressed($aKeyCodes[1])
          Sleep(10)
        WEnd
;         ConsoleWrite("Case 2: " & $aKeyCodes[1] & @CRLF)
      EndIf

    Case 3 ; 2 Steuertasten werden benutzt = 1 Steuertaste ist UNBENUTZT = Temp-Array bekommt 1 Item.

      ; Ermittlung der 1 UNBENUTZEN Steuertaste.
      If ($aKeyCodes[1] <> "10") And ($aKeyCodes[2] <> "10") Then _ArrayAdd($aTmpCodes, "10")
      If ($aKeyCodes[1] <> "11") And ($aKeyCodes[2] <> "11") Then _ArrayAdd($aTmpCodes, "11")
      If ($aKeyCodes[1] <> "12") And ($aKeyCodes[2] <> "12") Then _ArrayAdd($aTmpCodes, "12")

      If _IsPressed($aKeyCodes[0]) And _IsPressed($aKeyCodes[1]) And _IsPressed($aKeyCodes[2]) _
          And Not _IsPressed($aTmpCodes[0]) Then
        $bLeftParenthesisWasPressed = True
        While _IsPressed($aKeyCodes[0]) And _IsPressed($aKeyCodes[1]) And _IsPressed($aKeyCodes[2])
          Sleep(10)
        WEnd
;         ConsoleWrite("Case 3: " & $aKeyCodes[1] & " + " & $aKeyCodes[2] & @CRLF)
      EndIf

    Case 4 ; 3 Steuertasten werden benutzt = 0 Steuertasten sind UNBENUTZT = Temp-Array bekommt 0 Items.

      If _IsPressed($aKeyCodes[0]) And _IsPressed("10") And _IsPressed("11") And _IsPressed("12") Then
        $bLeftParenthesisWasPressed = True
        While _IsPressed($aKeyCodes[0]) And _IsPressed($aKeyCodes[1]) And _IsPressed($aKeyCodes[2])
          Sleep(10)
        WEnd
;         ConsoleWrite("Case 3: " & $aKeyCodes[1] & " + " & $aKeyCodes[2] & @CRLF)
      EndIf
  EndSwitch

  Return $bLeftParenthesisWasPressed
EndFunc ; ==> KeysForLeftParenthesisWerePressed

Alles anzeigen

Edit: Bugs bei der Ermittlung der unbenutzen Steuertasten gefunden und (hoffentlich) behoben.

**Bitnugger** · 16. Februar 2021

Zitat von Professor Bernd

Global Const $User32 = DllOpen("User32.dll")

Wenn du die Dll schon öffnest, warum benutzt du sie dann nicht?

Zitat von Professor Bernd

If _IsPressed($aKeyCodes[0])

If _IsPressed($aKeyCodes[0], $User32) ...

Zitat von Professor Bernd

#include <WinAPISys.au3>

Wofür?

Du prüfst übrigens auch nicht, ob noch weitere Tasten gedrückt sind... z.B. SHIFT + 8 + 9 -->> 10|38|39|A1

Es gibt zudem auch billige Tastaturen, die nicht mehr als 3 Zeichen gleichzeitig verarbeiten können...

Hier mal meine Version:

AutoIt: Bingo.au3

;-- TIME_STAMP   2021-02-16 09:14:13

Opt('MustDeclareVars', 1)

#include <Array.au3>
#include <Misc.au3>

Global Const $User32 = DllOpen("User32.dll")

; =====================================================
; "(" -->> 10|38|A0 -->> $VK_SHIFT + $VK_8 + $VK_LSHIFT
; "(" -->> 10|38|A1 -->> $VK_SHIFT + $VK_8 + $VK_RSHIFT
; =====================================================

_Bingo()

Func _Bingo()
    Local $aPressed[0], $sPressed, $sOldPressed
    ToolTip('Press RSHIFT + 8 or LSHIFT + 8 ...or SHIFT + F1 for Exit', @DesktopWidth / 2 - 150, @DesktopHeight / 2)
    GUICreate('Bingo', 1, 1, -80, -80) ; <<-- GUI muss aktiv sein, damit die Tasteneingaben funktionieren und keinen Unsinn machen!
    GUISetState()
    While 1
        Sleep(10)
        _GetPressedKeys($aPressed)
        If UBound($aPressed) Then
            $sPressed = _ArrayToString($aPressed)
            If StringRegExpReplace($sPressed, '10\|70\|(A0|A1)', '') = '' Then Exit ; SHIFT + F1
            If $sPressed <> $sOldPressed Then
                $sOldPressed = $sPressed
                If $sPressed = '10|38|A1' Or $sPressed = '10|38|A0' Then
                    ConsoleWrite('! Bingo!!!             -->> ' & $sPressed & ($sPressed = '10|38|A1' ? ' (RSHIFT + 8)' : ' (LSHIFT + 8)') & @CRLF)
                ElseIf StringRegExpReplace($sPressed, '10|A0|A1|\|', '') Then
                    ConsoleWrite('> Magst du kein Bingo? -->> ' & $sPressed & @CRLF)
                EndIf
            EndIf
            ReDim $aPressed[0]
        EndIf
    WEnd
EndFunc   ;==>_Bingo

Func _GetPressedKeys(ByRef $aPressed)
    For $i = 1 To 255 Step 1
        If _IsPressed(Hex($i, 2), $User32) Then _ArrayAdd($aPressed, Hex($i, 2))
    Next
EndFunc   ;==>_GetPressedKeys

Alles anzeigen

Professor Bernd · 16. Februar 2021

Zitat von Bitnugger

DllOpen("User32.dll") ...

Wenn du die Dll schon öffnest, warum benutzt du sie dann nicht?

Vielen Dank dafür! Und wieder hast du mich gerettet aus der Betriebsblindheit. Das hätte ich noch 1.000x durchgucken können, ich hätt's nicht gemerkt. - Gut gemacht! Dann sind wir jetzt wieder Freunde!

Spoiler anzeigen

Zitat von Bitnugger

#include <WinAPISys.au3>
Wofür?

Das mache ich um zu sehen, wie aufmerksam du bist!

Zitat von Bitnugger

Du prüfst übrigens auch nicht, ob noch weitere Tasten gedrückt sind... z.B. SHIFT + 8 + 9 -->> 10|38|39|A1

Guter Punkt. Allerdings:

Zitat von Professor Bernd

; Diese Routine prüft, ob die Tasten (1 oder mehrere) gedrückt wurden, die zum
; Schreiben einer öffnenden runden Klammer "(" benötigt werden.

Auf der MS-Seite für "VkKeyScanExW()" steht: "Translates a character to the corresponding virtual-key code and shift state." und für "Return value": "If the function succeeds, the low-order byte of the return value contains the virtual-key code and the high-order byte contains the shift state, which can be a combination of the following flag bits."

Der langen Rede kurzer Sinn: So wie ich es verstehe, wird nur 1 virtueller Key-Code zurückgegeben, was 1 Taste entspricht.

Oder irre ich mich? Wie wahrscheinlich ist es, das es ein KB-Layout gibt, bei dem man mehere Zeichen-Tasten drückt um "(" zu schreiben? (Geht das überhaupt?)

Zitat von Bitnugger

Es gibt zudem auch billige Tastaturen, die nicht mehr als 3 Zeichen gleichzeitig verarbeiten können...

Das sind meine Freunde, denn denen geht es wie mir!

Deinen Code habe ich kurz durchgesehen. Der scheint wie immer sehr interessant zu sein! Ich bin erst heute abend wieder zu hause, dann werde ich ihn mir zu Gemühte führen.

Professor Bernd · 16. Februar 2021

Zitat von Professor Bernd

Wenn ich wüsste wie, würde ich folgendes programmieren:

If _IsPressed(Zeichentaste) And _IsPressed(Steuertasten) And Not _IsPressed(AndereTasten) Then

Interessante Sache, dein Code. Beim Durchlaufen der 255 KeyCodes mit _IsPressed() könnte fast meinen, du hättest das im Zitat als Vorgabe genommen. Wenn ich das richtig verstehe, macht es genau das, was dort beschrieben wird: Es prüft, ob die gesuchten Tasten gedrückt sind und ob alle anderen Tasten nicht gedrückt sind.

Für wie performant hältst du das ständige Abfragen von 255 Tasten?

**Bitnugger** · 17. Februar 2021

Ja, das Zitat habe ich als Vorgabe genommen... anders macht es doch auch keinen Sinn... denn SHIFT + 8 + 9 ist ja nicht SHIFT + 8, wobei es bei der Auswertung natürlich auf die Reihenfolge ankommt, in der die Tasten gedrückt wurden... hätte wohl besser SHIFT + 9 + 8 schreiben sollen... denn da darf dann kein "Bingo" kommen!

Switch...Case...EndSwitch ist übrigens um einiges schneller als For...To...Step...Next... damit könnten die nicht relevanten Tasten (Umschalttasten (Toggle-Keys), z.B. CAPS LOCK ($VK_CAPITAL)) dann auch ohne Mehraufwand ausgelassen werden... Switch benötigt allerdings deutlich mehr Code.

Zitat von Professor Bernd

Für wie performant hältst du das ständige Abfragen von 255 Tasten?

Das nennt sich Polling... und das ist nur in sehr seltenen Fällen eine gute Wahl... doch zu unserem Glück bietet uns Windows ja Message-Handler an, die man registrieren kann, um zu erfahren ob eine Taste gedrückt oder losgelassen wurde... das ist performant!

Davon bräuchtest du dann (mindestens) folgende: WM_KEYDOWN, WM_SYSKEYDOWN, WM_KEYUP und WM_SYSKEYUP

Bsp.:

GUIRegisterMsg($WM_KEYDOWN, 'WM_KEYDOWN')

GUIRegisterMsg($WM_SYSKEYDOWN, 'WM_KEYDOWN') ; *¹

GUIRegisterMsg($WM_KEYUP, 'WM_KEYUP')

GUIRegisterMsg($WM_SYSKEYUP, 'WM_KEYUP') ; *¹

*¹ Kann man natürlich auch in eigene Funktionen umleiten, ist aber nicht nötig.

In der Funktion WM_KEYDOWN fügst du die gedrückte Taste deinem Array *² hinzu, in der Funktion WM_KEYUP löscht du die losgelassene Taste (falls vorhanden) wieder aus dem Array.

*² Array evtl. sortieren, um die Auswertung zu vereinfachen.

Die (255) Tasten müssen dann nicht mehr überprüft werden... und falls doch, dann nur bei einem KEYDOWN-Event... was evtl. besser mit _WinAPI_GetKeyboardState in einem Rutsch gemacht werden sollte, als 255 mal _IsPressed (_WinAPI_GetAsyncKeyState) aufzurufen.

Ich habe dafür bereits ein fast fertiges Script, in dem das zu verwendende Tastaturlayout beliebig umgestellt werden kann... getestet habe ich mit de-DE, en-EN und fr-FR... und es funktioniert!

Es dauert aber noch etwas, bis ich es fertig habe... bin mom. nicht in Form... starke Kopfschmerzen... schätze mal bis zum WE.

Was mich allerdings interessieren würde... gibt es auch eine (Dll-)Funktion, mit der ich beim Drücken von z.B. SHIFT + 8 aus den VkCodes ($wParam) das auszugebende Zeichen "(" ermitteln kann?

Bsp. Send("("):

"(" -->> 10|38|A0 -->> $VK_SHIFT + $VK_8 + $VK_LSHIFT

"(" -->> 10|38|A1 -->> $VK_SHIFT + $VK_8 + $VK_RSHIFT

10|38|A0 -->> $VK_SHIFT + $VK_8 + $VK_LSHIFT -->> "(" ?

10|38|A1 -->> $VK_SHIFT + $VK_8 + $VK_RSHIFT -->> "(" ?

Alternativ zu den Message-Handlern ginge es auch mit _WinAPI_SetWindowsHookEx...

Professor Bernd · 17. Februar 2021

Bevor wir uns der Erkennung zuwenden, ob ein "(" eingegeben wurde, erstmal ein Status-Update.

Bis hierhin ist das eigentliche Thema dieses Thread zu meiner Zufriedenheit geklärt: "_IsPressed() Abfrage strukturieren/verbessern". Deine Infos waren eine große Hilfe: In meinem Code wurde der Bug entdeckt, dass "User32.dll" in "_IsPressed()" NICHT verwedet wurde und du hast einige nützliche Erklärungen geschrieben, z.B. zur Auswertung der gedrückten Tasten per Stringvergleich, zu Polling, Select..Case, uvm.

Unwichtige Frage zu Polling

Und nun lass uns meinen Thread kapern!

----------- schnipp ----------------------------------------------------------------------------------------------------

Falls das Nachfolgende umfangreicher wird, kann ich später einen anderen Thread dafür erstellen.

----------- schnapp ----------------------------------------------------------------------------------------------------

In diesem Thread ging es um die Verbesserung der _IsPressed Abfrage aus Posting #1. Diese Abfrage erfolgt erst nach der Erkennung, ob die Tasten für "(" gedrückt wurden. Und natürlich ist es in erster Linie interessant, diese Erkennung zu verbessern.

Wie kann man in einem fremden Fenster erkennen, ob vom User Tasten gedrückt wurden, die dort eine öffnende runde Klammer "(" ergeben?

Hier im Forum hatte ich die Möglichkeit erörtert, mit "VkKeyScanEx()" zu ermitteln, welche Tasten benötigt werden um "(" im fremden Fenster zu schreiben und diese Tasten dann ständig systemweit abzufragen. Das ergab einen Workaround, der brauchbar funktioniert. Aber er hat auch Schwächen, wie du geschrieben hast, ob z.B. die ~~Umschalttaste~~ Edit: gemeint ist Feststelltaste (Caps Lock) gedrückt ist u.ä.

Message-Handler

Dann hast du die Frage aller Fragen gestellt:

Zitat von Bitnugger

Was mich allerdings interessieren würde... gibt es auch eine (Dll-)Funktion, mit der ich beim Drücken von z.B. SHIFT + 8 aus den VkCodes ($wParam) das auszugebende Zeichen "(" ermitteln kann?

Das war vor Monaten für mich die erfolgsversprechendste Herangehensweise, ... die ich leider nicht lösen konnte. Es wäre im Prinzip so einfach: Man prüft, ob die gedrückten Tasten im fremden Fenster (mit dessen KB-Layout) ein "(" schreiben. - Das Prinzip ist einfach, aber die Umsetzung ist mir nicht gelungen.

Nach einigen fehlgeschlagenen Tests hatte ich die Erkennung der Tastatur-Codes per Windows-Message-Hook erstellt, um die Tasten zu erkennen, die im fremden Fenster gedrückt wurden. Damit könnte man in einem eigenen Fenster das KB-Layout des fremden Fensters einstellen und prüfen, wann ein "(" ankommt. Leider weiß ich bis heute nicht, wie man diese Messages "verdoppeln" kann, sodass man sie zum einen an das fremde Fenster durchreichen und zum anderen in einem eigenen Fenster auswerten kann. UND es darf natürlich nicht zu einer Endlosschleife im Msg-Hook führen!

Wie könnte man das bewerkstelligen?

**BugFix** · 17. Februar 2021

Das Problem liegt im vkCode. Dieser enthält nunmal keine layoutspezifischen Werte, sondern ist für jedes Layout identisch.

Man muss sich den "Werdegang" eines Zeichens vom Drücken der Taste bis zum Erscheinen im Edit etc. mal genauer ansehen:

- Tastendruck - Auslösen eines Hardware-Interupts, Scancode (Tastenposition) wird gelesen. Der Scancode gibt nur die Position der gedrückten Taste für eine Standardtastatur an, unabhängig von der Anordnung, der Sprache des BS oder der Tastenbeschriftung.

- Der Scancode wird vom System in den vkCode übersetzt, dem die ASCII-Zeichen zugrunde liegen

Bis hier ist das LowLevel - was wir z.B. mit _IsPressed() abfragen. -- Also sind wir da eigentlich falsch, denn das sagt uns noch nichts über das tatsächlich im Editor ankommende Zeichen, nur über die gedrückte Taste.

- Weiter gehts mit der System-Message WM_CHAR. Hier wird aus vkCode und Layout das letztlich gewünschte Zeichen an die Anwendung gesendet. Somit sollte der Ansatz sein, diese Message auszuwerten.

Da wir dann aber nicht mehr LowLevel sind, hat das auch ein paar zu beachtende Punkte:

Wir können nicht einfach auf WM_CHAR warten, sondern müssen mit GetMessage() vom Message-Queue abfragen.

Die Nachricht ist an ein Fenster gebunden, dessen Handle ich angeben muss. Alle evtl. zu berücksichtigenden Fenster müssen zu einem Prozess gehören.

Somit ist eine systemweite Abfrage eines Zeichens wohl nicht realisierbar.

P.S.

Ist mir gerade noch eingefallen: Bei der Abfrage eines mit Shift generierten Zeichens muss der Vollständigkeit halber immer auch Capslock abgefragt werden.

Professor Bernd · 17. Februar 2021

Dein Ansatz hört sich gut an.

Zitat von BugFix

Somit ist eine systemweite Abfrage eines Zeichens wohl nicht realisierbar.

Das ist bei deinem Ansatz vielleicht gar nicht nötig, denn es geht ja um ein bestimmtes Fenster (das aktive PSPad-Fenster).

Zitat von BugFix

Die Nachricht ist an ein Fenster gebunden, dessen Handle ich angeben muss.

Wie gesagt, aktives PSPad-Fenster. Wenn man einen Hook auf dieses Fenster setzen könnte und dort den VkCode und den ShiftState (die Flags?) erhalten könnte, bräuchte man sie "nur noch" an eine eigenes Edit weiterzuleiten. Das eigene Edit bekommt das gleiche KB-Layout verpasst wie das PSPad-Fenster. Wenn das klappen würde, bräuchte man hier nur noch zu prüfen, ob ein "(" im eigenen Edit erscheint.

**BugFix** · 17. Februar 2021

Ich habe mal versucht, die Nachricht abzugreifen, bevor die Msg-Queue Verarbeitung beginnt.

M. M. n. ist das vom Code her korrekt, jedoch erhalte ich ausschliesslich die Messages: WM_TIMER und WM_HOTKEY (beim Beenden) . Das lässt mich etwas ratlos zurück.

Aber vielleicht hilft es dir als Ansatz.

AutoIt

#cs
https://docs.microsoft.com/en-us/windows/win32/inputdev/wm-char
https://www.codeproject.com/Articles/50397/System-Wide-Hooking-for-the-WM-CHAR-Message
https://docs.microsoft.com/en-us/windows/win32/api/winuser/ns-winuser-msg

#ce
#include <WinAPISys.au3>
#include <WinAPIConstants.au3>
#include <WinAPIError.au3>
#include <WinAPIProc.au3>
#include <WinAPIConv.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)
OnAutoItExitRegister("_CharHookOf")

HotKeySet('^!{F7}', '_Exit') ; Strg+Alt+F7 zum Beenden

Global $g_hMsgProc, $g_hMod, $g_hHook

_CharHookOn()


While True
    Sleep(20)
WEnd


Func _Exit()
    Exit
EndFunc

Func _CharHookOn()
    $g_hMsgProc = DllCallbackRegister("_MsgProc", "long", "int;wparam;lparam")
    $g_hMod = _WinAPI_GetModuleHandle(0)
    $g_hHook = _WinAPI_SetWindowsHookEx($WH_GETMESSAGE, DllCallbackGetPtr($g_hMsgProc), $g_hMod, _WinAPI_GetCurrentThreadId())
    If $g_hHook = 0 Then Exit ConsoleWrite(_WinAPI_GetLastErrorMessage() & @CRLF)
EndFunc

Func _CharHookOf()
    _WinAPI_UnhookWindowsHookEx($g_hHook)
    DllCallbackFree($g_hMsgProc)
EndFunc

Func _MsgProc($_nCode, $_wParam, $_lParam)
    If $_nCode < 0 Then Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
    Local $tMSG = DllStructCreate('hwnd hwnd;uint message;wparam wParam;lparam lParam;dword time;struct;long x;long y;endstruct;dword lPrivate;', $_lParam)

Local $sMsg = $tMSG.message = 0x0113 ? 'WM_TIMER' : ($tMSG.message = 0x0312 ? 'WM_HOTKEY' : '0x' & Hex($tMSG.message, 4))
ConsoleWrite('MSG: ' & $sMsg & _
            ' Time: [' & _WinAPI_StrFromTimeInterval($tMSG.time)  & '],' & _
            ' x: ' & $tMSG.x & ', y: ' & $tMSG.y & _
            ', hWnd: ' & $tMSG.hwnd & _
            ', lParam: ' & $tMSG.lParam & _
            ', lPrivate: ' & $tMSG.lPrivate & @CRLF)

    ; only work with message: $WM_CHAR
    If $tMSG.message <> $WM_CHAR Then Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
    ; wParam from MSG struct is the character code of the pressed key
    Local $charCode = $tMSG.wParam
    ConsoleWrite('CharCode: ' & $charCode & @CRLF)

    Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
EndFunc

Alles anzeigen

Professor Bernd · 17. Februar 2021

Mir gehts ähnlich! Probiere seit Stunden - habe das hier gefunden. Das ist das Einzigste, das überhaupt was erreicht: 1 Zeichen im eigenen Edit, aber kein Shift, ... Caps Lock, ... nichts. Ich habs mal quick & dirty in einen Code von dir reingehauen. Meine vergeblichen Versuche habe ich als Kommentare drin gelassen.

AutoIt

;===================================================================================================
;     Bsp. Auto-Ersetzen mit Hook
;   Umlaute und ß
;   linke Shift ergibt z.B. Ae, rechte Shift und CapsLock ergibt AE
;   Ä- Ae (AE)      ä - ae
;   Ö- Oe (OE)      ö - oe
;   Ü- Ue (UE)      ü - ue
;                   ß - ss (SS mit RSHIFT)
;===================================================================================================

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include "VKCodeConstants.au3"

OnAutoItExitRegister("_KeyHookOf")

HotKeySet('^!{F7}', '_Exit') ; Strg+Alt+F7 zum manuellen Beenden

Global $g_procPSPad = "PSPad.exe"
Global $g_classPSPad = "TfPSPad"
Global $g_editPSPad = "TPSSynEdit1"
Global $g_hPSPad, $g_hActive
Global $g_bPSPadActive = False, $g_bEditActive = False
Global $g_hKeyProc, $g_hMod, $g_hHook
Global $g_bLShift = False, $g_bRShift = False, $g_bLCtrl = False, $g_bRCtrl = False
Global $g_user32 = DllOpen("user32.dll")
Global $g_bDebug = True

Global $hGui = GUICreate("Beispiel", 300, 200, 10, 80)
Global $idOK1 = GUICtrlCreateButton("OK", 310, 370, 85, 25)
Global $Edt1 = GUICtrlCreateEdit("", 10, 10, 200, 100)
Global $Edt1 = GUICtrlCreateLabel("PSPad öffnen und Zeichen eintippen.", 10, 120, 200, 44)

; Zeigt die GUI
GUISetState(@SW_SHOW, $hGui)

Global $hEdit1 = ControlGetHandle($hGui, "", "Edit1")

; Starte Tastatur-Hook
_KeyHookOn()

While True
  If ProcessExists($g_procPSPad) Then
    $g_hPSPad = WinGetHandle(StringFormat("[CLASS:%s]", $g_classPSPad))
  Else
    $g_hPSPad = 0
  EndIf
  $g_hActive = WinGetHandle("[ACTIVE]")
  $g_bPSPadActive = ($g_hActive = $g_hPSPad)
  Sleep(10)
WEnd

Func _Exit()
  Exit
EndFunc   ;==>_Exit

Func _KeyHookOn()
  ; Registrieren der Funktion "_KeyProc" als Callback
  $g_hKeyProc = DllCallbackRegister("_KeyProc", "long", "int;wparam;lparam")

  ; Installieren einer eigenen Prozedur zur Verarbeitung der Tastaturereignisse
  $g_hMod = _WinAPI_GetModuleHandle(0)
  $g_hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($g_hKeyProc), $g_hMod)
EndFunc   ;==>_KeyHookOn

Func _KeyHookOf()
  ; Entfernen der eigenen Key-Prozedur
  _WinAPI_UnhookWindowsHookEx($g_hHook)
  DllCallbackFree($g_hKeyProc)
  ; Dll Handle schliessen
  DllClose($g_user32)
EndFunc   ;==>_KeyHookOf

Func _KeyProc($_nCode, $_wParam, $_lParam)
  Local Const $KEYEVENTF_KEYUP = 0x0002
  Local $tKEYHOOKS, $vkCode, $scanCode, $extKeyFlags, $timeStamp, $dwExtraInfo
  Local $ret, $bCapsLock = False
  $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $_lParam)

  ; kommen Events vom Editor, wenn NEIN --> verlassen
  If $_nCode < 0 Or Not $g_bPSPadActive Then Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)

  ; hat das Editorfeld von PSPad den Focus, wenn NEIN --> verlassen
  If ControlGetFocus($g_hPSPad) <> $g_editPSPad Then Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)

  ; Auslesen Struktur
  $vkCode = $tKEYHOOKS.vkCode
  $scanCode = $tKEYHOOKS.scanCode
  $extKeyFlags = $tKEYHOOKS.flags
  $timeStamp = $tKEYHOOKS.time
  $dwExtraInfo = $tKEYHOOKS.dwExtraInfo

  ; Auswerten "flags"
  Local $bExtKey = (BitAND($tKEYHOOKS.flags, $LLKHF_EXTENDED) = $LLKHF_EXTENDED)
  Local $bEvtInjected = (BitAND($tKEYHOOKS.flags, $LLKHF_INJECTED) = $LLKHF_INJECTED)
  Local $bAltDown = (BitAND($tKEYHOOKS.flags, $LLKHF_ALTDOWN) = $LLKHF_ALTDOWN)

  Local Static $aSign[] = ['-', '+']
  Local Static $iSwap = 0
  If $g_bDebug Then
    $iSwap = Abs($iSwap - 1)
    ConsoleWrite($aSign[$iSwap] & ($_wParam = $WM_KEYDOWN ? ' KEYDOWN' : ' KEYUP') & @CRLF)
    ConsoleWrite(StringFormat("%s Time: %s | vkCode: 0x%s | CodeName: %s | ScanCode: %3s | KeyFlags: 0x%s | ", $aSign[$iSwap], $timeStamp, Hex($vkCode, 2), _VKCodeName($vkCode), $scanCode, Hex($extKeyFlags, 4)))
    ConsoleWrite(StringFormat("ExtendeKey: %5s | EventInjected: %5s | AltDown: %5s\n", $bExtKey, $bEvtInjected, $bAltDown))
  EndIf

  ; Tastaturereignisse auswerten
  ; auf Ereignis "Taste gedrückt" reagieren
  If $_wParam = $WM_KEYDOWN Then



;     _SendMessage($hEdit1, $_nCode, $_wParam, $_lParam)
;     _SendMessage($hEdit1, $WM_SETTEXT, $_wParam, DllStructGetPtr($tKEYHOOKS))  ; <== setzt 1 Zeichen OHNE ShiftState
    _SendMessage($hEdit1, $WM_SETTEXT, $_wParam, $_lParam) ; <== setzt 1 Zeichen OHNE ShiftState

;     _SendMessage($hEdit1, $WM_KEYDOWN, $VK_LSHIFT, 0)
;     _SendMessage($hEdit1, $WM_KEYDOWN, $_lParam, 0)
;     _SendMessage($hEdit1, $WM_KEYUP, $_lParam, 0)
;     _SendMessage($hEdit1, $WM_KEYUP, $VK_LSHIFT, 0)

;     _SendMessage($hEdit1, $WM_KEYDOWN, $VK_LSHIFT, 0)
;     _SendMessage($hEdit1, $WM_SYSCOMMAND, $_wParam, $_lParam) ; <== setzt 1 Zeichen OHNE ShiftState
;     _SendMessage($hEdit1, $WM_KEYUP, $VK_LSHIFT, 0)

;     _SendMessage($hEdit1, $WM_KEYDOWN, $VK_LSHIFT, $_lParam)
;     _SendMessage($hEdit1, $WM_KEYUP, $VK_LSHIFT, $_lParam)

    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $_wParam = ' & $_wParam & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console



    ; Auswerten Status Capslock
    $ret = DllCall($g_user32, "long", "GetKeyState", "long", $VK_CAPITAL)
    If $ret[0] Then $bCapsLock = True

    Switch $vkCode
      Case $VK_LSHIFT
        $g_bLShift = True
        If $g_bDebug Then ConsoleWrite(StringFormat("%s LShift: %s\n", $aSign[$iSwap], $g_bLShift) & @CRLF)
      Case $VK_RSHIFT
        $g_bRShift = True
        If $g_bDebug Then ConsoleWrite(StringFormat("%s RShift: %s\n", $aSign[$iSwap], $g_bRShift) & @CRLF)
      Case $VK_LCONTROL
        $g_bLCtrl = True
        If $g_bDebug Then ConsoleWrite(StringFormat("%s LCtrl: %s\n", $aSign[$iSwap], $g_bLCtrl) & @CRLF)
      Case $VK_RCONTROL
        $g_bRCtrl = True
        If $g_bDebug Then ConsoleWrite(StringFormat("%s RCtrl: %s\n", $aSign[$iSwap], $g_bRCtrl) & @CRLF)
      Case $VK_OEM_1       ; ü ==> ue
        _keybd_event($VK_U)
        If $g_bLShift Then _keybd_event($VK_LSHIFT, $KEYEVENTF_KEYUP)          ; Shift-Taste lösen
        _keybd_event($VK_E)
        Return -1                 ; verhindert, dass ursprüngliche Nachricht an das System weitergegeben wird
      Case $VK_OEM_3       ; ö ==>oe
        _keybd_event($VK_O)
        If $g_bLShift Then _keybd_event($VK_LSHIFT, $KEYEVENTF_KEYUP)
        _keybd_event($VK_E)
        Return -1
      Case $VK_OEM_4       ; ß ==> ss - nicht ausführen, wenn LShift/Capslock aktiv, mit RShift ==> SS
        If ($g_bLShift Or $bCapsLock) Then Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
        _keybd_event($VK_S)
        _keybd_event($VK_S)
        Return -1
      Case $VK_OEM_7       ; ä ==> ae
        _keybd_event($VK_A)
        If $g_bLShift Then _keybd_event($VK_LSHIFT, $KEYEVENTF_KEYUP)
        _keybd_event($VK_E)
        Return -1
    EndSwitch
  ElseIf $_wParam = $WM_KEYUP Then
    Switch $extKeyFlags
      Case 0x80, 0x81       ; 0x80= UP für 'normale' Tasten u. li. paarige,  0x81= UP für paarige und rechte (Pos, End, PgUp,...)
        Switch $vkCode
          Case $VK_LSHIFT
            $g_bLShift = False
          Case $VK_RSHIFT
            $g_bRShift = False
          Case $VK_LCONTROL
            $g_bLCtrl = False
          Case $VK_RCONTROL
            $g_bRCtrl = False
        EndSwitch
    EndSwitch
  EndIf
  Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
EndFunc   ;==>_KeyProc

; vkCodes: https://docs.microsoft.com/de-de/windows/win32/inputdev/virtual-key-codes
Func _keybd_event($_vkCode, $_iFlag = 0)
  Local Const $KEYEVENTF_EXTENDEDKEY = 0x0001
  DllCall($g_user32, 'int', 'keybd_event', 'int', $_vkCode, 'int', 0, 'int', BitOR($KEYEVENTF_EXTENDEDKEY, $_iFlag), 'ptr', 0)
  ;     _SendMessage(
EndFunc   ;==>_keybd_event

Alles anzeigen

Es muss doch irgendwie möglich sein, die (Keyboard-)Messages von PSPad 1:1 in ein AutoIt-Edit zu kopieren. Dann bräuchte man sich nicht um ShiftStates, Caps Lock oder zusätzlich gedrückten Tasten zu kümmern.

Übrigens: Bei der Gelegenheit sei erwähnt, es wäre eine (einfachere?) Möglichkeit, den Text am Caret in PSPad auszulesen und auf "(" zu prüfen. ABER: Das Textauslesen ist mir bisher noch nicht gelungen. Das SynEdit (= Editor-Control von PSPad) erlaubt manchmal das Auslesen von einigen Zeilen Text, aber dann ohne ersichtlichen Grund kommen nur noch chinesische Zeichen. Falls jemand weiß, wie man den Text am Caret in PSPad zuverlässig auslesen kann, wäre das auch eine Lösung!

**Bitnugger** · 18. Februar 2021

Zitat von BugFix

M. M. n. ist das vom Code her korrekt, jedoch erhalte ich ausschliesslich die Messages: WM_TIMER und WM_HOTKEY (beim Beenden) .

Vermute mal, es liegt daran...

$pProc Pointer to the hook procedure. If the $iThreadId parameter is zero or specifies the identifier of a thread created by a different process, the $pProc parameter must point to a hook procedure in a DLL. Otherwise, $pProc can point to a hook procedure in the code associated with the current process

Evtl. lässt sich das Problem hiermit lösen: https://www.autoitscript.com/f…-global-setwindowshookex/

**Bitnugger** · 18. Februar 2021

Mit selbst erstellten Fenstern geht es... WM_TIMER & WM_HOTKEY & WM_KEYDOWN & WM_KEYUP & WM_CHAR

AutoIt

;-- TIME_STAMP   2021-02-18 02:19:06

#cs
https://docs.microsoft.com/en-us/windows/win32/inputdev/wm-char
https://www.codeproject.com/Articles/50397/System-Wide-Hooking-for-the-WM-CHAR-Message
https://docs.microsoft.com/en-us/windows/win32/api/winuser/ns-winuser-msg

#ce
#include <Array.au3>
#include <WinAPISys.au3>
#include <WinAPIConstants.au3>
#include <WinAPIError.au3>
#include <WinAPIProc.au3>
#include <WinAPIConv.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)
OnAutoItExitRegister("_CharHookOf")

HotKeySet('^!{F7}', '_Exit') ; Strg+Alt+F7 zum Beenden

Global $g_hMsgProc, $g_hMod, $g_hHook

; Hier geht nur WM_TIMER & WM_HOTKEY.
Run("notepad.exe")
WinWait("[CLASS:Notepad]")

; Hier geht alles... WM_TIMER & WM_HOTKEY & WM_KEYDOWN & WM_KEYUP & WM_CHAR
Global $g_hGUI = GUICreate('Input', 200, 24, -1, -1, -1, $WS_EX_TOPMOST)
GUICtrlCreateInput('', 0, 0, 200, 24)
GUISetState()

_CharHookOn()

;~ While True
;~     Sleep(20)
;~ WEnd

Do
Until GUIGetMsg() = -3 ; $GUI_EVENT_CLOSE

Func _Exit()
    Exit
EndFunc

Func _CharHookOn()
    $g_hMsgProc = DllCallbackRegister("_MsgProc", "long", "int;wparam;lparam")
    $g_hMod = _WinAPI_GetModuleHandle(0)
    $g_hHook = _WinAPI_SetWindowsHookEx($WH_GETMESSAGE, DllCallbackGetPtr($g_hMsgProc), $g_hMod, _WinAPI_GetCurrentThreadId())
    If $g_hHook = 0 Then Exit ConsoleWrite(_WinAPI_GetLastErrorMessage() & @CRLF)
EndFunc

Func _CharHookOf()
    _WinAPI_UnhookWindowsHookEx($g_hHook)
    DllCallbackFree($g_hMsgProc)
EndFunc

Func _MsgProc($_nCode, $_wParam, $_lParam)
    If $_nCode < 0 Then Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)

    Local Static $aOldHook[2]
    Local $sHook, $iMsg, $sMsg, $charCode = @CRLF, $tMSG = DllStructCreate('hwnd hwnd;uint message;wparam wParam;lparam lParam;dword time;struct;long x;long y;endstruct;dword lPrivate;', $_lParam)

    $sHook = $iMsg & $tMSG.hwnd & $tMSG.wParam & $tMSG.lParam

    $iMsg = $tMSG.message

    Switch $iMsg
        Case $WM_TIMER
            Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
            $sMsg = '- WM_TIMER  '
        Case $WM_HOTKEY
            $sMsg = '- WM_HOTKEY '
        Case $WM_KEYDOWN
            If $sHook = $aOldHook[0] Then Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
            $aOldHook[0] = $sHook
            $sMsg = '> WM_KEYDOWN'
        Case $WM_KEYUP
            $sMsg = '> WM_KEYUP  '
        Case $WM_CHAR
            If $sHook = $aOldHook[1] Then Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
            $aOldHook[1] = $sHook
            ; only work with message: $WM_CHAR
            ; wParam from MSG struct is the character code of the pressed key
            $sMsg = '! WM_CHAR   '
            $charCode = ', CharCode: ' & $tMSG.wParam & ' "' & ChrW($tMSG.wParam) & '"' & @CRLF
;~         Case True
;~             $sMsg = 'Other '
        Case Else
            Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
    EndSwitch

    $sMsg &= _
        ' $iMsg: 0x' & Hex($iMsg, 4) & _
        ', hWnd: ' & $tMSG.hwnd & _
        ', wParam: ' & $tMSG.wParam & _
        ', lParam: ' & $tMSG.lParam & _
        ', Time: [' & _WinAPI_StrFromTimeInterval($tMSG.time)  & ']' & _
        ' x: ' & $tMSG.x & ', y: ' & $tMSG.y & _
        ', lPrivate: ' & $tMSG.lPrivate & _
        $charCode
    ConsoleWrite($sMsg)

    Return _WinAPI_CallNextHookEx($g_hHook, $_nCode, $_wParam, $_lParam)
EndFunc

Alles anzeigen

Professor Bernd · 18. Februar 2021

Zitat von BugFix

Local $sMsg = $tMSG.message = 0x0113 ? 'WM_TIMER' : ($tMSG.message = 0x0312 ? 'WM_HOTKEY' : '0x' & Hex($tMSG.message, 4))

Ähem, ... ist das hier eine 256 Bit Verschlüsselung?

Professor Bernd · 22. Februar 2021

Leute, ich werd' noch wahnsinnig! Ich krieg es einfach nicht hin, in der Erkennung den "Caps Lock" und "drücken zusätzlicher Zeichen" (z.B. Shift+8+9) zu verarbeiten.

Ich denke, der Ansatz ist einfach ungeeignet, die Tastatur-Eingabe zu prüfen um zu erkennen, ob der User in PSPad ein "(" schreibt. Der bessere Ansatz wäre wahrscheinlich, das was in PSPad geschrieben wird in ein eigenes (Edit-)Control zu verdoppeln/kopieren und dort zu prüfen, ob das letzte Zeichen ein "(" ist.

- Vielleicht werde ich einen anderen Thread aufmachen.

Professor Bernd · 23. Februar 2021

Hier ist mein überarbeiteter Workaround (basiert auf dem Code in Posting #1), der lediglich einige Fälle prüft, aber bei weitem NICHT alles abfängt. So wird z.B. NICHT geprüft, ob eine weitere Zeichentaste gedrückt wird, z.B. Shift+7+8. Könnt ihr bitte mal reingucken, ob meine Logik stimmt, ob man das eleganter lösen kann und ob Bugs drin sind?

AutoIt

#include <Array.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <WinAPISys.au3>

Global Const $User32 = DllOpen("User32.dll")

Example()

DllClose($User32)

Func Example()
  While 1
    Sleep(10)

    If KeysForLeftParenthesisWerePressed() Then
      MsgBox($MB_SYSTEMMODAL, "", "'(' wurde eingegeben")
      ConsoleWrite("'(' wurde eingegeben" & @CRLF)
    EndIf

    ; -------------------------------
    ; Zum Abbrechen Shift+F1 drücken!
    ; -------------------------------
    If _IsPressed("10", $User32) And _IsPressed("70", $User32) Then ExitLoop
  WEnd
EndFunc


; ==============================================================================
; KeysForLeftParenthesisWerePressed
;
; Diese Routine prüft, ob die Tasten (1 oder mehrere) gedrückt wurden, die zum
; Schreiben einer öffnenden runden Klammer "(" benötigt werden.
;
; Hint: Die Routine pausiert die weitere Ausführung des Scripts, bis die
;       o.g. Tasten NICHT mehr gedrückt sind!
;
;       Das heißt, wenn alle benötigte Tasten gedrückt sind, wird eine
;       Schleife gestartet, die solange läuft, bis min. 1 der Tasten NICHT
;       mehr gedrückt ist. Erst danach wird das Script weiter ausgeführt.
;
; Wichtig: Dies ist nur ein Workaround, der lediglich einige Fälle prüft, aber
;          bei weitem NICHT alles abfängt. So wird z.B. NICHT geprüft, ob eine
;          weitere Zeichentaste gedrückt wird, z.B. Shift+7+8. 2021-02-23.
;
; Rückgabe: True  = Tasten für linke öffnende Klammer wurden gedrückt.
;           False = Tasten für linke öffnende Klammer wurden NICHT gedrückt.
; ------------------------------------------------------------------------------
Func KeysForLeftParenthesisWerePressed()

  Local $aKeyCodes, $aTmpCodes[0]
  Local $bLeftParenthesisWasPressed = False

;   $aKeyCodes = GetKeyCodesForLeftParenthesis()
;   ;   [0]:   Enthält den virtuellen KeyCode der Zeichentaste als Hex-Wert, den
;   ;          man z.B. in _IsPressed() benutzen kann.
;   ;
;   ; [1]-[3]: Enthalten die virtuellen KeyCodes der Steuertasten "Shift", "Ctrl"
;   ;          und "Alt" als Hex-Wert, den man z.B. in _IsPressed() benutzen kann.
;   ;
;   ; Die Items 1-3 sind optional, das heißt, das Array kann 1 - 4 Items enthalten.

  ; Zum Testen ist die Funktion "GetKeyCodesForLeftParenthesis()" NICHT verfügbar.
  ; Deshalb hier Test-Werte manuell erzeugen. Zuerst die Zeichentaste, dann die Steuertaste(n).
  $aKeyCodes = StringSplit("38|10", "|", $STR_NOCOUNT) ; = 8+Shift = DE KB-Layout für "("
;   $aKeyCodes = StringSplit("35", "|", $STR_NOCOUNT) ; = 5 = FR KB-Layout für "("
;   $aKeyCodes = StringSplit("DB|11|12", "|", $STR_NOCOUNT) ; = ß+AltGr = DE KB-Layout für "\"

  ; Ermitteln, ob die Feststelltaste "ein" ist.
  Local $bCapsLockOn = (BitAND(_WinAPI_GetKeyState(0x14), 1) = 1)

  Switch UBound($aKeyCodes)

    Case 1 ; 0 Steuertasten werden benutzt = 3 Steuertasten sind UNBENUTZT = Temp-Array bekäme 3 Items.
          ; Beispiel: 5 (franz. KB-Layout)

      ; Statt Temp-Array alle 3 UNBENUTZEN Steuertasten "fest verdrahten" als "10", "11" und "12".
      If _IsPressed($aKeyCodes[0], $g_hDLL) And $bCapsLockOn And _IsPressed("10", $g_hDLL) _
          And Not _IsPressed("11", $g_hDLL) And Not _IsPressed("12", $g_hDLL) Then
        $bLeftParenthesisWasPressed = True
        While _IsPressed($aKeyCodes[0], $g_hDLL) And $bCapsLockOn And _IsPressed("10", $g_hDLL)
          Sleep(10)
        WEnd
;         ConsoleWrite("Case 1: " & $aKeyCodes[0] & "  Char: " & Chr(Dec($aKeyCodes[0])) & @CRLF)
      ElseIf _IsPressed($aKeyCodes[0], $g_hDLL) And Not $bCapsLockOn And Not _IsPressed("10", $g_hDLL) _
          And Not _IsPressed("11", $g_hDLL) And Not _IsPressed("12", $g_hDLL) Then
        $bLeftParenthesisWasPressed = True
        While (_IsPressed($aKeyCodes[0], $g_hDLL)
          Sleep(10)
        WEnd
;         ConsoleWrite("Case 1: " & $aKeyCodes[0] & "  Char: " & Chr(Dec($aKeyCodes[0])) & @CRLF)
      EndIf

    Case 2 ; 1 Steuertaste wird benutzt = 2 Steuertasten sind UNBENUTZT = Temp-Array bekommt 2 Items.
           ; Beispiel: 8+Shift (deu. KB-Layout).

      ; Ermittlung der 2 UNBENUTZEN Steuertasten.
      If $aKeyCodes[1] <> "10" Then _ArrayAdd($aTmpCodes, "10")
      If $aKeyCodes[1] <> "11" Then _ArrayAdd($aTmpCodes, "11")
      If $aKeyCodes[1] <> "12" Then _ArrayAdd($aTmpCodes, "12")

      If $aKeyCodes[1] = "10" And $bCapsLockOn Then
        If _IsPressed($aKeyCodes[0], $User32) _
            And Not _IsPressed($aKeyCodes[1], $User32) And Not _IsPressed($aTmpCodes[0], $User32) And Not _IsPressed($aTmpCodes[1], $User32) Then
          $bLeftParenthesisWasPressed = True
          While _IsPressed($aKeyCodes[0], $User32)
            Sleep(10)
          WEnd
;           ConsoleWrite("Case 2: " & $aKeyCodes[1] & @CRLF)
        EndIf
      Else
        If _IsPressed($aKeyCodes[0], $User32) And _IsPressed($aKeyCodes[1], $User32) _
            And Not _IsPressed($aTmpCodes[0], $User32) And Not _IsPressed($aTmpCodes[1], $User32) Then
          $bLeftParenthesisWasPressed = True
          While _IsPressed($aKeyCodes[0], $User32) And _IsPressed($aKeyCodes[1], $User32)
            Sleep(10)
          WEnd
;           ConsoleWrite("Case 2: " & $aKeyCodes[1] & @CRLF)
        EndIf
      EndIf

    Case 3 ; 2 Steuertasten werden benutzt = 1 Steuertaste ist UNBENUTZT = Temp-Array bekommt 1 Item.
           ; Beispiel: 7+Shift+Ctrl.

      ; Ermittlung der 1 UNBENUTZEN Steuertaste.
      If ($aKeyCodes[1] <> "10") And ($aKeyCodes[2] <> "10") Then _ArrayAdd($aTmpCodes, "10")
      If ($aKeyCodes[1] <> "11") And ($aKeyCodes[2] <> "11") Then _ArrayAdd($aTmpCodes, "11")
      If ($aKeyCodes[1] <> "12") And ($aKeyCodes[2] <> "12") Then _ArrayAdd($aTmpCodes, "12")

      If $aKeyCodes[1] = "10" And $bCapsLockOn Then
        If _IsPressed($aKeyCodes[0], $User32) And _IsPressed($aKeyCodes[2], $User32) _
            And Not _IsPressed($aKeyCodes[1], $User32) And Not _IsPressed($aTmpCodes[0], $User32) Then
          $bLeftParenthesisWasPressed = True
          While _IsPressed($aKeyCodes[0], $User32) And _IsPressed($aKeyCodes[2], $User32)
            Sleep(10)
          WEnd
;           ConsoleWrite("Case 3: " & $aKeyCodes[1] & " + " & $aKeyCodes[2] & @CRLF)
        EndIf
      ElseIf $aKeyCodes[2] = "10" And $bCapsLockOn Then
        If _IsPressed($aKeyCodes[0], $User32) And _IsPressed($aKeyCodes[1], $User32) _
            And Not _IsPressed($aKeyCodes[2], $User32) And Not _IsPressed($aTmpCodes[0], $User32) Then
          $bLeftParenthesisWasPressed = True
          While _IsPressed($aKeyCodes[0], $User32) And _IsPressed($aKeyCodes[1], $User32)
            Sleep(10)
          WEnd
;           ConsoleWrite("Case 3: " & $aKeyCodes[1] & " + " & $aKeyCodes[2] & @CRLF)
        EndIf
      Else
        If _IsPressed($aKeyCodes[0], $User32) And _IsPressed($aKeyCodes[1], $User32) And _IsPressed($aKeyCodes[2], $User32) _
            And Not _IsPressed($aTmpCodes[0], $User32) Then
          $bLeftParenthesisWasPressed = True
          While _IsPressed($aKeyCodes[0], $User32) And _IsPressed($aKeyCodes[1], $User32) And _IsPressed($aKeyCodes[2], $User32)
            Sleep(10)
          WEnd
;           ConsoleWrite("Case 3: " & $aKeyCodes[1] & " + " & $aKeyCodes[2] & @CRLF)
        EndIf
      EndIf

    Case 4 ; 3 Steuertasten werden benutzt = 0 Steuertasten sind UNBENUTZT = Temp-Array bekommt 0 Items.
           ; Beispiel: 7+Shift+Ctrl+Alt.

      If ($aKeyCodes[1] = "10" Or  $aKeyCodes[2] = "10" Or $aKeyCodes[3] = "10") And $bCapsLockOn Then
        If _IsPressed($aKeyCodes[0], $User32) And Not _IsPressed("10", $User32) And _IsPressed("11", $User32) And _IsPressed("12", $User32) Then
          $bLeftParenthesisWasPressed = True
          While _IsPressed($aKeyCodes[0], $User32) And _IsPressed("11", $User32) And _IsPressed("12", $User32)
            Sleep(10)
          WEnd
        EndIf
      Else
        If _IsPressed($aKeyCodes[0], $User32) And _IsPressed("10", $User32) And _IsPressed("11", $User32) And _IsPressed("12", $User32) Then
          $bLeftParenthesisWasPressed = True
          While _IsPressed($aKeyCodes[0], $User32) And _IsPressed("10", $User32) And _IsPressed("11", $User32) And _IsPressed("12", $User32)
            Sleep(10)
          WEnd
        EndIf
      EndIf
  EndSwitch

  Return $bLeftParenthesisWasPressed
EndFunc ; ==> KeysForLeftParenthesisWerePressed

Alles anzeigen

Edit: Den ersten Bug selbst gefunden und (hoffentlich) behoben.

**Bitnugger** · 27. Februar 2021

Zitat von Professor Bernd

Das SynEdit (= Editor-Control von PSPad) erlaubt manchmal das Auslesen von einigen Zeilen Text, aber dann ohne ersichtlichen Grund kommen nur noch chinesische Zeichen.

So geht es...

AutoIt

;-- TIME_STAMP   2021-02-27 00:49:45   v 0.1

;~ Opt('MustDeclareVars', 1)

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <Debug.au3>
#include <SendMessage.au3>
;~ #include <WinAPIConv.au3>
#include <WinAPISys.au3>
#include <WinAPISysWin.au3>
;~ #include <WinGetControls.au3>
#include <_ConOut.au3> ; <<-- WinAPIConv.au3

Local $aControls, $tChars, $sTxt, $hKeybLayout, $hActive = WinGetHandle('[ACTIVE]'), $hPSPad = ControlGetHandle('[CLASS:TfPSPad]', '', '[CLASS:TPSSynEdit; INSTANCE:1]')
ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hPSPad      --> " & $hPSPad & @LF)
If Not IsHWnd($hPSPad) Then Exit 1

$hKeybLayout = _WinAPI_GetKeyboardLayout($hPSPad)
ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hKeybLayout --> " & $hKeybLayout & @LF)

Local $iLen = _SendMessage($hPSPad, $WM_GETTEXTLENGTH)
If $iLen < 1 Then Exit 2

$tChars = DllStructCreate('char['&$iLen&']')
_SendMessage($hPSPad, $WM_GETTEXT, $iLen, DllStructGetPtr($tChars))
For $i = 1 To $iLen Step 1
    $sTxt &= DllStructGetData($tChars, 1, $i)
Next
_ConOut($sTxt & @CRLF)

; Funktioniert, aber nicht wie erwartet!
ControlFocus('', '', $hPSPad)
Local $iPID, $aInfo = _WinAPI_GetGUIThreadInfo(_WinAPI_GetWindowThreadProcessId($hPSPad, $iPID))
ConsoleWrite('- CaretX: ' & $aInfo[7] & ' CaretY: ' & $aInfo[8] & @CRLF)

;~ $aControls = _WinGetControls(WinGetHandle('[CLASS:TfPSPad]'))
;~ _ArrayDisplay($aControls, '$aControls')

WinActivate($hActive)

Alles anzeigen

Professor Bernd · 27. Februar 2021

Das Auslesen scheint schonmal besser zu funktionieren! (Manchmal zeigt das SynEdit erst nach einiger Zeit (oder nach einigen Zugriffen?) die chinesischen Zeichen.) Wie ich vom Gesamt-Text zum Text am Caret kommen kann, weiß ich noch nicht. Mal sehen, was ich draus machen kann. Auf jeden Fall ein interessanter Ansatz!

**BugFix** · 27. Februar 2021

Zitat von Professor Bernd

Wie ich vom Gesamt-Text zum Text am Caret kommen kann, weiß ich noch nicht. Mal sehen, was ich draus machen kann. Auf jeden Fall ein interessanter Ansatz!

Das korrekte Auslesen des Textes war doch doch schon seit langer Zeit erledigt (oder interpretiere ich das falsch: RE: Selektierten Text in SynEdit finden?

Zeichen am Caret (also davor) ist doch Erweiterung der Auswahl auf (pos-1, pos). Vielleicht ist das mit der Objektlösung realisierbar.

**Bitnugger** · 27. Februar 2021

Zitat von BugFix

Vielleicht ist das mit der Objektlösung realisierbar.

Ja, ist es... hier die korrigierte und erweiterte Version von PsPadExt.au3

f:\AutoIt\AutoIt3_MyInclude\AutoItObject.au3

f:\Progdir\PSPad4AutoIt3\Script\VBScript\AutoItScriptExtension.vbs

f:\Progdir\PSPad4AutoIt3\PSPad4Au3\Au3 scripts\PsPadExt.au3

AutoIt: PsPadExt.au3

;-- TIME_STAMP   2021-02-27 15:16:00   v 0.1

;*****************************************
;PsPadExt.au3 by Churanos
;Created with ISN AutoIt Studio v. 1.10
;*****************************************
#NoTrayIcon

#include <AutoItObject.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

AutoItSetOption("GUIOnEventMode", 1)
OnAutoItExitRegister("_Exit")
_AutoItObject_Startup()

#Region Define variables
Global Const $sExtName    = "PsPadExt"
Global Const $sExtVersion = "0.0.1"
Global Const $sExtAuthor  = "Churanos <kleist.steven@gmail.com>"

Global Const $sClsId      = "PsPadExt.Bridge"

Global $oPlugin           = Null
Global $hROTHandle        = Null

Global $bShouldQuit       = False
Global $bInit             = False

Global $oError = ObjEvent("AutoIt.Error", "_ErrFunc")
#EndRegion Define variables

#Region GUI Part
Global $frm_Main = GUICreate($sExtName, 320, 360, -1, -1, -1, $WS_EX_TOPMOST)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
Global $btn_GetText = GUICtrlCreateButton("Get sel. Text", 10, 10, 100, 25)
GUICtrlSetOnEvent(-1, "_GetTextFromEditor")
Global $btn_LeftChar = GUICtrlCreateButton("Get left Char", 120, 10, 100, 25)
GUICtrlSetOnEvent(-1, "_GetLeftCharFromEditor")
Global $txt_Text = GUICtrlCreateEdit("", 10, 50, 300, 300)
#EndRegion GUI Part

#Region Main Loop
_Init()
While 1
    ; Do stuff
    If $bShouldQuit Then _Exit()
    Sleep(10)
Wend
#EndRegion Main Loop

#Region Functions
;##############################################################################
;### Init function
;##############################################################################
Func _Init()
    $oPlugin = _PSPadExt()
    If @error Then
        MsgBox(16, "Error", "Error while creating object from Func: _PsPadExt()!")
        _Exit()
    EndIf
    $hROTHandle = _AutoItObject_RegisterObject($oPlugin, $sClsId)
    GUISetState(@SW_SHOW, $frm_Main)
EndFunc
;##############################################################################

;##############################################################################
;### Exit function
;##############################################################################
Func _Exit()
    _AutoItObject_UnregisterObject($hROTHandle)
    $oPlugin = 0
    _AutoItObject_Shutdown()
    Exit
EndFunc
;##############################################################################

Func _GetTextFromEditor()
    GUICtrlSetData($txt_Text, $oPlugin.PsPadSelectedText())
EndFunc

Func _GetLeftCharFromEditor()
    Local $aCaret = $oPlugin.PsPadLeftChar()
    GUICtrlSetData($txt_Text, StringFormat("Editor.caretY(): %s  Editor.caretX(): %s\r\nEditor.LineText(): %s\r\nEditor.LeftChar(): %s\r\n", $aCaret[0], $aCaret[1], $aCaret[2], $aCaret[3]))
EndFunc
#EndRegion Functions

#Region Object Functions
Func _PSPadExt()
    Local $class = _AutoItObject_Class()
    With $class
        .AddProperty("Name", $ELSCOPE_READONLY, $sExtName)
        .AddProperty("Version", $ELSCOPE_READONLY, $sExtVersion)
        .AddProperty("PsPad", $ELSCOPE_PUBLIC, Null)

        .AddMethod("PsPadSelectedText", "_PsPadExt_PsPadSelectedText")
        .AddMethod("PsPadLeftChar", "_PsPadExt_PsPadLeftChar")
        .AddMethod("Quit", "_PsPadExt_Quit")
    EndWith

    Return $class.Object
EndFunc

Func _PsPadExt_PsPadSelectedText($this)
    $this.PsPad.Item("Editor").assignActiveEditor()
    ConsoleWrite(StringFormat("Editor.selText(): %s", $this.PsPad.Item("Editor").selText()) & @CRLF)
    Return $this.PsPad.Item("Editor").selText()
EndFunc

Func _PsPadExt_PsPadLeftChar($this)
    $this.PsPad.Item("Editor").assignActiveEditor()
    Local $iCaretRow = $this.PsPad.Item("Editor").caretY() - 1
    Local $iCaretCol = $this.PsPad.Item("Editor").caretX() - 1
    Local $sLineText = $this.PsPad.Item("Editor").lineText()
    ConsoleWrite(StringFormat("Editor.caretY(): %s", $iCaretRow) & @CRLF)
    ConsoleWrite(StringFormat("Editor.caretX(): %s", $iCaretCol) & @CRLF)
    ConsoleWrite(StringFormat("Editor.LineText(): %s", $sLineText) & @CRLF)
    ConsoleWrite(StringFormat("Editor.LeftChar(): %s", StringMid($sLineText, $iCaretCol, 1)) & @CRLF)
    Local $aCaret = [$iCaretRow, $iCaretCol, $sLineText, StringMid($sLineText, $iCaretCol, 1)]
    Return $aCaret
EndFunc

Func _PSPadExt_Quit($this)
    $bShouldQuit = True
EndFunc
#EndRegion Object Functions

#Region COM Error Function
Func _ErrFunc()
    ConsoleWrite("COM Error, ScriptLine(" & $oError.scriptline & ") : Number 0x" & Hex($oError.number, 8) & " - " & $oError.windescription & @CRLF)
EndFunc    ;==>_ErrFunc
#EndRegion COM Error Function

Alles anzeigen

Professor Bernd · 27. Februar 2021

Cool vielen Dank euch beiden! Damals hatte ich an diesem Code weitergearbeitet und mangels COM-Fähigkeiten die Arbeiten irgendwann eingestellt. Mein Code war etwa auf deinem Stand Bitnugger, aber bei weitem nicht so sauber (weil ich eigentlich nur probiert und rumgestochert habe).

Ich habe dein Script "PsPadExt.au3" umbenannt in "AutoItObject_PSPadExtBridge.au3" und in das alte Test-Demo gepackt, wo es automatisch mit PSPad gestartet wird. (Übrigens für die Namensfetichisten: Eigenname ist "PSPad", nicht "PsPad".) Die Buttons sind auskommentiert und die Erfassung des Zeichens links vom Caret in PSPad wird in der Hauptschleife der eigenen GUI automatisch in das eigene Edit geschrieben. Es gibt jedoch auch mit deiner Version die gleichen Probleme wie damals:

Die Erkennung funktioniert manchmal nicht, bzw. erst, wenn man PSPad und die GUI mit dem Edit 2 oder 3x neustartet.
Die Erkennung erfolgt in der Hauptschleife des Scripts. Dort habe ich ein Sleep(100) fürs Demo benutzt, weil sonst nichts ankam. Aber eigentlich dürfte die Schleife nur für 10 ms schlafen, weil sonst die Erkennung der Zeichen nicht korrekt erfasst, wenn jemand ein schneller Tipper ist. Außerdem muss anderer Code ausgeführt werden können und dafür darf nur Sleep(10) benutzt werden.
Wenn eine weitere PSPad Instanz gestartet wird, erfolgt die Erkennung in der zweiten Instanz, aber NICHT mehr in der ersten Instanz.

Wichtig: Dieses Demo ist "uralt", etwa von Juni 2020. Aber für diese Test-Zwecke sollte das gehn.

Edit: 2021-03-12, Tests beendet, Demo entfernt von Professor Bernd. Sollte jemand an weiteren Tests interessiert sein, bitte melden, dann lade ich es wieder hoch.

Teilen