2 Apps abwechselnd anzeigen lassen

RSBox

Hallo,

ich bin neu hier und gerade dabei, 2 Apps abwechselnd anzeigen zu lassen.

Ich ein Bsp. im "gute Frage" gefunden (Dank an "TheDoessler623") und getestet und dabei ein paar kleine Fehler berichtet.

Nun mein Problem: das erste Programm startet und dann hängt es aber in Line 21:

While _Timer_GetTimer($timer) > 0 And Not $killSwitch

Ich finde auch keine Anleitung zum Befehl killswitch.

Kann mir hier vielleicht jemand helfen?
Ich schicke das BSp. in einer 2. Nachricht (zu viele Zeichen).

Hier das Bsp. (1. Teil)

AutoIt

#include <Timers.au3>

Global $Program1 = "C:\Program Files\WindowsApps\64885BlueEdge.OneCalendar_2025.1108.1.0_x64__8kea50m9krsh2\CalendarApp.Gui.Win10.exe"
Global $Program2 = "C:\Program Files\Google\Chrome\Application\chrome_proxy.exe"
Global $interval = 10 * 1000 ; 10 Sekunden
Global $timer = _Timer_Init()
Global $currentProgram = $Program1
Global $killSwitch = False

While Not $killSwitch
	Run($currentProgram)
	_Timer_SetTimer($timer, $interval)
	While _Timer_GetTimer($timer) > 0 And Not $killSwitch
		Sleep(100)
		If WinActive($currentProgram) Then
			WinSetState($currentProgram, "", @SW_MINIMIZE)
		EndIf
	WEnd
	If $currentProgram = $Program1 Then

Alles anzeigen

Grüße RSBox

**Kanashius**

Ohne den Rest des Programmes (in dem auch dein Problem ist) kann man nur schwer helfen, aber eine Frage kann ich dir Beantworten:

$killSwitch is kein Befehl/Funktion sondern eine Variable. In diesem Fall ein bool, also ein Wahr (True) oder Falsch (False).

While _Timer_GetTimer($timer) > 0 And Not $killSwitch besagt also, dass die Schleife weiterlaufen soll, wenn _Timer_GetTimer($timer)>0 ist und $killSwitch nicht True ist.

In dem bisherigen Code wird $killSwitch nie vom initialen "False" auf True geändert. Wenn die Schleife verlassen wird, dann nur weil _Timer_GetTimer($timer)>0 irgendwann nicht mehr zutrifft.

Vielleicht hilft dir das ja weiter.

gmmg

das ist dein Post dazu bei "Gute Frage"

App die 2 Programme abwechselnd anzeigt?

Hi,Du kannst beispielsweise Autolt dafür installieren. Das ist eine Skriptsprache, mit der man mit wenig Kenntnissen und wenig aufwand in Windows verschiedene…

www.gutefrage.net

Ein einfaches Beispiel:

AutoIt

HotKeySet("{ESC}", "KillAll")

Run("notepad.exe")
Run("calc.exe")

While 1
    WinActivate("Rechner")
    Sleep(5000)

    WinActivate("Unbenannt")
    Sleep(5000)
WEnd

Func KillAll()

	WinClose("Rechner")
	WinClose("Unbenannt")
    Exit
EndFunc

Alles anzeigen

Gruß Marcel

**Moombas**

Wobei das Beispiel aus "Gute Frage" ja jedesmal das Programm startet und minimiert und nicht anzeigt.

AutoIt

#include <Timers.au3>

Global $Programm1 = "C:\Program Files\Programm1.exe"
Global $Programm2 = "C:\Program Files\Programm2.exe"
Global $interval = 30 * 1000 ; 30 Sekunden
Global $timer = _Timer_Init()
Global $currentProgram = $Program1
Global $killSwitch = False

While Not $killSwitch
	Run($currentProgram)
	_Timer_SetTimer($timer, $interval)

	While _Timer_GetTimer($timer) > 0 And Not $killSwitch
		Sleep(100)

		If WinActive($currentProgram) Then
			WinSetState($currentProgram, "", @SW_MINIMIZE)
		EndIf

	WEnd

	If $currentProgram = $Program1 Then
		$currentProgram = $Program2
	Else
		$currentProgram = $Program1
	EndIf
