MsgBox hooken und Countdown hinzufügen

**UEZ**

Ich möchte gerne einen Countdown in das Ok Button hinzufügen, das die vorgebene Zeit herunter zählt. Man könnte dies natürlich mit einer eigen gebastelten GUI realisieren, aber will ich nicht.

Das habe ich soweit zusammen gebastelt, funktioniert leider nicht und meine Augen fallen gerade zu:

AutoIt

#include <WindowsConstants.au3>
#include <WinAPIConstants.au3>
#include <WinAPISys.au3>
#include <WinAPIProc.au3>
#include <Timers.au3>

Global $tagCWPSTRUCT = "long lParam;long wParam;uint message;hwnd hwnd"
Global $HCBT_ACTIVATE = 5, $g_hMsgBoxHook, $g_hMod, $g_hThreadID, $g_hSubMsgBox, $g_SubMsgBox, $g_lPrevWnd, $g_BtnID, $g_HWND, $g_idTImer
Global $g_Time = 5

Func _WinAPI_SetDlgItemText($hDlg, $nIDDlgItem, $lpString) ;https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-setdlgitemtextw
    Local $aRet = DllCall("user32.dll", "int", "SetDlgItemText", "hwnd", $hDlg, "int", $nIDDlgItem, "str", $lpString)
    If @error Then Return SetError(@error, @extended, 0)
    Return $aRet[0]
EndFunc   ;==>_WinAPI_SetDlgItemText

Func _SubMsgBoxProc($hwnd, $iMsg, $wParam, $lParam)
    Switch $iMsg
        Case $WM_SHOWWINDOW
        Case $WM_TIMER
            _WinAPI_SetDlgItemText($g_BtnID, $IDOK, "OK [" & $g_Time & "]")
            $g_Time -= 1
            If $g_Time < 0 Then
                _Timer_KillTimer($g_idTImer, $g_HWND)
                _WinAPI_SetWindowLong($hwnd, $GWL_WNDPROC, $g_lPrevWnd)
            EndIf
            Return 0
        Case $WM_DESTROY
            _Timer_KillTimer($g_idTImer, $g_HWND)
            ;_WinAPI_SetWindowLong($hwnd, $GWL_WNDPROC, $g_lPrevWnd)
    EndSwitch
    Return _WinAPI_CallWindowProc($g_lPrevWnd, $hWnd, $iMsg, $wParam, $lParam)
EndFunc

Func _CBTHookProc($nCode, $wParam, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($g_hMsgBoxHook, $nCode, $wParam, $lParam)
    Local $tCWP = DllStructCreate($tagCWPSTRUCT, $lParam)
    Switch $nCode
        Case $HCBT_ACTIVATE
            $g_HWND = HWnd($wParam)
            If _WinAPI_GetClassName($g_HWND) = "#32770" Then
                $g_idTImer = _Timer_SetTimer($g_HWND, 1000)
                $g_BtnID = HWnd($wParam) ;_WinAPI_GetDlgItem($wParam, 1)
                _WinAPI_SetDlgItemText($g_BtnID, $IDOK, "OK [" & $g_Time & "]")
                $g_lPrevWnd = _WinAPI_SetWindowLong($g_HWND, $GWL_WNDPROC, DllCallbackGetPtr($g_SubMsgBox))
            EndIf
    EndSwitch
    Return _WinAPI_CallNextHookEx($g_hMsgBoxHook, $nCode, $wParam, $lParam)
EndFunc


$g_SubMsgBox = DllCallbackRegister("_SubMsgBoxProc", "long", "hwnd;uint;wparam;lparam")
$g_MsgProc = DllCallbackRegister("_CBTHookProc", "int", "uint;wparam;lparam")
$g_hMod = _WinAPI_GetModuleHandle(0)
$g_hThreadID = _WinAPI_GetCurrentThreadId()
$g_hMsgBoxHook = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($g_MsgProc), Null, $g_hThreadID)
MsgBox(0, "Test", "This is a test message box!")
_WinAPI_UnhookWindowsHookEx($g_hMsgBoxHook)
_WinAPI_UnhookWindowsHookEx($g_lPrevWnd)
DllCallbackFree($g_SubMsgBox)
DllCallbackFree($g_MsgProc)

Alles anzeigen

