Tab ohne Hintergrundfarbe

**Tweaky** · 10. Juli 2022

Hi,

ich würde gerne den Tab in der gleichen Hintergrundfarbe wie die GUI erstellen.

In dem Beispiel ist die GUI grau und der Tab weiß.

Es soll aber beides grau sein.

Wie kann man die Hintergrundfarbe der GUI auslesen?

Außerdem flackern die Tabs wie wild, wenn ich die Checkbox "Tab umbenennen" anklicke

AutoIt

#Region    ;************ Includes ************
#include <GuiConstantsEx.au3>
#include <GuiTab.au3>
#EndRegion ;************ Includes ************

; Tab colours
Global $aTabColours[4] = [0xFFC0C0, 0xC0FFC0, 0xC0C0FF, 0xC0C0C0]

; Create GUI
Global $hGUI = GUICreate("Test", 400, 300)

; Create tab
Global $hTab = GUICtrlCreateTab(5, 5, 390, 290)

; Create Tab items and colour them
For $i = 0 To 3
    GUICtrlCreateTabItem("Tab item - " & $i)
    If $i > 1 Then _GUICtrlTab_SetBkColor($hGUI, $hTab, $aTabColours[$i])
    GUICtrlCreateTabItem("")
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUICtrlTab_SetBkColor($hWnd, $hSysTab32, $sBkColor)

    ; Get Tab position
    Local $aTabPos = ControlGetPos($hWnd, "", $hSysTab32)
    ; Get size of user area
    Local $aTab_Rect = _GUICtrlTab_GetItemRect($hSysTab32, -1)
    ; Create label
    GUICtrlCreateLabel("", $aTabPos[0] + 2, $aTabPos[1] + $aTab_Rect[3] + 4, $aTabPos[2] - 6, $aTabPos[3] - $aTab_Rect[3] - 7)
    ; colour label
    GUICtrlSetBkColor(-1, $sBkColor)
    ; Disable label
    GUICtrlSetState(-1, $GUI_DISABLE)

EndFunc   ;==>_GUICtrlTab_SetBkColor

Alles anzeigen

**funkey** · 11. Juli 2022

Hallo,

mit meiner OwnTab-UDF kann man das lösen, wenn man will. Mit dem Standard-Control wird es auch irgendwie gehen, aber sicherlich mit mehr Aufwand.

Spoiler anzeigen

**BugFix** · 11. Juli 2022

Zitat von Tweaky

Wie kann man die Hintergrundfarbe der GUI auslesen?

AutoIt

#include <WinAPISysWin.au3>
#include <WindowsConstants.au3>

$RGB_BG = _WinAPI_GetSysColor($COLOR_MENU)  ; "$COLOR_WINDOW - Window background" sollte dem Namen nach das richtige sein - liefert aber die falsche Farbe. _MENU passt bei mir

Ich hatte mal versucht mit "WM_DRAWITEM" die Tabs zu färben. Gefiel mir aber nicht so sehr. Vielleicht kannst du es als Idee nutzen:

AutoIt

;-- TIME_STAMP   2012-06-30 21:33:51

#include <FontConstants.au3>
#include <TabConstants.au3>
#include <WinAPI.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

Global Const $ODT_TAB        = 101
Global Const $ODS_SELECTED   = 0x0001
Global Const $ODA_DRAWENTIRE = 0x1
Global Const $ODS_FOCUS      = 0x0010

Global $aColTabItem[3][2] = [['Item1',0x11AADD],["Item2",0xEEBB99],["Item3",0x4763FF]] ; [[TabItem-Bezeichnung,TabItem-Color]]
Global $hFont, $iBrush

