Funktionreferenz

_GUICtrlRebar_GetBandChildSize

Beschreibung anzeigen in

Ermittelt die Größeneinstellungen des Child-Fensters

#include <GuiRebar.au3>
_GUICtrlRebar_GetBandChildSize ( $hWnd, $iIndex )

Parameter

$hWnd Handle des Rebar-Controls
$iIndex 0-basierender Index der Gruppe

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - Minimale Breite des Child-Fensters in Pixel.
    [1] - Minimale Höhe des Child-Fensters in Pixel.
    [2] - Ausgangshöhe der Gruppe in Pixel.
    [3] - Maximale Höhe der Gruppe in Pixel.
    [4] - Schrittwert in Pixel, durch den die Gruppe wachsen oder schrumpfen kann.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include "Extras\HelpFileInternals.au3"

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    Local $hGui, $idBtn_Exit, $hReBar, $hToolbar, $idInput, $aChildSize
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

    $hGui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Erstellt ein Rebar-Control
    $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    _MemoCreate(2, 100, 396, 250, $WS_VSCROLL)

    ; Erstellt eine Toolbar in der Rebar
    $hToolbar = _GUICtrlToolbar_Create($hGui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

    ; Erstellt eine Inputbox in der Rebar
    $idInput = GUICtrlCreateInput("Input-Control", 0, 0, 120, 20)

    ; Fügt eine Gruppe mit dem Control hinzu
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:")

    ; Fügt eine Gruppe mit dem Control am Anfang der Rebar hinzu
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    _GUICtrlRebar_SetBandBackColor($hReBar, 1, Int(0x00008B))
    _GUICtrlRebar_SetBandForeColor($hReBar, 1, Int(0xFFFFFF))

    For $x = 0 To _GUICtrlRebar_GetBandCount($hReBar) - 1
        $aChildSize = _GUICtrlRebar_GetBandChildSize($hReBar, $x)
        _MemoWrite("Gruppenindex " & $x)
        _MemoWrite("==== Child-Größe ======")
        _MemoWrite("cxMinChild: " & $aChildSize[0])
        _MemoWrite("cyMinChild: " & $aChildSize[1])
        _MemoWrite("cyChild...: " & $aChildSize[2])
        _MemoWrite("cyMaxChild: " & $aChildSize[3])
        _MemoWrite("cyIntegral: " & $aChildSize[4])
        _MemoWrite("======================")
    Next

    $idBtn_Exit = GUICtrlCreateButton("Beenden", 150, 360, 100, 25)
    GUICtrlSetState($idBtn_Exit, $GUI_DEFBUTTON)
    GUICtrlSetState($idBtn_Exit, $GUI_FOCUS)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idBtn_Exit
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example