Timer Sonstiges

WhiteHorse

Hallo, ich probiere schon eine ganze weile hin und her.

Ich hatte sowas Ähnliches schoneinmal ich habe den Code mir mal aus dem Internet geholt.

Ich möchte ein Timer so wie der hier mit Stunden, Minuten und Sekunden.

Alles schön und gut, aber dieser wird mit einem Button gestartet. Ich möchte diesen aber mit der Hotkey taste F7 Starten.

Ich habe einiges probiert leider verstehe ich nicht richtig wie überhaupt der Code aufgebaut ist, weil ich mich mit Timer noch nicht so beschäftigt habe, aber vielleicht kann mir einer Licht ins dunkle bringen?

Überarbeitet

While 1

;Switch GUIGetMsg()

;Case $go

If $HotkeyF7Zaehler = 2 Then

$running = Not $running

GUICtrlSetData($go, $button[$running])

$end = Convert($input)

$timer=TimerInit()

EndIf

; Case Else

; EndSwitch

If $running And TimerDiff($timer)>=$end Then

$running = False

GUICtrlSetData($go, $button[$running])

MsgBox(0, 'Info', 'Timer End')

;Call ("MainMenu")

Call ("Jump2")

EndIf

Ich weiß einige werden jetzt sagen was ist das den für ein durcheinander, ich habe alles versucht und stehe vor einem Rätsel. Das Hauptproblem in dem Code wird hier liegen $running = Not $running aber wie gesagt ich weiß nicht genau wie so ein Timer Code richtig gebaut wird ich fand dieses Skript so perfekt, weil es fast alles beinhaltet, was ich brauche.

Ich lade das Original auch mal hoch

Original

Code

GUICreate('timer', 220, 70, Default, Default, 0x10C80000)
Dim $end, $timer, $running = False, $input[3], $name[3]=['Stunden','Minuten','Sekunden'], $button[2]=['Start','Stop']
For $i=0 To 2
	GUICtrlCreateGroup($name[$i], 5+70*$i, 5, 70, 40)
	$input[$i]=GUICtrlCreateInput('', 10+70*$i, 20, 60, 20, 1)
Next
$go=GUICtrlCreateButton('Start', 5, 45, 210, 20)

While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $go
			$running = Not $running
			GUICtrlSetData($go, $button[$running])
			$end = Convert($input)
			$timer=TimerInit()
		Case Else
			If $running And TimerDiff($timer)>=$end Then
				$running = False
				GUICtrlSetData($go, $button[$running])
				MsgBox(0, 'Info', 'Game Over')
			EndIf
	EndSwitch
WEnd

Func Convert($array)
	Return 1000*(60*(60*(GUICtrlRead($array[0]))+GUICtrlRead($array[1]))+GUICtrlRead($array[2]))
EndFunc

Alles anzeigen

Wie gesagt es soll mit einem Hotkey gestartet werden der Button kann von mir aus bleiben damit sehe ich, ob es läuft oder nicht.

Gruß Whitey

**Musashi**

Falls Du einen sogenannten "Countdown Timer" suchst, dann probiere mal dies :

AutoIt

; Quelle : https://www.autoitscript.com/forum/topic/127667-how-to-create-a-countdown-timer-in-autoit/#elControls_885650_menu
; - leicht modifiziert

#include <WindowsConstants.au3>

HotKeySet("{ESC}", _Terminate)
HotKeySet("{F7}", _StartCountdown)

Global $SS_CENTER, $_CountStartVal = 60000, $_Minutes, $_Seconds, $b_Running = False, $bInit = False

$_GuiCountDown = GUICreate ( "CountDown...", 400, 150, @DesktopWidth/2 -200, @DesktopHeight/2 -75, $WS_EX_TOPMOST  )
GUISetBkColor (0xA6CAF0)
$TimeLabel = GUICtrlCreateLabel ( "F7=Start", 30, 10, 380, 100, $SS_CENTER )
GUICtrlSetFont ( -1, 50, 400 )
GUISetState ( )
WinSetOnTop ( $_GuiCountDown, "", 1 )

While 1
    If Not $bInit Then $TimeTicks = TimerInit ( )
    If $b_Running Then
        $bInit = True
        _Check ( )
    EndIf
    Sleep (200)