Könnt ihr den Fehler sehen?

**Oscar**

Zitat von UEZ

Ich möchte gerne einen Countdown in das Ok Button hinzufügen, das die vorgebene Zeit herunter zählt.

Es gäbe da auch noch die Möglichkeit mittels der Timer-UDF:

AutoIt

#include <MsgBoxConstants.au3>
#include <Timers.au3>

Global $hDummyGui = GUICreate('dummy')
Global $iSec = 10
_Timer_SetTimer($hDummyGui, 1000, '_ShowSeconds')

MsgBox($MB_ICONQUESTION, 'Time-Test', 'Diese MsgBox wird nach ' & $iSec & ' Sekunden geschlossen!', $iSec)

_Timer_KillAllTimers($hDummyGui)

Func _ShowSeconds($hWnd, $Msg, $iIDTimer, $dwTime)
    #forceref $hWnd, $Msg, $iIDTimer, $dwTime
    $iSec -= 1
    ControlSetText('Time-Test', '', '[CLASS:Button; INSTANCE:1]', 'Ok  ' & $iSec & 's')
EndFunc

Alles anzeigen

**UEZ**

Oscar danke für deine Alternative!

Das hier funktioniert jetzt:

AutoIt

;Coded by UEZ build 2023-04-27 beta

#include <Timers.au3>
#include <WinAPIConstants.au3>
#include <WinAPIGdi.au3>
#include <WinAPIProc.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

Global $HCBT_ACTIVATE = 5, $g_hMsgBoxHook, $g_hMod, $g_hThreadID, $g_hSubMsgBox, $g_SubMsgBox, $g_lPrevWnd, $g_HWND, $g_idTImer, $g_
Global $g_Time = 5

Func _WinAPI_SetDlgItemText($hDlg, $nIDDlgItem, $lpString) ;https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-setdlgitemtextw
    Local $aRet = DllCall("user32.dll", "int", "SetDlgItemText", "hwnd", $hDlg, "int", $nIDDlgItem, "str", $lpString)
    If @error Then Return SetError(@error, @extended, 0)
    Return $aRet[0]
EndFunc   ;==>_WinAPI_SetDlgItemText

Func _SubMsgBoxProc($hwnd, $iMsg, $wParam, $lParam)
    Switch $iMsg
        Case $WM_SHOWWINDOW
        Case $WM_CTLCOLORDLG, $WM_CTLCOLORSTATIC
;~             Local $tLOGBRUSH = DllStructCreate("uint lbStyle;long lbColor;ulong_ptr lbHatch")
;~             _WinAPI_SetBkColor($wParam, 0xFEDCBA)
;~             $tLOGBRUSH.lbColor = 0xFEDCBA
;~             DllCall("gdi32.dll", "handle", "CreateBrushIndirect", "struct*", $tLOGBRUSH)
;~             Return 0
        Case $WM_TIMER
            Local $sText = "Exit [" & $g_Time & "]"
            $g_Time -= 1
;~             ControlSetText($g_HWND, "", "[CLASS:Button; INSTANCE:1]", $sText)
            _WinAPI_SetDlgItemText($hWnd, $IDOK + 1, $sText)
            ConsoleWrite($g_Time & @CRLF)

            If $g_Time < 0 Then
                _Timer_KillTimer($g_HWND, $g_idTImer)
                _WinAPI_SetWindowLong($hwnd, $GWL_WNDPROC, $g_lPrevWnd)
                GUIDelete($hwnd)
            EndIf
            Return 0
        Case $WM_DESTROY
            _Timer_KillTimer($g_HWND, $g_idTImer)
            _WinAPI_SetWindowLong($hwnd, $GWL_WNDPROC, $g_lPrevWnd)
    EndSwitch
    Return _WinAPI_CallWindowProc($g_lPrevWnd, $hWnd, $iMsg, $wParam, $lParam)
EndFunc   ;==>_SubMsgBoxProc

