Website wird nicht gefunden

hipfzwirgel

Hallo Gemeinde,

ich muss eine Tabelle unserer KVM-Switche auslesen. Leider geht das nicht via SSH oder REST, etc.. D. h. mein Programm startet den Firefox, öffnet die LoginSeite und sendet die Logindaten.
Leider geht das nicht da er die Seite nicht findet. Laut Logfile: Logwrite(379,...).
Alle Versuche das via KI zu fixen funktionieren nicht. Findet jemand den Fehler oder hat eine Idee wie ich das so hinbekomme, dass die Loginseite auf jeden Fall gefunden wird?
Der Name der Website Login — Mozilla Firefox wurde durch Weblist verifiziert...

Code

Func LoginToKVMWebInterface($sFirefoxPath, $sProfile, $sURL, $sAccount, $sPwd, $iKVMID)
	Opt("WinTitleMatchMode", 2)
	Local $sTempProfile = @TempDir & "\ffprofile_" & $iKVMID
	DirCreate($sTempProfile)

	Local $sCmd = '"' & $sFirefoxPath & '" -no-remote -profile "' & $sTempProfile & '" "' & $sURL & '"'
	Run($sCmd, "", @SW_HIDE)
	LogWrite(375, "INFO: Firefox fuer KVM-ID " & $iKVMID & " gestartet mit URL: " & $sURL)

	Local $bLoginWindow = WinWaitActive("Login — Mozilla Firefox", "", 20)
	If Not $bLoginWindow Then
		LogWrite(379, "ERROR: Login-Fenster bei " & $sURL & " nicht gefunden!")
		KillFirefoxInstance($sTempProfile)
		DirRemove($sTempProfile, 1)
		Return SetError(1, 0, "")
	EndIf

	; Anmeldedaten eingeben
	; Warten bis Login-Fenster erscheint
	Local $hWnd = WinWait("[REGEXPTITLE:^Login — Mozilla Firefox$]", "", 20)

	If $hWnd = 0 Then
		LogWrite(389, "FEHLER: Browser/Login-Fenster nicht gefunden")
		Return
	EndIf

	; Aktivieren und sicher warten
	WinActivate($hWnd)
	If Not WinWaitActive($hWnd, "", 10) Then
		LogWrite(392, "FEHLER: Fenster konnte nicht aktiviert werden")
		Return
	EndIf

	LogWrite(395, "Fenster aktiv")

	; WICHTIG: kurze Stabilisierung
	Sleep(1000)
	WinActivate($hWnd)
	; Anmeldedaten eingeben
	Send($sAccount)
	Sleep(200)
	Send("{TAB}")
	Sleep(200)
	Send($sPwd)
	Sleep(200)
	Send("{TAB}")
	Sleep(200)
	Send("{ENTER}")
;~ 	Sleep(3000)
	LogWrite(405, "INFO: Anmeldedaten gesendet fuer KVM-ID " & $iKVMID)

	; Auf erfolgreichen Login (Fenstertitel der Startseite) warten
	Local $bLoginSuccess = False
	For $i = 1 To 20
		Sleep(1000)
		Local $sTitle = WinGetTitle("[ACTIVE]")
		If StringInStr($sTitle, "Port Access") Or StringInStr($sTitle, "/home.asp") Then
			$bLoginSuccess = True
			ExitLoop
		EndIf
	Next

	If Not $bLoginSuccess Then
		LogWrite(419, "ERROR: Login fehlgeschlagen fuer KVM-ID " & $iKVMID & " bei URL: " & $sURL)
		KillFirefoxInstance($sTempProfile)
		DirRemove($sTempProfile, 1)
		Return SetError(2, 0, "")
	EndIf

	LogWrite(425, "INFO: Login erfolgreich fuer KVM-ID " & $iKVMID & " bei URL: " & $sURL)
	Return $sTempProfile

EndFunc   ;==>LoginToKVMWebInterface

Alles anzeigen

Velted

Moin, was zeigt denn das Firefox Fenster?

Velted

Noch eine Anmerkung:

Code

	Local $bLoginWindow = WinWaitActive("Login — Mozilla Firefox", "", 20)
	If Not $bLoginWindow Then
		LogWrite(379, "ERROR: Login-Fenster bei " & $sURL & " nicht gefunden!")
		KillFirefoxInstance($sTempProfile)
		DirRemove($sTempProfile, 1)
		Return SetError(1, 0, "")
	EndIf

Der Wert, der von WinWaitActive() in $bLoginWindow abgelegt wird, ist kein boolescher Wert ($b...) sondern ein Handle ($h...). Wenn das Fenster früh genug aktiv wurde, steht deshalb in dieser Variablen der später von Dir als $hWnd genutzte Wert und das Fenster ist aktiv.

