_GUICtrlListView_SetColumnWidth() - keine Funktion bei Aufruf mit Array-Variabel

chrisbyRRC

Moin Forum,

ich habe gerade wieder ein sehr merkwürdiges Problem das ich mir nicht ganz erklären kann. Wäre super wenn da jemand nen Tipp hätte:

Hintergrund: Ich habe ein Script mit einer ListView das ich nun um eine, eigentlich, einfache Option erweitern wollte - Das Speichern und Laden der vom Nutzer veränderten Spaltenbreite in die Registry.

Problem: Aus einen mir unerklärlichen Grund funktioniert der Aufruf, nach auslesen der Werte aus der Registry in ein Array, von _GUICtrlListView_SetColumnWidth() zum ändern der Breite nicht.

Noch merkwürdiger - Es wird entweder keine Änderung durchgeführt, oder jede Spalte bekommt sporadisch eine Vergrößerung mit Werten > 2000, obwohl sowohl in Registry als auch beim Auslesen der Variabel die richtigen Werte stehen. Und nun der Hammer - wenn ich statt der Array-Variabel direkt die Breite übergebe, funktioniert die Änderung ohne Probleme!

Ich habe nun schon so viel ausprobiert und sitze bereits mehrere Tage daran, dass ich nun mein Skript mittlerweile auf das absolute Minimum runtergebrochen habe.

Ich habe nun mittlerweile sogar die Includes gegen neuere Versionen getauscht um einen vermeintlichen Bug in diesen auszuschließen.

AutoIt: Hier mein aktuelller Test:

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <GuiListView.au3>

Global $ListView_Overview
Global $SavedLVwidth_String = ""
Global $Switch_AutoReadInData = True
Global $Switch_SaveLVwidht = False
Global $Switch_FirstLVSearch = True

if RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","Auto Read-In Data") == False Then $Switch_AutoReadInData = False
if RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","Save ListView Width") == True Then    $Switch_SaveLVwidht = True
if $Switch_SaveLVwidht == True Then $SavedLVwidth_String = RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","LV-Saved-Width")

$MainGUI = GUICreate("TEST", 1402, 855)
$ListView_Overview = GUICtrlCreateListView("Case|S-Icon|Auftragsname|Erstellt am|Angelegt|Deadline|Status|MV (Mont.-Verantw.)|EV (Einricht.Verantw.)|Montage|Doku|Computername|PC-SN|Vision-Lizenz|Dongle-SN|Windows-Lizenz|Windows|Gehäuse|Netzteil|Mainboard|Prozessor|Grafikkarte|RAM|Festplatten|Netzwerkkarte|Perle-Karte|Grabber-Karte|COM-Port-Blende", 8, 64, 1385, 753,-1)

GUISetState(@SW_SHOW)

_GetDataArray()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _GetDataArray()

        $LVwidth = StringSplit($SavedLVwidth_String,";",2)

        _GUICtrlListView_SetColumnWidth($ListView_Overview, 2, $LVwidth[2])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 3, $LVwidth[3])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 4, $LVwidth[4])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 5, $LVwidth[5])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 6, $LVwidth[6])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 7, $LVwidth[7])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 8, $LVwidth[8])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 9, $LVwidth[9])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 10, $LVwidth[10])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 11, $LVwidth[11])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 12, $LVwidth[12])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 13, $LVwidth[13])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 14, $LVwidth[14])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 15, $LVwidth[15])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 16, $LVwidth[16])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 17, $LVwidth[17])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 18, $LVwidth[18])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 19, $LVwidth[19])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 20, $LVwidth[20])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 22, $LVwidth[22])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 23, $LVwidth[23])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 24, $LVwidth[24])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 25, $LVwidth[25])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 26, $LVwidth[26])
        _GUICtrlListView_SetColumnWidth($ListView_Overview, 27, $LVwidth[27])
        _ArrayDisplay($LVwidth)

EndFunc

Alles anzeigen

Der in die Registry geschriebene String für die Spaltenbreite sieht dann z.B. so aus:

Code

50;59;712;77;60;66;1504;124;125;260;156;227;127;165;327;354;419;321;203;509;516;313;458;569;314;150;545;178

Habe die Reg die das Prog anlegt mal exportiert und hier angehängt: RegExport.zip

**BugFix**

Es gibt häufig Probleme, wenn ein mit nativer Funktion erstelltes Control in UDF genutzt werden soll, da diese in der Regel ein Handle statt einer ID erwarten.

_GuiCtrlListViewSetColumnWidth switcht und ruft bei Übergabe eines Handle _SendMessage($hWnd, $LVM_SETCOLUMNWIDTH, $iCol, $iWidth) und bei Übergabe einer ID GUICtrlSendMsg($hWnd, $LVM_SETCOLUMNWIDTH, $iCol, $iWidth) auf.

Somit sollte das in beiden Fällen funktionieren. - Aber versuche es doch mal mit

_GUICtrlListView_SetColumnWidth(GUICtrlGetHandle($ListView_Overview), ... )

Gofel

Code

Oder probier mal "Number"
...
_GUICtrlListView_SetColumnWidth($ListView_Overview, 2, Number($LVwidth[2]))
...

chrisbyRRC

Oha, hätte nicht gedacht das es Unterschiede beim Aufruf mit Handle oder ID gibt, immerhin wird auch in den Bsp. der Hilfe der Aufruf mit der ID durchgeführt.

Aber, tatsächlich funktioniert es nun mit GUICtrlGetHandle() ohne Probleme!

Vielen Dank für den heißen Tipp BugFix, jetzt kann ich endlich weiter machen!

**Moombas**

Tipp1:

Code

if RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","Auto Read-In Data") == False Then $Switch_AutoReadInData = False
if RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","Save ListView Width") == True Then    $Switch_SaveLVwidht = True

Solte so auch reichen:

Code

$Switch_AutoReadInData = RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","Auto Read-In Data")
$Switch_SaveLVwidht    = RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","Save ListView Width")

Tipp2:

Deine Zuordnung kannst du in eine Schleife packen:

Code

For $x = 1 To $LVwidth[0]
  _GUICtrlListView_SetColumnWidth($ListView_Overview, $x, $LVwidth[$x])
Next

Tipp 3:

Unschön:

Code

if $Switch_SaveLVwidht == True Then $SavedLVwidth_String = RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","LV-Saved-Width")

Besser:

Code

if $Switch_SaveLVwidht Then $SavedLVwidth_String = RegRead("HKEY_CURRENT_USER\Software\PCF-Doku-Tool\User-Options","LV-Saved-Width")

Geschmackssache:

ich hätte diese beiden getauscht (GUI erst anzeigen, wenn diese korrekt eingestellt ist):

GUISetState(@SW_SHOW)

_GetDataArray()

chrisbyRRC

Gofel: Klasse! Das funktioniert tatsächlich auch. Hatte erst mit Binary() und String() probiert. Aber Number() gibts ja auch und macht mehr Sinn...

Moombas: Ja, ich weiß das ich nicht immer den saubersten / ordentlichsten Schreibstil beim programmieren habe. Du hast natürlich Recht, so gehts auch bzw. besser!

**Moombas**

Es geht ja nicht nur um "besser", ich hab mal gelernt man prüft nicht auf "True" Und der Rest macht es halt übersichtlicher.

Je nach Umfang kommen sonst ettliche Zeilen zusammen, wo man schnell den Überblick verlieren kann.

**Bitnugger**

Hehe, das mit _GUICtrlListView_SetColumnWidth ist mir auch passiert... aber anstelle Number() verwende ich Int().