Func _CBTHookProc($nCode, $wParam, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($g_hMsgBoxHook, $nCode, $wParam, $lParam)
    Switch $nCode
        Case $HCBT_ACTIVATE
            $g_HWND = HWnd($wParam)
            If _WinAPI_GetClassName($g_HWND) = "#32770" Then
                $g_idTImer = _Timer_SetTimer($g_HWND, 1000)
                _WinAPI_SetDlgItemText($wParam, $IDOK, "Exit [" & $g_Time & "]")
                $g_lPrevWnd = _WinAPI_SetWindowLong($g_HWND, $GWL_WNDPROC, DllCallbackGetPtr($g_SubMsgBox))
            EndIf
    EndSwitch
    Return _WinAPI_CallNextHookEx($g_hMsgBoxHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_CBTHookProc


$g_SubMsgBox = DllCallbackRegister("_SubMsgBoxProc", "long", "hwnd;uint;wparam;lparam")
$g_MsgProc = DllCallbackRegister("_CBTHookProc", "int", "uint;wparam;lparam")
$g_hMod = _WinAPI_GetModuleHandle(0)
$g_hThreadID = _WinAPI_GetCurrentThreadId()
$g_hMsgBoxHook = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($g_MsgProc), Null, $g_hThreadID)
MsgBox(0, "Test", "This is a test message box with a counter!", $g_Time + 2)
_WinAPI_UnhookWindowsHookEx($g_hMsgBoxHook)
_WinAPI_UnhookWindowsHookEx($g_lPrevWnd)
DllCallbackFree($g_SubMsgBox)
DllCallbackFree($g_MsgProc)

Alles anzeigen

Kürzere Version angelehnt an funkey's Methode:

AutoIt

;Coded by UEZ build 2023-04-29 beta

#include <Timers.au3>
#include <WinAPIConstants.au3>
#include <WinAPIGdi.au3>
#include <WinAPIProc.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

Const $HCBT_CREATEWND = 3, $HCBT_DESTROYWND = 4, $HCBT_ACTIVATE = 5, $g_iFlagDefault = BitOR($MB_TOPMOST, $MB_ICONINFORMATION)
Global $g_hMsgBoxHook, $g_hSubMsgBox, $g_idTImer, $g_sBtn1_Txt = "Close", $g_sBtn2_Txt, $g_sBtn3_Txt
Global $g_Timeout = 0

Func _WinAPI_SetDlgItemText($hDlg, $nIDDlgItem, $lpString) ;https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-setdlgitemtextw
    Local $aRet = DllCall("user32.dll", "int", "SetDlgItemText", "hwnd", $hDlg, "int", $nIDDlgItem, "str", $lpString)
    If @error Then Return SetError(@error, @extended, 0)
    Return $aRet[0]
EndFunc   ;==>_WinAPI_SetDlgItemText

Func _TimerProc($hwnd, $iMsg, $wParam, $lParam)
    If $g_Timeout <= 1 Then
        WinClose($hwnd)
    Else
        $g_Timeout -= 1
        _WinAPI_SetDlgItemText($hWnd, $IDOK + 1, $g_sBtn1_Txt & " [" & $g_Timeout & "]")
    EndIf
EndFunc   ;==>_TimerProc

Func _CBTHookProc($nCode, $wParam, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($g_hMsgBoxHook, $nCode, $wParam, $lParam)
    Local Const $hHWND = HWnd($wParam)
    Switch $nCode
        Case $HCBT_ACTIVATE
            If _WinAPI_GetClassName($hHWND) = "#32770" Then
                If $g_Timeout Then $g_idTImer = _Timer_SetTimer($hHWND, 1000, "_TimerProc")
                _WinAPI_SetDlgItemText($wParam, $IDOK, $g_Timeout ? $g_sBtn1_Txt & " [" & $g_Timeout & "]" : $g_sBtn1_Txt)
            EndIf
        Case $HCBT_DESTROYWND
            If _WinAPI_GetClassName($hHWND) = "#32770" Then _Timer_KillTimer($hHWND, $g_idTImer)
    EndSwitch
    Return _WinAPI_CallNextHookEx($g_hMsgBoxHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_CBTHookProc

Func MsgBoxEx($sText, $sTitle = Default, $iTimeout = 0, $iFlag = Default, $sBtn_Txt = Default, $hParentHWND = "")
    If $sBtn_Txt <> Default Then $g_sBtn1_Txt = $sBtn_Txt
    If $iFlag = Default Then $iFlag = $g_iFlagDefault
    $g_Timeout = $iTimeout
    $g_MsgProc = DllCallbackRegister("_CBTHookProc", "int", "uint;wparam;lparam")
    Local Const $hThreadID = _WinAPI_GetCurrentThreadId()
    $g_hMsgBoxHook = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($g_MsgProc), Null, $hThreadID)
    If $sTitle = Default Then $sTitle = "Information"
    Local Const $iReturn = MsgBox($iFlag, $sTitle, $sText, $iTimeout, $hParentHWND)
    _WinAPI_UnhookWindowsHookEx($g_hMsgBoxHook)
    DllCallbackFree($g_MsgProc)
    Return $iReturn
EndFunc   ;==>MsgBoxEx

ConsoleWrite(MsgBoxEx("This is a test", "Information", 5) & @CRLF)

Alles anzeigen

**funkey**

Hallo,

hab das mal in meine HookDlgBox-UDF eingebaut.

HookDlgBox.au3

AutoIt

#include-once
#include <winapi.au3>
#include <timers.au3>

Global Const $tagCBT_CREATEWND = "ptr lpcs;HWND tagCBT_CREATEWND"
Global Const $tagCREATESTRUCT = "ptr lpCreateParams;handle hInstance;HWND hMenu;HWND hwndParent;int cy;int cx;int y;int x;LONG style;ptr lpszName;ptr lpszClass;DWORD dwExStyle"

Global $g__hProcDlgBox = DllCallbackRegister("__DlgBox_CbtHookProc", "LRESULT", "int;WPARAM;LPARAM")
Global $g__TIdDlgBox = _WinAPI_GetCurrentThreadId()
Global $g__hHookDlgBox = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($g__hProcDlgBox), 0, $g__TIdDlgBox)

Global Const $g__MaxDlgBtns = 5 ; maximum of 5 buttons to rename text
Global Const $g__MaxDlgItemId = 11 ; maximun ID of buttons to search is 11 as this is the maximun used in Messagebox

Global $g__DlgBoxPosX, $g__DlgBoxPosY, $g__DlgBoxWidth, $g__DlgBoxHeight
Global $g__aDlgBoxBtnText[$g__MaxDlgBtns]

Global $g__DlgBtnCount = 0
Global $g_DlgBoxTimeout = 0
Global $g_DlgBoxTimeCtrlNum, $g_DlgBoxTimeCtrlId
Global $g_DlgBoxTimerId

_DlgBox_SetDefaults()

OnAutoItExitRegister("__DlgBox_UnregisterHook")


Func _DlgBox_SetButtonNames($TxtBtn1 = Default, $TxtBtn2 = Default, $TxtBtn3 = Default, $TxtBtn4 = Default, $TxtBtn5 = Default)
    $g__aDlgBoxBtnText[0] = $TxtBtn1
    $g__aDlgBoxBtnText[1] = $TxtBtn2
    $g__aDlgBoxBtnText[2] = $TxtBtn3
    $g__aDlgBoxBtnText[3] = $TxtBtn4
    $g__aDlgBoxBtnText[4] = $TxtBtn5

    $g__DlgBtnCount = @NumParams
EndFunc   ;==>_DlgBox_SetButtonNames

Func _DlgBox_SetPosition($x = Default, $y = Default) ;only for MsgBox, not working and not needed for InputBox
    $g__DlgBoxPosX = $x
    $g__DlgBoxPosY = $y
EndFunc   ;==>_DlgBox_SetPosition

Func _DlgBox_SetSize($w = Default, $h = Default)
    $g__DlgBoxWidth = $w
    $g__DlgBoxHeight = $h
EndFunc   ;==>_DlgBox_SetSize

Func _DlgBox_SetDefaults()
    $g__DlgBoxPosX = Default
    $g__DlgBoxPosY = Default
    $g__DlgBoxWidth = Default
    $g__DlgBoxHeight = Default
    For $i = 0 To UBound($g__aDlgBoxBtnText) - 1
        $g__aDlgBoxBtnText[$i] = Default
    Next
    $g_DlgBoxTimeout = 0
EndFunc   ;==>_DlgBox_SetDefaults

Func _DlgBox_SetTimeout($iTimeout = 0, $CtrlId = 1)
    $g_DlgBoxTimeout = $iTimeout
    $g_DlgBoxTimeCtrlNum = $CtrlId
EndFunc   ;==>_DlgBox_SetTimeout

Func __DlgBox_CbtHookProc($nCode, $wParam, $lParam)
    Local $tcw, $tcs
    Local $iSearch = 0
    Local $ahBtn[$g__DlgBtnCount]
    If $nCode < 0 Then
        Return _WinAPI_CallNextHookEx($g__hHookDlgBox, $nCode, $wParam, $lParam)
    EndIf

    Switch $nCode
        Case 3 ;5=HCBT_CREATEWND
            If _WinAPI_GetClassName(HWnd($wParam)) = "#32770" Then ;Dialog window class
                $tcw = DllStructCreate($tagCBT_CREATEWND, $lParam)
                $tcs = DllStructCreate($tagCREATESTRUCT, DllStructGetData($tcw, "lpcs"))

                If $g__DlgBoxPosX <> Default Then DllStructSetData($tcs, "x", $g__DlgBoxPosX)
                If $g__DlgBoxPosY <> Default Then DllStructSetData($tcs, "y", $g__DlgBoxPosY)
                If $g__DlgBoxWidth <> Default Then DllStructSetData($tcs, "cx", $g__DlgBoxWidth)
                If $g__DlgBoxHeight <> Default Then DllStructSetData($tcs, "cy", $g__DlgBoxHeight)

                If $g_DlgBoxTimeout <> 0 Then
                    $g_DlgBoxTimerId = _Timer_SetTimer(HWnd($wParam), 1000, "_UpdateTime")
                EndIf
            EndIf
        Case 5 ;5=HCBT_ACTIVATE
            If _WinAPI_GetClassName(HWnd($wParam)) = "#32770" Then ;Dialog window class
                For $i = 1 To $g__MaxDlgItemId
;~                     ConsoleWrite($i & " - " & $iSearch & " - " & _WinAPI_GetDlgItemText($wParam, $i) & @CRLF)
                    If IsHWnd(_WinAPI_GetDlgItem($wParam, $i)) Then
                        If $g_DlgBoxTimeout > 0 Then
                            If $g__aDlgBoxBtnText[$iSearch] = Default Then $g__aDlgBoxBtnText[$iSearch] = _WinAPI_GetDlgItemText($wParam, $i)
                            If $iSearch == $g_DlgBoxTimeCtrlNum - 1 Then
                                $g_DlgBoxTimeCtrlId = $i
                                If $g__aDlgBoxBtnText[$iSearch] <> Default Then _WinAPI_SetDlgItemText($wParam, $i, $g__aDlgBoxBtnText[$iSearch] & " [" & $g_DlgBoxTimeout & "]")
                            Else
                                If $g__aDlgBoxBtnText[$iSearch] <> Default Then _WinAPI_SetDlgItemText($wParam, $i, $g__aDlgBoxBtnText[$iSearch])
                            EndIf
                        Else
                            If $g__aDlgBoxBtnText[$iSearch] <> Default Then _WinAPI_SetDlgItemText($wParam, $i, $g__aDlgBoxBtnText[$iSearch])
                        EndIf

                        $iSearch += 1
                        ;Vorzeitiges Abbrechen der Schleife deaktiviert
;~                         If $iSearch >= UBound($ahBtn) Then ExitLoop
                    EndIf
                Next
            EndIf
            ;Bugfix: OK-Button wechselt von ID1 nach ID2 wenn er alleine angezeigt wird!???
            If $iSearch = 1 And $g_DlgBoxTimeCtrlId = 1 Then $g_DlgBoxTimeCtrlId = 2
        Case 4 ;4=HCBT_DESTROYWND
            If _WinAPI_GetClassName(HWnd($wParam)) = "#32770" Then ;Dialog window class
                _Timer_KillTimer(HWnd($wParam), $g_DlgBoxTimerId)
                $g_DlgBoxTimeout = 0
            EndIf
    EndSwitch
    Return _WinAPI_CallNextHookEx($g__hHookDlgBox, $nCode, $wParam, $lParam)
EndFunc   ;==>__DlgBox_CbtHookProc

Func _UpdateTime($hWnd, $iMsg, $iIDTimer, $iTime)
    #forceref $hWnd, $iMsg, $iIDTimer, $iTime
    $g_DlgBoxTimeout -= 1
    _WinAPI_SetDlgItemText($hWnd, $g_DlgBoxTimeCtrlId, $g__aDlgBoxBtnText[$g_DlgBoxTimeCtrlNum - 1] & " [" & $g_DlgBoxTimeout & "]")
    If $g_DlgBoxTimeout <= 0 Then
        WinClose($hWnd)
    EndIf
EndFunc   ;==>_UpdateTime

Func __DlgBox_UnregisterHook()
    _WinAPI_UnhookWindowsHookEx($g__hHookDlgBox)
    DllCallbackFree($g__hProcDlgBox)
EndFunc   ;==>__DlgBox_UnregisterHook

Func _WinAPI_SetDlgItemText($hDlg, $nIDDlgItem, $lpString)
    Local $aRet = DllCall('user32.dll', "int", "SetDlgItemText", _
            "hwnd", $hDlg, _
            "int", $nIDDlgItem, _
            "str", $lpString)
    Return $aRet[0]
EndFunc   ;==>_WinAPI_SetDlgItemText

Func _WinAPI_GetDlgItemText($hDlg, $nIDDlgItem)
    Local $aRet = DllCall('user32.dll', "uint", "GetDlgItemTextW", _
            "hwnd", $hDlg, _
            "int", $nIDDlgItem, _
            "wstr", "", _
            "int", 1000)
    Return $aRet[3]
EndFunc   ;==>_WinAPI_GetDlgItemText
</timers.au3></winapi.au3>

Alles anzeigen

HookDlgBox Timeout Beispiel

AutoIt

#include "HookDlgBox.au3"

Global $Timeout = 5

_DlgBox_SetTimeOut($Timeout, 1)
_DlgBox_SetButtonNames("one", "two", "three")

Global $iRet1 = MsgBox(3, "Test 1", "Custom button texts", $Timeout)
ConsoleWrite($iRet1 & @CRLF)


Global $iRet2 = MsgBox(3, "Test 2", "Custom button texts", $Timeout)
ConsoleWrite($iRet2 & @CRLF)

_DlgBox_SetTimeOut($Timeout, 2)

Global $iRet3 = MsgBox(3, "Test 3", "Custom button texts")
ConsoleWrite($iRet3 & @CRLF)

_DlgBox_SetTimeOut($Timeout, 3)

Global $iRet4 = MsgBox(3, "Test 4", "Custom button texts")
ConsoleWrite($iRet4 & @CRLF)

Alles anzeigen

**UEZ**

funkey

Velted

UEZ ,

AutoIt

                _Timer_KillTimer($g_idTImer, $g_HWND) ; <<<<< umgekehrte Parameterreihenfolge

Das hat immerhin den drolligen Effekt, dass sich das Skript bei Ablauf der Zeit beendet. Ich habe ein Weilchen gerätselt, warum das passiert.

**UEZ**

Velted : stimmt, danke für den Hinweis.

**UEZ**

Zitat von funkey

Hallo,

hab das mal in meine HookDlgBox-UDF eingebaut.

HookDlgBox.au3

AutoIt

#include-once
#include <WinAPI.au3>
#include <Timers.au3>

Global Const $tagCBT_CREATEWND = "ptr lpcs;HWND tagCBT_CREATEWND"
Global Const $tagCREATESTRUCT = "ptr lpCreateParams;handle hInstance;HWND hMenu;HWND hwndParent;int cy;int cx;int y;int x;LONG style;ptr lpszName;ptr lpszClass;DWORD dwExStyle"

Global $g__hProcDlgBox = DllCallbackRegister("__DlgBox_CbtHookProc", "LRESULT", "int;WPARAM;LPARAM")
Global $g__TIdDlgBox = _WinAPI_GetCurrentThreadId()
Global $g__hHookDlgBox = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($g__hProcDlgBox), 0, $g__TIdDlgBox)