$hGUI = GUICreate("Draw Tab", 300, 200)
$hTab = GUICtrlCreateTab(10, 10, 280, 180, $TCS_OWNERDRAWFIXED)
$TabItem_1 = GUICtrlCreateTabItem("Item1") ; Bezeichnung im Array $aColTabItem muss identisch, wie hier sein!
; == erst alle Ctrl für Tab-Item_1 erstellen, dann das nächste Tab usw.
GUICtrlCreateLabel('Label-TAB_1',30,50)
$TabItem_2 = GUICtrlCreateTabItem("Item2")
GUICtrlCreateLabel('Label-TAB_2',30,50)
$TabItem_2 = GUICtrlCreateTabItem("Item3")
GUICtrlCreateLabel('Label-TAB_3',30,50)
GUICtrlCreateTabItem("")

GUISetState()

GUIRegisterMsg($WM_DRAWITEM, "WM_DRAWITEM")

_GUICtrlTab_SetCurSel($hTab, 2)
_GUICtrlTab_SetCurSel($hTab, 1)
_GUICtrlTab_SetCurSel($hTab, 0)
_GUICtrlTab_SetCurFocus($hTab, 1)



Do
Until GUIGetMsg() = -3
_WinAPI_DeleteObject($iBrush)


Func WM_DRAWITEM($hWnd, $Msg, $wParam, $lParam)
    Local $DRAWITEMSTRUCT = DllStructCreate("uint cType;uint cID;uint itmID;uint itmAction;uint itmState;" & _
                            "hwnd hItm;hwnd hDC;dword itmRect[4];dword itmData", $lParam)
    If DllStructGetData($DRAWITEMSTRUCT, "cType") <> $ODT_TAB Then Return $GUI_RUNDEFMSG
    If DllStructGetData($DRAWITEMSTRUCT, "itmAction") <> $ODA_DRAWENTIRE Then Return $GUI_RUNDEFMSG
    Local $itmID = DllStructGetData($DRAWITEMSTRUCT, "itmID")
    Local $hDC   = DllStructGetData($DRAWITEMSTRUCT, "hDC")
    Local $hItm  = DllStructGetData($DRAWITEMSTRUCT, "hItm")
    Local $itmText = $aColTabItem[$itmID][0], $iBrushColor = $aColTabItem[$itmID][1]

    DLLCall("gdi32.dll","int","SetBkMode", "hwnd", $hDC, "int", 1)

    Local $iBrush = DLLCall("gdi32.dll","hwnd","CreateSolidBrush", "int", $iBrushColor)
    $iBrush = $iBrush[0]

    Local $iBrushOld = _WinAPI_SelectObject($hDC, $iBrush)
    DLLCall("user32.dll","int","FillRect", "hwnd", $hDC, "ptr", DllStructGetPtr($DRAWITEMSTRUCT, "itmRect"), "hwnd", $iBrush)
    Local $tBuffer = DllStructCreate("char[256]")
    DllStructSetData($tBuffer, 1, $itmText)
    $itmText = DllStructGetData($tBuffer, 1)

    DllStructSetData($DRAWITEMSTRUCT, "itmRect", DllStructGetData($DRAWITEMSTRUCT, "itmRect", 1) + 10, 1)
    DllStructSetData($DRAWITEMSTRUCT, "itmRect", DllStructGetData($DRAWITEMSTRUCT, "itmRect", 2) + 5, 2)

    DllCall("user32.dll", "int", "DrawText", "hwnd", $hDC, "str", $itmText, "int", StringLen($itmText), _
            "ptr", DllStructGetPtr($DRAWITEMSTRUCT, "itmRect"), "int", $DT_LEFT)

    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

**Tweaky** · 11. Juli 2022

funkey

Danke, gefällt mir aber optisch nicht so

BugFix

Danke, gefällt mir aber optisch nicht so

Ich habe mal mit _WinAPI_GetSysColor($COLOR_MENU) die Farbe ermittelt. Ist dies wirklich die Hintergrundfarbe des Fensters oder nur die gleiche von einem anderen Element?

AutoIt

#Region    ;************ Includes ************
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GuiTab.au3>
#EndRegion ;************ Includes ************

;Farbe des Fensters
$farbe = "0x" & StringTrimLeft(Hex(Number(_WinAPI_GetSysColor($COLOR_MENU), 1), 8), 2)
ConsoleWrite($farbe & @CRLF)

