ArrayFindAll 2DArray

wuff100

Moin,

ich möchte aus einem 2D Array von der Spalte 2 drei neue Array's in Schleife erzeugen.

Also, 2 Zeilen mit 27, eine Zeile mit 28 und zwei Zeilen mit 29., jeweils mit 5 Spalten.

Könnt ihr mir helfen?

Gruß

Code

#include <Array.au3>

Local $aArray[5][5] = [[0, "Test1", 27, 1, 0], _
		[1, "Test1", 27, 4, 2], _
		[2, "Test2", 28, 1, 3], _
		[3, "Test3", 29, 1, 0], _
		[4, "Test4", 29, 4, 1]]
_ArrayDisplay($aArray, "2D Array")

Dim $aResultFindAll[5][5]
For $i = 1 To 30 Step +1
	Local $aResult = _ArrayFindAll($aArray, $i, Default, Default, Default, Default, 2)
	_ArrayDisplay($aResult)

	For $f = 0 To UBound($aResult) - 1
		$aResultFindAll = $aArray[$aResult[$f]][1]
		$aResultFindAll = $aArray[$aResult[$f]][2]
		_Arraydisplay($aResultFindAll)
	Next
Next

Alles anzeigen

**Moombas**

Soll in den Arrays einfach nur der Inhalt von der Spalte 2 stehen (Und das in allen 3?) oder das was dahinter steht?

Also entweder:
3* : [27],[27],[28],[29],[29]

oder:
27: [1, 0, 4, 2]
28: [1, 3]
29: [1, 0, 4, 1]

wuff100

Alle Spalten mit 2x 27, 1x28, 2x 29

**BugFix**

Zitat von wuff100

Alle Spalten mit 2x 27, 1x28, 2x 29

Bitte schreibe es eindeutig.

Ich vermute:

Code

[[0, "Test1", 27, 1, 0], _
[1, "Test1", 27, 4, 2]]

[[2, "Test2", 28, 1, 3]]

[[3, "Test3", 29, 1, 0], _
[4, "Test4", 29, 4, 1]]

P.S. Ist die Spalte 3 aufsteigend sortiert oder hier nur zufällig in Reihenfolge?

**AspirinJunkie**

Ich bin nicht 100% sicher ob ich die Aufgabe genau verstanden habe.
So wie ich das verstanden habe möchtest du aus diesem kompletten Array für die jeweiligen Werte in Spalte 3 eigene Arrays machen?

Das geht schon mit Bordmitteln.
Bedenke aber dass _ArrayFindAll nur die Indizes wiedergibt.
Das extrahieren dieser Zeilen und den Aufbau eines neuen Arrays musst du dann noch hinterher programmieren.

Das geht - aber für sowas habe ich mal eine UDF (>>ArrayPlus-UDF<<) mit der man sich soetwas deutlich einfacher basteln kann.
Hier mal als Beispiel wie man damit deine Aufgabe umsetzen könnte:

AutoIt

#include <ArrayPlus.au3>

Local $aArray[5][5] = [[0, "Test1", 27, 1, 0], _
		[1, "Test1", 27, 4, 2], _
		[2, "Test2", 28, 1, 3], _
		[3, "Test3", 29, 1, 0], _
		[4, "Test4", 29, 4, 1]]
;~ _ArrayDisplay($aArray, "2D Array")

; die Suchwerte extrahieren
Global $aSearchValues = _ArraySlice($aArray, "[:][2]")
$aSearchValues = _ArrayUnique($aSearchValues, 0, 0, 0, 0)
_ArrayDisplay($aSearchValues, "Suchwerte")

; Die Suchwerte einzeln durchgen und 
; das Array nach dem jeweiligen Suchwert filtern
For $dSearchValue In $aSearchValues

	$aResult = _ArrayFilter($aArray, "$A[2] = " & $dSearchValue)

	_ArrayDisplay($aResult, "Nr. " & $dSearchValue, "", 96)
Next

Alles anzeigen

**Moombas**

Mein Hauptproblem dabei ist, das die Arrays ja auch irgendwie dynamisch gebaut/ zugewiesen werden müssen.

Dann wäre meine Lösung dise hier (aber recht unschön wie ich finde):

AutoIt

;~ Opt('MustDeclareVars', 1)
#include <Array.au3>

Global $a27[0][2], $a28[0][2], $a29[0][2]
Global $aArray[5][5] = [[0, "Test1", 27, 1, 0], _
		[1, "Test1", 27, 4, 2], _
		[2, "Test2", 28, 1, 3], _
		[3, "Test3", 29, 1, 0], _
		[4, "Test4", 29, 4, 1]]
_ArraySort($aArray, Default, Default, Default, 2) ;to ensure right order in 3. column
_ArrayDisplay($aArray, "2D Array")


For $Row = 0 to UBound($aArray) - 1
	Execute('_ArrayAdd($a' & $aArray[$Row][2] & ', $aArray[$Row][3] & "|" & $aArray[$Row][4])')
Next
_ArrayDisplay($a27)
_ArrayDisplay($a28)
_ArrayDisplay($a29)

Alles anzeigen

Vielleicht da eher die Lösung von AspirinJunkie sich anschauen.

**BugFix**

Hier mal eine variable Lösung (also egal ob 3 oder beliebig viele Arrays entstehen):

AutoIt

Local $aArray[5][5] = [[0, "Test1", 27, 1, 0], _
		[1, "Test1", 27, 4, 2], _
		[2, "Test2", 28, 1, 3], _
		[3, "Test3", 29, 1, 0], _
		[4, "Test4", 29, 4, 1]]

Local $aOfArrays = _Separate($aArray)
For $a In $aOfArrays
    _ArrayDisplay($a)