Global Const $g__MaxDlgBtns = 5 ; maximum of 5 buttons to rename text
Global Const $g__MaxDlgItemId = 11 ; maximun ID of buttons to search is 11 as this is the maximun used in Messagebox

Global $g__DlgBoxPosX, $g__DlgBoxPosY, $g__DlgBoxWidth, $g__DlgBoxHeight
Global $g__aDlgBoxBtnText[$g__MaxDlgBtns]

Global $g__DlgBtnCount = 0
Global $g_DlgBoxTimeout = 0
Global $g_DlgBoxTimeCtrlNum, $g_DlgBoxTimeCtrlId
Global $g_DlgBoxTimerId

_DlgBox_SetDefaults()

OnAutoItExitRegister("__DlgBox_UnregisterHook")


Func _DlgBox_SetButtonNames($TxtBtn1 = Default, $TxtBtn2 = Default, $TxtBtn3 = Default, $TxtBtn4 = Default, $TxtBtn5 = Default)
    $g__aDlgBoxBtnText[0] = $TxtBtn1
    $g__aDlgBoxBtnText[1] = $TxtBtn2
    $g__aDlgBoxBtnText[2] = $TxtBtn3
    $g__aDlgBoxBtnText[3] = $TxtBtn4
    $g__aDlgBoxBtnText[4] = $TxtBtn5

    $g__DlgBtnCount = @NumParams
