Menu Item wieder zurückholen

**UEZ**

Hat jemand eine Idee, wie ich ein Menu Item, welches ich mit _GUICtrlMenu_RemoveMenu() gelöscht habe, wieder zurückholen kann mit allen Untermenüs?

Beispiel: in Notepad wird der Menueintrag "Hilfe / Help" gelöscht.

AutoIt

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain

    ; Open Notepad
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $hMain = ' & $hMain & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    $iD = _GUICtrlMenu_GetItemID ( $hMain, 4)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iD = ' & $iD & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    $hMenu_save = _GUICtrlMenu_GetItemSubMenu($hMain, 4)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $hMenu_save = ' & $hMenu_save & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

    Sleep(1000)
    ; Remove Help menu
    _GUICtrlMenu_RemoveMenu($hMain, 4)

    Sleep(2000)
;~     ConsoleWrite(_GUICtrlMenu_SetMenu($hMain, $hMenu_save) & @CRLF)
;~     ConsoleWrite(_GUICtrlMenu_SetItemSubMenu ( $hMain, 4, $hMenu_save) & @CRLF)
;~     _GUICtrlMenu_InsertMenuItem ( $hMain, 4, "Help", $iD,  $hMain)
    _GUICtrlMenu_DrawMenuBar($hMain)

EndFunc   ;==>Example

Alles anzeigen

Laut MS

Zitat

Deletes a menu item or detaches a submenu from the specified menu. If the menu item opens a drop-down menu or submenu, RemoveMenu does not destroy the menu or its handle, allowing the menu to be reused. Before this function is called, the GetSubMenu function should retrieve a handle to the drop-down menu or submenu.

Danke.

**Bitnugger**

Hier zwei Bsp.:

AutoIt

;-- TIME_STAMP   2021-04-24 19:00:24   v 0.1

Opt('MustDeclareVars', 1)

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Global $g_idMemo


Example1()
Example2()

Func Example1()
    Local $hWnd, $hMain, $iCmdID, $hMenu_save

    ; Open Notepad
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $hMain = ' & $hMain & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    $iCmdID = _GUICtrlMenu_GetItemID ( $hMain, 4)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iCmdID = ' & $iCmdID & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    Sleep(1000)

    ; Remove Help menu
    $hMenu_save = _GUICtrlMenu_GetItemSubMenu($hMain, 4)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : Remove Help menu  : ' & _GUICtrlMenu_RemoveMenu($hMain, 4) & ' - $hMenu_save = ' & $hMenu_save & @CRLF)
    Sleep(2000)

    ; Restore Help menu
    _GUICtrlMenu_InsertMenuItem($hMain, 4, "&New Help", $iCmdID,  $hMain)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : Restore Help menu : ' & _GUICtrlMenu_SetItemSubMenu($hMain, 4, $hMenu_save) & @CRLF)
    _GUICtrlMenu_SetMenu($hWnd, $hMain)
EndFunc   ;==>Example1