WEnd

Func _Check ( )
    $_CountStartVal -= TimerDiff ( $TimeTicks )
    $TimeTicks = TimerInit ( )
    Local $_MinCalc = Int ( $_CountStartVal / ( 60 * 1000 ) ), $_SecCalc = $_CountStartVal - ( $_MinCalc * 60 * 1000 )
    $_SecCalc = Int ( $_SecCalc / 1000 )
    If $_MinCalc <= 0 And $_SecCalc <= 0 Then
        GUISetBkColor ( 0xFF0000, $_GuiCountDown )
        GUICtrlSetData ( $TimeLabel, "Bye !" )
        Sleep ( 1000 )
        ; If @Compiled Then Shutdown ( 13 )
        Exit
    Else
        If $_MinCalc <> $_Minutes Or $_SecCalc <> $_Seconds Then
            $_Minutes = $_MinCalc
            $_Seconds = $_SecCalc
            GUICtrlSetData ( $TimeLabel, StringFormat ( "%02u" & ":" & "%02u", $_Minutes, $_Seconds ) )
            If $_Minutes = 0 And $_Seconds <= 10 Then
                Beep ( 1200, 100 )
                GUISetBkColor ( 0xA093FF, $_GuiCountDown )
            EndIf
        EndIf
    EndIf
EndFunc ;==> _Check ( )

Func _StartCountdown()
    $b_Running = True
EndFunc   ;==>_StartCountdown

Func _Terminate()
    Exit 0
EndFunc   ;==>Terminate

Alles anzeigen

WhiteHorse

Zitat von Musashi

Falls Du einen sogenannten "Countdown Timer" suchst, dann probiere mal dies :

AutoIt

; Quelle : https://www.autoitscript.com/forum/topic/127667-how-to-create-a-countdown-timer-in-autoit/#elControls_885650_menu
; - leicht modifiziert

#include <WindowsConstants.au3>

HotKeySet("{ESC}", _Terminate)
HotKeySet("{F7}", _StartCountdown)

Global $SS_CENTER, $_CountStartVal = 60000, $_Minutes, $_Seconds, $b_Running = False, $bInit = False

$_GuiCountDown = GUICreate ( "CountDown...", 400, 150, @DesktopWidth/2 -200, @DesktopHeight/2 -75, $WS_EX_TOPMOST  )
GUISetBkColor (0xA6CAF0)
$TimeLabel = GUICtrlCreateLabel ( "F7=Start", 30, 10, 380, 100, $SS_CENTER )
GUICtrlSetFont ( -1, 50, 400 )
GUISetState ( )
WinSetOnTop ( $_GuiCountDown, "", 1 )

While 1
    If Not $bInit Then $TimeTicks = TimerInit ( )
    If $b_Running Then
        $bInit = True
        _Check ( )
    EndIf
    Sleep (200)
WEnd

Func _Check ( )
    $_CountStartVal -= TimerDiff ( $TimeTicks )
    $TimeTicks = TimerInit ( )
    Local $_MinCalc = Int ( $_CountStartVal / ( 60 * 1000 ) ), $_SecCalc = $_CountStartVal - ( $_MinCalc * 60 * 1000 )
    $_SecCalc = Int ( $_SecCalc / 1000 )
    If $_MinCalc <= 0 And $_SecCalc <= 0 Then
        GUISetBkColor ( 0xFF0000, $_GuiCountDown )
        GUICtrlSetData ( $TimeLabel, "Bye !" )
        Sleep ( 1000 )
        ; If @Compiled Then Shutdown ( 13 )
        Exit
    Else
        If $_MinCalc <> $_Minutes Or $_SecCalc <> $_Seconds Then
            $_Minutes = $_MinCalc
            $_Seconds = $_SecCalc
            GUICtrlSetData ( $TimeLabel, StringFormat ( "%02u" & ":" & "%02u", $_Minutes, $_Seconds ) )
            If $_Minutes = 0 And $_Seconds <= 10 Then
                Beep ( 1200, 100 )
                GUISetBkColor ( 0xA093FF, $_GuiCountDown )
            EndIf
        EndIf
    EndIf
EndFunc ;==> _Check ( )

