Gruppenmitgliedschaft ermitteln

Racer

Hallo!

Ich bin auf der Suche wie ich die Mitgliedschaft einer Gruppe am Client ermitteln kann (diesmal nicht via AD).

Auf der Commandlineebene mache ich das mit "whoami /groups" bzw. "whoami /groups | findstr /i "gesuchte gruppe". Gibt es so was im AutoIt oder muss ich da wohl oder über über die CMD gehen?

lg

Racer

**BugFix**

Das Arbeiten mit der CMDLine geht doch mit AutoIt.

AutoIt

Func _CMDLineRead($_sCMD)
    Local $PID = Run(@ComSpec & " /c " & $_sCMD, "", @SW_HIDE, $STDOUT_CHILD)
    Local $sLine, $sOutput = ''
    While 1
        $sLine = StdoutRead($PID)
        If @error Then ExitLoop
        If StringStripWS($sLine, 8) <> '' Then $sOutput &= $sLine
    WEnd
    Return $sOutput
EndFunc


$group = _CMDLineRead("whoami /groups")
ConsoleWrite($group & @CRLF)

Alles anzeigen

Den Rückgabewert musst du natürlich noch auswerten.

Racer

Zitat von BugFix

Das Arbeiten mit der CMDLine geht doch mit AutoIt.

AutoIt

Func _CMDLineRead($_sCMD)
    Local $PID = Run(@ComSpec & " /c " & $_sCMD, "", @SW_HIDE, $STDOUT_CHILD)
    Local $sLine, $sOutput = ''
    While 1
        $sLine = StdoutRead($PID)
        If @error Then ExitLoop
        If StringStripWS($sLine, 8) <> '' Then $sOutput &= $sLine
    WEnd
    Return $sOutput
EndFunc


$group = _CMDLineRead("whoami /groups")
ConsoleWrite($group & @CRLF)

Alles anzeigen

Ja, schon klar!
Ich wollte nur wissen ob es da was schönes direkt im AutoIT gibt....

lg
Racer

**Schnuffel**

das schreit ja schon wieder nach einem Projekt

gmmg

sowas hier?

Get localgroup members

Hello again AutoIt people I'm having troubles on how to create a script, that would check a list (txt file) of computers for users of localgroup…

www.autoitscript.com

**Schnuffel**

ich spiele gerade ein wenig mit WMIC / WMI herum und da passt das ja ganz gut rein ...

versuch mal das:

AutoIt

#AutoIt3Wrapper_UseX64=y
#include <Array.au3>

Opt("MustDeclareVars", 1)


Local $aWMI = _GetWMIClass("Win32_GroupUser")
_ArrayDisplay($aWMI)


Func _GetWMIClass($Class)
    Local $objWMIService = ObjGet("winmgmts:\\" & @ComputerName & "\root\CIMV2")
    Local $colItems = $objWMIService.ExecQuery('SELECT * FROM ' & $Class)
    If Not IsObj($colItems) Then Return SetError(1) ; "Not an object"
    If Not $colItems.count Then Return SetError(2) ; "Not found"
    Local $aWMI[$colItems.ItemIndex(0).Properties_.count][$colItems.count + 1], $iCount = 0, $nCount = 1
    For $oProperty In $colItems.ItemIndex(0).Properties_
        $aWMI[$iCount][0] = $oProperty.name
        $iCount += 1
    Next
    For $oItem In $colItems
        $iCount = 0
        For $oProperty In $oItem.Properties_
            $aWMI[$iCount][$nCount] = $oProperty.Value
            $iCount += 1
        Next
        $nCount += 1
    Next
    $aWMI[0][0] = UBound($aWMI) - 1
    Return $aWMI
EndFunc   ;==>_GetWMIClass

Alles anzeigen

Die Ausgabe lässt sich ja anpassen

Racer

Hallo Schnuffel!

Ich habe es jetzt nur zu Hause testen können, sieht aber auf den ersten Blick gut aus.
Morgen kann ich es in der Arbeit ausprobieren, mal sehen ob es das gewünschte Ergebnis bringt!

Zur Info: Es soll ermittelt werden ob ein Computer in eine bestimmten AD-Gruppe ist. Aber jetzt nicht das AD abfragen (so ruft Water gleich "hier" ), sondern ob die Gruppeninformation am Client ist.

Hintergrund: Am Ende soll entschieden werden ob das Programm ausgeführt werden darf (auch offline), zuvor muss aber einmal die Gruppe ermittelt werden!

lg
Racer

Racer

Spät aber doch: Erster Test in der AD Umgebung!

Leider bleibt das Script bei "If Not $colItems.count Then Return SetError(2) ; "Not found" einfach hängen....

lg

Racer

**Schnuffel**

ich bin bisher auch davon ausgegangen, dass du User in AD Gruppen suchst. ..

ich schau mal

**Schnuffel**