Func Example2()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain, $idRestore
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Create GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Create File menu
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Create Edit menu
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Create Help menu
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)

    ; Create Main menu
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, 0)

    ; Set window menu
    _GUICtrlMenu_SetMenu($hGUI, $hMain)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 249);, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")

    $idRestore = GUICtrlCreateButton('Remove Help menu', 2, 252, 396, 26)
    GUICtrlSetBkColor($idRestore, 0x00AAFF)
    GUISetState(@SW_SHOW)

    ; Get/Set Help menu
    MemoWrite("Get Help submenu handle : " & _GUICtrlMenu_GetItemSubMenu($hMain, 2))
    _GUICtrlMenu_SetItemSubMenu($hMain, 2, $hHelp)
    MemoWrite("Get Help submenu handle : " & _GUICtrlMenu_GetItemSubMenu($hMain, 2) & @CRLF)

    #Region - GUI SwitchLoop
    While True
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
            Case $idRestore
                Local $sRestore = GUICtrlRead($idRestore)
                Switch $sRestore
                    Case 'Remove Help menu'
                        MemoWrite("Remove Help menu        : " & _GUICtrlMenu_RemoveMenu($hMain, 2) & @CRLF)
                        GUICtrlSetBkColor($idRestore, 0xFFAA00)
                        GUICtrlSetData($idRestore, 'Restore Help menu')
                    Case 'Restore Help menu'
                        MemoWrite("Insert Main Help menu   : " & _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, 0))
                        MemoWrite("Restore Help menu handle: " & _GUICtrlMenu_SetItemSubMenu($hMain, 2, $hHelp))
                        MemoWrite("Get Help submenu handle : " & _GUICtrlMenu_GetItemSubMenu($hMain, 2))
                        MemoWrite("Update Main menu        : " & _GUICtrlMenu_SetMenu($hGUI, $hMain) & @CRLF)
                        GUICtrlSetData($idRestore, 'Remove Help menu')
                        GUICtrlSetBkColor($idRestore, 0x00AAFF)
                EndSwitch
        EndSwitch
    WEnd
    #EndRegion
EndFunc   ;==>Example2

; Write message to memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

Alles anzeigen

**UEZ**

Bitnugger vielen Dank! Funzt wie erwartet!

Jetzt muss ich sehen, ob man auch für das CMD Box Fenster dies anwenden kann.

ruby

Hallo Bitnugger,

bei Deinem obriges Script Example 1 kann man ja nur ein Item entfernen.

Durch eine Schleife kann man ja alle Menü Items mit _GUICtrlMenu_RemoveMenu entfernen.

Aber wie hole ich die wieder mit einer Schleife zurück?

Ich möchte gerne von einem externen Program das Menü Item komplett verstecken und nach einem Tastendruck wieder hervorholen.

Schon mal danke im vorraus.

C

Opt('MustDeclareVars', 1) 

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Global $g_idMemo


Example1()
;~ Example2()

Func Example1()

    Local $hWnd, $hMain, $iCmdID, $hMenu_save

    ; Open Notepad
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")

    $hMain = _GUICtrlMenu_GetMenu($hWnd)
;~     ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $hMain = ' & $hMain & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
;~     $iCmdID = _GUICtrlMenu_GetItemID ( $hMain, 4)
;~     ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iCmdID = ' & $iCmdID & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

    Sleep(1000)

    ; Remove Help menu
;~     $hMenu_save = _GUICtrlMenu_GetItemSubMenu($hMain, 4)
;~     ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : Remove Help menu  : ' & _GUICtrlMenu_RemoveMenu($hMain, 4) & ' - $hMenu_save = ' & $hMenu_save & @CRLF)

        For $iCmdID = _GUICtrlMenu_GetItemCount ($hMain) - 1 To 0 Step - 1
            ConsoleWrite($hMain & " " & $iCmdID & @CRLF)
            _GUICtrlMenu_RemoveMenu ($hMain, $iCmdID)
        Next

    Sleep(1000)

    ; Restore Help menu
   ; _GUICtrlMenu_InsertMenuItem($hMain, 4, "&New Help", $iCmdID,  $hMain)
   ; ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : Restore Help menu : ' & _GUICtrlMenu_SetItemSubMenu($hMain, 4, $hMenu_save) & @CRLF)
   ; _GUICtrlMenu_SetMenu($hWnd, $hMain)

;funktioniert nicht
         For $iCmdID = _GUICtrlMenu_InsertMenuItem ($hMain, $iCmdID,  $hMain) - 1 To 0 Step - 1
            _GUICtrlMenu_SetMenu($hWnd, $hMain)
         Next



EndFunc   ;==>Example1

Alles anzeigen

**Bitnugger**

Zitat von ruby

Ich möchte gerne von einem externen Program das Menü Item komplett verstecken und nach einem Tastendruck wieder hervorholen.