Func _StartCountdown()
    $b_Running = True
EndFunc   ;==>_StartCountdown

Func _Terminate()
    Exit 0
EndFunc   ;==>Terminate

Alles anzeigen

Hi, danke für deine Idee aber das mit den Input Feldern so wie oben ist am besten ich möchte nur das die Aktion mit Hotkey F7 gestartet wird.

Dazu muss ich sagen, dass ich es so gemacht habe das, wenn F7 gedrückt wurde +1 für $HotkeyF7Zaehler gezählt wird und wenn $HotkeyF7Zaehler = 2 dann Starte den Timer und das klappt nicht richtig das geht Start, Stop, Start, Stop, Start, Stop

**Moombas**

Wie wäre es wenn du mal den ganzen relevanten Code (also setzen des Kotkeys, die Funktionen selber etc.) postest (idealerweise hier als AutoIt Code anzeigen lassen).

Dann knnen wir viel besser schauen was du falsch machst.

Dein Auszug oben sieht verwirrend aus.

WhiteHorse

Code

$HotkeyF7Zaehler = 0

Call ("Aufnahme1")

Func Aufnahme1 ()
Global $Aufnahme1 = GUICreate('Aufnahme1', 220, 70, Default, Default, 0x10C80000)
Global $end
Global $timer
Global $running = True
Global $input[3]
Global $name[3]=['Stunden','Minuten','Sekunden']
Global $button[2]=['Start','Stop']

For $i=0 To 2
    GUICtrlCreateGroup($name[$i], 5+70*$i, 5, 70, 40)
    $input[$i]=GUICtrlCreateInput('', 10+70*$i, 20, 60, 20, 1)
Next
;GUICtrlSetData($input[0], IniRead($ini, "1","Stunden", ""))
;GUICtrlSetData($input[1], IniRead($ini, "2","Minuten", ""))
;GUICtrlSetData($input[2], IniRead($ini, "3","Sec", ""))
Global $go=GUICtrlCreateButton('Start', 5, 45, 210, 20)
Call ("Jump1")
;Call ("MainMenu")


EndFunc


Func Jump1 ()
HotKeySet ("{F7}", "Jump1") ;MIT F7 STARTET...................................
$HotkeyF7Zaehler += 1
MsgBox ("", "YES", "+1 Weiter", "2")
While 1

            If $HotkeyF7Zaehler = 2 Then
            $running = Not $running ;[Problem muss an dieser Zeile hier liegen] Start Stop Start Stop....
            GUICtrlSetData($go, $button[$running])
            $end = Convert($input)
            $timer=TimerInit()
            EndIf
            If $running And TimerDiff($timer)>=$end Then
                $running = False
                GUICtrlSetData($go, $button[$running])
            EndIf

        ;Switch GUIGetMsg()
            ;Case -3
            ;GUISetState $Aufnahme1 @SW_HIDE
            ;GUIDelete($Aufnahme1)
            ;Call ("MainMenu")





WEnd
EndFunc



Func Convert($array)
    Return 1000*(60*(60*(GUICtrlRead($array[0]))+GUICtrlRead($array[1]))+GUICtrlRead($array[2]))
EndFunc

Alles anzeigen

Das ist der Code von Aufnahme1 und wenn er losläuft, macht er Start Stop Start Stop... er soll aber normal durchlaufen.

Siehe oben Original, bloß dort wird der Timer mit einem Button gestartet :-/

Das die While mit Call ("Jump1") nochmal angesprochen wird ist richtig, weil ich nachdem ich den Timer erstellt habe nochmal den Weg verlasse. Dient dazu das ich später wieder in die While hinein komme.

PS ich habe den Code nochmal etwas ausgemistet jetzt ist es etwas übersichtlicher.

**Moombas**

Mein erster Blick:

1. Warum rufst du Funktionen mit "Call" auf, das ist nur nötig, wenn der Funktionsname (als String) "generiert" wird.

2. Variablen in einer Funktion sind immer Local zu definieren, brauchst du sie auch außerhalb, gehört die Definition auch nach draußen:

3. Hotkeyset, gehört an den Anfang des Scriptes.

