*.zip *.7z Archive durchsuchen ohne entpacken

Guten Abend miteinander,

gibt es mittlerweile - war ja ein paar Jahre abwesend - eine Funktion um Dateien in einem Archiv auszulesen ohne diese entpacken zu müssen?

Hab ne zeit lang gegoogelt, aber irgendwie kam ich da nicht richtig weiter, vor allem da die Threads älter als 10 Jahre waren.

Warum, weshalb, wieso brauche ich das?

Muss beruflich eine jede Menge Datensicherungen welche gezippt sind verwalten.

Aus einigen Files muss ich "Produktnummern" rauskopieren und in eine Excel Liste eintragen.

Ja ich weiss dass es die Möglichkeit mit 7z und AutoIT gibt, aber das ist ne gewaltige Datenmenge das alles zu entzippen.

Also ich möchte sämtliche Ordner und Dateistrukturen sehen, davon in einen speziellen Ordner reinsehen und hier ein bestimmtes Textfile durchsuchen.

LG

JoGi

Zitat von AspirinJunkie

Von 7-Zip gibt es eine Kommandozeilenversion, welche du super verwenden kannst um mit dieser per Skript zu arbeiten.
Natürlich kann man mit dieser sich auch eine Dateiliste ausgeben lassen.

Das kann man z.B. folgendermaßen machen - daraus ist auch schnell eine Funktion zur Wiederverwendung gebastelt:

AutoIt

#include <Array.au3>

; Pfad zur 7za.exe
Global $sPath7Za = @ScriptDir & "\7za.exe"

; Pfad zur Zip/7z-Datei
Global $sPathZipFile = "C:\Users\Admin\Downloads\7z2201-extra.7z"

; 7za Datei analysieren lassen
Global $hPID = Run('"' & $sPath7Za & '" l "' & $sPathZipFile & '"', "", @SW_HIDE, 2)

; warten bis Prozess beendet ist
ProcessWaitClose($hPID)

; Rückgabe in Variable einlesen:
Global $sFileList = StdoutRead($hPID)

; Dateiliste auslesen:
Global $aFilesRaw = StringRegExp($sFileList, '(?xm)^(20\d\d-\d\d-\d\d)\h(\d\d:\d\d:\d\d).{6}\h+(\d+)\h+(\d*)\h+(.+)$', 4)

; In 2D-Array konvertieren:
Global $aFiles[UBound($aFilesRaw)][5]
Global $iC = 0
For $aFile In $aFilesRaw
    For $i = 0 To 4
        $aFiles[$iC][$i] = $aFile[$i+1]
    Next
    $iC += 1
Next

; Dateiliste ausgeben:
_ArrayDisplay($aFiles, "Dateiliste", "", 64, "|", "Datum|Zeit|Größe|komprimiert|Name")

Alles anzeigen

Danke für die raschen Antworten.

Deine Version entzippt die Datei? Oder ist die Kommandozeilenversion so programmiert dass es wirklich nur mit Array ohne entzippen funktioniert?

LG

Vielen Dank für die Rückmeldungen! Also kann ich mir die Dateistrukturen ansehen und muss dann nur die benötigten Files entpacken und nicht den ganzen Ordner.

mfG

Alles Klar, Danke.

Gelöst.