Funktionreferenz

_GUICtrlRebar_GetBandBorders

Beschreibung anzeigen in

Ermittelt die Ränder einer Gruppe

#include <GuiRebar.au3>
_GUICtrlRebar_GetBandBorders ( $hWnd, $iIndex )

Parameter

$hWnd Handle des Rebar-Controls
$iIndex 0-basierender Index der Gruppe, für den die Ränder ermittelt werden sollen

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - X Koordinate der oberen linken Ecke des Rechtecks
    [1] - Y Koordinate der oberen linken Ecke des Rechtecks
    [2] - X Koordinate der unteren rechten Ecke des Rechtecks
    [3] - Y Koordinate der unteren rechten Ecke des Rechtecks

Bemerkungen

Das Ergebnis dieser Nachricht kann für das Berechnen der nutzbaren Fläche in einer Gruppe verwendet werden.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlRebar_GetBandBordersEx, _GUICtrlRebar_GetBandRect, _GUICtrlRebar_GetBandRectEx

Beispiel

#include "Extras\HelpFileInternals.au3"

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsStylesConstants.au3>

Global $_g_idLst_Memo

Example()

Func Example()
    Local $hGui, $idBtn_Exit, $hReBar, $hToolbar, $idInput, $aBorders
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

    $hGui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Erstellt ein Rebar-Control
    $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    _MemoCreate(2, 100, 396, 250, $WS_VSCROLL)

    ; Erstellt eine Toolbar in der Rebar
    $hToolbar = _GUICtrlToolbar_Create($hGui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

    ; Erstellt eine Inputbox in der Rebar
    $idInput = GUICtrlCreateInput("Input-Control", 0, 0, 120, 20)

    ; Fügt eine Gruppe mit dem Control hinzu
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:")

    ; Fügt eine Gruppe mit dem Control am Anfang der Rebar hinzu
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    _GUICtrlRebar_SetBandBackColor($hReBar, 1, Int(0x00008B))
    _GUICtrlRebar_SetBandForeColor($hReBar, 1, Int(0xFFFFFF))

    For $x = 0 To _GUICtrlRebar_GetBandCount($hReBar) - 1
        $aBorders = _GUICtrlRebar_GetBandBorders($hReBar, $x)
        _MemoWrite("Gruppenindex " & $x)
        _MemoWrite("==== Ränder der Gruppe ====")
        _MemoWrite("Links..: " & $aBorders[0])
        _MemoWrite("Oben...: " & $aBorders[1])
        _MemoWrite("Rechts.: " & $aBorders[2])
        _MemoWrite("Unten..: " & $aBorders[3])
        _MemoWrite("======================")
        $aBorders = _GUICtrlRebar_GetBandRect($hReBar, $x)
        _MemoWrite("====== Rechteck der Gruppe =====")
        _MemoWrite("Links..: " & $aBorders[0])
        _MemoWrite("Oben...: " & $aBorders[1])
        _MemoWrite("Rechts.: " & $aBorders[2])
        _MemoWrite("Unten..: " & $aBorders[3])
        _MemoWrite("======================")
    Next

    $idBtn_Exit = GUICtrlCreateButton("Beenden", 150, 360, 100, 25)
    GUICtrlSetState($idBtn_Exit, $GUI_DEFBUTTON)
    GUICtrlSetState($idBtn_Exit, $GUI_FOCUS)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idBtn_Exit
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example