4. Du erstellst jedes mal einen Button/Gruppe/inputs, wenn die Funktion "Aufnahme1 aufgerufen wird. Du solltest ihn lieber in der GUI erstellen und ausblenden und hier nur wieder einblenden!

5. du setzt den Zähler nie runter, bedeutet mit jedem Aufruf von "Jump1" wird es 1 mehr. Damit passt deine Abfrage spätestens beim 3. mal nicht mehr (startest mit 0) wobei du die 1 aaktuell auch nicht abfragst.

**Moombas**

Ich hab das ganze mal ein wenig überarbeitet und mein test war Erfolgreich:

AutoIt

Opt('MustDeclareVars', 1)
#include <GUIConstantsEx.au3>

;GUI
Global $Aufnahme, $go, $input[4]

;Globale Variablen
Global Const $ini = 'anyinifile.ini' ;trag hier die Inifile ein für deinen Timer

HotKeySet ("{F7}", "Jump1")

_CreateTimerGUI() ;Beispielfunktion um die GUI zu erstellen, nur deinen geposteten Part gesetzt, nicht den Rest der noch erforderlich wäre!
Jump1()
;~ MainMenu()

Func _CreateTimerGUI()
Local $name[4]=[3, 'Stunden','Minuten','Sekunden']
    $input[0] = $name[0]

    $Aufnahme = GUICreate('Aufnahme1', 370, 70, Default, Default, 0x10C80000)
    For $i=1 To $name[0]
        GUICtrlCreateGroup($name[$i], (5+70)*$i,  5, 70, 40, Default)
        $input[$i] = GUICtrlCreateInput('', (7+70)*$i, 20, 60, 20, 1)
    Next
    $go = GUICtrlCreateButton('Start', 75, 45, 220, 20)
EndFunc

Func Jump1()
Local $end, $timer
Local $running = False
Local $Button[2]=['Start','Stop']
    GUISetState(@SW_SHOW, $Aufnahme)

    ;Achtung: Sektion angepasst, da alle Timerwerte in einer Sektion platz finden
    GUICtrlSetData($input[1], IniRead($ini, "Timer","Stunden" , 0)) ;ggf. den Defaultwert (0) (wenn die Ini nicht gefunden/gelesen werden kann) ändern
    GUICtrlSetData($input[2], IniRead($ini, "Timer","Minuten" , 0)) ;ggf. den Defaultwert (0) (wenn die Ini nicht gefunden/gelesen werden kann) ändern
    GUICtrlSetData($input[3], IniRead($ini, "Timer","Sekunden", 2)) ;ggf. den Defaultwert (2) (wenn die Ini nicht gefunden/gelesen werden kann) ändern

    While 100
        If $running And TimerDiff($timer)>=$end Then
            $running = False
            GUICtrlSetData($go, $button[$running])
            MsgBox ("", "Test", "Timer abgelaufen", "")
        EndIf

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                GUISetState(@SW_HIDE, $Aufnahme)
                ExitLoop
            Case $go
                If $running = False Then
                    $running = True
                    GUICtrlSetData($go, $button[$running])
                    $end = Convert($input)
                    $timer = TimerInit()
                Else ;
                    $running = False
                    GUICtrlSetData($go, $button[$running])
                EndIf
        EndSwitch
    WEnd
    GUISetState(@SW_HIDE, $Aufnahme)
EndFunc

Func Convert($array)
    Return 1000*(60*(60*(GUICtrlRead($array[1]))+GUICtrlRead($array[2]))+GUICtrlRead($array[3]))
EndFunc

Alles anzeigen

WhiteHorse

Zitat von Moombas

Ich hab das ganze mal ein wenig überarbeitet und mein test war Erfolgreich:

AutoIt

Opt('MustDeclareVars', 1)
#include <GUIConstantsEx.au3>

;GUI
Global $Aufnahme, $go, $input[4]

;Globale Variablen
Global Const $ini = 'anyinifile.ini' ;trag hier die Inifile ein für deinen Timer

HotKeySet ("{F7}", "Jump1")

_CreateTimerGUI() ;Beispielfunktion um die GUI zu erstellen, nur deinen geposteten Part gesetzt, nicht den Rest der noch erforderlich wäre!
Jump1()
;~ MainMenu()