ich denke mit dem Script von BugFix kannst du doch alles holen.
Da will ich das Rad gar nicht neu erfinden.

**Schnuffel**

Also:

die Gruppenmitgliedschaft eines Computers ohne AD-Tools lässt sich über "GPResult /R" ermitteln.
Bitte beachte, dass für die Computer Anteile Admin-Rechte benötigt werden.
Den Output kannst/musst du dir nach deinen Bedürfnissen anpassen/filtern

AutoIt

#RequireAdmin
Global $group = _CMDLineRead("gpresult /r")
ConsoleWrite($group & @CRLF)

Func _CMDLineRead($sCMD)
	Local $sLine, $sRetStr, $sOutput = '', $iStart = 1
	Local $iPID = Run(@ComSpec & " /c " & $sCMD, "", @SW_HIDE, 8)
	If ProcessWaitClose($iPID, 30) = 0 Then Return SetError(1, 1, 0)
	$sOutput= StdoutRead($iPID)
	Local $nLen = StringLen($sOutput)
	While $iStart < $nLen
		$aCall = DllCall('user32.dll', 'bool', 'OemToCharA', 'str', StringMid($sOutput, $iStart, 65536), 'str', '')
		If @error Or Not $aCall[0] Then Return SetError(@error + 10, @extended, '')
		$sRetStr &= $aCall[2]
		$iStart += 65536
	WEnd
	Return $sRetStr
EndFunc   ;==>_CMDLineRead

Alles anzeigen

**Schnuffel**

hab mal ein Beispiel:

Das Prinzip lässt sich auf alle Ausgaben aus der Cmd anwenden

AutoIt

#RequireAdmin
#include<Array.au3>

Global $aTest = _GetUserGroupMember()
_ArrayDisplay($aTest)

Global $aTest = _GetComputerGroupMember()
_ArrayDisplay($aTest)

Func _GetComputerGroupMember()
	Local $aReturn[1] = [0], $aGroup = StringSplit(_CMDLineRead("GPRESULT /R /SCOPE COMPUTER"), @LF)
	For $i = 1 To $aGroup[0]
		If StringRegExp($aGroup[$i], '.*Computer.*Mitglied|Member.*') Then ExitLoop
	Next
	For $i = $i + 2 To $aGroup[0]
		If $i = $aGroup[0] THen ExitLoop
		$aReturn[0] += 1
		ReDim $aReturn[$aReturn[0] + 1]
		$aReturn[$aReturn[0] ] = StringStripWS($aGroup[$i], 3)
	Next
	Return $aReturn
EndFunc

Func _GetUserGroupMember()
	Local $aReturn[1] = [0], $aGroup = StringSplit(_CMDLineRead("GPRESULT /R /SCOPE USER"), @LF)
	For $i = 1 To $aGroup[0]
		If StringRegExp($aGroup[$i], '.*Benutzer|User.*Mitglied|Member.*') Then ExitLoop
	Next
	For $i = $i + 2 To $aGroup[0]
		If $i = $aGroup[0] THen ExitLoop
		$aReturn[0] += 1
		ReDim $aReturn[$aReturn[0] + 1]
		$aReturn[$aReturn[0] ] = StringStripWS($aGroup[$i], 3)
	Next
	Return $aReturn
EndFunc

Func _CMDLineRead($sCMD)
	Local $sLine, $sRetStr, $sOutput = '', $iStart = 1
	Local $iPID = Run(@ComSpec & " /c " & $sCMD, "", @SW_HIDE, 8)
	If ProcessWaitClose($iPID, 30) = 0 Then Return SetError(1, 1, 0)
	$sOutput= StdoutRead($iPID)
	Local $nLen = StringLen($sOutput)
	While $iStart < $nLen
		$aCall = DllCall('user32.dll', 'bool', 'OemToCharA', 'str', StringMid($sOutput, $iStart, 65536), 'str', '')
		If @error Or Not $aCall[0] Then Return SetError(@error + 10, @extended, '')
		$sRetStr &= $aCall[2]
		$iStart += 65536
	WEnd
	Return $sRetStr
EndFunc   ;==>_CMDLineRead

Alles anzeigen

Racer

Vielen Dank Schnuffel!

ja, gpresult /r wäre auch noch eine Alternative gewesen. Ich habe mich für den Dos-Output mit 'whoami /groups | findstr /i "meine Gruppe"' entschieden.
Das ist immer noch am schnellsten, funktioniert offline (Gruppeninformationen werden ja gecacht) und in meinen Fall ist es mit findstr sehr gut vorzufiltern. Damit brauch ich im Script nicht mehr viel parsen.

Für diesen Fall ist mein Problem (Aufgabe) gelöst, wie ich die Gruppeninformationen von einen Forest (Domainübergreifend) bekommen muss ich mir noch überlegen....aber das ist eine andere Herausforderung.

lg
Racer