WEnd

Func Terminate()

	$killSwitch = True

EndFunc

HotKeySet("^!k", "Terminate") ; Strg + Alt + K zum Beenden des Skrip

Alles anzeigen

Eigentlich müsste man vorher prüfen ob die Programme schon laufen, sich dann die PID dazu merken und darauf prüfen.

Sind die Programme noch nicht am laufen, starte sie, zeige das 1. Programm ~~und wechsel bei Hotkey~~ (ohne sie nochmal starten zu wollen).

Zudem eine gesonderter Hotkey zum Beenden der ganzen Schleife.

RSBox

Danke für die Antworten.
@ Kanashius: Moombas hat das Skript gefunden und hier reingestellt. Ich habe übersehen, dass der Rest nicht dabei war.
@ Moobas: danke! Ich werde die Programme davor mal starten und dann schauen was passiert

Ich bin wirklich ein kompletter Anfänger und für Eure Hilfe sehr dankbar.

gmmg

mit dem Beispiel kannst du ja auch probieren:

AutoIt

HotKeySet("{ESC}", "KillAll")
Opt("WinTitleMatchMode", 2)

$pid1 = ""
$pid2 = ""

$pid1 = ProcessExists("mspaint.exe")
;MsgBox(0,"",$pid1,2)

If $pid1 = 0 Then
	Run("mspaint.exe")
	$pid1 = ProcessExists("mspaint.exe")
EndIf

;MsgBox(0,"",$pid1,5)


$pid2 = ProcessExists("CalculatorApp.exe")
;MsgBox(0,"",$pid2,2)

If $pid2 = 0 Then
	Run("calc.exe")
	Sleep(1500)
	$pid2 = ProcessExists("CalculatorApp.exe")
EndIf

;MsgBox(0,"",$pid2,5)

; Warten bis Fenster existieren
WinWait("[CLASS:MSPaintApp]")
WinWait("Rechner")

While 1

   ; --- Notepad ---
   If ProcessExists($pid1) And WinExists("[CLASS:MSPaintApp]") Then
       WinActivate("[CLASS:MSPaintApp]")
       WinWaitActive("[CLASS:MSPaintApp]")
       Sleep(5000)
   EndIf

   ; --- Calculator ---
   If ProcessExists($pid2) And WinExists("Rechner") Then
       WinActivate("Rechner")
       WinWaitActive("Rechner")
       Sleep(5000)
   EndIf

   Sleep(200)

WEnd


Func KillAll()
    If ProcessExists($pid1) Then ProcessClose($pid1)
    If ProcessExists($pid2) Then ProcessClose($pid2)
    Exit
EndFunc

Alles anzeigen

**Moombas**

Das Problem was meinen Vorschlag angeht, ist, das ich (unter Win11) es nicht hin bekomme, von der pid zum hwnd zu kommen, da der erstellte Prozess (wo man ja eine pid zurück bekommt) weder in ProcessList, noch in Winlist auftaucht. Erklären kann ich mir das aber nicht.

Ansonsten sähe meine Umsetzung ca. so aus (nicht komplett zu testen, aus genannten Gründen, leider)

AutoIt

Opt('MustDeclareVars', 1)
#include <Timers.au3>

HotKeySet("^!k", "Terminate") ; Strg + Alt + K zum Beenden des Skrip

Global $Programm[2][3] = [[2, "C:\Windows\System32\notepad.exe", "C:\Windows\System32\calc.exe"]]
Global $killSwitch = False

If Check_Programs() then Loop()

Func Check_Programs()
Local $pid
	For $i = 1 to $Programm[0][0]
		$pid = ProcessExists($Programm[1][$i])
		If $pid = 0 Then $pid = Run($Programm[0][$i])
		if $pid = 0 Then return false
		Consolewrite($pid & @CRLF)
		Sleep(2000)
		$Programm[1][$i] = _WinActivatePID($pid)
	Next
	return True
