_GUICtrlListView_GetItemImage
Beschreibung anzeigen in
Ermittelt den Index des Icons eines (ListView-)Items
#include <GuiListView.au3>
_GUICtrlListView_GetItemImage ( $hWnd, $iIndex [, $iSubItem = 0] )
Parameter
| $hWnd | Control-ID / Handle des Controls |
| $iIndex | 0-basierender Index des Items |
| $iSubItem | [optional] 1-basierender Index des Subitems |
Rückgabewert
| Erfolg: | 0-basierender Index des Icons des Items |
| Fehler: | -1 |
Bemerkungen
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
Local $iStylesEx = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
GUICreate("ListView: Setzt und ermittelt das Itembild (v" & @AutoItVersion & ")", 500, 300)
Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
_GUICtrlListView_SetExtendedListViewStyle($idListview, $iStylesEx)
GUISetState(@SW_SHOW)
; Setzt das ANSI Format
;~ _GUICtrlListView_SetUnicodeFormat($idListview, False)
; Lädt die Bilder
Local $hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($idListview, $hImage, 1)
; Fügt die Spalten hinzu
_GUICtrlListView_AddColumn($idListview, "Spalte 0", 120)
_GUICtrlListView_AddColumn($idListview, "Spalte 1", 120)
_GUICtrlListView_AddColumn($idListview, "Spalte 2", 120)
; Fügt die Items hinzu
_GUICtrlListView_AddItem($idListview, "Zeile 0: Spalte 0", 0)
_GUICtrlListView_AddSubItem($idListview, 0, "Zeile 0: Spalte 1", 1, 1)
_GUICtrlListView_AddSubItem($idListview, 0, "Zeile 0: Spalte 2", 2, 2)
_GUICtrlListView_AddItem($idListview, "Zeile 1: Spalte 0", 1)
_GUICtrlListView_AddSubItem($idListview, 1, "Zeile 1: Spalte 1", 1, 2)
_GUICtrlListView_AddItem($idListview, "Zeile 2: Spalte 0", 2)
; Setzt das Bild vom Item 1, Subitem 1
_GUICtrlListView_SetItemImage($idListview, 1, 1, 1)
MsgBox($MB_SYSTEMMODAL, "Information", "Bild vom Item 1, Subitem 1: " & _GUICtrlListView_GetItemImage($idListview, 1, 1))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example