Pipette

      Hi, ich habe ein kleines Script gemacht (110 Zeilen) welches es euch ermöglicht, Farben, die auf dem Bildschirm dargestellt werden zu identifizieren (als HEX, RBG und RBG %). Schaut es euch einfach mal an. Es ist wirklich nichts Großes, aber vielleicht findet ja der ein oder andere daran Gefallen. Ich werde in nächster Zeit wahrscheinlich noch ein paar Updates rausbringen.

      Feedback ist erwünscht :) .



      Version 1.1:
      • Code jetzt ressourcenschonender (danke an Kizum)
      Version 1.2
      • Bugfix beim Kopieren des RGB Farbwerts
      • Icon binär eingebunden
      • Code optimiert (danke an RR04)
      Version 1.2.1
      • Code "verschönert" - keinerlei Änderrungen an Programmfunktionalität (danke an RR04)
      Dateien
      • Pipette.au3

        (4,88 kB, 203 mal heruntergeladen, zuletzt: )
      GrooveLoad

      Geh mit Gott, aber geh!

      Dieser Beitrag wurde bereits 5 mal editiert, zuletzt von „Cheater Dieter“ ()

      AutoIt-Quellcode

      1. IniWrite (@TempDir & "\Pipette.txt"
      8| 8|

      Habe mal die Dateiendung "ini" eingeführt.
      Und eine Prüfung ob $farbe immer noch die selbe Farbe wie im vorherigen Schleifendurchgang ist, dann kann man sich den Rest der Schleife sparen.
      Und noch ein kleiner Sleep(25), ..freut sich der Prozessor.


      Spoiler anzeigen

      AutoIt-Quellcode

      1. #include <ButtonConstants.au3>
      2. #include <EditConstants.au3>
      3. #include <GUIConstantsEx.au3>
      4. #include <GUIListBox.au3>
      5. #include <StaticConstants.au3>
      6. #include <WindowsConstants.au3>
      7. Global $farbebackup
      8. Global $farbe
      9. Global $ini = @ScriptDir & "\Pipette.ini"
      10. $farbehtml = "#000000"
      11. $R = 0
      12. $G = 0
      13. $B = 0
      14. $on = False
      15. GUICreate("Pipette", 615, 219)
      16. GUICtrlCreateGroup("", 8, 8, 161, 201)
      17. $vorschau = GUICtrlCreateLabel("", 13, 20, 148, 148)
      18. GUICtrlSetBkColor(-1, 0x0)
      19. $start = GUICtrlCreateButton("Pipette aufnehmen", 16, 176, 147, 25)
      20. GUICtrlCreateGroup("", -99, -99, 1, 1)
      21. GUICtrlCreateGroup("Farbmodelle", 176, 16, 233, 193)
      22. GUICtrlCreateLabel("Hexadezimal (HEX):", 192, 40, 98, 17)
      23. $hex_input = GUICtrlCreateInput("#000000", 208, 57, 161, 21)
      24. $copy_hex = GUICtrlCreateButton("", 376, 56, 21, 21, $BS_ICON)
      25. GUICtrlSetImage(-1, "copy.ico", -1)
      26. GUICtrlCreateLabel("RGB-Farbraum (RGB):", 192, 88, 109, 17)
      27. $RGB_R = GUICtrlCreateInput("0", 208, 104, 49, 21)
      28. $RGB_G = GUICtrlCreateInput("0", 264, 104, 49, 21)
      29. $RGB_B = GUICtrlCreateInput("0", 320, 104, 49, 21)
      30. $copy_rbg = GUICtrlCreateButton("", 376, 104, 21, 21, $BS_ICON)
      31. GUICtrlSetImage(-1, "copy.ico", -1)
      32. GUICtrlCreateLabel("Prozentualer RGB-Farbraum (RBG %):", 192, 136, 182, 17)
      33. $Proz_R = GUICtrlCreateInput("0", 208, 152, 49, 21)
      34. $Proz_G = GUICtrlCreateInput("0", 264, 152, 49, 21)
      35. $Proz_B = GUICtrlCreateInput("0", 320, 152, 49, 21)
      36. $copy_proz = GUICtrlCreateButton("", 376, 152, 21, 21, $BS_ICON)
      37. GUICtrlSetImage(-1, "copy.ico", -1)
      38. GUICtrlCreateGroup("", -99, -99, 1, 1)
      39. GUICtrlCreateGroup("Verlauf", 416, 16, 153, 193)
      40. $verlauf = GUICtrlCreateList("", 424, 32, 137, 162)
      41. GUICtrlCreateGroup("", -99, -99, 1, 1)
      42. GUISetState(@SW_SHOW)
      43. While 1
      44. $nMsg = GUIGetMsg()
      45. Switch $nMsg
      46. Case $GUI_EVENT_CLOSE
      47. FileDelete ($ini)
      48. Exit
      49. Case $copy_hex
      50. ClipPut ($farbehtml)
      51. Case $copy_rbg
      52. ClipPut (Round ($R/255*100,1) & ", " & Round ($B/255*100,1) & ", " & Round ($G/255*100,1))
      53. Case $start
      54. HotKeySet ("{Enter}","_Mark")
      55. GUICtrlSetState ($start,$GUI_DISABLE)
      56. GUICtrlSetData ($start,"Zum Ablegen Enter drücken")
      57. $on = True
      58. Case $verlauf
      59. GUICtrlSetData ($hex_input,IniRead ($ini,GUICtrlRead ($verlauf),"HexHTML","Error"))
      60. GUICtrlSetBkColor ($vorschau,IniRead ($ini,GUICtrlRead ($verlauf),"HexVorschau","Error"))
      61. GUICtrlSetData ($RGB_R, IniRead ($ini,GUICtrlRead ($verlauf),"R","Error"))
      62. GUICtrlSetData ($RGB_G, IniRead ($ini,GUICtrlRead ($verlauf),"G","Error"))
      63. GUICtrlSetData ($RGB_B, IniRead ($ini,GUICtrlRead ($verlauf),"B","Error"))
      64. GUICtrlSetData ($Proz_R,Round (IniRead ($ini,GUICtrlRead ($verlauf),"R","Error")/255*100,1))
      65. GUICtrlSetData ($Proz_G,Round (IniRead ($ini,GUICtrlRead ($verlauf),"G","Error")/255*100,1))
      66. GUICtrlSetData ($Proz_B,Round (IniRead ($ini,GUICtrlRead ($verlauf),"B","Error")/255*100,1))
      67. EndSwitch
      68. If $on = True Then
      69. $farbe = PixelGetColor (MouseGetPos (0),MouseGetPos (1))
      70. if $farbebackup <> $farbe Then
      71. $farbehex = Hex ($farbe)
      72. $farbehex = StringTrimLeft ($farbehex,2)
      73. $farbehtml = "#" & $farbehex
      74. $farbedarstellung = "0x" & $farbehex
      75. GUICtrlSetBkColor($vorschau, $farbedarstellung)
      76. $HR = StringMid($farbehex, 1, 2)
      77. $HG = StringMid($farbehex, 3, 2)
      78. $HB = StringMid($farbehex, 5, 2)
      79. $R = Dec($HR)
      80. $G = Dec($HG)
      81. $B = Dec($HB)
      82. GUICtrlSetData ($hex_input,$farbehtml)
      83. GUICtrlSetData ($RGB_R, $R)
      84. GUICtrlSetData ($RGB_G, $G)
      85. GUICtrlSetData ($RGB_B, $B)
      86. GUICtrlSetData ($Proz_R,Round ($R/255*100,1))
      87. GUICtrlSetData ($Proz_G,Round ($G/255*100,1))
      88. GUICtrlSetData ($Proz_B,Round ($B/255*100,1))
      89. EndIf
      90. EndIf
      91. $farbebackup = $farbe
      92. Sleep(25)
      93. WEnd
      94. Func _Mark ()
      95. $on = False
      96. HotKeySet ("{Enter}")
      97. GUICtrlSetState ($start,$GUI_ENABLE)
      98. GUICtrlSetData ($start,"Pipette aufnehmen")
      99. GUICtrlSetData ($verlauf, $R & " " & $G & " " & $B)
      100. IniWrite ($ini,$R & " " & $G & " " & $B,"HexHTML",$farbehtml)
      101. IniWrite ($ini,$R & " " & $G & " " & $B,"HexVorschau",$farbedarstellung)
      102. IniWrite ($ini,$R & " " & $G & " " & $B,"R",$R)
      103. IniWrite ($ini,$R & " " & $G & " " & $B,"G",$G)
      104. IniWrite ($ini,$R & " " & $G & " " & $B,"B",$B)
      105. EndFunc
      106. Func _binaer ()
      107. $Icon = "0x000001000100101010000100040028010000160000002800000010000000200000000100040000000000000000000000000000000000000000000000000080808000FFFFFF0000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000002222200000000222222220111111002222222011111101022200001111110000220110111111111022011011000111102201101111111110220110110000011022011011111111102201101100000110220110111111111022011011111111102201100000000000220111111111022222011111111102222200000000000222F8070000F8030000F8010000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0070000C0070000C0070000"
      108. FileOpen("copy.ico", 18)
      109. FileWrite(FileOpen("copy.ico", 18), Binary($Icon))
      110. FileClose("copy.ico")
      111. EndFunc
      Danke Kizum, ich hab mir jetzt mal deinen Code angeschaut und 2 Sachen übernommen: Den Sleep und die Prüfung, ob sich die Farbe verändert hat.
      Ob die Datei jetzt Pipette.txt oder Pipette.ini heißt, ist wohl grad egal (theoretisch sind TXTs ja sogar besser, denn INIs haben doch eine Größenbeschränkung oder irre ich mich?).

      ===> Version 1.1
      GrooveLoad

      Geh mit Gott, aber geh!

      Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „Cheater Dieter“ ()

      @Cheater Deater - Haben sie ?
      Wahrscheinlich hat die Ini-Read Funktion das, aber mir wäre das neu; somit müsste jede Datei auf deinem System eine Beschränkung auf 4096 KB haben ...
      Aber es ist doch egal, ob die Datei WAYNE.Weihnachten, Farbe.txt oder farbe.schlagmichtot heißt ...
      Der Dateiname ist ja letztendlich nur eine Erkennungsmarke, wie ein Hund sie hat -> An der Erkennungsmarke erkennt man den Besitzer. Stellen wir uns vor die Erkennungsmarke ist deine Datei und der Besitzer das Programm das sie ausführt :D
      Etwas blöd aber so in etwa ^^
      Hi,
      gute Arbeit, sehr schöner Stil.

      Tipps:
      Keine Includes nötig.
      Den 14 mal "@TempDir & "\Pipette.txt"" eine Variable spendieren "Global $PipetteTXT = @TempDir & "\Pipette.txt"".
      Das Icon in das Script einbauen.
      Spoiler anzeigen

      AutoIt-Quellcode

      1. #region ;**** Directives created by AutoIt3Wrapper_GUI ****
      2. #AutoIt3Wrapper_Outfile=Pipette.exe
      3. #AutoIt3Wrapper_Res_Icon_Add=copy.ico ;i icon wird in die EXE eingebaut !erst beim kompilieren!
      4. #AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 ;i mehr Auskunft u. Sicherheit fürs Script
      5. #AutoIt3Wrapper_Run_Tidy=y
      6. #AutoIt3Wrapper_Run_Obfuscator=y
      7. #Obfuscator_Parameters=/striponly
      8. #endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
      9. $farbehtml = "#000000"
      10. $R = 0
      11. $G = 0
      12. $B = 0
      13. $on = False
      14. Global $PipetteTXT = @TempDir & "\Pipette.txt" ;i eine Globale Var für alle 14 Pfade !
      15. Global $farbebackup, $title = "Pipette"
      16. GUICreate($title, 615, 219)
      17. GUICtrlCreateGroup("", 8, 8, 161, 201)
      18. $vorschau = GUICtrlCreateLabel("", 13, 20, 148, 148)
      19. GUICtrlSetBkColor(-1, 0x0)
      20. $start = GUICtrlCreateButton($title, 16, 176, 147, 25)
      21. GUICtrlCreateGroup("", -99, -99, 1, 1)
      22. GUICtrlCreateGroup("Farbmodelle", 176, 16, 233, 193)
      23. GUICtrlCreateLabel("Hexadezimal (HEX):", 192, 40, 98, 17)
      24. $hex_input = GUICtrlCreateInput("#000000", 208, 57, 161, 21)
      25. $copy_hex = GUICtrlCreateButton("", 376, 56, 21, 21, 0x0040)
      26. GUICtrlSetImage(-1, @ScriptFullPath, -5) ;i Aufruf des eingebauten Icons !
      27. GUICtrlCreateLabel("RGB-Farbraum (RGB):", 192, 88, 109, 17)
      28. $RGB_R = GUICtrlCreateInput("0", 208, 104, 49, 21)
      29. $RGB_G = GUICtrlCreateInput("0", 264, 104, 49, 21)
      30. $RGB_B = GUICtrlCreateInput("0", 320, 104, 49, 21)
      31. $copy_rbg = GUICtrlCreateButton("", 376, 104, 21, 21, 0x0040)
      32. GUICtrlSetImage(-1, @ScriptFullPath, -5) ;i Aufruf des eingebauten Icons !
      33. GUICtrlCreateLabel("Prozentualer RGB-Farbraum (RBG %):", 192, 136, 182, 17)
      34. $Proz_R = GUICtrlCreateInput("0", 208, 152, 49, 21)
      35. $Proz_G = GUICtrlCreateInput("0", 264, 152, 49, 21)
      36. $Proz_B = GUICtrlCreateInput("0", 320, 152, 49, 21)
      37. $copy_proz = GUICtrlCreateButton("", 376, 152, 21, 21, 0x0040)
      38. GUICtrlSetImage(-1, @ScriptFullPath, -5) ;i Aufruf des eingebauten Icons !
      39. GUICtrlCreateGroup("", -99, -99, 1, 1)
      40. GUICtrlCreateGroup("Verlauf", 416, 16, 153, 193)
      41. $verlauf = GUICtrlCreateList("", 424, 32, 137, 162)
      42. GUICtrlCreateGroup("", -99, -99, 1, 1)
      43. GUISetState(@SW_SHOW)
      44. While 1
      45. $nMsg = GUIGetMsg()
      46. Switch $nMsg
      47. Case -3
      48. FileDelete($PipetteTXT)
      49. Exit
      50. Case $copy_hex
      51. ClipPut($farbehtml)
      52. Case $copy_rbg
      53. ClipPut(Round($R / 255 * 100, 1) & ", " & Round($B / 255 * 100, 1) & ", " & Round($G / 255 * 100, 1))
      54. Case $start
      55. HotKeySet("{Enter}", "_Mark")
      56. GUICtrlSetState($start, 128)
      57. GUICtrlSetData($start, "Enter drücken zum ablegen !")
      58. $on = True
      59. Case $verlauf
      60. GUICtrlSetData($hex_input, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexHTML", "Error"))
      61. GUICtrlSetBkColor($vorschau, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexVorschau", "Error"))
      62. GUICtrlSetData($RGB_R, IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error"))
      63. GUICtrlSetData($RGB_G, IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error"))
      64. GUICtrlSetData($RGB_B, IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error"))
      65. GUICtrlSetData($Proz_R, Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error") / 255 * 100, 1))
      66. GUICtrlSetData($Proz_G, Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error") / 255 * 100, 1))
      67. GUICtrlSetData($Proz_B, Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error") / 255 * 100, 1))
      68. EndSwitch
      69. If $on = True Then
      70. $farbe = PixelGetColor(MouseGetPos(0), MouseGetPos(1))
      71. If $farbebackup <> $farbe Then
      72. $farbehex = Hex($farbe)
      73. $farbehex = StringTrimLeft($farbehex, 2)
      74. $farbehtml = "#" & $farbehex
      75. $farbedarstellung = "0x" & $farbehex
      76. GUICtrlSetBkColor($vorschau, $farbedarstellung)
      77. $HR = StringMid($farbehex, 1, 2)
      78. $HG = StringMid($farbehex, 3, 2)
      79. $HB = StringMid($farbehex, 5, 2)
      80. $R = Dec($HR)
      81. $G = Dec($HG)
      82. $B = Dec($HB)
      83. GUICtrlSetData($hex_input, $farbehtml)
      84. GUICtrlSetData($RGB_R, $R)
      85. GUICtrlSetData($RGB_G, $G)
      86. GUICtrlSetData($RGB_B, $B)
      87. GUICtrlSetData($Proz_R, Round($R / 255 * 100, 1))
      88. GUICtrlSetData($Proz_G, Round($G / 255 * 100, 1))
      89. GUICtrlSetData($Proz_B, Round($B / 255 * 100, 1))
      90. EndIf
      91. $farbebackup = $farbe
      92. EndIf
      93. Sleep(25)
      94. WEnd
      95. Func _Mark()
      96. $on = False
      97. HotKeySet("{Enter}")
      98. GUICtrlSetState($start, 64)
      99. GUICtrlSetData($start, $title)
      100. GUICtrlSetData($verlauf, $R & " " & $G & " " & $B)
      101. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexHTML", $farbehtml)
      102. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexVorschau", $farbedarstellung)
      103. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "R", $R)
      104. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "G", $G)
      105. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "B", $B)
      106. EndFunc ;==>_Mark
      107. ; Ende

      Schöne Feiertage ! 8)
      Dateien
      • Pipette(2).zip

        (291,68 kB, 83 mal heruntergeladen, zuletzt: )

      RR04 schrieb:

      Keine Includes nötig.
      8o Danke für den Tipp, das kannte ich nicht.

      RR04 schrieb:

      Das Icon in das Script einbauen.
      Oder es einfach binär einbinden.

      RR04 schrieb:

      Den 14 mal "@TempDir & "\Pipette.txt"" eine Variable spendieren "Global $PipetteTXT = @TempDir & "\Pipette.txt"".
      Gut, habe ich gemacht.

      ==> Das und ein Bugfix in Version 1.2 eingebaut.
      GrooveLoad

      Geh mit Gott, aber geh!

      Nettes Skript, erinnert mich an frühere Versionen von Paint...
      Spoiler anzeigen

      AutoIt-Quellcode

      1. $Show = False
      2. HotKeySet('{F1}', '_Toggle')
      3. HotKeySet('{ESC}', '_Exit')
      4. Do
      5. If $Show Then
      6. ToolTip(Hex(PixelGetColor(MouseGetPos(0), MouseGetPos(1))))
      7. EndIf
      8. Until False
      9. Func _Toggle()
      10. $Show = Not $Show
      11. If Not $Show Then
      12. ToolTip('')
      13. EndIf
      14. EndFunc
      15. Func _Exit()
      16. Exit
      17. EndFunc
      "Possible? Anything is possible. Practical? I'm doubtful. Demonstrable? That can be debated. Easy? Hell no."

      AutoIt Version: 3.3.9.5 | SciTE Version: 2.28 (SciTE Lite)

      IRC: irc.afterworkchat.com #minxomat
      Pipette

      AutoIt-Quellcode

      1. #AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
      2. #cs
      3. 1. Eine Var für 4 mal "@TempDir & "\" & "copy.jpg"".
      4. 2. 2x3 = 6 Inputs erstellt.
      5. 3. Das Bild "copy.jpg" gelöscht.
      6. #ce
      7. Global $icon = ""
      8. $icon &= "0x000001000100101010000100040028010000160000002800000010000000200000000100040000000000000000000000000000000000000000000000000080808000FFFFFF0000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000002222200000000222222220111111002222222011111101022200001111110000220110111111111022011011000111102201101111111110220110110000011022011011111111102201101100000110220110111111111022011011111111102201100000000000220111111111022222011111111102222200000000000222F8070000F8030000F8010000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0070000C0070000C0070000"
      9. Global $copyJPG = @TempDir & "\" & "copy.jpg" ;i Eine Var für 4 mal "@TempDir & "\" & "copy.jpg"".
      10. $handle = FileOpen($copyJPG, 18)
      11. FileWrite($handle, Binary($icon))
      12. FileClose($handle)
      13. Global $PipetteTXT = @TempDir & "\Pipette.txt"
      14. Global $farbehtml = "#000000"
      15. $R = 0
      16. $G = 0
      17. $B = 0
      18. $on = False
      19. Global $farbebackup
      20. GUICreate("Pipette", 615, 219)
      21. GUICtrlCreateGroup("", 8, 8, 161, 201)
      22. $vorschau = GUICtrlCreateLabel("", 13, 20, 148, 148)
      23. GUICtrlSetBkColor(-1, 0x0)
      24. $start = GUICtrlCreateButton("Pipette aufnehmen", 16, 176, 147, 25)
      25. GUICtrlCreateGroup("", -99, -99, 1, 1)
      26. GUICtrlCreateGroup("Farbmodelle", 176, 16, 233, 193)
      27. GUICtrlCreateLabel("Hexadezimal (HEX):", 192, 40, 98, 17)
      28. $hex_input = GUICtrlCreateInput("#000000", 208, 57, 161, 21)
      29. $copy_hex = GUICtrlCreateButton("", 376, 56, 21, 21, 0x0040)
      30. GUICtrlSetImage(-1, $copyJPG, -1)
      31. GUICtrlCreateLabel("RGB-Farbraum (RGB):", 192, 88, 109, 17)
      32. #region ### Start 2x3 = 6 Inputs erstellen ###
      33. Global $RGB[3], $Proz[3] ;i 2x3 = 6 Inputs erstellen
      34. For $i = 0 To 2
      35. $RGB[$i] = GUICtrlCreateInput("0", 208 + $i * 56, 104, 49, 21)
      36. $Proz[$i] = GUICtrlCreateInput("0", 208 + $i * 56, 152, 49, 21)
      37. Next
      38. #endregion ### Start 2x3 = 6 Inputs erstellen ###
      39. $copy_rbg = GUICtrlCreateButton("", 376, 104, 21, 21, 0x0040)
      40. GUICtrlSetImage(-1, $copyJPG, -1)
      41. GUICtrlCreateLabel("Prozentualer RGB-Farbraum (RBG %):", 192, 136, 182, 17)
      42. $copy_proz = GUICtrlCreateButton("", 376, 152, 21, 21, 0x0040)
      43. GUICtrlSetImage(-1, $copyJPG, -1)
      44. GUICtrlCreateGroup("", -99, -99, 1, 1)
      45. GUICtrlCreateGroup("Verlauf", 416, 16, 153, 193)
      46. $verlauf = GUICtrlCreateList("", 424, 32, 137, 162)
      47. GUICtrlCreateGroup("", -99, -99, 1, 1)
      48. GUISetState(@SW_SHOW)
      49. While 1
      50. $nMsg = GUIGetMsg()
      51. Switch $nMsg
      52. Case -3
      53. FileDelete($PipetteTXT)
      54. FileDelete($copyJPG) ;i Das Bild auch löschen!
      55. Exit
      56. Case $copy_hex
      57. ClipPut($farbehtml)
      58. Case $copy_rbg
      59. ClipPut($R & ", " & $B & ", " & $G)
      60. Case $copy_proz
      61. ClipPut(Round($R / 255 * 100, 1) & ", " & Round($B / 255 * 100, 1) & ", " & Round($G / 255 * 100, 1))
      62. Case $start
      63. HotKeySet("{Enter}", "_Mark")
      64. GUICtrlSetState($start, 128)
      65. GUICtrlSetData($start, "Zum Ablegen Enter drücken")
      66. $on = True
      67. Case $verlauf
      68. GUICtrlSetData($hex_input, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexHTML", "Error"))
      69. GUICtrlSetBkColor($vorschau, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexVorschau", "Error"))
      70. GUICtrlSetData($RGB[0], IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error"))
      71. GUICtrlSetData($RGB[1], IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error"))
      72. GUICtrlSetData($RGB[2], IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error"))
      73. GUICtrlSetData($Proz[0], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error") / 255 * 100, 1))
      74. GUICtrlSetData($Proz[1], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error") / 255 * 100, 1))
      75. GUICtrlSetData($Proz[2], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error") / 255 * 100, 1))
      76. EndSwitch
      77. If $on = True Then
      78. $farbe = PixelGetColor(MouseGetPos(0), MouseGetPos(1))
      79. If $farbebackup <> $farbe Then
      80. $farbehex = Hex($farbe)
      81. $farbehex = StringTrimLeft($farbehex, 2)
      82. $farbehtml = "#" & $farbehex
      83. $farbedarstellung = "0x" & $farbehex
      84. GUICtrlSetBkColor($vorschau, $farbedarstellung)
      85. $HR = StringMid($farbehex, 1, 2)
      86. $HG = StringMid($farbehex, 3, 2)
      87. $HB = StringMid($farbehex, 5, 2)
      88. $R = Dec($HR)
      89. $G = Dec($HG)
      90. $B = Dec($HB)
      91. GUICtrlSetData($hex_input, $farbehtml)
      92. GUICtrlSetData($RGB[0], $R)
      93. GUICtrlSetData($RGB[1], $G)
      94. GUICtrlSetData($RGB[2], $B)
      95. GUICtrlSetData($Proz[0], Round($R / 255 * 100, 1))
      96. GUICtrlSetData($Proz[1], Round($G / 255 * 100, 1))
      97. GUICtrlSetData($Proz[2], Round($B / 255 * 100, 1))
      98. EndIf
      99. $farbebackup = $farbe
      100. EndIf
      101. Sleep(25)
      102. WEnd
      103. Func _Mark()
      104. $on = False
      105. HotKeySet("{Enter}")
      106. GUICtrlSetState($start, 64)
      107. GUICtrlSetData($start, "Pipette aufnehmen")
      108. GUICtrlSetData($verlauf, $R & " " & $G & " " & $B)
      109. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexHTML", $farbehtml)
      110. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexVorschau", $farbedarstellung)
      111. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "R", $R)
      112. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "G", $G)
      113. IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "B", $B)
      114. EndFunc ;==>_Mark

      ;)

      Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „RR04“ ()

    autoit.de Webutation