; Tab colours
Global $aTabColours[4] = [$farbe, $farbe, $farbe, $farbe]

; Create GUI
Global $hGUI = GUICreate("Test", 400, 300)

; Create tab
Global $hTab = GUICtrlCreateTab(5, 5, 390, 290)

; Create Tab items and colour them
For $i = 0 To 3
    GUICtrlCreateTabItem("Tab item - " & $i)
    _GUICtrlTab_SetBkColor($hGUI, $hTab, $aTabColours[$i])
    GUICtrlCreateTabItem("")
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUICtrlTab_SetBkColor($hWnd, $hSysTab32, $sBkColor)

    ; Get Tab position
    Local $aTabPos = ControlGetPos($hWnd, "", $hSysTab32)
    ; Get size of user area
    Local $aTab_Rect = _GUICtrlTab_GetItemRect($hSysTab32, -1)
    ; Create label
    GUICtrlCreateLabel("", $aTabPos[0] + 2, $aTabPos[1] + $aTab_Rect[3] + 4, $aTabPos[2] - 6, $aTabPos[3] - $aTab_Rect[3] - 7)
    ; colour label
    GUICtrlSetBkColor(-1, $sBkColor)
    ; Disable label
    GUICtrlSetState(-1, $GUI_DISABLE)

EndFunc   ;==>_GUICtrlTab_SetBkColor

Alles anzeigen

**BugFix** · 11. Juli 2022

Zitat von Tweaky

Ich habe mal mit _WinAPI_GetSysColor($COLOR_MENU) die Farbe ermittelt. Ist dies wirklich die Hintergrundfarbe des Fensters oder nur die gleiche von einem anderen Element?

Kann ich nicht mit Gewissheit sagen. Bei mir war es übereinstimmend, $COLOR_WINDOW brachte jedoch völlig falsche Farben.

**Alina** · 11. Juli 2022

Zitat von BugFix

$TabItem_2 = GUICtrlCreateTabItem("Item3")

Muss das hier nicht $TabItem_3 heißen?
streiche 2, setze 3 ?

**BugFix** · 11. Juli 2022

Zitat von Alina

Muss das hier nicht $TabItem_3 heißen?

In Zeile 25 - ja Copy & Paste Error

**Alina** · 11. Juli 2022

Jetzt habe ich mit dem von BugFix etwas rumgespielt. Gefällt mit !

Und da Wochenstart ist, ein kleinen SPASS eingebaut.

Spoiler anzeigen

C

#include <FontConstants.au3>
#include <TabConstants.au3>
#include <WinAPI.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

Global Const $ODT_TAB        = 101
Global Const $ODS_SELECTED   = 0x0001
Global Const $ODA_DRAWENTIRE = 0x1
Global Const $ODS_FOCUS      = 0x0010

; TAB Namen
Global Const $_I1 = "Beispiel seeeeehr lang"
Global Const $_I2 = "Beispiel mittel lang"
Global Const $_I3 = "Beispiel kurz"

; Labelinhalt
Global Const $_t_1_l_1 = 'Maria Musterfrau.'
Global Const $_t_1_l_2 = 'Musterbeispielstr. 1-99'
Global Const $_t_1_l_3 = '12345 Beispielmusterstadt'

Global Const $_t_2_l_1 = 'ein mittellanger TAB'

Global Const $_t_3_l_1 = 'ein kurzer TAB'


; Items Farbe zuordnen
Global $aColTabItem[3][2] = [[$_I1,0x11AADD],[$_I2,0xEEBB99],[$_I3,0x4763FF]] ; [[TabItem-Bezeichnung,TabItem-Color]]
Global $hFont, $iBrush