Der folgende Code ist damit überflüssig:

Code

	; Anmeldedaten eingeben
	; Warten bis Login-Fenster erscheint
	Local $hWnd = WinWait("[REGEXPTITLE:^Login — Mozilla Firefox$]", "", 20)

	If $hWnd = 0 Then
		LogWrite(389, "FEHLER: Browser/Login-Fenster nicht gefunden")
		Return
	EndIf

	; Aktivieren und sicher warten
	WinActivate($hWnd)
	If Not WinWaitActive($hWnd, "", 10) Then
		LogWrite(392, "FEHLER: Fenster konnte nicht aktiviert werden")
		Return
	EndIf

Alles anzeigen

hipfzwirgel

Hallo Velted,

zunächst vielen lieben Dank für deine Antwort. Ich bin insofern ein kleines Stück weiter, als das beim vorigen Code einfach

mal das Winactivate gefehlt hat und die Loginseite somit nicht fokussiert wurde. Der Code ist jetzt wie folgt:

Code

Func LoginToKVMWebInterface($sFirefoxPath, $sProfile, $sURL, $sAccount, $sPwd, $iKVMID)

	Local $sTempProfile = @TempDir & "\ffprofile_" & $iKVMID
	DirCreate($sTempProfile)

	Local $sCmd = '"' & $sFirefoxPath & '" -no-remote -profile "' & $sTempProfile & '" "' & $sURL & '"'
	Run($sCmd, "", @SW_HIDE)
	LogWrite(394, "INFO: Firefox fuer KVM-ID " & $iKVMID & " gestartet mit URL: " & $sURL)

	$bLoginWindow = WinActivate("Login")
	LogWrite(397, "Handle von WinActivate: " & $bLoginWindow)
	Local $hWnd = WinWaitActive($bLoginWindow, "", 60)
	If Not $hWnd Then
		LogWrite(399, "ERROR: Login-Fenster bei " & $sURL & " nicht gefunden!")
		KillFirefoxInstance($sTempProfile)
		DirRemove($sTempProfile, 1)
		Return SetError(1, 0, "")
	EndIf

Alles anzeigen

Es ist dennoch zum Haare raufen (so denn man welche hat ), dass immer im ersten Durchgang (die Func wird ja per Schleife 4 mal aufgerufen) der Login nicht funktioniert, da die Seite
gem. Zeile 14 nicht gefunden wird, obwohl Winactivate die Seite fokussiert. Dennoch ist die Variable $bLoginWindow 0. Seltsamer Weise funktionieren die Aufrufe 2 bis 4 tadellos.
Die Zeile Opt("WinTitleMatchMode", 2) habe ich an den Anfang des Proggis gestellt.
Im Anhang ist die Website abgebildet...

gmmg

hipfzwirgel warum nutzt du dazu nicht die Webdriver Automatisierung.

Die gibt es für Edge/Google Chrome/ Firefox und ggf. andere und im Forum sollte es auch diverse Beispiele geben.

Hier mal ein Beispiel per Webdriver für den GoogleChrome Browser und was man dafür alles braucht.

Beitrag

RE: Google Chrome Automatisierung WebDriver UDF

Das ist ohne dein Script zu kennen schwierig zu beantworten, da es verschiedene Ansätze gibt.

Schau dir einmal das "Getting started example" Script im Abschnitt "create capabilites for session" auf der folgenden Webseite an, da sollte das klar werden.

https://www.autoitscript.com/wiki/WebDriver

Ansonsten poste doch mal dein Script (ohne URL und Passwörter)

Hier mal ein Beispiel zum Login für Autoit, so wie ich das mache. Achtung hier wird noch die Chrome Version anhand der GoogleChrome.exe…

gmmg

5. September 2024 um 13:03

Gruß gmmg

hipfzwirgel

Hallo gmmg,

ich habe das schon einmal versucht. Aber leider scheiterte ich schon daran, das ich den Webdriver nicht richtig zum Einsatz bringen konnte. Mal
fehlte eine Funktion in der UDF. Dann war es eine veraltete oder falsche Version der UDF usw. Google Chrome kann ich aus Policy-Gründen leider nicht nutzen.

Es treibt mich in den Wahnsinn, das der Task gestern das Programm alle 30 min. startete und es sauber durchlief. Heute findet das Proggi wieder die Login-Seite nicht.

Wie kann es sein, dass die Webseite angezeigt wird, geladen ist, per Winlist ausgelesen werden kann aber Winactivate das Fenster nicht findet

Das kann doch nicht wahr sein....

gmmg

welche Browser kannst du denn nutzen?

nur Firefox oder auch den Edge?

