Powershell Cmdlet Get-Service "Windows Defender Antivirus Service"

co_steffl

Hallo zusammen,

hatte gestern schon mal ähnliche Frage gestellt. (ShellExecute)

alpines hat mir hier geholfen. Danke nochmal

Jetzt habe ich immer noch das Problem das PS Cmdlet "Windows Defender Antivirus Service" zu verarbeiten.

Ich habe Google zur Hilfe gezogen finde ab nicht so das passende. Mit ShellExecute bekomme ich das auch nicht hin.

Sehe immer nur das .ps1 Script gestartet werden.

Würde mich freuen wenn ich hier einen Tipp bekommen würde. Evtl auch Hinweis wo oder ob es darüber eine Tut gibt.

co_steffl

**Bitnugger**

Meine fragt: Wo ist dein Script?

https://technet.microsoft.com/de-de/library/…v=wps.630).aspx

**autoiter**

Hallo co_steffl

Das kannst du mit Run lösen. Ich habe es dir mal beispielhaft umgesetzt. Hier wird erst das cmdlet geschrieben, dann mit Run ausgeführt und die Ausgabe gelesen. Danach wird die cmdlet-Datei wieder gelöscht und es erfolgt die Rückgabe der Funktion. Die Rückgabe kannst du in der SciTE-Konsole lesen.

Code

ConsoleWrite(RunCmdlet() & @CRLF)

Func RunCmdlet()


    Local $sFilePath = @ScriptDir & '\cmdlet.ps1'
    Local $hOpen = FileOpen($sFilePath, 2)
    FileWrite($hOpen, 'Get-Service "Windows Defender Antivirus Service"')
    FileClose($hOpen)

    Local $sContent = ""
    Local $iPid = Run('PowerShell.exe -ExecutionPolicy Bypass -Command "' & $sFilePath & '"', @ScriptDir, @SW_HIDE, 2)
    While 1
        $sContent &= StdoutRead($iPid)
        If @error Then ExitLoop
    WEnd

    FileDelete($sFilePath)

    Return $sContent
EndFunc   ;==>RunCmdlet

Alles anzeigen

_mk_

So fragst Du den Dienststatus mit Hilfe der PowerShell ab. Alternative zum Get-Service CmdLet ist das Konsolenprogramm sc.exe.

pasted-from-clipboard.png

**Bitnugger**

Das geht auch ohne eine temporäre Datei anzulegen und auszuführen...

AutoIt

ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   RunCmdlet()" & RunCmdlet() & @CRLF & "!@ " & @TAB & "#Error: " & @error & @CRLF)

Func RunCmdlet()
    Local $iPid = Run("PowerShell.exe -Command Get-Service 'Windows Defender Antivirus Service'", @ScriptDir, @SW_HIDE, 2)
    If Not $iPid Then Return SetError(1, 0, False)
    ProcessWaitClose($iPid)
    Return StringStripWS(StdoutRead($iPid), 2)
EndFunc   ;==>RunCmdlet

**autoiter**

Hahaha, ich bin so doof.

_mk_

Damit Du Dir die Zeichenkettenoperationen ersparst, würde ich direkt auf die Eigenschaft Status zugreifen.

co_steffl

Moin zusammen,

danke an alle für die Hilfe

Bitnugger Der Script ist erst ein Gerüst, steht noch nicht viel drin. Danke für deinen Script/Beispiel und Link. Mach mich gleich an die Arbeit.

_mk_ Danke auch für den Tipp. An SC.exe hab ich nicht gedacht. Werde auch dies ausprobieren...

autoiter Danke auch an dich. Ich denke nicht das du doof bist.... Viele Wege führen nach Rom

co_steffl

Hallo

so ich muß nochmal nerven und mir einen Tipp von den Profis erhoffen

Hier mal der Code von Bitnugger.

Code

Global $s_ServWDAS = "Windows Defender Antivirus Service"

_RunCmdlet($s_ServWDAS)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : _RunCmdlet($s_ServWDAS) = ' & _RunCmdlet($s_ServWDAS) & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console



