ListView Markierung mit den Pfeiltasten bewegen

**UEZ**

Hat jemand ein Idee, wie ich den Code erweitern kann, sodass die Selektion mit den Pfeiltasten nach oben / unten verschoben werden kann?

AutoIt

;coded by LarsJ
#include <Array.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Opt("MustDeclareVars", 1)

Global $hGui, $hLV, $iLVx, $iLVy, $aHit[2] = [-1, -1]    ; $aHit contains row & col of marked cell

Example()


Func Example()

    $hGui = GUICreate("Mark Cell in Listview", 500, 540)

    Local $idLV0 = GUICtrlCreateListView("Column 0|Column 1|Column 2", 25, 10, 250, 500)
    For $i = 0 To 99
        GUICtrlCreateListViewItem("Cell " & $i & ".0" & "|Cell " & $i & ".1" & "|Cell " & $i & ".2", $idLV0)
    Next
    $hLV = GUICtrlGetHandle($idLV0)
    $iLVx = 25
    $iLVy = 10

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom

        Case $hLV
            Local $iSelectedItem = _GUICtrlListView_GetSelectionMark($hLV)
            ConsoleWrite(_GUICtrlListView_GetSelectedIndices($hLV) & @CRLF)
            Switch $iCode
                ; Handle arrow key presses for selection movement

                Case $LVN_KEYDOWN
                    Local $tNMLVKEYDOWN = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                    Local $iVKey = DllStructGetData($tNMLVKEYDOWN, "VKey")
;~                     If $iSelectedItem > -1 Then
;~                         Local $iNewIndex = -1
;~                         If $iVKey = 38 Then ; Up arrow key
;~                             $iNewIndex = $iSelectedItem - 1
;~                         ElseIf $iVKey = 40 Then ; Down arrow key
;~                             $iNewIndex = $iSelectedItem + 1
;~                         EndIf
;~                         ConsoleWrite($iNewIndex & @CRLF)
;~                         If $iNewIndex > -1 And $iNewIndex < _GUICtrlListView_GetItemCount($hLV) Then
;~                             _GUICtrlListView_SetItemSelected($hLV, $iNewIndex, True, False)
;~                             _GUICtrlListView_RedrawItems($hLV, $iNewIndex, $iNewIndex)
;~                         EndIf
;~                     EndIf

                Case $LVN_ITEMCHANGED
                    Local $tNMLISTVIEW, $iItem, $aInfo
                    $tNMLISTVIEW = DllStructCreate($tagNMLISTVIEW, $lParam)
                    $iItem = DllStructGetData($tNMLISTVIEW, "Item")
                    _GUICtrlListView_SetItemSelected($hLV, $iItem, False)
                    _GUICtrlListView_SetItemState($hLV, $iItem, 0, $LVIS_FOCUSED)

                    Local $aInfo = GUIGetCursorInfo($hGui)
                    If $aInfo[2] Then
                        $aInfo = _GUICtrlListView_SubItemHitTest($hLV, $aInfo[0] - $iLVx, $aInfo[1] - $iLVy)
                        If $aInfo[0] > -1 And $aInfo[1] > -1 And $aInfo[0] = $iItem Then
                            If $aHit[0] > -1 Then _GUICtrlListView_RedrawItems($hLV, $aHit[0], $aHit[0])
                            If $aHit[0] <> $aInfo[0] Or $aHit[1] <> $aInfo[1] Then
                                $aHit[0] = $aInfo[0] ; Row
                                $aHit[1] = $aInfo[1] ; Col
                            Else
                                $aHit[0] = -1 ; Row
                                $aHit[1] = -1 ; Col
                            EndIf
                            _GUICtrlListView_RedrawItems($hLV, $iItem, $iItem)
                        EndIf
                    EndIf
                Case $NM_CUSTOMDRAW
                    Local $tNMLVCUSTOMDRAW = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $dwDrawStage = DllStructGetData($tNMLVCUSTOMDRAW, "dwDrawStage")

                    Switch $dwDrawStage                     ; Holds a value that specifies the drawing stage

                        Case $CDDS_PREPAINT                 ; Before the paint cycle begins
                            Return $CDRF_NOTIFYITEMDRAW     ; Notify the parent window of any ITEM-related drawing operations

                        Case $CDDS_ITEMPREPAINT             ; Before painting an item
                            Return $CDRF_NOTIFYSUBITEMDRAW  ; Notify the parent window of any SUBITEM-related drawing operations

                        Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM) ; Before painting a subitem
                            Local $dwItemSpec = DllStructGetData($tNMLVCUSTOMDRAW, "dwItemSpec") ; Item index
                            Local $iSubItem = DllStructGetData($tNMLVCUSTOMDRAW, "iSubItem") ; Subitem index
                            Local $uItemState = DllStructGetData($tNMLVCUSTOMDRAW, "uItemState") ; Item state
                            If $dwItemSpec = $aHit[0] Then ; Marked row
                                Switch $iSubItem
                                    Case 0 To 1 ; Marked column
                                        DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", 0xFFFFFF) ; Forecolor white
                                        DllStructSetData($tNMLVCUSTOMDRAW, "clrTextBk", 0xCC6600) ; Backcolor dark blue, BGR
                                    Case Else ; Other columns
                                        DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", 0x000000) ; Forecolor black
                                        DllStructSetData($tNMLVCUSTOMDRAW, "ClrTextBk", 0xFFFFFF) ; Backcolor white
                                EndSwitch
                            Else ; Other rows
                                DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", 0x000000)
                                DllStructSetData($tNMLVCUSTOMDRAW, "ClrTextBk", 0xFFFFFF)
                            EndIf
                            Return $CDRF_NEWFONT            ; $CDRF_NEWFONT must be returned after changing font or colors

                    EndSwitch

            EndSwitch

    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

