Funktionreferenz

_GUICtrlRebar_BeginDrag

Beschreibung anzeigen in

Startet eine drag-and-drop Aktion im Rebar-Control. Diese Nachricht führt nicht dazu, dass eine $RBN_ENDDRAG gesendet wird

#include <GuiRebar.au3>
_GUICtrlRebar_BeginDrag ( $hWnd, $iIndex [, $iPos = -1] )

Parameter

$hWnd Handle des Rebar-Controls
$iIndex 0-basierender Index der Gruppe den die drag-and-drop Aktion betrifft
$iPos [optional] DWORD Wert der die neuen Mauskoordinaten enthält.
Die horizontale Koordinate ist in LOWORD enthalten und die vertikale Koordinate ist in HIWORD enthalten.
Falls (DWORD)-1 verwendet wird, wird das Rebar-Control die Position der Maus verwenden, die beim letzten Aufruf von GetMessage oder PeekMessage aktuell war.

Rückgabewert

Keine.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlRebar_DragMove, _GUICtrlRebar_EndDrag

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $idBtnExit, $hReBar, $hToolbar, $idInput, $idBtnBeginDrag
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    $hGui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Erstellt ein Rebar-Control
    $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; Erstellt eine Toolbar in der Rebar
    $hToolbar = _GUICtrlToolbar_Create($hGui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Erstellt eine Inputbox in der Rebar
    $idInput = GUICtrlCreateInput("Input-Control", 0, 0, 120, 20)

    ; Fügt eine Gruppe mit dem Control hinzu
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:")

    ; Fügt eine Gruppe mit dem Control am Anfang der Rebar hinzu
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)


    $idBtnBeginDrag = GUICtrlCreateButton("Beginnt die Drag Aktion", 150, 330, 100, 25)
    $idBtnExit = GUICtrlCreateButton("Beenden", 150, 360, 100, 25)
    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idBtnExit
                Exit
            Case $idBtnBeginDrag
                _GUICtrlRebar_BeginDrag($hReBar, 0)
                _GUICtrlRebar_DragMove($hReBar)
                _GUICtrlRebar_EndDrag($hReBar)
        EndSwitch
    WEnd
EndFunc   ;==>Example