Func _RunCmdlet($s_Service)
    Local $TmpCmd = "Get-Service & $s_Service"
    Local $iPid = Run("PowerShell.exe -Command $TmpCmd", @ScriptDir, @SW_HIDE, 2)
    If Not $iPid Then Return SetError(1, 0, False)
        ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : SetError(1, 0, False) = ' & SetError(1, 0, False) & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    ProcessWaitClose($iPid)
    $sRead = StringStripWS(StdoutRead($iPid), 2)
    Return StringStripWS(StdoutRead($iPid), 2)
EndFunc   ;==>RunCmdlet

Alles anzeigen

Hintergrund:

Ich möchte als erstes wissen ob es diesen Dienst überhaupt existiert.

Danach möchte ich den Status abfragen (Kommt später)

Ich habe nun das Problem, das es in diesem Fall den Dienst nicht gibt.

StdoutRead liefert mir nun keine Daten.

Die Konsole liefert mir dies.

Code

@@ Debug(13) : SetError(1, 0, False) = False
>Error code: 1
@@ Debug(13) : SetError(1, 0, False) = False
>Error code: 1
@@ Debug(5) : _RunCmdlet($s_ServWDAS) = 
>Error code: 0
+>09:58:40 AutoIt3.exe ended.rc:0
+>09:58:40 AutoIt3Wrapper Finished.
>Exit code: 0    Time: 1.929

Wie frage ich dies jetzt am besten ab. Abfrage nach StdoutRead nach "" Leerzeichen möchte ich nicht so gerne.

Die Console/Run liefert mir ja "Error Code: 1"

Ich könnte notfalls damit leben. Aber gibt es da noch eine elegantere Lösung?

**Bitnugger**

Zitat von co_steffl

Hier mal der Code von Bitnugger.

Schreibe demnächst bitte dabei, dass du den Code geändert hast.

Zitat von co_steffl

StdoutRead liefert mir nun keine Daten.

In dem Fall liest du dann einfach StderrRead aus... hier ein Beispiel nach der Art, wie es _mk_ vorgeschlagen hat.

AutoIt

;-- TIME_STAMP   2018-07-20 15:49:22   v 0.1

Local $sCommand = "(Get-Service -Name gamingxxl).Status"
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sCommand = "' & $sCommand & '"'& @CRLF & _
    _RunPSCommand($sCommand) & @CRLF & "!@ " & @TAB & "#Error: " & @error & @CRLF & @CRLF)

$sCommand = "(Get-Service -Name windefend).Status"
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sCommand = "' & $sCommand & '"' & @CRLF & _
    _RunPSCommand($sCommand) & @CRLF & "!@ " & @TAB & "#Error: " & @error & @CRLF & @CRLF)

Func _RunPSCommand($sCommand)
    Local $iPID = Run("PowerShell.exe -Command " & $sCommand, @ScriptDir, @SW_HIDE, 6) ; 6 = BitOR($STDERR_CHILD, $STDOUT_CHILD)
    If Not $iPID Then Return SetError(1, 0, False)
    ProcessWaitClose($iPID)
    Local $sStderrOutput = StringStripWS(StderrRead($iPID), 2)
    Local $sStdOutput = StringStripWS(StdoutRead($iPID), 2)
    Return SetError($sStderrOutput ? 1 : 0, 0, $sStderrOutput ? $sStderrOutput : $sStdOutput)
EndFunc   ;==>_RunPSCommand

Alles anzeigen

co_steffl

Hallo zusammen,

sorry sorry sorry... nach 6 Std. an der Glotze wird man Betriebsblind.

Code

falscher Code

Local $iPid = Run("PowerShell.exe -Command & $TmpCmd", @ScriptDir, @SW_HIDE, 6)


richtiger Code

Local $iPid = Run("PowerShell.exe -Command " & $TmpCmd, @ScriptDir, @SW_HIDE, 6)

Trotzdem Danke für die Unterstützung.

**alpines**

Zitat von co_steffl

sorry sorry sorry... nach 6 Std. an der Glotze wird man Betriebsblind.

Lass dir immer Testweise deine Pfade in der Konsole ausgeben, dann findest du deine Fehler sofort.