EndFunc   ;==>_DlgBox_SetButtonNames

Func _DlgBox_SetPosition($x = Default, $y = Default) ;only for MsgBox, not working and not needed for InputBox
    $g__DlgBoxPosX = $x
    $g__DlgBoxPosY = $y
EndFunc   ;==>_DlgBox_SetPosition

Func _DlgBox_SetSize($w = Default, $h = Default)
    $g__DlgBoxWidth = $w
    $g__DlgBoxHeight = $h
EndFunc   ;==>_DlgBox_SetSize

Func _DlgBox_SetDefaults()
    $g__DlgBoxPosX = Default
    $g__DlgBoxPosY = Default
    $g__DlgBoxWidth = Default
    $g__DlgBoxHeight = Default
    For $i = 0 To UBound($g__aDlgBoxBtnText) - 1
        $g__aDlgBoxBtnText[$i] = Default
    Next
    $g_DlgBoxTimeout = 0
EndFunc   ;==>_DlgBox_SetDefaults

Func _DlgBox_SetTimeOut($iTimeout = 0, $CtrlId = 1)
    $g_DlgBoxTimeout = $iTimeout
    $g_DlgBoxTimeCtrlNum = $CtrlId
EndFunc

Func __DlgBox_CbtHookProc($nCode, $wParam, $lParam)
    Local $tcw, $tcs
    Local $iSearch = 0
    Local $ahBtn[$g__DlgBtnCount]
    If $nCode < 0 Then
        Return _WinAPI_CallNextHookEx($g__hHookDlgBox, $nCode, $wParam, $lParam)
    EndIf

    Switch $nCode
        Case 3 ;5=HCBT_CREATEWND
            If _WinAPI_GetClassName(HWnd($wParam)) = "#32770" Then ;Dialog window class
                $tcw = DllStructCreate($tagCBT_CREATEWND, $lParam)
                $tcs = DllStructCreate($tagCREATESTRUCT, DllStructGetData($tcw, "lpcs"))

                If $g__DlgBoxPosX <> Default Then DllStructSetData($tcs, "x", $g__DlgBoxPosX)
                If $g__DlgBoxPosY <> Default Then DllStructSetData($tcs, "y", $g__DlgBoxPosY)
                If $g__DlgBoxWidth <> Default Then DllStructSetData($tcs, "cx", $g__DlgBoxWidth)
                If $g__DlgBoxHeight <> Default Then DllStructSetData($tcs, "cy", $g__DlgBoxHeight)

                If $g_DlgBoxTimeout <> 0 Then
                    $g_DlgBoxTimerId = _Timer_SetTimer(HWnd($wParam), 1000, "_UpdateTime")
                EndIf
            EndIf
        Case 5 ;5=HCBT_ACTIVATE
            If _WinAPI_GetClassName(HWnd($wParam)) = "#32770" Then ;Dialog window class
                For $i = 1 To $g__MaxDlgItemId
                    If IsHWnd(_WinAPI_GetDlgItem($wParam, $i)) Then
                        If $g_DlgBoxTimeout > 0 Then
                            If $iSearch == $g_DlgBoxTimeCtrlNum - 1 Then
                                $g_DlgBoxTimeCtrlId = $i
                                If $g__aDlgBoxBtnText[$iSearch] <> Default Then _WinAPI_SetDlgItemText($wParam, $i, $g__aDlgBoxBtnText[$iSearch] & " [" & $g_DlgBoxTimeout & "]")
                            Else
                                If $g__aDlgBoxBtnText[$iSearch] <> Default Then _WinAPI_SetDlgItemText($wParam, $i, $g__aDlgBoxBtnText[$iSearch])
                            EndIf
                        Else
                            If $g__aDlgBoxBtnText[$iSearch] <> Default Then _WinAPI_SetDlgItemText($wParam, $i, $g__aDlgBoxBtnText[$iSearch])
                        EndIf

                        $iSearch += 1
                        If $iSearch >= UBound($ahBtn) Then ExitLoop
                    EndIf
                Next
            EndIf
        Case 4 ;4=HCBT_DESTROYWND
            If _WinAPI_GetClassName(HWnd($wParam)) = "#32770" Then ;Dialog window class
                _Timer_KillTimer(HWnd($wParam), $g_DlgBoxTimerId)
                $g_DlgBoxTimeout = 0
            EndIf
    EndSwitch
    Return _WinAPI_CallNextHookEx($g__hHookDlgBox, $nCode, $wParam, $lParam)
