Funktionsparameter als Const ByRef

Naja der Vorteil einer Konstante ist das sie halt nicht veränderbar ist.

Man nutzt es also für Werte, die sich nicht verändern sollten oder dürfen. Das kann natürlich auch die Referenz sein, die erhalten bleiben soll (es darf keine andere Referenz oder Wert eingetragen werden).

Sprich wenn du versuchst später im Code diese zu verändern schlägt es beim kompilieren fehl und du musst nach bessern.

Ich nutze nach Möglichkeit immer Local/Global Const für fixe Werte (z.B. Benutzername, Passwort, Serveradresse, Pfad,...).

Variablen nur, wenn ich das nicht vorab defnieren kann oder der Wert veränderbar sein darf/soll.

Beispiel (Versionsnummer als Konstante):

Global Const $Ver = Number(StringSplit(_FileGetProperty(@Scriptdir & '\tocopy\Installer\GoogleChromeStandaloneEnterprise.msi', $comment), '.')[1])

Edit: Hat auch den Vorteil, das du dir sicher sein kannst, was für einen Wert diese Konstante hat (weil sie eben nach der Initialisierung nicht mehr veränderbar ist).

Ein konstruiertes Beispiel dafür findest Du hier: Variables

Ganz unten, unter dem Punkt "A couple of more advanced points:"

Zitat von BugFix

Welchen Vorteil bringt das - wenn überhaupt?

Beispiel: Du übergibst Strings mit mehreren Megabyte Größe an deine Funktion.
In dieser willst du den String selbst nicht verändern - nur analysieren.

Wie du selbst sagtest wäre eine Übergabe ohne ByRef unnötig lahm und frisst unnötig Speicher, da erst eine Kopie des Strings erstellt werden muss.

Deswegen macht also schonmal ein ByRef Sinn.

Um nun noch klar zu machen und ganz sicher zu gehen, dass du diesen String in der Funktion nicht veränderst, wird dann noch einfach das Const dazu geschrieben.

Kurz: Sorgt dafür, dass sich außerhalb der Funktion die übergebene Variable nicht ändert und bleibt dennoch performant und Speicherfreundlich.

Ja klar - du könntest das auch ohne Const machen wenn du einfach in der Funktion von der Variable die Finger lässt.

Das Const bringt hierzu lediglich zusätzlich:

1. eine technische Schutzschicht vor Veränderungen und
2. eine menschenlesbare Klarstellung darüber, dass nicht geplant ist diese Variable in der Funktion zu verändern. (wenn du später den Code anschaust weißt du sofort, dass das ByRef nur aus Performance-Gründen dort steht)

BTW: AutoIt erstellt erst dann eine lokale Kopie von Parametern, wenn sie geändert werden.
Da Const nicht geändert werden kann, ist ByRef nicht notwendig.

Zitat von water

AutoIt erstellt erst dann eine lokale Kopie von Parametern, wenn sie geändert werden.

Guck an - das war mir bislang ja völlig unbekannt.

Hab's auch schnell testen und nachvollziehen können.

Steht das irgendwo in der Hilfe?

In der Hilfe für "Func"

Zitat

Entire arrays can be passed to functions (and returned from them) by simply using the array name without any brackets. Arrays should be passed to user-defined functions using the ByRef keyword to avoid the overhead of copying all the data in the array. Note that AutoIt only copies an array parameter if the contents are changed, so it is only in this case that ByRef offers an advantage, although it is recommended that to use it in all cases.

Ich glaube aber, mich erinnern zu können, dass dies nicht nur für Arrays gilt. War vor ewigen Zeiten mal eine Diskussion im engl. Forum.

Gilt scheinbar doch nur für Arrays.

Ne scheint schon so zu sein - hab es mal mit nem großen String probiert - kein relevanter Unterschied feststellbar:

Local $N = 100

; sehr großer String (ca 800 MB, da UCS-2)
Global $sString = ""
For $i = 1 To 40 * 1024 * 1024
    $sString &= "xxxxxxxxxx"
Next


$iT = TimerInit()
For $i = 1 To $N
    constTest($sString)
Next
$iT = TimerDiff($iT)
ConsoleWrite(StringFormat("% 20s: %f ms\n", "Nur Const", $iT  / $N))

$iT = TimerInit()
For $i = 1 To $N
    byRefTest($sString)
Next
$iT = TimerDiff($iT)
ConsoleWrite(StringFormat("% 20s: %f ms\n", "ByRef", $iT / $N))

$iT = TimerInit()
For $i = 1 To $N
    ohneTest($sString)
Next
$iT = TimerDiff($iT)
ConsoleWrite(StringFormat("% 20s: %f ms\n", "ohne const & byref", $iT  / $N))


Func constTest(Const $sString)
    Return StringRight($sString, 1)
EndFunc

Func byRefTest(ByRef $sString)
    Return StringRight($sString, 1)
EndFunc

Func ohneTest($sString)
    Return StringRight($sString, 1)
EndFunc

Ich frage mal die Gurus im engl. Forum
Vielleicht sollte man dann die Hilfe etwas anpassen.

Melba meint, dass das nur für Arrays gilt.

Die Messwerte widerprechen ihm da aber.