Wichtig ist, dass nur die ersten zwei Zellen markiert bleiben.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Sehr im unreinen.... den Mauszeiger via Tastatur (Pfeiltasten) eine neue Position zuweisen?

LG

Peter

**Moombas**

Wie wäre es mit

In den jeweiligen Funktionen für die Pfeiltaste die aktuelle Markierung auslesen und entsprechend der Listview (+/-1) neu zuweisen
Erzwingen der oberen beiden Zeilen, diese zu markieren

Wobei ich beim Testen mit deinem Code, nie die ID des angeklickten ListView Items bekomme, sondern immer 0 (keins ausgewählt).

Außerdem musst du den Style vom LV ändern, damit du mehrere Zeilen auswählen kannst. Default ist meine ich, das du nur 1 Zeile zur Zeit auswählen kannst.

Edit:

Deine Zeile 74 verhindert zusätzlich eine Multiauswahl.

Velted

Moin UEZ,

vielleicht so?

AutoIt

;coded by LarsJ
#include <Array.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Opt("MustDeclareVars", 1)

Global $hGui, $hLV, $iLVx, $iLVy, $aHit[2] = [-1, -1]    ; $aHit contains row & col of marked cell

Example()


Func Example()

    $hGui = GUICreate("Mark Cell in Listview", 500, 540)

    Local $idLV0 = GUICtrlCreateListView("Column 0|Column 1|Column 2", 25, 10, 250, 500)
    For $i = 0 To 99
        GUICtrlCreateListViewItem("Cell " & $i & ".0" & "|Cell " & $i & ".1" & "|Cell " & $i & ".2", $idLV0)
    Next
    $hLV = GUICtrlGetHandle($idLV0)
    $iLVx = 25
    $iLVy = 10

    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom

        Case $hLV
            Local $iSelectedItem = _GUICtrlListView_GetSelectionMark($hLV)
            ; ConsoleWrite(_GUICtrlListView_GetSelectedIndices($hLV) & @CRLF)

            Switch $iCode
                ; Handle arrow key presses for selection movement
                Case $NM_CUSTOMDRAW
                    
                    Local $tNMLVCUSTOMDRAW = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $dwDrawStage = DllStructGetData($tNMLVCUSTOMDRAW, "dwDrawStage")
                    Local $dwItemSpec = DllStructGetData($tNMLVCUSTOMDRAW, "dwItemSpec") ; Item index
                    Local $iSubItem = DllStructGetData($tNMLVCUSTOMDRAW, "iSubItem") ; Subitem index
                    Local $uItemState = DllStructGetData($tNMLVCUSTOMDRAW, "uItemState") ; Item state

                    Switch $dwDrawStage                     ; Holds a value that specifies the drawing stage

                        Case $CDDS_PREPAINT                 ; Before the paint cycle begins
                            Return $CDRF_NOTIFYITEMDRAW     ; Notify the parent window of any ITEM-related drawing operations

                        Case $CDDS_ITEMPREPAINT             ; Before painting an item
                            ConsoleWrite("Row: " & $dwItemSpec & " - State: " & $uItemState & @CRLF)
                            If _GUICtrlListView_GetItemSelected($hLV, $dwItemSpec) Then
                                Return $CDRF_NOTIFYSUBITEMDRAW  ; Notify the parent window of any SUBITEM-related drawing operations
                            Else
                                Return $CDRF_DODEFAULT
                            EndIf

                        Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM) ; Before painting a subitem
                            DllStructSetData($tNMLVCUSTOMDRAW, "uItemState", BitAND($uItemState, BitNOT(0x11)))
                            Switch $iSubItem
                                Case 0 To 1 ; Marked column
                                    DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", 0xFFFFFF) ; Forecolor white
                                    DllStructSetData($tNMLVCUSTOMDRAW, "clrTextBk", 0xCC6600) ; Backcolor dark blue, BGR
                                Case Else ; Other columns
                                    DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", 0x000000) ; Forecolor black
                                    DllStructSetData($tNMLVCUSTOMDRAW, "ClrTextBk", 0xFFFFFF) ; Backcolor white
                            EndSwitch
                            Return $CDRF_NEWFONT            ; $CDRF_NEWFONT must be returned after changing font or colors

                    EndSwitch

            EndSwitch

    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