Beispiel für Firefox:

AutoIt

#include "wd_core.au3"
#include "wd_helper.au3"

Local $sDesiredCapabilities, $sSession
_WD_Option('Driver', 'geckodriver.exe') ; Pfad zum Geckodriver
_WD_Option('Port', 4444)

; Firefox Profil/Einstellungen definieren
$sDesiredCapabilities = '{"capabilities": {"alwaysMatch": {"browserName": "firefox"}}}'

; Browser starten
_WD_Startup()
$sSession = _WD_CreateSession($sDesiredCapabilities)

; autoit.de aufrufen
_WD_Navigate($sSession, "https://autoit.de/wcf/login/?url=https%3A%2F%2Fautoit.de%2F")

; Login-Felder ausfüllen (Beispiel-IDs/Namen, ggf. via F12 im Browser prüfen)
Local $sUserField = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//input[@id='username']")
_WD_ElementAction($sSession, $sUserField, 'value', "DeinBenutzername")

Local $sPassField = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//input[@id='password']")
_WD_ElementAction($sSession, $sPassField, 'value', "DeinPasswort")

; Login-Button klicken
Local $sLoginBtn = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//*[@id='tpl_wcf_login']")
_WD_ElementAction($sSession, $sLoginBtn, 'click')

; Session beenden (optional)
; _WD_DeleteSession($sSession)
_WD_Shutdown()

Alles anzeigen

gmmg

du benötigst dazu den aktuellen Geckodriver (https://github.com/mozilla/geckodriver/releases)

und einige au3 Dateien für das Webdriver Projekt.

Releases · Danp2/au3WebDriver

Web Driver UDF for AutoIt. Contribute to Danp2/au3WebDriver development by creating an account on GitHub.

github.com

und unter https://github.com/Danp2/au3WebDriver die preconditions:

Json UDF - Archive includes Json.au3 & BinaryCall.au3.
WinHTTP UDF - Archive includes WinHttp.au3 & WinHttpConstants.au3. bzw. version 1.6.4.2 https://github.com/dragana-r/auto…ter/WinHttp.au3

schau dir auch das utoit-webdriver-boilerplate Projekt von Sven dazu an:

GitHub - sven-seyfert/autoit-webdriver-boilerplate: The project "autoit-webdriver-boilerplate" can be used as quick entry point for the awesome "au3WebDriver" project by @Danp2 (and @mlipok). The intention is, give people a easy start with WebDriver for…

The project "autoit-webdriver-boilerplate" can be used as quick entry point for the awesome "au3WebDriver" project by @Danp2 (and @mlipok).…

github.com

Velted

Moin,

nach dem Bild in Beitrag #4 gehe ich davon aus, dass Du das kleine Login-Fenster unten rechts ansprechen willst. Wenn die "Window Info" das als eigenständiges Fenster mir eigener fester Klasse erkennt, kannst Du die Fensterklasse als zusätzliches Auswahlkriterium nutzen:

Code

$hWnd = WinWait("[TITLE:Login; CLASS:FensterKlasse]", , 10)
If $hwnd = 0 Then Fehler!!!
WinActivate($hWnd)
If Not WinWaitActive($hWnd), , 5) Then Fehler!!!
; Gefunden!

hipfzwirgel

Hallo gmmg und Velted,

allerherzlichsten Dank für eure Beiträge.

@ gmmg: ich werde mir zu gegebener Zeit das mit dem Webdriver nochmals anschauen. Werde ich ja doch öfter benötigen
zur Zeit benutze ich den Firefox. MS Edge wäre auch erlaubt. Verstehe ich das richtig? Wenn ich den o.g. Geckodriver installiere und die beiden UDF's in den Include-Ordner ablege,
dann sollte das funktionieren?

@ Velted: Einer der größten Fehler war, dass der Task-Scheduler das Programm als Admin startete. Dadurch war das UserProfil vom eigentlichen User nicht "rechtzeitig" geladen worden.
Darum liefen die weiteren Durchgänge dann durch, da da dann das Profil da war...Es hatte also nichts mit dem Code direkt zu tun.
Nachdem ich den Task angepasst hatte lief das Proggi wie es sollte

gmmg

hipfzwirgel ja, wenn du alle benötigten Webdriver Dateinen so ablegst geht das. Wenn die Exe kompiliert ist, brauchst du nur noch deine Exe Datei und die Webdriver exe (gekko.exe/ chromdriver.exe oder die Edgedriver.exe)

Website wird nicht gefunden

RE: Google Chrome Automatisierung WebDriver UDF

Ähnliche Themen

Community Projekt: Teil 1 - Interesse an einem gemeinsamen größeren (Software)Projekt?