_GUICtrlRichEdit_StreamFromFile

Beschreibung anzeigen in

Setzt den Inhalt einer Datei als Text in einem Control

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamFromFile ( $hWnd, $sFileSpec [, $iFileEncoding = Default] )

Parameter

$hWnd	Handle des Controls
$sFileSpec	Dateipfad
$iFileEncoding	[optional] Dateicodierungsspezifikation (Siehe FileOpen () für weitere Informationen). Standard; $FO_READ.

Rückgabewert

Erfolg:	True.
Fehler:	False und setzt das @error Flag auf ungleich null.
@error:	101 - $hWnd ist kein Handle 1021 - Konnte die Datei nicht öffnen 1022 - Die Datei ist leer 700 - Zu viele Zeichen

Bemerkungen

Wenn Text markiert ist, wird die Auswahl ersetzt, ansonsten der gesamte Text.

Es ist _GUICtrlRichEdit_SetLimitOnText() zu benutzen um die Anzahl der Zeichen, die in ein Control sein können, zu ändern.

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach EM_STREAMIN in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Das ist ein Test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Erster Abschnitt")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetData($idLblMsg, "Gestreamt in Variable")
                    Case 2
                        _GUICtrlRichEdit_SetText($hRichEdit, "")
                        _GUICtrlRichEdit_StreamFromFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetData($idLblMsg, "Gestreamt aus Variable")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
                        _GUICtrlRichEdit_StreamFromFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetData($idLblMsg, "Einfügen an gewählter Position: Ein absichtliches Durcheinander!")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example