**UEZ**

Velted wow, genau so sollte es sein. Danke!

Moombas Peter S. Taler Eine Multiauswahl will ich nicht - nur ein simples hoch und runter zusätzlich mit den Pfeiltasten.

Danke euch allen!

**Moombas**

UEZ : Habe mich auch verlesen XD Du hast geschrieben "Wichtig ist, dass nur die ersten zwei Zellen markiert bleiben." ... anstatt Zellen habe ich "Zeilen" gelesen... wer lesen kann ist zweifelsohne im Vorteil

Dann hätte ich auch zwischendurch eine Lösung präsentieren können -.- Menno^^

**UEZ**

Moombas kein Problem.

Was macht eigentlich die Zeile?

Code

DllStructSetData($tNMLVCUSTOMDRAW, "uItemState", BitAND($uItemState, BitNOT(0x11)))

Die 3. Spalte beinhaltet die Farbe, die in der Spalte 2 steht. Mit der Lösung oben wird sie überschrieben (gut, hatte ich nicht erwähnt).

**UEZ**

Gibt es eine Möglichkeit, dass die Farben in der 3 Spalte immer angezeigt werden, nicht nur bei der Selektion?

AutoIt

;coded by LarsJ / Velted
#include <Array.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Opt("MustDeclareVars", 1)

Global $hGui, $hLV, $iLVx, $iLVy

Example()


Func Example()

    $hGui = GUICreate("Mark Cell in Listview", 500, 540)

    Local $idLV0 = GUICtrlCreateListView("Column 0|Column 1|Column 2", 25, 10, 250, 500)
    For $i = 0 To 99
        GUICtrlCreateListViewItem("Cell " & $i & ".0" & "|" & Hex(Int(Random() * 0xFFFFFF), 6) & "|", $idLV0)
    Next
    $hLV = GUICtrlGetHandle($idLV0)
    $iLVx = 25
    $iLVy = 10

    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hLV
            Switch $iCode
                ; Handle arrow key presses for selection movement
                Case $NM_CUSTOMDRAW
                    Local $tNMLVCUSTOMDRAW = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $dwDrawStage = DllStructGetData($tNMLVCUSTOMDRAW, "dwDrawStage")
                    Local $dwItemSpec = DllStructGetData($tNMLVCUSTOMDRAW, "dwItemSpec") ; Item index
                    Local $iSubItem = DllStructGetData($tNMLVCUSTOMDRAW, "iSubItem") ; Subitem index
                    Local $uItemState = DllStructGetData($tNMLVCUSTOMDRAW, "uItemState") ; Item state

                    Switch $dwDrawStage                     ; Holds a value that specifies the drawing stage
                        Case $CDDS_PREPAINT                 ; Before the paint cycle begins
                            Return $CDRF_NOTIFYITEMDRAW     ; Notify the parent window of any ITEM-related drawing operations
                        Case $CDDS_ITEMPREPAINT             ; Before painting an item
                            If _GUICtrlListView_GetItemSelected($hLV, $dwItemSpec) Then Return $CDRF_NOTIFYSUBITEMDRAW  ; Notify the parent window of any SUBITEM-related drawing operations
                            Return $CDRF_DODEFAULT
                        Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM) ; Before painting a subitem
                            DllStructSetData($tNMLVCUSTOMDRAW, "uItemState", BitAND($uItemState, BitNOT($CDIS_SELECTED)))
                            Switch $iSubItem
                                Case 0 To 1 ; Marked column
                                    DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", 0xFFFFFF) ; Forecolor white
                                    DllStructSetData($tNMLVCUSTOMDRAW, "clrTextBk", 0xCC6600) ; Backcolor dark blue, BGR
                                Case Else ; Other columns
                                    DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", 0x000000) ; Forecolor black
                                    DllStructSetData($tNMLVCUSTOMDRAW, "ClrTextBk", "0x" & _GUICtrlListView_GetItemText($hLV, $dwItemSpec, 1)) ; Backcolor white
                            EndSwitch
                            Return $CDRF_NEWFONT            ; $CDRF_NEWFONT must be returned after changing font or colors
                    EndSwitch
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

