Legt die Art der Absatznummerierung der markierten Absätze oder, wenn keine markiert sind, die der nach dem Einfügungspunkt eingefügten Absätze fest
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaNumbering ( $hWnd, $sStyle [, $iTextToNbrSpace = Default [, $bForceRoman = False]] )
$hWnd | Handle des Controls |
$sStyle | Ein String, der den Typ und die Startnummer definiert, z.B. "." (nur Punkte), "1)","(b)", "C.", "iv", "V)" Dies ist die Nummerierung, die für den ersten Absatz benutzt wird. Nachfolgende Leerzeichen geben die minimale Anzahl Leerzeichen zwischen der Nummerierung und dem Absatz an, es sei denn, $iTextToNbrSpace wird gesetzt. Spezialfälle: "=" - Dies ist ein nicht nummerierter Absatz innerhalb des vorangegangenen Listenelements "" - Entfernt die Nummerierung der ausgewählten Absätze |
$iTextToNbrSpace | [optional] Der Abstand zwischen der Zahl/Punkt und dem Absatz (in Leerzeichen-Einheiten) Voreinstellung: Anzahl der nachfolgenden Leerzeichen mal Punktgröße |
$bForceRoman | [optional] False - i, v, x ... in $sStyle sind die Buchstaben i, v, x ... (Voreinstellung) |
Erfolg: | True. |
Fehler: | False und setzt das @error Flag auf ungleich null. |
@error: | 101 - $hWnd ist kein Handle 103 - $iTextToNbrSpace ist keine positive Zahl 104 - $bForceRoman ist nicht True oder False |
Um die Leerzeichen-Einheit zu ändern (Standard: Inch), ist _GUICtrlRichEdit_SetSpaceUnit() zu benutzen.
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlRichEdit_GetParaNumbering, _GUICtrlRichEdit_SetSpaceUnit
Suche nach EM_SETPARAFORMAT in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg, $g_hRichEdit
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($g_hRichEdit, "Erster Absatz")
_GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 1)
Report("Absatz mit den Standard-Eigenschaften")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CR & "Zweiter Absatz")
_GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, ".")
Report("Füge einen zweiten Absatz hinzu")
Case 2
_GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
Report("Aussehen des ersten Absatzes in der Auswahl")
Case 3
_GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, "v) ", Default, True)
Report("Ändere die Einstellungen beider Absätze")
Case 4
_GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, "2. ", Default, True)
Report("Ändere die Einstellungen beider Absätze")
Case 5
; Streamt den Text in eine Datei auf dem Desktop, um dessen Eigenschaften in Word ansehen zu können.
_GUICtrlRichEdit_Deselect($g_hRichEdit)
_GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & " Die Rückgaben der Funktion " & @CR & _GUICtrlRichEdit_GetParaNumbering($g_hRichEdit)
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report