EndFunc

Func Loop()
Local $i = 1
Local $currentProgram = $Programm[1][$i]
Local $interval = 5 * 1000 ; 5 Sekunden
Local $timer = _Timer_Init()
Local $TimerProgress = 0
Local $diff = $interval

	While Not $killSwitch
		While $diff > 0
			$TimerProgress = _Timer_Diff($timer)
			$diff = $interval-$TimerProgress
			If not WinActive($currentProgram) Then
				WinSetState($currentProgram, "", @SW_MAXIMIZE)
			EndIf
			Sleep(100)
		WEnd

		If $currentProgram = $Programm[1][$i] Then
;~ 			WinSetState($currentProgram, "", @SW_MINIMIZE)
			ConsoleWrite($i & @CRLF)
			ConsoleWrite($Programm[1][$i] & @CRLF)
			$i += 1
			If $i > UBound($Programm, 2)-1 Then $i = 1

			$currentProgram = $Programm[1][$i]
			WinSetState($currentProgram, "", @SW_MAXIMIZE)
		EndIf
		$TimerProgress = 0
		$diff = $interval
		$timer = _Timer_Init()
	WEnd
EndFunc

Func _WinActivatePID($iPID)
Local $aList, $i
	$aList = WinList()
	For $i = 1 To $aList[0][0]
		If WinGetProcess($aList[$i][1]) = $iPID Then Return WinActivate($aList[$i][1])
	Next
	Return -1
EndFunc

Func Terminate()
	$killSwitch = True
EndFunc

Alles anzeigen

gmmg

Moombas hört sich nach meinem Problem an. Da hatte ich bei der Calc.exe auch das Problem.

Beitrag

RE: Windows 11 Calculator - Prozess PID herausfinden

Schnuffel , danke ich prüfe weiter

Kommt mir auch komisch vor, dass es machmal nicht geht.

So funktioniert es bei mir auch, lasse ich das Sleep weg, kommt auch ein 0 Wert zurück. Scheinbar braucht die Anwendung zu lange oder das Scxript ist zu schnell.

(Quelltext, 10 Zeilen)

gmmg

20. Februar 2026 um 09:34

Eventuell hilft es weiter

**Moombas**

Naja ProcessExists funktioniert bei mir ja aber halt in der ProcessList oder Winlist taucht der Prozess entweder nicht auf oder mit einer anderen PID als das was ich beim erstellen zurück bekommen habe.

gmmg

Wie prüfst du denn die Pids, wenn du immer nur $pid erstellst? Weiter unten greifst du dann auf die $iPID zu.

Bei der Calc.exe heißt der Process dann auch "CalculatorApp.exe"

$pid = ProcessExists("CalculatorApp.exe")

so kommen die korrekten PID's

AutoIt

;Global $Programm[2][3] = [[2, "C:\Windows\System32\notepad.exe", "C:\Windows\System32\calc.exe"]]
Global $Programm[2][3] = [[2, "notepad.exe", "calc.exe"]]
Global $killSwitch = False

If Check_Programs() then Loop()

Func Check_Programs()
	Local $pid, $pidNotepad, $pidcalc
	For $i = 1 to $Programm[0][0]

		MsgBox(0,"",$Programm[0][$i])
		;$pid = ProcessExists("CalculatorApp.exe")
		;$pid = ProcessExists("notepad.exe")

		If ($Programm[0][$i]) = "notepad.exe" Then
			MsgBox(0,"","test")
			If $pidNotepad = 0 Then Run($Programm[0][$i])
			Sleep(1500)
			$pidNotepad = ProcessExists("notepad.exe")
			Consolewrite($Programm[0][$i] & ": " & $pidNotepad & @CRLF)
			If $pidNotepad = 0 Then Return False
		EndIf
		$pidcalc = ProcessExists($Programm[0][$i])
		If $Programm[0][$i] = "calc.exe" Then
			If $pidcalc = 0 Then Run($Programm[0][$i])
			Sleep(1500)
			$pidcalc = ProcessExists("CalculatorApp.exe")
			Consolewrite($Programm[0][$i] & ": " & $pidcalc & @CRLF)
			If $pidcalc = 0 Then Return False
		EndIf

		;Consolewrite($Programm[0][$i] & ": " & $pidNotepad & @CRLF & $pidcalc)
		Sleep(2000)
		;$Programm[1][$i] = _WinActivatePID($pid)
	Next
	Return True