Wenn du sagst komplett, dann meinst du wohl kein Item, sondern ein SubMenu, zB. das "Help Menu" komplett verstecken...

Hier ein Bsp.:

AutoIt: _GUICtrlMenu_RemoveRestoreMenu_Example.au3

;-- TIME_STAMP   2022-04-16 21:12:25   

Opt('MustDeclareVars', 1)

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Global $iPID, $hWnd, $hMain, $hHelp

HotKeySet('{F2}', '_SwitchMenu')
HotKeySet('{ESC}', '_Exit')

Example()

Func Example()
    ; Open Notepad
    $iPID = Run("notepad.exe")
    $hWnd = WinWaitActive("[CLASS:Notepad]")

    ; Main menu
    $hMain = _GUICtrlMenu_GetMenu($hWnd)

    ; Help menu
    $hHelp = _GUICtrlMenu_GetItemSubMenu($hMain, 4)

    Writeln('\n\tPress F2 to show/hide Help menu')
    Writeln('\n\tPress ESC for Exit')

    While Sleep(100)
    WEnd
EndFunc   ;==>Example

Func _SwitchMenu()
    Local Static $bRemove = True
    If $bRemove Then
        ; Remove Help menu
        $bRemove = False
        _GUICtrlMenu_RemoveMenu($hMain, 4)
    Else
        ; Restore Help menu
        $bRemove = True
        _GUICtrlMenu_InsertMenuItem($hMain, 4, "&Hilfe", 0, $hHelp)
        _GUICtrlMenu_SetMenu($hWnd, $hMain)
    EndIf
EndFunc   ;==>_SwitchMenu

; Write a line of text to Notepad
Func Writeln($sText)
    ControlSetText("[CLASS:Notepad]", "", "Edit1", StringFormat(ControlGetText("[CLASS:Notepad]", "", "Edit1") & $sText), 0)
EndFunc   ;==>Writeln

Func _Exit()
    HotKeySet('{F2}')
    HotKeySet('{ESC}')
    ProcessClose($iPID)
    Exit
EndFunc   ;==>_Exit

Alles anzeigen

ruby

Hallo Bitnugger,

danke für die Rückantwort, das funktioniert.

Das Du so schnell Antwortest damit habe ich gar nicht gerechnet.

Erst einmal frohe Ostern.

Es geht eigentlich nur um folgendes:

Ich nutze privat Sketchup Pro 2019, mit sehr vielen Buttons (siehe Screenshot) und deswegen möchte ich gerne das Zeichenhandle

Local $hWnd = ControlGetHandle($title,"","[CLASS:AfxFrameOrView140u; INSTANCE:1]") manchmal in den Vollbildmodus setzten.

Um mehr geht es eigentlich nicht, aber...

Ist das Zeichenhandle im Vollbildmodus sieht man oben immer noch die Menüs (siehe rotes Rechteck),

und wenn die ganzen Buttons, Afx:ToolBar und Afx:ControlBar, nicht versteckt werden und man will was zeichen,

springt das Handle AfxFrameOrView140u wieder in den Normalmodus allesdings ohne Rahmen zurück.

Deswegen verstecke ich alle Afx:ToolBar und Afx:ControlBar da erst dann das Zeichenhandle im Vollmodus bleibt.

Die Menüs oben sind aber immer noch sichtbar.

Deswegen der Gedankengang die Menüs oben auch auszublenden und dann wieder wenn man im Normalmodus wechselt wieder da sind.

Vielleicht schafft man es aber, das das Handle AfxFrameOrView140u im Vollbildmodus bleibt ohne den Rest.

Vielen Dank schon einmal.

C

#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <Misc.au3>
#include <GuiMenu.au3>

Global $iOrgStyle, $fPressed = False, $hMenu, $hide = ControlHide, $show = ControlShow, $ProgramName = "fullscreen.exe"

