Fügt eine Gruppe hinzu
#include <GuiListView.au3>
_GUICtrlListView_InsertGroup ( $hWnd, $iIndex, $iGroupID, $sHeader [, $iAlign = 0] )
$hWnd | Control-ID / Handle des Controls |
$iIndex | Index wo die Gruppe hinzugefügt werden soll. Falls dies -1 ist, wird die Gruppe an das Ende der Liste hinzugefügt. |
$iGroupID | ID der Gruppe |
$sHeader | Überschrift |
$iAlign | [optional] Ausrichtung der Überschrift für die Gruppe: 0 - links 1 - mittig 2 - rechts |
Erfolg: | der Index des Items, welchem die Gruppe hinzugefügt wurde |
Fehler: | -1 |
Eine Gruppe kann nicht in ein leeres Control eingefügt werden.
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlListView_SetItemGroupID
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
Example()
Func Example()
GUICreate("ListView: Gruppe einfügen (v" & @AutoItVersion & ")", 400, 300)
Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
; Aktiviert die erweiterten Control Stile
_GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUISetState(@SW_SHOW)
; Setzt das ANSI Format
;~ _GUICtrlListView_SetUnicodeFormat($idListview, False)
; Lädt die Bilder
Local $hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($idListview, $hImage, 1)
; Fügt die Spalten hinzu
_GUICtrlListView_AddColumn($idListview, "Spalte 1", 120)
_GUICtrlListView_AddColumn($idListview, "Spalte 2", 120)
_GUICtrlListView_AddColumn($idListview, "Spalte 3", 120)
; Fügt die Items hinzu
_GUICtrlListView_AddItem($idListview, "Zeile 1: Spalte 1", 0)
_GUICtrlListView_AddSubItem($idListview, 0, "Zeile 1: Spalte 2", 1, 1)
_GUICtrlListView_AddSubItem($idListview, 0, "Zeile 1: Spalte 3", 2, 2)
_GUICtrlListView_AddItem($idListview, "Zeile 2: Spalte 1", 1)
_GUICtrlListView_AddSubItem($idListview, 1, "Zeile 2: Spalte 2", 1, 2)
_GUICtrlListView_AddItem($idListview, "Zeile 3: Spalte 1", 2)
; Gruppen erstellen
_GUICtrlListView_EnableGroupView($idListview)
_GUICtrlListView_InsertGroup($idListview, -1, 1, "Gruppe 1")
_GUICtrlListView_InsertGroup($idListview, -1, 2, "Gruppe 2")
_GUICtrlListView_SetItemGroupID($idListview, 0, 1)
_GUICtrlListView_SetItemGroupID($idListview, 1, 2)
_GUICtrlListView_SetItemGroupID($idListview, 2, 2)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example