EndFunc   ;==>__DlgBox_CbtHookProc

Func _UpdateTime($hWnd, $iMsg, $iIDTimer, $iTime)
    #forceref $hWnd, $iMsg, $iIDTimer, $iTime
;~     ConsoleWrite($hWnd&" - "&$iMsg&" - "&$iIDTimer&" - "&$iTime & @CRLF)

    $g_DlgBoxTimeout -= 1
    _WinAPI_SetDlgItemText($hWnd, $g_DlgBoxTimeCtrlId, $g__aDlgBoxBtnText[$g_DlgBoxTimeCtrlNum - 1] & " [" & $g_DlgBoxTimeout & "]")
    If $g_DlgBoxTimeout <= 0 Then
        WinClose($hWnd)
    EndIf
EndFunc   ;==>_UpdateTime


Func __DlgBox_UnregisterHook()
    _WinAPI_UnhookWindowsHookEx($g__hHookDlgBox)
    DllCallbackFree($g__hProcDlgBox)
EndFunc   ;==>__DlgBox_UnregisterHook

Func _WinAPI_SetDlgItemText($hDlg, $nIDDlgItem, $lpString)
    Local $aRet = DllCall('user32.dll', "int", "SetDlgItemText", _
            "hwnd", $hDlg, _
            "int", $nIDDlgItem, _
            "str", $lpString)
    Return $aRet[0]