; es wird nur eine Instanz ausgeführt.
If _Singleton($ProgramName, 1) = 0 Then
    ;"The program is already running."
    Exit
EndIf

While Sleep(20)
    If _IsPressed("7B") And $fPressed = False Then ;F12

;~         Opt("WinTitleMatchMode", 1)
;~         $WinHandle = WinGetHandle("[REGEXPTITLE:(?i)Sketchup Pro(.*?)]")
        $WinHandle = WinGetHandle("[active]")
        $sWinTitle = WinGetTitle($WinHandle)
;~         ConsoleWrite("Fenstertitel: " & $sWinTitle  & @CRLF)

        If not StringInStr($sWinTitle,'SketchUp Pro') Then Exit

        ;~ Hauptfenster Fullscreen
;~         $title = WinGetHandle("[active]")
        $title = WinGetHandle($sWinTitle)

        ;schaltet Menü aus
        $hMenu = _GUICtrlMenu_GetMenu($title)
        _GUICtrlMenu_SetMenu($title, 0)

        $aPos = WinGetPos($title) ;ursprüngliche Position und Grösse ermitteln
        $iOrgStyleFull = _WinAPI_SetWindowLong($title, $GWL_STYLE, $WS_POPUPWINDOW) ;Rückgabewert ist der ursprüngliche Stil Hauptfenster

        WinSetState($title, "", @SW_MAXIMIZE) ;Maximieren für Vollbild Hauptfenster

    ;~     Zeichenfenster Afx -> Fullscreen
        ; Assign a Local variable the handle of the Sketchup window
        Local $hWnd = ControlGetHandle($title,"","[CLASS:AfxFrameOrView140u; INSTANCE:1]")

        ; Assign a Local variable the style of the Sketchup window.
        Local $iStyle = _WinAPI_GetWindowLong($hWnd, $GWL_STYLE)

        ; Remove from the window style the MAXIMIZEBOX, MINIMIZEBOX and SIZEBOX styles.
        $iStyle = BitXOR($iStyle, $WS_MAXIMIZEBOX, $WS_MINIMIZEBOX, $WS_SIZEBOX)

        ; Set the style of the window. !!!nicht hier, da sonst resizeborder da ist!!!
    ;~     _WinAPI_SetWindowLong($hWnd, $GWL_STYLE, $iStyle)
    ;~ $iOrgStyleAfx = _WinAPI_SetWindowLong($hWnd, $GWL_STYLE, $iStyle)

        ; Apply the style zeigt das Afx Fenster als Vollbild im Vordergrund
        _WinAPI_SetWindowPos($hWnd, $HWND_TOP, 0, 0, @DesktopWidth, @DesktopHeight, $SWP_FRAMECHANGED)

        ;versteckt alle Button
        _WinGetControlList_all($hide)

        $fPressed = True

    ElseIf _IsPressed("7B") And $fPressed = True Then ;F12

        ;schaltet Menü weider ein
        _GUICtrlMenu_SetMenu($title, $hMenu)

        ;zeigt wieder alle Button
        _WinGetControlList_all($show)

        $iOrgStyleAfx = _WinAPI_SetWindowLong($hWnd, $GWL_STYLE, $iStyle) ;Rückgabewert des ursprüngliche Stil von Afx

        ; Hauptfenster und Zeichenfenster wieder herstellen
        _WinAPI_SetWindowLong($title, $GWL_STYLE, $iOrgStyleFull) ;ursprünglichen Stil Hauptfenster wiederherstellen
        WinMove($title, "", $aPos[0], $aPos[1], $aPos[2], $aPos[3]) ;ursprünglichen Position und Grösse wiederherstellen

        ; Set the style of the window Zeichenfenster.
        _WinAPI_SetWindowLong($hWnd, $GWL_STYLE, $iOrgStyleAfx) ;ursprünglichen Stil Afx Fenster wiederherstellen

        WinSetState($title, "", @SW_RESTORE)
        WinSetState($hWnd, "", @SW_SHOW )

        $fPressed = False

    EndIf

