GDI+, Kleiner Farbverlauf

Snake Plissken

Hallo Leute,

ich beschäftige mich gerade mit GDI+ und versuche einen kleinen blauen Farbverlauf mit PenSetColor und GraphicsDrawLine zu zeichnen. Mann nannte das früher mal eine CopperBar.

Leider bekomme ich nur einen schwarzen Balken der zwar genau so breit ist wie ich möchte aber eben nur schwarz.

Ich habe das und viele anderes graphisches Zeug schon in anderen Sprachen geproggt und dachte ich code das mal schnell nach zum lernen eben, aber es klappt nicht und ich suche schon seit Stunden den Fehler!

So sollte es aussehen (Bild_1):

http://picload.org/view/daoodgia/copper_1.png.html

Aber so sieht es aus (Bild_2):

http://picload.org/view/daoodddl/copper_2.png.html

Die Sinuswerte aus Bild_1 lasse ich mir zur Kontrolle in eine Textdatei schreiben und in AutoIT nicht auf das Fenster ausgeben (weiß nicht wie).

Hier mein Code:

C

#Include<GDIPlus.au3>
#include <FileConstants.au3>
#include <WinAPIFiles.au3>
#include <MsgBoxConstants.au3>
        

$hGUI = GUICreate("Einfacher Copper", 500, 500)
GUISetState(@SW_SHOW)

Global $sinColor[360]
Dim $Werte[100]
Global $color, $red = 0, $green = 0, $blue = 0
Global $i, $j, $k, $sinWert

$datei = FileOpen("TEST.txt", 1)
    
    $k = 0
    For $i = 0 to 360
        $sinWert = sin($i)*250
        $sinColor[$k] = $sinWert
;~     FileWriteLine($datei, $sinColor[$k] & @CRLF)
        $k += $k
    Next
    

_GDIPlus_Startup()  

    $Graphics =    _GDIPlus_GraphicsCreateFromHWND($hGUI)
    Local $hPen = _GDIPlus_PenCreate(0,1)
    
    $k = 0
    For $j = 0 to 180 Step 5 
        
        $color =("0xCF" & Hex($red, 2) & Hex($green, 2) & Hex($blue + $sinColor[$j], 2))
        _GDIPlus_PenSetColor($hPen, $color)
        _GDIPlus_GraphicsDrawLine($Graphics, 0, 50 + $k, 500, 50 + $k, $hPen)
;~         FileWriteLine($datei, $sinColor[$k] & @CRLF)
        $k += 1
        
    Next



_GDIPlus_Shutdown()
Sleep(3000)
FileClose($datei)

Alles anzeigen

Wäre klasse wenn Ihr mir da helfen könntet. Bin halt noch relativ neu bei AutoIT und ein Bloody Noob bei GDI+!

Vielen Dank vorab für Eure Mühe.

Grüße,

Snake

**UEZ**

Probiere es mal damit:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    _GDIPlus_Startup() ;initialize GDI+
    Local Const $iWidth = 600, $iHeight = 100, $iBgColor = 0x303030 ;$iBgColor format RRGGBB

    Local $hGUI = GUICreate("GDI+ Example (" & @ScriptName & ")", $iWidth, $iHeight) ;create a test GUI
    GUISetBkColor($iBgColor, $hGUI) ;set GUI background color
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ;create a graphics object from a window handle
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;sets the graphics object rendering quality (antialiasing)
    Local $hBrush = _GDIPlus_LineBrushCreate($iWidth / 2, 0, $iWidth / 2, $iHeight / 2, 0xFF0000FF, 0xFFFFFFFF, 3) ;create linear gradient brush

    _GDIPlus_GraphicsFillRect($hGraphics, 0, 0, $iWidth, $iHeight, $hBrush)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ;cleanup GDI+ resources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

Snake Plissken

Hi,

vielen Dank für Deine schnelle Antwort UEZ.

Du arbeitest mit einem Brush und ich mit PenSetColor. Das müsste doch auck klappen.

Ich denke es liegt daran dass ich das SinusArray falsch mit den Werten befülle.

Die Sinusfunktion von AutoIT wirft bei sin(1) 0.841470984807897 und der Taschenrechner 0,017452 raus. Nur bei sin(0) sind beide gleich????

Aber was mache ich da falsch????

Grüße,

Plissken

**alpines**

Zitat von Snake Plissken

Die Sinusfunktion von AutoIT wirft bei sin(1) 0.841470984807897 und der Taschenrechner 0,017452 raus. Nur bei sin(0) sind beide gleich????

Das liegt daran, dass AutoIt in Radianten rechnet und dein Taschenrechner auf Grad eingestellt ist.

Allgemeint gilt: sin(1 Radiant) = sin (1 Grad * pi/180)

Snake Plissken

Danke alpines das sieht schon deutlich besser aus, wenn auch noch nicht perfekt!

