Sucht nach einem Text mit dem Einfüge- oder Ankerpunkt der Selektion als Startpunkt
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_FindText ( $hWnd, $sText [, $bForward = True [, $bMatchCase = False [, $bWholeWord = False [, $iBehavior = 0]]]] )
$hWnd | Handle des Controls |
$sText | Zu suchender Text |
$bForward | [optional] Suchrichtung (Win 95: Sucht immer Vorwärts) |
$bMatchCase | [optional] Groß- Kleinschreibung wird beachtet Standard: Groß- Kleinschreibung wird nicht beachtet |
$bWholeWord | [optional] Sucht nur nach dem Text als ganzes Wort Standard: Teil eines Wortes |
$iBehavior | [optional] Jede BitOr Kombination von $FR_MATCHALEFHAMZA, $FR_MATCHDIAC and $FR_MATCHKASHIDA Standard: 0 |
Erfolg: | die Position vor dem ersten Buchstaben des übereinstimmenden Textes, sonst -1 |
Fehler: | Setzt das @error Flag auf ungleich null |
@error: | 101 - $hWnd ist kein Handle 102 - $sText = "" 103 - $bForward ist weder True noch False 104 - $bMatchCase ist weder True noch False 105 - $bWholeWord ist weder True noch False 1061 - $iBehavior ist keine gültige Zahl 1062 - $iBehavior ist ungültig |
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlRichEdit_FindTextInRange
Suche nach EM_FINDTEXT in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $hRichEdit, $iStep = 0
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Dies ist angehängter Text.")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetSel($hRichEdit, 8, 8)
Report("1.Setze Startposition ")
Case 2
Report('2."angehängt" gefunden an Zeichenposition ' & _
_GUICtrlRichEdit_FindText($hRichEdit, "angehängt"))
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report
#include <GuiRichEdit.au3>
Local $sText = "Erste Zeile" & @CR & @CR & "Letzt Zeile" & @CR
Local $iStart, $iEnd, $sLine, $i
Local $iTextLen
Local $iFindTextError, $iGetTextError
Local $sMsgBuff = ""
Local $hGUI = GUICreate("Text finden Test", 300, 300)
Local $hRichEdit = _GUICtrlRichEdit_Create($hGUI, "", 10, 10, 280, 280)
GUISetState(@SW_SHOW, $hGUI)
_GUICtrlRichEdit_SetText($hRichEdit, $sText)
$iStart = 0
$iTextLen = _GUICtrlRichEdit_GetTextLength($hRichEdit, True, True)
$sMsgBuff = $iTextLen & " Zeichen in Rich Edit Box"
For $i = 1 To 6
If Not _GUICtrlRichEdit_GotoCharPos($hRichEdit, $iStart) Then
;~ MsgBox(0, "", "False von GotoCharPos")
ExitLoop
EndIf
$iEnd = _GUICtrlRichEdit_FindText($hRichEdit, @CR) ; Findet die nächste CR
If $iEnd = -1 Then ExitLoop
$iFindTextError = @error
If $iEnd = $iStart Then
$sLine = "" ; end = Start bedeutet einfach eine Leerzeile
$iGetTextError = 0
Else
$sLine = _GUICtrlRichEdit_GetTextInRange($hRichEdit, $iStart, $iEnd) ; die Zeile besteht aus allen Zeichen zwischen Anfang und Ende
$iGetTextError = @error
EndIf
$sMsgBuff &= @CRLF & $i & ": Start = " & $iStart & ", Ende = " & $iEnd & ": <" & $sLine & "> (@errors = " & $iFindTextError & ", " & $iGetTextError & ")" ; Ergebnisse kumulieren
$iStart = $iEnd + 1 ; Die nächste Suche beginnt ein Zeichen nach dem zuletzt gefundenen CR
Next
MsgBox(0, "Test Ergebnisse", $sMsgBuff)
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete($hGUI)
Exit