Next


Func _Separate(ByRef $_a)
    Local $aRes[] = [Null], $aTmp
    Local $iLastCompare = Null
    For $i = 0 To UBound($_a) -1
        If $iLastCompare <> $_a[$i][2] Then
            If $iLastCompare <> Null Then _AddToRes($aRes, $aTmp)
            $iLastCompare = $_a[$i][2]
            _NewEntryByDiff($_a, $i, $aTmp)
        Else
            _NewEntryBySame($_a, $i, $aTmp)
        EndIf
    Next
    _AddToRes($aRes, $aTmp)
    Return $aRes
EndFunc


Func _NewEntryByDiff(ByRef $_a, $_i, ByRef $_aTmp)
    $_aTmp = _NewArray()
    For $j = 0 To UBound($_a, 2) -1
        $_aTmp[0][$j] = $_a[$_i][$j]
    Next
EndFunc


Func _NewEntryBySame(ByRef $_a, $_i, ByRef $_aTmp)
    If $_aTmp[UBound($_aTmp) -1][0] <> Null Then ReDim $_aTmp[UBound($_aTmp) +1][5]
    For $j = 0 To UBound($_a, 2) -1
        $_aTmp[UBound($_aTmp) -1][$j] = $_a[$_i][$j]
    Next
EndFunc


Func _AddToRes(ByRef $_aRes, $_aTmp)
    If $_aRes[UBound($_aRes) -1] <> Null Then ReDim $_aRes[UBound($_aRes) +1]
    $_aRes[UBound($_aRes) -1] = $_aTmp
EndFunc


Func _NewArray()
    Local $a[][5] = [[Null]]
    Return $a
EndFunc

Alles anzeigen

**AspirinJunkie**

Na gut bei so vielen Lösungen wäre hier noch die von mir angesprochene Lösung wie man mit _ArrayFindAll() rangehen könnte:

AutoIt

#include <Array.au3>

Global $aIndices
Global $aArray[5][5] = [[0, "Test1", 27, 1, 0], _
		[1, "Test1", 27, 4, 2], _
		[2, "Test2", 28, 1, 3], _
		[3, "Test3", 29, 1, 0], _
		[4, "Test4", 29, 4, 1]]

; die Suchwerte extrahieren
Global $aSearchValues = _ArrayExtract($aArray, -1, -1, 2, 2)
$aSearchValues = _ArrayUnique($aSearchValues, 0, 0, 0, 0)

; Die Suchwerte einzeln durchgehen und 
; das Array nach dem jeweiligen Suchwert filtern
For $dSearchValue In $aSearchValues

	; Indizes der Zeilen mit dem aktuellen Suchwert ermitteln
	$aIndices = _ArrayFindAll($aArray, $dSearchValue, 0,0,0,0,2)

	; Neues 2D-Array mit den Ergebniszeilen erstellen
	Global $aFiltered[UBound($aIndices)][UBound($aArray, 2)]
	For $i = 0 To UBound($aFiltered) - 1
		For $j = 0 To UBound($aArray, 2) - 1
			$aFiltered[$i][$j] = $aArray[$aIndices[$i]][$j]
		Next
	Next

	; gefiltertes Array ausgeben:
	_ArrayDisplay($aFiltered, "Nr. " & $dSearchValue, "", 96)
Next

Alles anzeigen

wuff100

AspirinJunkie, BugFix , vielen lieben Dank.

Eure beiden letzten Ansätze sind die Lösung.

wuff100

BugFix

Das Beispiel war nur mit 5 Spalten.

Mein Array hat 30 Spalten.

Fehlermeldung: Array variable has incorrect number of subscripts or subscript dimension range exceeded

**Moombas**

Dann ändere bei dem Code von Bugfix mal in Zeile 53 die 5 auf die 30

**BugFix**

Zitat von wuff100

Mein Array hat 30 Spalten.

Dann musst du entsprechend in den Funktionen erweitern.

Am Skriptanfang:

AutoIt

Global $giColumn = 5 ; oder was du brauchst

Und die Funktion ändern:

AutoIt

Func _NewArray()
    Local $a[][$giColumn] = [[Null]]
    Return $a
EndFunc

wuff100

BugFix , Dankeschön.

Velted

Moin,

weil das konkrete Problem recht einfach mit einem Map-Objekt gelöst werden kann, gibt es noch einen späten Nachschlag:

AutoIt

#Include <Array.au3>
Local $aArray[5][5] = [[0, "Test1", 27, 1, 0], _
					   [1, "Test1", 27, 4, 2], _
					   [2, "Test2", 28, 1, 3], _
					   [3, "Test3", 29, 1, 0], _
					   [4, "Test4", 29, 4, 1]]

Local $mOfArrays = _SeparateByColumn($aArray, 2)

For $Key In MapKeys($mOfArrays)
	_ArrayDisplay($mOfArrays[$Key])
Next

Func _SeparateByColumn(Const $aArr, $iCol)
	Local $mOut[]
	Local $iCols = UBound($aArr, 2)
	For $I = 0 To UBound($aArr) - 1
		$mOut[$aArr[$I][$iCol]] &= $I & " "
	Next
	For $Key In MapKeys($mOut)
		$aRows = StringSplit(StringStripWS($mOut[$Key], 2), " ", 2)
		Local $aTmp[UBound($aRows)][$iCols]
		For $I = 0 To UBound($aRows) - 1
			For $J = 0 To $iCols - 1
				$aTmp[$I][$J] = $aArr[$aRows[$I]][$J]
			Next
		Next
		$mOut[$Key] = $aTmp
	Next
	Return $mOut
EndFunc

Alles anzeigen