Werd auf jeden Fall weiter dran basteln.

C

#Include<GDIPlus.au3>
#include <FileConstants.au3>
#include <WinAPIFiles.au3>


$hGUI = GUICreate("Einfacher Copper", 500, 500)
GUISetState(@SW_SHOW)

$datei = FileOpen("TEST.txt", 1)

Dim $Werte[100]
Global $color, $red = 0, $green = 0, $blue = 0
Global $sinColor[360]
Global $i, $j, $k, $sinWert
Const $Pi = 3.1415926535897932384626433832795

    $k = 0
    For $i = 0 to 359
        $sinWert = sin($i*$Pi/180)
        $sinColor[$k] = $sinWert
    FileWriteLine($datei, $sinColor[$k] & @CRLF)
        $k += 1
    Next
    

_GDIPlus_Startup()  

    $Graphics =    _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0,1)
    $i = 0   
    $k = 0
    For $j = 0 to 180 Step 5
        
        $color =("0xFF" & Hex($red, 2) & Hex($green, 2) & Hex($blue + $sinColor[$j], 2))
        _GDIPlus_PenSetColor($hPen, $color)
        _GDIPlus_GraphicsDrawLine($Graphics, 0, 50 + $k, 500, 50 + $k, $hPen)
;~         FileWriteLine($datei, $sinColor[$j] & @CRLF)
        $k += 1
        
    Next

_GDIPlus_Shutdown()
Sleep(3000)
FileClose($datei)

Alles anzeigen

Grüße,

Plissken

Snake Plissken

Das ist Stand der Dinge !

http://picload.org/view/daooalwl/copper_4.png.html

Grüße,

Plissken

**Oscar**

Du musst das auch auf die möglichen Blauwerte (0...255) umrechnen:

AutoIt

#include <Array.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Global Const $Pi = 3.141592653589793
Global Const $fDegToRad = $PI / 180
Global $iARGB, $aSinColor[360]

Global $hGui = GUICreate("Einfacher Copper", 500, 500)
GUISetState(@SW_SHOW)
For $i = 0 To 359
    $aSinColor[$i] = Int(255 * Sin($i * $fDegToRad))
Next
;~ _ArrayDisplay($aSinColor)
_GDIPlus_Startup()
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
$hPen = _GDIPlus_PenCreate(0xFF000000, 1)
$k = 0
For $j = 0 To 180 Step 5
    $iARGB = "0xFF0000" & Hex($aSinColor[$j], 2)
    _GDIPlus_PenSetColor($hPen, $iARGB)
    _GDIPlus_GraphicsDrawLine($hGraphics, 0, 50 + $k, 500, 50 + $k, $hPen)
    $k += 1
Next
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()

Alles anzeigen

Snake Plissken

Oscar

Ja hast natürlich Recht!!!!

Jetzt klappt alles!

Aber eine Frage hab ich noch, muss es bei Deiner Variablen Deklaration nicht heißen RadToDeg, da wir doch Radianten in Grad umrechnen?

Viele Grüße,

Plissken

**Oscar**

Zitat von Snake Plissken

muss es bei Deiner Variablen Deklaration nicht heißen RadToDeg, da wir doch Radianten in Grad umrechnen?

Nein, wir rechnen mit Grad/Deg (For-Schleife: 0...360). Der Sin-Befehl erwartet den Wert aber in Radian/Rad, deswegen ist DegToRad schon richtig.

Edit: Wenn Du gerade anfängst Dich mit GDI+ zu beschäftigen, dann solltest Du auch gleich lernen, wie man einen Backbuffer verwendet. Das hat nämlich den Vorteil, dass man die Grafik schnell wieder neuzeichnen kann (beim Restore oder WM_PAINT).

Außerdem sieht man es nicht, wenn Dein Programm die Grafiken, Linien, Punkte etc. zeichnet, sondern es wird erst die fertige Grafik auf das Fenster gezeichnet:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

_GDIPlus_Startup()
Global Const $Pi = 3.141592653589793
Global Const $fDegToRad = $PI / 180
Global $iARGB, $aSinColor[360]
Global $iW = 640, $iH = 160, $iX = 10, $iY = 50, $iLine = 0

For $iDeg = 0 To 359
    $aSinColor[$iDeg] = Int(255 * Sin($iDeg * $fDegToRad))
Next
;~ _ArrayDisplay($aSinColor)

Global $hGui = GUICreate("Einfacher Copper", $iW, $iH)
GUISetBkColor(0x000000)
Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui) ; Graphic vom Fenster erstellen
Global $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics) ; Backbuffer erstellen
Global $hGfxCtx = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; Graphic vom Backbuffer
Global $hPen = _GDIPlus_PenCreate(0xFF000000, 1)
For $i = 0 To 180 Step 5
    $iARGB = "0xFF0000" & Hex($aSinColor[$i], 2)
    _GDIPlus_PenSetColor($hPen, $iARGB)
    _GDIPlus_GraphicsDrawLine($hGfxCtx, $iX, $iY + $iLine, $iW - $iX, $iY + $iLine, $hPen) ; wir zeichnen in den Backbuffer
    $iLine += 1