EndFunc

Alles anzeigen

**Moombas**

Wenn ich den Prozess starte (egal ob mit Shellexecute oder run) bekommst du ja bereits eine pid zurück.

Dort lag erst mal mein Fokus (Programme laufen noch nicht).

Und mit WinList() kannst du ja durchgehen und mit WinGetProcess($aList[$i][1]) die jeweiligen pids auslesen, bleibt aber immer ohne Ergebnis.
Auch wenn ich mir per Processlist (wo ja keine hwnd zu bekommen ist aber ich halt zur Prüfung geschaut habe) die Prozesse nach dem starten anschaue, taucht die pid vom erstellen nicht auf.
Manchmal auch nichtmal der Prozess laut Name (z.B. Rechner) oder eben mit einer ganz anderen pid (und ja es ist kein 2. Prozess dieser Programme am laufen).

Keine Ahnung was da falsch läuft.

BananaJoe

probier doch mal _ArrayDisplay(ProcessList('CalculatorApp.exe'))

gmmg

Hab's oben nochmal den quelltext angepasst. so bekomme ich die Pids.

**Moombas**

Alles schon gemacht (ein sich ändernder Exename lässt sich aber nicht dynamisch einfach mal so abfangen, ohne ihn manuell mit anzugeben, was ich vermeiden wollte, der calc war auch nur zum testen da).

Aber ich nehme das trotzdem mal als Beispiel:
- calc.exe gestartet -> pid: 24316
- CalculatorApp.exe pid über ProcessList ausgelesen -> pid: 2452
- msedge.exe gestartet -> pid: 31180
- msedge.exe pid über ProcessList ausgelesen -> 13 pids aber nicht die 31180

Oder ist das Problem nur bei mir, weil Unternehmens PC und sich irgendwas dazwischen setzt und daher die pids nicht passen?

Velted

Moin,

der Rechner "Calc.exe" startet jetzt die App "CalculatorApp.exe". Das Hauptfenster der Apps gehört immer der "ApplicationFrameHost.exe". Das Fenster des Rechners verbirgt sich unter dem Control "ApplicationFrameInputSinkWindow1". Deshalb all die 'Unstimmigkeiten'.

Velted

Noch mal Moin,

dass Run eine 'falsche' PID liefert entsteht dadurch, dass "Calc.exe" nur einen weiteren Prozess mit eigener PID startet und sich dann verabschieded. Die gelieferte PID ist dann wertlos.

**Moombas**

Zitat von Velted

Noch mal Moin,
dass Run eine 'falsche' PID liefert entsteht dadurch, dass "Calc.exe" nur einen weiteren Prozess mit eigener PID startet und sich dann verabschieded. Die gelieferte PID ist dann wertlos.

Das das nicht nur Calc betrifft hast du gesehen? Ich kann das mit msedge (siehe oben) als auch notepad nachstellen, andere habe ich noch nicht probiert.

**Moombas**

Nochmal mit VSCode getestet,damit geht es, es scheint hier ggf. ein Problem mit bestimmten MS Programmen zu sein, die in Windoof integriert sind und sich da anders verhalten.

Folgendes Beispiel funktionierte bei mir nun Einwandfrei (Achtung, die Zeit musst du verlängern, zum Testen hier auf 5 Sekunden gesetzt):

AutoIt

Opt('MustDeclareVars', 1)
#include <Timers.au3>
#include <Array.au3>

HotKeySet("^!k", "Terminate") ; Strg + Alt + K zum Beenden des Skrip

