Switch GUI

wuff100

Moin,

wie im Beispiel unten soll die Form2 mit der Form1 über den Button $Button1 gestartet werden.

Die Form1 verliert damit den Loop!

Wenn ich von der Form2 ohne Schließen der Form1 den $Button2 auf der Form1 wieder betätigen möchte, ist es ja nicht mehr möglich, da Form2 den Loop hat.

Wie kann ich es lösen, habt ihr eine Idee?

Gruß Wuff

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 615, 437, -1, -1)
$Button1 = GUICtrlCreateButton("Button1", 200, 56, 145, 41)
$Button2 = GUICtrlCreateButton("Hallo", 208, 184, 137, 41)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			If GUIDelete($Form1) Then ExitLoop

		Case $Button1
			_Form2()

		Case $Button2
			MsgBox(1, "", "Hallo Form1")


	EndSwitch
WEnd


Func _Form2()
	#include <ButtonConstants.au3>
	#include <GUIConstantsEx.au3>
	#include <WindowsConstants.au3>
	#Region ### START Koda GUI section ### Form=
	$Form2 = GUICreate("Form2", 615, 437, 500, -1)
	$Button2 = GUICtrlCreateButton("Button1", 200, 56, 145, 41)
	$Button3 = GUICtrlCreateButton("Hallo", 208, 184, 137, 41)
	GUISetState(@SW_SHOW)
	#EndRegion ### END Koda GUI section ###

	While 1
		$nMsg = GUIGetMsg()
		Switch $nMsg
			Case $GUI_EVENT_CLOSE
				If GUIDelete($Form2) Then ExitLoop

			Case $Button2
				_Form2()

			Case $Button3
				MsgBox(1, "", "Hallo Form2")

		EndSwitch
	WEnd
EndFunc   ;==>_Form2

Alles anzeigen

**Moombas**

Warum überhaupt 2 loops? Du kannst doch beides in einer abfragen...

wuff100

Zitat von Moombas

Warum überhaupt 2 loops? Du kannst doch beides in einer abfragen...

Das stimmt! Aber vielleicht gibt es für die Version ja eine Lösung.

**Kanashius**

Eine Loop, oder du nutzt den OnEvent mode (https://www.autoitscript.com/autoit3/docs/g…OnEventMode.htm), dann hast du garkeine (GuiGetMsg) Loop mehr.

gmmg

schau mal hier: https://www.autoitscript.com/wiki/Managing_Multiple_GUIs

**Moombas**

Zitat von wuff100

Das stimmt! Aber vielleicht gibt es für die Version ja eine Lösung.

Mal ganz abgesehen von dem was hier schon (sehr relevanter Weise) gepostet wurde. Warum sollte es das, wenn du es nicht brauchst? Also warum unbedingt 2 Loops benutzen?

wuff100

gmmg, Kanashius , Moombas

Vielen Dank für eure Hilfe!

Habe es nach dem Schema gelöst.

AutoIt

#include <GUIConstantsEx.au3>

Global $gui2 = 9999, $button3 = 9999

gui1()

Func gui1()

    $gui1 = GUICreate("Gui 1", 200, 200, -1, -1)
    $button1 = GUICtrlCreateButton("Show Gui 1", 20, 20, 100, 20)
    $button2 = GUICtrlCreateButton("Msgbox", 20, 40, 100, 20)
    GUISetState()

    While 1
        $aMsg = GUIGetMsg(1) ; Use advanced parameter to get array
        Switch $aMsg[1] ; check which GUI sent the message
            Case $gui1
                Switch $aMsg[0] ; Now check for the messages for $gui1
                    Case $GUI_EVENT_CLOSE
                        ExitLoop
                    Case $button1
                        GUICtrlSetState($button1, $GUI_DISABLE)
                        gui2()
                    Case $button2
                        MsgBox("", "msgbox", "test from gui1")
                EndSwitch
            Case $gui2
                Switch $aMsg[0] ; Now check for the messages for $gui2
                    Case $GUI_EVENT_CLOSE
                        GUIDelete($gui2)
                        GUICtrlSetState($button1, $GUI_ENABLE)
                    Case $button3
                        MsgBox("", "msgbox", "test from gui2")
                EndSwitch
        EndSwitch
    WEnd

EndFunc   ;==>gui1

Func gui2()
    $gui2 = GUICreate("Gui 2", 200, 200, -1, -1)
    $button3 = GUICtrlCreateButton("Button1", 20, 20, 40, 20)
    GUISetState()
EndFunc   ;==>gui2

Alles anzeigen

Switch GUI

Ähnliche Themen

eine etwas andere uhr mit erweiterten features

das problem mit der maus und der minimierung

Schleifenabbruch nur über HotKey möglich

Favoriten Menü

sortieren nach IP