;~     If _IsPressed("1B") Then Exit ;Esc
    If not ProcessExists("SketchUp.exe") Then Exit

WEnd


Func _WinGetControlList_all($hide_or_show)

    $sTitle = ""
    $sText = ""

    Global $n = 0, $iCount
    Global $sClassList = WinGetClassList($sTitle, $sText)
    Global $aResult = StringRegExp($sClassList, "(\N+)", 3)
    Redim $aResult[UBound($aResult)][10]
    Global $aClasses = StringRegExp($sClassList, "(?s)(?:\A|\R)(\N+)(?=\R)(?!(?:\R\N+)*\R\1\R)", 3)

    For $i = 0 To UBound($aClasses) - 1
        StringRegExpReplace($sClassList, "\Q" & $aClasses[$i] & "\E\R", "")

        $iCount = @extended

        For $iInstance = 1 To $iCount
            $aResult[$n][0] = $aClasses[$i]                                                  ; Class
            $aResult[$n][1] = $aClasses[$i] & $iInstance                                     ; ClassnameNN
            $aResult[$n][2] = "[CLASS:" & $aClasses[$i] & "; INSTANCE:" & $iInstance & "]"    ; Advanced mode
            $aResult[$n][3] = ControlGetHandle($sTitle, $sText, $aResult[$n][2])             ; Handle
            $aResult[$n][4] = ControlGetText($sTitle, $sText, $aResult[$n][3] )              ; Text
            $aResult[$n][5] = _WinAPI_GetDlgCtrlID($aResult[$n][3])                          ; ID

            If StringInStr($aResult[$n][0], "Afx:ToolBar") Or StringInStr($aResult[$n][0], "Afx:ControlBar") = 1 Then
;~                 ControlHide($sTitle, "", $aResult[$n][3])
                $hide_or_show($sTitle, "", $aResult[$n][3])
            EndIf

            $n += 1

        Next
    Next

    Return $aResult

EndFunc

Alles anzeigen

Velted

Moin ruby,

nach Deinem letzten Beitrag denke ich, dass Du das komplette Fenstermenü entfernen willst. Das sollte recht einfach sein:

AutoIt

Opt('MustDeclareVars', 1)

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
#include <Misc.au3>


Global $hWnd, $hMenu, $fPressed = False

; Open Notepad
Run("notepad.exe")
WinWaitActive("[CLASS:Notepad]")
$hWnd = WinGetHandle("[CLASS:Notepad]")
$hMenu = _GUICtrlMenu_GetMenu($hWnd)

While Sleep(20)
    If _IsPressed("7B") Then ; F12
        If $fPressed = False Then
            _GUICtrlMenu_SetMenu($hWnd, 0)
            ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : Menu removed!' & @CRLF)
            $fPressed = True
        Else
            _GUICtrlMenu_SetMenu($hWnd, $hMenu)
            ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : Menu restored!' & @CRLF)
            $fPressed = False
        EndIf
        While _IsPressed("7B")
            Sleep(10)
        WEnd
    ElseIf _IsPressed("1B") Then ; Esc
        Exit
    EndIf
WEnd

Alles anzeigen

**Bitnugger**

Zitat von Velted

nach Deinem letzten Beitrag denke ich, dass Du das komplette Fenstermenü entfernen willst.

Klar... da soll einer drauf kommen...

Code

WinWaitActive("[CLASS:Notepad]")
$hWnd = WinGetHandle("[CLASS:Notepad]")

$hWnd = WinWaitActive("[CLASS:Notepad]")

ruby

Hi Velted und Bitnugger,

vielen Dank für die Rückinfo.

Funktioniert einwandfrei.

Konnte mich erst jetzt melden da ich mich heute morgen nicht einloggen konnte.

An beide Danke noch einmal.