Funktionreferenz


_GUICtrlListView_SetItemGroupID

Beschreibung anzeigen in

Setzt die Gruppe-ID eines Items

#include <GuiListView.au3>
_GUICtrlListView_SetItemGroupID ( $hWnd, $iIndex, $iGroupID )

Parameter

$hWnd Control-ID / Handle des Controls
$iIndex 0-basierender Index des Items
$iGroupID Gruppen-ID

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListView_GetItemGroupID, _GUICtrlListView_InsertGroup

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView: Setzt und ermittelt die Item-Gruppen-ID (v" & @AutoItVersion & ")", 500, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Lädt die Bilder
    Local $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListview, "Spalte 0", 120)
    _GUICtrlListView_AddColumn($idListview, "Spalte 1", 120)
    _GUICtrlListView_AddColumn($idListview, "Spalte 2", 120)

    ; Fügt die Items hinzu
    _GUICtrlListView_AddItem($idListview, "Zeile 0: Spalte 0", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Zeile 0: Spalte 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Zeile 0: Spalte 2", 2)
    _GUICtrlListView_AddItem($idListview, "Zeile 1: Spalte 0", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Zeile 1: Spalte 1", 1)
    _GUICtrlListView_AddItem($idListview, "Zeile 2: Spalte 0", 2)

    ; Gruppen erzeugen
    _GUICtrlListView_EnableGroupView($idListview)
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "Gruppe 1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "Gruppe 2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    ; Zeigt die Item 3 Gruppen-ID
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 3 Gruppe-ID: " & _GUICtrlListView_GetItemGroupID($idListview, 2))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example