Denkknoten im Umgang mit Timerinit/Timerdiff

GerhardSchr

Hallo zusammen,

ich habe folgendes vor:

Es soll z.B. alle 60 Sekunden für 5 Sekunden eine Meldung angezeigt werden (oder ein Label auf der GUI mit Text gefüllt werden)

Ich möchte nicht Sleep verwenden, da sonst die GUI während dieser Zeit nicht reagiert.

Hier mal mein Versuch: (Codeausschnitt)

AutoIt

$timer_interfallmeldung = TimerInit()
$timer_meldung = TimerInit()

$intervallmeldung = 60000
$dauermeldung = 5000

AdlibRegister(checkMeldung, 1000)

Func checkMeldung()

	If TimerDiff($timer_intervallmeldung) > $intervallmeldung Then
		$timer_intervallmeldung = TimerInit()
		If TimerDiff($timer_meldung) < $dauermeldung Then
			GUICtrlSetData($lbl_Alarm, "ALARM")
		Else
			GUICtrlSetData($lbl_Alarm, "kein Alarm")
			$timer_meldung = TimerInit()
		EndIf
	EndIf


EndFunc   ;==>checkMeldung

Alles anzeigen

Ob ich später AdlibRegister brauche, weiß ich noch nicht. Könnte dann auch direkt in der While Schleife von der GUI aufgerufen werden.

Irgendwie hat mein Kopf einen Knoten, wann welcher Timer zurückgesetzt werden muss.

Oder gibt es sogar einen ganz anderen Ansatz dafür?

Danke!

**BugFix**

Wenn du Sleep kpl. raushaben möchtest, würde ich nur mit AdlibRegister arbeiten (hier mal so gestaltet, dass es mit der konsole funktioniert):

AutoIt

Global $TimerShow

$dauermeldung = 5000
$intervallmeldung = 60000 - $dauermeldung   ;####

AdlibRegister(checkMeldung, $intervallmeldung)


; zum Beenden
HotKeySet('{ESC}', _Exit)

While True
    Sleep(50)
WEnd

Func _Exit()
    Exit
EndFunc


Func checkMeldung()
    Local $aInfo[] = ['ALARM', 'Kein ALARM']
    AdlibUnRegister(checkMeldung)
    Local $AlarmInfo = $aInfo[Random(0,1,1)]            ; hier gehört die Überprüfung auf Alarmzustand rein
    $TimerShow = TimerInit()
;~     GUICtrlSetData($lbl_Alarm, $AlarmInfo)
    ConsoleWrite('[check]' & @CRLF)
    ConsoleWrite($AlarmInfo & @CRLF)
    AdlibRegister(_ShowMsg)
EndFunc   ;==>checkMeldung

Func _ShowMsg()
    If TimerDiff($TimerShow) < $dauermeldung Then Return
;~     GUICtrlSetData($lbl_Alarm, '[check ended]')
    ConsoleWrite('[check ended]' & @CRLF)
    AdlibUnRegister(_ShowMsg)
    AdlibRegister(checkMeldung, $intervallmeldung) ; jetzt ist die gesamte Intervall-Zeit um ($intervallmeldung -$dauermeldung +$dauermeldung)
EndFunc

Alles anzeigen

**Oscar**

Man kommt auch ganz ohne Adlib und mit nur einem Timer aus:

AutoIt

$iTimer = TimerInit()

$iIntervallmeldung = 60000
$iDauermeldung = 5000
HotKeySet('{ESC}', _Exit)

While Sleep(1000)
	_CheckMeldung()
WEnd

Func _CheckMeldung()
	Local Static $iLastMillis = 0, $bMeldung = False
	Local $iMillis = TimerDiff($iTimer)
	ConsoleWrite(Int(($iMillis - $iLastMillis) / 1000) & @CRLF)
	If $iMillis - $iLastMillis > $iIntervallmeldung Then
		$iLastMillis = $iMillis
		$bMeldung = True
	EndIf
	If $bMeldung Then
		ConsoleWrite(' Alarm' & @CRLF)
		If $iMillis - $iLastMillis > $iDauermeldung Then
			ConsoleWrite(' Alarm aus' & @CRLF)
			$bMeldung = False
		EndIf
	EndIf
EndFunc

Func _Exit()
	Exit
EndFunc

Alles anzeigen

GerhardSchr

Danke euch.

Schaue ich mir mal an

Schönes Wochenende

**Schnuffel**

ich werf mal noch meine Idee dazu in den Ring:

AutoIt

HotKeySet('{ESC}', _Exit)

Global $iTimer = TimerInit()
Global $bAdLibSet = False
Global $Turnus = 20 ; in Sekunden
Global $Anzeigedauer = 5 ; in Sekunden
While 1
	If TimerDiff($iTimer) > $Turnus * 1000  And $bAdLibSet = False Then
		$bAdLibSet = True
		AdlibRegister("__Funktion", 1000)
	EndIf
	If TimerDiff($iTimer) > ($Turnus + $Anzeigedauer) * 1000 Then
		AdlibUnRegister("__Funktion")
		$bAdLibSet = False
		$iTimer = TimerInit()
	EndIf
WEnd

Func __Funktion()
	ConsoleWrite("Zeit: " & @SEC & @CRLF)
EndFunc

Func _Exit()
	Exit
EndFunc

Alles anzeigen

Racer

Für eine asynchrone Anzeige (Hinweis, Zähler,...) habe ich die Funktion mit Adlib sehr zu schätzen gelernt. Vorallem kann das echt Speed in deinen Projekten bringen...

Beipspiel: Du hast eine Schleife mit 100000 Durchläufe, dazwischen Berechnungen und vielleicht ein paar Strings die du noch parsen musst. Wenn Du bei jedem Durchgang die Anzeige refresht kostet das wertvolle Rechenzeit. Nichts Anzeigen frustiert, aber wenn sich die Anzeige nur alle 5 Sekunden ändert sieht man den Fortschritt und das Script läuft richtig flott.

Ist nur ein Gedanke bzw. meine Erfahrungen...

lg

Racer

GerhardSchr

Danke für die unterschiedlichen Lösungsansätze.

Glaube nun ist der Knoten in meinem Kopf weg

Gruß

Mark