Func _CreateTimerGUI()
Local $name[4]=[3, 'Stunden','Minuten','Sekunden']
    $input[0] = $name[0]

    $Aufnahme = GUICreate('Aufnahme1', 370, 70, Default, Default, 0x10C80000)
    For $i=1 To $name[0]
        GUICtrlCreateGroup($name[$i], (5+70)*$i,  5, 70, 40, Default)
        $input[$i] = GUICtrlCreateInput('', (7+70)*$i, 20, 60, 20, 1)
    Next
    $go = GUICtrlCreateButton('Start', 75, 45, 220, 20)
EndFunc

Func Jump1()
Local $end, $timer
Local $running = False
Local $Button[2]=['Start','Stop']
    GUISetState(@SW_SHOW, $Aufnahme)

    ;Achtung: Sektion angepasst, da alle Timerwerte in einer Sektion platz finden
    GUICtrlSetData($input[1], IniRead($ini, "Timer","Stunden" , 0)) ;ggf. den Defaultwert (0) (wenn die Ini nicht gefunden/gelesen werden kann) ändern
    GUICtrlSetData($input[2], IniRead($ini, "Timer","Minuten" , 0)) ;ggf. den Defaultwert (0) (wenn die Ini nicht gefunden/gelesen werden kann) ändern
    GUICtrlSetData($input[3], IniRead($ini, "Timer","Sekunden", 2)) ;ggf. den Defaultwert (2) (wenn die Ini nicht gefunden/gelesen werden kann) ändern

    While 100
        If $running And TimerDiff($timer)>=$end Then
            $running = False
            GUICtrlSetData($go, $button[$running])
            MsgBox ("", "Test", "Timer abgelaufen", "")
        EndIf

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                GUISetState(@SW_HIDE, $Aufnahme)
                ExitLoop
            Case $go
                If $running = False Then
                    $running = True
                    GUICtrlSetData($go, $button[$running])
                    $end = Convert($input)
                    $timer = TimerInit()
                Else ;
                    $running = False
                    GUICtrlSetData($go, $button[$running])
                EndIf
        EndSwitch
    WEnd
    GUISetState(@SW_HIDE, $Aufnahme)
EndFunc

Func Convert($array)
    Return 1000*(60*(60*(GUICtrlRead($array[1]))+GUICtrlRead($array[2]))+GUICtrlRead($array[3]))
EndFunc

Alles anzeigen

danke, aber der Timer wird auch mit dem Button gestartet und wenn ich F7 drücke öffnet sich ein neues Fenster darüber?

**Moombas**

F7 habe ich vergessen zu testen, sorry

**Moombas**

Hier die leicht abgeänderte Version (jetzt funktioniert auch das F7):

(Dein Style macht irgendwie keinen Sinn (es gibt kein Flag, das 0x00C80000 enthält), daher hab ich es mal geändert)

AutoIt

Opt('MustDeclareVars', 1)
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

;GUI
Global $Aufnahme, $go, $input[4]

;Globale Variablen
Global Const $ini = 'anyinifile.ini' ;trag hier die Inifile ein für deinen Timer

HotKeySet("{F7}", "PressTimerButton")

_CreateTimerGUI() ;Beispielfunktion um die GUI zu erstellen, nur deinen geposteten Part gesetzt, nicht den Rest der noch erforderlich wäre!
Jump1()

Func _CreateTimerGUI()
Local $name[4]=[3, 'Stunden','Minuten','Sekunden']
    $input[0] = $name[0]

    $Aufnahme = GUICreate('Aufnahme1', 370, 70, Default, Default, BitOR($WS_VISIBLE, $WS_OVERLAPPEDWINDOW)) ;vorher:0x10C80000 = 0x10CF0000?

    For $i=1 To $name[0]
        GUICtrlCreateGroup($name[$i], (5+70)*$i,  5, 70, 40, Default)
        $input[$i] = GUICtrlCreateInput('', (7+70)*$i, 20, 60, 20, 1)
    Next

    $go = GUICtrlCreateButton('Start', 75, 45, 220, 20)
EndFunc