Global $Programm[2][3] = [[2, "C:\Program Files\Notepad++\notepad++.exe", "C:\Program Files\Microsoft VS Code\Code.exe"]]
Global $killSwitch = False

If Check_Programs() then Loop()

Func Check_Programs()
Local $pid
	For $i = 1 to $Programm[0][0]
		$pid = ProcessExists($Programm[1][$i])
		If $pid = 0 Then $pid = Run($Programm[0][$i])
		if $pid = 0 Then return false
		Sleep(2000)
		$Programm[1][$i] = _WinActivatePID($pid)
	Next
	return True
EndFunc

Func Loop()
Local $i = 1
Local $currentProgram = $Programm[1][$i]
Local $interval = 5 * 1000 ; 5 Sekunden
Local $timer = _Timer_Init()
Local $TimerProgress = 0
Local $diff = $interval

	While Not $killSwitch
		While $diff > 0
			$TimerProgress = _Timer_Diff($timer)
			$diff = $interval-$TimerProgress
			If not WinActive($currentProgram) Then
				WinSetOnTop($currentProgram, Default, $WINDOWS_ONTOP)
				sleep(100)
				WinSetOnTop($currentProgram, Default, $WINDOWS_NOONTOP)
			EndIf
			Sleep(100)
		WEnd

		If $currentProgram = $Programm[1][$i] Then
			$i += 1
			If $i > UBound($Programm, 2)-1 Then $i = 1

			$currentProgram = $Programm[1][$i]
			WinSetOnTop($currentProgram, Default, $WINDOWS_ONTOP)
			sleep(100)
			WinSetOnTop($currentProgram, Default, $WINDOWS_NOONTOP)
		EndIf
		$TimerProgress = 0
		$diff = $interval
		$timer = _Timer_Init()
	WEnd
EndFunc

Func _WinActivatePID($iPID)
Local $aList, $i
	$aList = WinList()
	For $i = 1 To $aList[0][0]
		If WinGetProcess($aList[$i][1]) = $iPID Then Return WinActivate($aList[$i][1])
	Next
	Return -1
EndFunc

Func Terminate()
	$killSwitch = True
EndFunc

Alles anzeigen

RSBox

Boa, ihr seid super. Vielen Dank für eure Bemühungen.

Ich werde es morgen mal testen. Mit meinen Programmen.

**Kanashius**

Ich fand das Problem interessant und hab mal ein Programm dafür geschrieben. Das sollte umsetzen, was du möchtest:

Thema

Window Looper

Dieses Script kann verwendet werden, um verschiedene Fenster mit dem Processnamen, Processpfad, Windowtitle und visibility auszuwählen und abwechselnd ein/aus zu blenden.

Processname und Processpfad müssen identisch sein, der Fenstertitel muss nur in dem richtigen Titel enthalten sein. Mehrere Bedingungen können auch kombiniert werden.

Außerdem ist es möglich, einen Modus zu aktivieren, in dem mit "ENTER" das jeweils aktive Fenster hinzugefügt werden kann.

Das Interval, wie lange das jeweilige…

Kanashius

21. Februar 2026 um 01:30

Das Programm kann Fenster automatisch erkennen (Nach Prozessname, Prozesspfad, Fenstertitel und Sichtbarkeit des Fensters). Außerdem können Fenster manuell hinzugefügt werden (Das hinzufügen im Programm aktivieren, dann das Fenster auswählen und ENTER drücken. ENTER ist in dem Modus natürlich blockiert, bis der Modus beendet wird).

Die Fenster werden dann nacheinander durchgegangen (Reihenfolge kann geändert werden) und angezeigt. Sie werden dabei nicht "aktiviert". Das heißt, man kann den PC nebenbei ganz normal verwenden. Wenn andere Fenster vor die ein/ausblendenden Fenster geschoben werden, bleiben sie auch dahinter.

Ich hoffe, das ist es was du gesucht hast, ansonsten kannst du dir im Quellcode in Zeile 346 die Funktion _winHandle ansehen, dort kann geändert werden, was passiert, wenn ein Fenster "aktiviert" wird.

Viel Spaß damit