; GUI erstellen
$hGUI = GUICreate("Original von BugFix / Verfälscht von Alina / LOL", 300, 200)
$hTab = GUICtrlCreateTab(5, 10, 290, 180, $TCS_OWNERDRAWFIXED)
$TabItem_1 = GUICtrlCreateTabItem($_I1) ; Bezeichnung im Array $aColTabItem muss identisch, wie hier sein!
; == erst alle Ctrl für Tab-Item_1 erstellen, dann das nächste Tab usw.
GUICtrlCreateLabel($_t_1_l_1,10,35)
GUICtrlCreateLabel($_t_1_l_2,10,50)
GUICtrlCreateLabel($_t_1_l_3,10,65)
$TabItem_2 = GUICtrlCreateTabItem($_I2)
GUICtrlCreateLabel($_t_2_l_1,10,35)
$TabItem_3 = GUICtrlCreateTabItem($_I3)  ; streiche $TabItem_2   //  setze $TabItem_3
GUICtrlCreateLabel($_t_3_l_1,10,35)
GUICtrlCreateTabItem("")

; kleine Spaßabfrage
If $_t_1_l_1 = 'Maria Musterfrau' Then
GUISetState()
Else
MsgBox(0,"","Phui ! Wer bist Du denn? *lach* " & @CRLF & "Auf jeden Fall bist Du nicht " & $_t_1_l_1)
Exit
EndIf


GUIRegisterMsg($WM_DRAWITEM, "WM_DRAWITEM")

_GUICtrlTab_SetCurSel($hTab, 2)
_GUICtrlTab_SetCurSel($hTab, 1)
_GUICtrlTab_SetCurSel($hTab, 0)
_GUICtrlTab_SetCurFocus($hTab, 0) ; welcher TAB soll bei starten gesehen werden

Do
Until GUIGetMsg() = -3
_WinAPI_DeleteObject($iBrush)

Func WM_DRAWITEM($hWnd, $Msg, $wParam, $lParam)
    Local $DRAWITEMSTRUCT = DllStructCreate("uint cType;uint cID;uint itmID;uint itmAction;uint itmState;" & _
                            "hwnd hItm;hwnd hDC;dword itmRect[4];dword itmData", $lParam)
    If DllStructGetData($DRAWITEMSTRUCT, "cType") <> $ODT_TAB Then Return $GUI_RUNDEFMSG
    If DllStructGetData($DRAWITEMSTRUCT, "itmAction") <> $ODA_DRAWENTIRE Then Return $GUI_RUNDEFMSG
    Local $itmID = DllStructGetData($DRAWITEMSTRUCT, "itmID")
    Local $hDC   = DllStructGetData($DRAWITEMSTRUCT, "hDC")
    Local $hItm  = DllStructGetData($DRAWITEMSTRUCT, "hItm")
    Local $itmText = $aColTabItem[$itmID][0], $iBrushColor = $aColTabItem[$itmID][1]

    DLLCall("gdi32.dll","int","SetBkMode", "hwnd", $hDC, "int", 1)

    Local $iBrush = DLLCall("gdi32.dll","hwnd","CreateSolidBrush", "int", $iBrushColor)
    $iBrush = $iBrush[0]

    Local $iBrushOld = _WinAPI_SelectObject($hDC, $iBrush)
    DLLCall("user32.dll","int","FillRect", "hwnd", $hDC, "ptr", DllStructGetPtr($DRAWITEMSTRUCT, "itmRect"), "hwnd", $iBrush)
    Local $tBuffer = DllStructCreate("char[256]")
    DllStructSetData($tBuffer, 1, $itmText)
    $itmText = DllStructGetData($tBuffer, 1)

    DllStructSetData($DRAWITEMSTRUCT, "itmRect", DllStructGetData($DRAWITEMSTRUCT, "itmRect", 1) + 5, 1)
    DllStructSetData($DRAWITEMSTRUCT, "itmRect", DllStructGetData($DRAWITEMSTRUCT, "itmRect", 2) + 2, 2)

    DllCall("user32.dll", "int", "DrawText", "hwnd", $hDC, "str", $itmText, "int", StringLen($itmText), _
            "ptr", DllStructGetPtr($DRAWITEMSTRUCT, "itmRect"), "int", $DT_LEFT)

    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Teilen