EndFunc   ;==>_WinAPI_SetDlgItemText

Alles anzeigen

HookDlgBox Timeout Beispiel

AutoIt

#include "HookDlgBox.au3"

Global $Timeout = 5

_DlgBox_SetTimeOut($Timeout, 1)
_DlgBox_SetButtonNames("one", "two", "three")

Global $iRet1 = MsgBox(3, "Test 1", "Custom button texts", $Timeout)
ConsoleWrite($iRet1 & @CRLF)


Global $iRet2 = MsgBox(3, "Test 2", "Custom button texts", $Timeout)
ConsoleWrite($iRet2 & @CRLF)

_DlgBox_SetTimeOut($Timeout, 2)

Global $iRet3 = MsgBox(3, "Test 3", "Custom button texts")
ConsoleWrite($iRet3 & @CRLF)

_DlgBox_SetTimeOut($Timeout, 3)

Global $iRet4 = MsgBox(3, "Test 4", "Custom button texts")
ConsoleWrite($iRet4 & @CRLF)

Alles anzeigen

Dieses Beispiel funktioniert nicht:

AutoIt

#include <MsgBoxConstants.au3>
#include "HookDlgBox.au3"

Global $Timeout = 5

_DlgBox_SetTimeOut($Timeout, 1)
_DlgBox_SetButtonNames("Exit")
MsgBox(BitOR($MB_TOPMOST, $MB_ICONINFORMATION), "Information", "View has been refreshed!", $Timeout)

Anscheinend geht es nur mit $MB_YESNOCANCEL.

**funkey**

Hab da wohl zu wenig getestet...

Sollte jetzt funktionieren, hab's oben geändert.

Und jetzt auch mit den Standard-Button-Texten, also ohne SetButtonNames().

**UEZ**

funkey : Prima, werde es testen und mich melden, falls ich was finde...