Func Jump1()
Local $end, $timer
Local $running = False
Local $Button[2]=['Start','Stop']
    GUICtrlSetData($go, $button[$running])
    GUISetState(@SW_SHOW, $Aufnahme)

    ;Achtung: Sektion angepasst, da alle Timerwerte in einer Sektion platz finden
    GUICtrlSetData($input[1], IniRead($ini, "Timer","Stunden" , 0)) ;ggf. den Defaultwert (0) (wenn die Ini nicht gefunden/gelesen werden kann) ändern
    GUICtrlSetData($input[2], IniRead($ini, "Timer","Minuten" , 0)) ;ggf. den Defaultwert (0) (wenn die Ini nicht gefunden/gelesen werden kann) ändern
    GUICtrlSetData($input[3], IniRead($ini, "Timer","Sekunden", 2)) ;ggf. den Defaultwert (2) (wenn die Ini nicht gefunden/gelesen werden kann) ändern

    While 1
        If $running And TimerDiff($timer)>=$end Then
            $running = False
            GUICtrlSetData($go, $button[$running])
            MsgBox ("", "Test", "Timer abgelaufen", "")
        EndIf

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
;~                 GUISetState(@SW_HIDE, $Aufnahme)
;~                 MainMenu()
                ExitLoop
            Case $go
                If $running = False Then
                    $running = True
                    GUICtrlSetData($go, $button[$running])
                    $end = Convert($input)
                    $timer = TimerInit()
                Else ;
                    $running = False
                    GUICtrlSetData($go, $button[$running])
                EndIf
        EndSwitch
        sleep(100)
    WEnd
    GUISetState(@SW_HIDE, $Aufnahme)
EndFunc

Func PressTimerButton()
    ControlClick('', '', $go)
EndFunc

Func Convert($array)
    Return 1000*(60*(60*(GUICtrlRead($array[1]))+GUICtrlRead($array[2]))+GUICtrlRead($array[3]))
EndFunc

Alles anzeigen

WhiteHorse

sorry, aber der macht bei mir sobald ich F7 drücke das selbe Fenster nochmal auf ist das nur bei mir so?

(er öffnet die GUI ein zweites mal)

WhiteHorse

ok ich weiß warum, es muss an meiner Tastatur liegen ich habe mal ein anderen HotKey benutzt und jetzt geht es, vielen Dank!

**Moombas**

Ich empfehle dir halt Dringend Variablen so wenig wie möglichGlobal zu definieren und (wenn nicht nötig) kein Call für den Aufruf einer Funktion zu benutzen.

Auch verwende lieber Bitor() um die Flags zu setzen, dann weiß man später noch, was du da gesetzt hast, mit dem puren Hex-Wert kann später keiner mehr was anfangen bzw. muss sich das mühsam zusammen suchen.

Und das was ich in meinem Code hier gemacht habe (über Kommentare bei den globalen Variablen) kannst du diese dort dennoch "Gruppieren" und weißt somit wozu du diese brauchst.

Der Trick für den Hotkey isst ja eigentlich nur, das dieser einen manuellen Click auf den Button simuliert, sprich: Wichti war nur das der Button an sich funktioniert.

Ich hoffe du hast den Code auch verstanden den ich da zusammen gezimmert hat (mit Sicherheit noch weiter optimierbar aber dafür würde das restliche Skript evtl. fehlen bzw. ich wollte es dann nicht zu sehr von deinem ursprünglichen Code bringen).

Velted

Moin!

WhiteHorse:

Nur als weitere Alternative: Du kannst die Start/Stop-Routine in eine eigenen Funktion auslagern, die dann solwohl per Button als auch per Hotkey aufgerufen werden kann:

AutoIt

Global $End, $Timer, $Running = False, $Input[3]
Global $Name[3] = ['Stunden', 'Minuten', 'Sekunden']
Global $Button[2] = ['Start', 'Stop']

GUICreate('Timer', 220, 70, Default, Default, 0x10C80000)
For $I = 0 To 2
    GUICtrlCreateGroup($Name[$I], 5 + 70 * $I, 5, 70, 40)
    $Input[$I]=GUICtrlCreateInput('0', 10 +70 * $I, 20, 60, 20, 0x2001) ; ES_CENTER + ES_NUMBER