Next
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_PAINT, '_WM_PAINT')
_GDIPlus_GraphicsDrawImage($hGraphics, $hBitmap, 0, 0) ; hier wird der Backbuffer auf die Graphic des Fensters gezeichnet

While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _GDIPlus_PenDispose($hPen)
            _GDIPlus_GraphicsDispose($hGfxCtx)
            _GDIPlus_BitmapDispose($hBitmap)
            _GDIPlus_GraphicsDispose($hGraphics)
            _GDIPlus_Shutdown()
            Exit
        Case $GUI_EVENT_RESTORE
            _GDIPlus_GraphicsDrawImage($hGraphics, $hBitmap, 0, 0) ; beim Restore muss der Backbuffer auch wieder auf das Fenster gezeichnet werden
    EndSwitch
WEnd

Func _WM_PAINT($hWnd, $iMsg, $wParam, $lParam) ; wenn das Fenster neu gezeichnet werden muss (z.B. weil das Fenster ausserhalb des Desktopbereichs war)
    #forceref $hWnd, $iMsg, $wParam, $lParam
    _GDIPlus_GraphicsDrawImage($hGraphics, $hBitmap, 0, 0) ; den Backbuffer neu zeichnen
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Snake Plissken

Oscar

VielenDank Oscar, Ihr seid die beste und netteste Community die ich jemals kennengelernt habe!

Kennst Du ein gutes Buch zum Thema GDI+ oder einige gute Tutorials?

Muss nicht unbedingt AutoIT sein, C++ C# etc. oder sonstwas geht auch!

Vielend Dank nochmal und Grüße,

Plissken

**chesstiger**

Eine klitzekleine Kleinigkeit hab ich zu meckern.

Code

$iARGB = "0xFF0000" & Hex($aSinColor[$i], 2)

Das ist nicht so schön. Man wandelt zuerst einen Ganzzahl-Wert in einen String (genauer: in die Hexadezimaldarstellung) um, dann konkateniert man "0xFF0000" mit diesem String, nur um dann letztendlich wieder einen Cast zu einem Integer beim Aufruf von PenSetColor durchzuführen. Das ist volles Ausnutzen des Variant-Types, kostet aber wirklich einiges an Laufzeit, relativ gesehen. Dabei tut es auch eine simple Addition:

Code

$iARGB = 0xff000000 + $aSinColor[$i]

Das ist jetzt ungetestet, sollte aber auch funktionieren. Und ist nicht so Durch-Die-Brust-Ins-Auge-Mäßig.

Snake Plissken

Hi Chesstiger,

die Tutorials in Deiner Signatur klingen sehr gut. Ich weiß dass nach dem Forenumzug alle Links ins Nirvana zeigen und man mit einem HTML Sniffer die Inhalte dieser Links doch noch finden kann. Da ich aber von HTML Sniffern keine Ahnung habe wollte ich Dich bitten ob Du nicht funktionierende Links zu diesen Tutorials (Sauber Programmieren, GDI+ Rundumschlag) posten könntest!?

Vielen Dank und viele Grüße,

Plissken

Snake Plissken

Habe beide Tutorials gefunden!

GDI+ Rundumschlag:

https://autoit.de/index.php?thread/82986-rundumschlag-gdi/

Sauber Programmieren:

Grüße,

Plissken

https://autoit.de/index.php?thre…ieren/&pageNo=1

**chesstiger**

Ja, die Links aktualisiere ich dann auch mal... *hust*

Beide Tutorials bedarfen sowieso mal einer Anpassung und Überarbeitung, fürchte ich. Allein schon die ganzen zerhauenen Code-Schnipsel. Aber als Orientierung sollte es gehen.

Eine Anmerkung noch zum Thema: Statt Pi als Literal anzugeben, kann man es auch einfach berechnen, z.B. mit 4 * ATan(1).

Snake Plissken

chesstiger

Optimierungen sind nie verkehrt aber Deine Tutorials sind sehr, sehr gut.

Ich mache grad Dein GDI+ Rundschlag Tutorial und finde es einfach seeehhhr gut da es jedes wichtige Thema behandelt!

Ein Tipp bzw. Wunsch, wenn Du Regions z.B. Fenster mit Löchern und Buttons in ungewöhnlichen Formen einbauen könntest wäre das echt Klasse und Dein GDI+ Tutorial einzigartig und unschlagbar!

Beispiellink:

http://www.codeproject.com/Articles/254/The-RGN-Generator

Vielen Dank vorab und viele Grüße,

Plissken