Velted

Zitat von UEZ

Gibt es eine Möglichkeit, dass die Farben in der 3 Spalte immer angezeigt werden, nicht nur bei der Selektion?

So könnte es funktionieren:

AutoIt

;coded by LarsJ / Velted
#include <Array.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Opt("MustDeclareVars", 1)

Global $hGui, $hLV, $iLVx, $iLVy

Example()


Func Example()

    $hGui = GUICreate("Mark Cell in Listview", 500, 540)

    Local $idLV0 = GUICtrlCreateListView("Column 0|Column 1|Column 2", 25, 10, 250, 500)
    For $i = 0 To 99
        GUICtrlCreateListViewItem("Cell " & $i & ".0" & "|" & Hex(Int(Random() * 0xFFFFFF), 6) & "|", $idLV0)
    Next
    $hLV = GUICtrlGetHandle($idLV0)
    $iLVx = 25
    $iLVy = 10

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $iCode, $bIsSelected, $ClrText, $ClrTextBk
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hLV
            Switch $iCode
                ; Handle arrow key presses for selection movement
                Case $NM_CUSTOMDRAW
                    Local $tNMLVCUSTOMDRAW = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $dwDrawStage = DllStructGetData($tNMLVCUSTOMDRAW, "dwDrawStage")
                    Local $dwItemSpec = DllStructGetData($tNMLVCUSTOMDRAW, "dwItemSpec") ; Item index
                    Local $iSubItem = DllStructGetData($tNMLVCUSTOMDRAW, "iSubItem") ; Subitem index
                    Local $uItemState = DllStructGetData($tNMLVCUSTOMDRAW, "uItemState") ; Item state

                    Switch $dwDrawStage                     ; Holds a value that specifies the drawing stage
                        Case $CDDS_PREPAINT                 ; Before the paint cycle begins
                            Return $CDRF_NOTIFYITEMDRAW     ; Notify the parent window of any ITEM-related drawing operations
                        Case $CDDS_ITEMPREPAINT             ; Before painting an item
                            Return $CDRF_NOTIFYSUBITEMDRAW  ; Notify the parent window of any SUBITEM-related drawing operations
                        Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM) ; Before painting a subitem
                            $bIsSelected = _GUICtrlListView_GetItemSelected($hLV, $dwItemSpec)
                            If $bIsSelected Then DllStructSetData($tNMLVCUSTOMDRAW, "uItemState", BitAND($uItemState, BitNOT($CDIS_SELECTED)))
                            Switch $iSubItem
                                Case 0 To 1 ; Marked column
                                    $ClrText = $bIsSelected ? 0xFFFFFF : 0X0000000
                                    $ClrTextBk = $bIsSelected ? 0xCC6600 : 0xFFFFFF
                                Case 2
                                    $ClrText = 0x000000
                                    $ClrTextBk = "0x" & _GUICtrlListView_GetItemText($hLV, $dwItemSpec, 1)
                                Case Else ; Other columns
                                    Return $CDRF_DODEFAULT
                            EndSwitch
                            DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", $ClrText)     ; Forecolor black
                            DllStructSetData($tNMLVCUSTOMDRAW, "ClrTextBk", $ClrTextBk)     ; Backcolor white
                            Return $CDRF_NEWFONT            ; $CDRF_NEWFONT must be returned after changing font or colors
                    EndSwitch
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

Zitat von UEZ

Was macht eigentlich die Zeile?

Das hast Du anscheinend selbst herausgefunden. (Sie löscht die States $CDIS_SELECTED und $CDIS_FOCUS).

**UEZ**