Next
$Go = GUICtrlCreateButton('Start', 5, 45, 210, 20)
GUISetState()
HotKeySet("{F7}", "_StartStop")

While True
    Switch GUIGetMsg()
        Case -3 ; $GUI_EVENT_CLOSE
            Exit
        Case $Go
            _StartStop()
        Case Else
            If $Running And TimerDiff($Timer) >= $End Then
                _StartStop()
            EndIf
    EndSwitch
WEnd

Func _StartStop()
    $running = Not $running
    GUICTRLSETDATA($GO, $BUTTON[$RUNNING])
    If $Running = False Then
        MsgBox(0, 'Info', 'Game Over')
    Else
        $End = _Convert($Input)
        $Timer = TimerInit()
    EndIf
EndFunc

Func _Convert($Array)
    Return ((GUICtrlRead($Array[0]) * 3600) + (GUICtrlRead($Array[1]) * 60) + GUICtrlRead($Array[2])) * 1000
EndFunc

Alles anzeigen

Moombas:

Zitat

(Dein Style macht irgendwie keinen Sinn (es gibt kein Flag, das 0x00C80000 enthält), daher hab ich es mal geändert)

AutoIt

Global Const $WS_CAPTION = 0x00C00000
Global Const $WS_SYSMENU = 0x00080000
Global Const $WS_OVERLAPPEDWINDOW = BitOR($WS_CAPTION, $WS_MAXIMIZEBOX, $WS_MINIMIZEBOX, $WS_OVERLAPPED, $WS_SYSMENU, $WS_THICKFRAME)

0x00C8000 entspricht damit $WS_OVERLAPPEDWINDOW - $WS_MAXIMIZEBOX - $WS_MINIMIZEBOX - $WS_THICKFRAME - $WS_OVERLAPPED (0).

**Moombas**

Ah ok, dann war ich da falsch beim Zusammensetzen.

Noch ein Grund für:

Zitat

Auch verwende lieber Bitor() um die Flags zu setzen, dann weiß man später noch, was du da gesetzt hast, mit dem puren Hex-Wert kann später keiner mehr was anfangen bzw. muss sich das mühsam zusammen suchen.

WhiteHorse

Hallo, danke für die Hilfe

Zitat von Moombas

Ich empfehle dir halt Dringend Variablen so wenig wie möglichGlobal zu definieren und (wenn nicht nötig) kein Call für den Aufruf einer Funktion zu benutzen.
Auch verwende lieber Bitor() um die Flags zu setzen, dann weiß man später noch, was du da gesetzt hast, mit dem puren Hex-Wert kann später keiner mehr was anfangen bzw. muss sich das mühsam zusammen suchen.
Und das was ich in meinem Code hier gemacht habe (über Kommentare bei den globalen Variablen) kannst du diese dort dennoch "Gruppieren" und weißt somit wozu du diese brauchst.
Der Trick für den Hotkey isst ja eigentlich nur, das dieser einen manuellen Click auf den Button simuliert, sprich: Wichti war nur das der Button an sich funktioniert.
Ich hoffe du hast den Code auch verstanden den ich da zusammen gezimmert hat (mit Sicherheit noch weiter optimierbar aber dafür würde das restliche Skript evtl. fehlen bzw. ich wollte es dann nicht zu sehr von deinem ursprünglichen Code bringen).

Ja, das mit dem Call hab ich nun auch gelernt, dachte so konnte man immer eine Funktion aufrufen.

aber wenn z.b

StartTest ()

Func StartTest ()

Genügt dann weiß ich Bescheid danke für deinen Tipp, das mit dem (Flag 0x00C80000) ist nicht von mir wie gesagt ich habe das Skript aus dem Internet und hab es nur kopiert, weil es so gut gepasst hatte.

Wenn ich ehrlich bin, weiß ich nicht einmal was ein Flag ist

Lerne auch nur Stück für Stück dazu

Velted auch dir danke ich für deine Hilfe

WhiteHorse

@Moombas kannst du mir mal bitte noch erklären warum meine ini Datei nicht mehr geht, es steht zwar was in der ini aber die Input Felder werden nicht von der ini übernommen. Wenn jetzt aber "GUICtrlSetData($input1[3], IniRead($ini, "3","Sekunden", 2)) ;ggf. den Defaultwert (2) (wenn die Ini nicht gefunden/gelesen werden kann) ändern"

darin steht, trägt er die 2 ein so wie es im Code steht aber in der ini steht was anderes und die Zahlen trägt er nicht in die Input Felder.

Ich kann den fehler jetzt auch nicht finden.

**Musashi**

Zitat von WhiteHorse

Wenn jetzt aber "GUICtrlSetData($input1[3], IniRead($ini, "3","Sekunden", 2)) ;ggf. den Defaultwert (2) (wenn die Ini nicht gefunden/gelesen werden kann) ändern" darin steht, trägt er die 2 ein so wie es im Code steht aber in der ini steht was anderes und die Zahlen trägt er nicht in die Input Felder.

Hier ein kleines Demoprogramm für eine baugleiche .ini-Datei :

AutoIt

#include <Array.au3>
Global $aInput[4]
Global Const $sIniFile = @ScriptDir & '\timer.ini' ; <=== hier den Namen deiner .ini-Datei einsetzen

If Not FileExists($sIniFile) Then
    Exit MsgBox(BitOR(4096, 16), "", "Fehler beim Lesen von : " & $sIniFile & @CRLF)
EndIf

; .ini Werte lesen :
$aInput[0] = 3
$aInput[1] = IniRead($sIniFile, "Timer","Stunden" , 0)
$aInput[2] = IniRead($sIniFile, "Timer","Minuten" , 0)
$aInput[3] = IniRead($sIniFile, "Timer","Sekunden" ,0)

_ArrayDisplay($aInput, $sIniFile)

Alles anzeigen

timer.ini (nur zum Test - die Endung .ini ist als Dateianhang leider nicht zulässig) :

Code

[timer]
Stunden=12 
Minuten=7
Sekunden=6

WhiteHorse :

1. Was kommt heraus, wenn Du deine .ini-Datei verwendest ?

2. Prüfe mal die Codierung deiner .ini-Datei :

Sollte diese z.B. als UTF-8 mit BOM codiert sein, dann wird der erste Eintrag (hier der [Sektionsname]) und damit alle zugehörigen key=value Einträge überlesen.

**Moombas**

Zitat von WhiteHorse

@Moombas kannst du mir mal bitte noch erklären warum meine ini Datei nicht mehr geht, es steht zwar was in der ini aber die Input Felder werden nicht von der ini übernommen. Wenn jetzt aber "GUICtrlSetData($input1[3], IniRead($ini, "3","Sekunden", 2)) ;ggf. den Defaultwert (2) (wenn die Ini nicht gefunden/gelesen werden kann) ändern"
darin steht, trägt er die 2 ein so wie es im Code steht aber in der ini steht was anderes und die Zahlen trägt er nicht in die Input Felder.
Ich kann den fehler jetzt auch nicht finden.

Hast du denn $ini richtig gesetzt?

Bei meinem Code wäre das in Zeile 9, wo du den Dateinamen & Pfad natürlich noch anpassen musst.

Und ändere in Zeile 20 (bei meinem Code) BitOR($WS_VISIBLE, $WS_OVERLAPPEDWINDOW) in BitOR($WS_CAPTION, $WS_MAXIMIZEBOX, $WS_MINIMIZEBOX, $WS_OVERLAPPED, $WS_SYSMENU, $WS_THICKFRAME) (Danke nochmal Velted für das aufschlüsseln) damit du später weißt was da gemacht wurde.

WhiteHorse

ok, nochmal vielen Dank

Jetzt geht es, den Pfad von der ini war richtig alles gut

Nur wenn ich das in mein Hauptprogramm oder Skript, egal wie man es nennt, einfüge und ich die Aufnahme1 aufrufe, gebe ich meine Zeit ein usw.

Jetzt sagt er mir bei Minuten und Sekunden gleich nachdem ich den Timer gestartet habe, ist zu Ende. Obwohl die Zeit eigentlich noch nicht vorbei ist

bei den Stunden läuft er länger, nur Minuten und Sekunden ist er nach 2 sec durch

obwohl 1 min und 1 sec darin steht

bei dem Test Code den du mir geschickt hast Moombas geht es, im Hauptcode geht es nicht.