Velted genau so habe ich mir das vorgestellt.

MERCI.

Velted

Moin UEZ,

ich habe mir das nochmal durch den Kopf gehen lassen. Es geht in diesem Fall (soweit ich erkennen kann) nur darum, den Hintergrund der 3. Spalte mit einer selbstgewählten Farbe zu füllen, und das auch dann, wenn die Zeile selektiert ist. Wenn die 3. Spalte wie hier auch die letzte ist, reicht es deshalb wenn man sich ausschließlich mit ihr beschäftigt und alles andere dem ListView überlässt. Das Skript könnte dann so aussehen:

AutoIt

;coded by LarsJ / Velted
#include <Array.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Opt("MustDeclareVars", 1)

Global $hGui, $hLV

Example()


Func Example()

    $hGui = GUICreate("Mark Cell in Listview", 500, 540)

    Local $idLV0 = GUICtrlCreateListView("Column 0|Column 1|Column 2", 25, 10, 250, 500)
    For $i = 0 To 99
        GUICtrlCreateListViewItem("Cell " & $i & ".0" & "|" & Hex(Int(Random() * 0xFFFFFF), 6) & "|", $idLV0)
    Next

    $hLV = GUICtrlGetHandle($idLV0)

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    Local $iCode = DllStructGetData($tNMHDR, "code")
    If $hWndFrom = $hLV And $iCode = $NM_CUSTOMDRAW Then
        Return _LVSetColors($hWndFrom, DllStructCreate($tagNMLVCUSTOMDRAW, $lParam))
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _LVSetColors($hWnd, $tNMLVCUSTOMDRAW)
    Switch DllStructGetData($tNMLVCUSTOMDRAW, "dwDrawStage")    ; Holds a value that specifies the drawing stage
        Case $CDDS_PREPAINT                                        ; Before the paint cycle begins
            Return $CDRF_NOTIFYITEMDRAW                         ; Notify the parent window of any ITEM-related drawing operations
        Case $CDDS_ITEMPREPAINT                                 ; Before painting an item
            Return $CDRF_NOTIFYSUBITEMDRAW                      ; Notify the parent window of any SUBITEM-related drawing operations
        Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM)             ; Before painting a subitem
            Local $dwItemSpec = DllStructGetData($tNMLVCUSTOMDRAW, "dwItemSpec") ; Item index
            If DllStructGetData($tNMLVCUSTOMDRAW, "iSubItem") = 2 Then ; Set the color for the 3rd column
                If _GUICtrlListView_GetItemSelected($hWnd, $dwItemSpec) Then ; If the item is selected, clear the CDIS_SELECTED state bit.
                    Local $uItemState = DllStructGetData($tNMLVCUSTOMDRAW, "uItemState") ; Item state
                    DllStructSetData($tNMLVCUSTOMDRAW, "uItemState", BitAND($uItemState, BitNOT($CDIS_SELECTED)))
                EndIf
                DllStructSetData($tNMLVCUSTOMDRAW, "clrTextBk", Dec(_GUICtrlListView_GetItemText($hWnd, $dwItemSpec, 1)))
                Return $CDRF_NEWFONT ; $CDRF_NEWFONT must be returned after changing font or colors
            Else
                Return $CDRF_DODEFAULT    ; Let the ListView paint all other columns (1 & 2)
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_LVSetColors

Alles anzeigen

Mir gefällt das besser.

**UEZ**

Velted eigentlich geht es nicht um Autoit, sondern um ein Freebasic Tool, woran ich wieder mal arbeite. Es ist sehr interessant, wie man die WinAPI Funktionen ohne UDFs nutzt.

Dadurch kann / muss man mehr in die Details gehen und lernt dabei mehr, als nur die UDFs zu nutzen.

Falls interesse besteht: Color Constants v0.80 build 2023-11-08.zip

Manchmal suche ich nach bestimmten Farben und durch das Tool ist es einfacher, die Farbe zu suchen.

Velted

UEZ,

ok. Ich denke, dass das mit AutoIt auch möglich ist. Es ist ja niemand gezwungen, die UDFs zu benutzen. Sie liefern viele Informationen darüber, wie man die Windows-API-Funktionen nutzt. Mit WinUser.h und CommCtrl.h kommt man aber auch schon recht weit.

Viel Spaß weiterhin!

**UEZ**

Natürlich ist das mit Autoit möglich, sogar viel einfacher, aber man will ja sein Horizont erweitern...

Danke